Notes

Disk info for Soft_Disk_Magazine_September_1992_Side_2.dsk:

File Name: riag_011_Soft_Disk_Magazine_September_1992_Side_2/Soft_Disk_Magazine_September_1992_Side_2.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 4608
Used Space (bytes): 138752
Physical Size (KB): 140
Free Space (KB): 4
Used Space (KB): 135
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 18
Used Sectors: 542
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for Soft_Disk_Magazine_September_1992_Side_2.dsk:

riag_011_Soft_Disk_Magazine_September_1992_Side_2/Soft_Disk_Magazine_September_1992_Side_2.dsk DISK VOLUME #254
A 008 HELLO
A 021 MENU
A 012 A.DUEL
A 023 SPACE.CHASER
T 002 SPACE CHASER HIGH SCORE
A 015 DIVE.BOMBER
A 040 UFO.II
A 015 ARTILLERY
A 009 JFK
B 004 MINIASSEMBLER
A 004 MEMORY.TEST
A 014 SALYER.HELLO
A 041 NFL.RANKER
T 002 NFL.MATCHUPS
T 002 NFL.DATA
* T 002 DATE
A 018 DECISION.MAKER
A 004 INTRUDER.ALERT
A 008 INT.ALERT.PROG
A 026 SUPER.SCORES
T 002 SUPERSCORES.FILE
A 004 CARLOANS
A 026 FRACTION.PRACTICE
A 013 ROOTS.&.PREFIXES
T 004 ROOT 1
T 004 ROOT 2
T 004 ROOT 3
T 004 ROOT 4
T 004 ROOT 5
T 004 ROOT 6
T 004 ROOT 7
T 004 ROOT 8
A 000 BALLOONS
B 002 BALLOON SHAPES
A 004 ANIMATE.COW
B 002 HIRES COW
A 016 COMPILER.INTRO
A 005 COMPILER.DEMO
B 003 CURSORS
B 008 ]SMALL SQUARE
B 018 ]WESTERN
B 003 ]APPLE 95-96
B 004 BALL.OBJ
B 017 RUNTIME
A 002 ELF
A 028 TEXT DEMO
DOS 3.3 format; 4,608 bytes free; 138,752 bytes used.

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/A.DUEL.bas:

5 G0% = 20:G1% = 20:S0% = 0:S1% = 0
10 FOR I = 771 TO 789: READ A: POKE I,A: NEXT
20 DATA 173,48,192,136,208,4,198,1, 240,8,202,208,246,166,0,76,3,3,96
30 HOME : IF PEEK( -16287) >127 AND PEEK( -16286) >127 THEN VTAB 8: HTAB 4: PRINT "YOU WILL NEED PADDLES INSTALLED": VTAB 9: HTAB 9: PRINT "TO PLAY 'A DUEL'": VTAB 11: HTAB 2: PRINT "REBOOT DISK AFTER INSTALLING PADDLES": END
40 VTAB 5: HTAB 17: INVERSE : PRINT "A DUEL": NORMAL : VTAB 7: HTAB 13: PRINT "BY CARL BOWDEN": VTAB 10: HTAB 1
50 PRINT " GUY #0 IS CONTROLLED USING PDL (0).": PRINT " GUY #1 IS CONTROLLED USING PDL (1).": PRINT : PRINT "PRESS PADDLE BUTTON TO FIRE BULLET.
55 PRINT : PRINT "THE BULLET COURSE IS CONTROLLED USING": PRINT "THE PADDLES. MAY THE BEST DUELER WIN."
56 FOR J = 1 TO 10000: NEXT
60 VTAB 21: HTAB 2: INVERSE : PRINT " GUY #0 ";: VTAB 21: HTAB 30: PRINT " GUY #1 ";
70 NORMAL : VTAB 22: HTAB 2: PRINT "----------";: VTAB 22: HTAB 30: PRINT "----------";
80 INVERSE : VTAB 23: HTAB 2: PRINT ":HITS:0:::";: VTAB 23: HTAB 30: PRINT ":HITS:0:::";
85 VTAB 23: HTAB 17: PRINT "A DUEL";
90 NORMAL : VTAB 24: HTAB 2: PRINT "----------";: VTAB 24: HTAB 30: PRINT "----------";
100 GR : COLOR= 11: FOR X = 0 TO 39: HLIN 0,39 AT X: NEXT
110 GOSUB 450: GOSUB 350
120 GOSUB 450
130 IF PEEK( -16287) >127 THEN GOTO 600
140 GOTO 120
150 GOSUB 350
160 IF PEEK( -16286) >127 THEN GOTO 800
170 GOTO 150
350 GX% = INT(( PDL(1) -128)/40)
360 COLOR= 11: FOR J = G1% -3 TO G1% +3: HLIN 33,36 AT J: NEXT
370 G1% = G1% -GX%
380 IF G1% <3 THEN G1% = 3
390 IF G1% >36 THEN G1% = 36
400 COLOR= 13: PLOT 36,G1%: PLOT 35,G1%: PLOT 35,G1% -1: PLOT 34,G1% -1: PLOT 35,G1% -2: COLOR= 9: PLOT 35,G1% -3: PLOT 34,G1% -3: PLOT 33,G1% -1: PLOT 36,G1% +1
410 COLOR= 3: PLOT 35,G1% +1: PLOT 34,G1% +1: PLOT 35,G1% +2: PLOT 34,G1% +2: COLOR= 0: PLOT 36,G1% +3: PLOT 34,G1% +3
420 RETURN
450 GY% = INT(( PDL(0) -128)/40)
460 COLOR= 11: FOR J = G0% -3 TO G0% +3: HLIN 3,6 AT J: NEXT
470 G0% = G0% -GY%
480 IF G0% <3 THEN G0% = 3
490 IF G0% >36 THEN G0% = 36
500 COLOR= 13: PLOT 3,G0%: PLOT 4,G0%: PLOT 4,G0% -1: PLOT 5,G0% -1: PLOT 4,G0% -2: COLOR= 9: PLOT 4,G0% -3: PLOT 5,G0% -3: PLOT 6,G0% -1: PLOT 3,G0% +1
510 COLOR= 3: PLOT 4,G0% +1: PLOT 5,G0% +1: PLOT 4,G0% +2: PLOT 5,G0% +2: COLOR= 0: PLOT 3,G0% +3: PLOT 5,G0% +3
530 RETURN
600 COLOR= 15: PLOT 7,G0% -1: PLOT 8,G0% -2: PLOT 8,G0%
610 B = -16336: FOR J = 1 TO 6:S = PEEK(B) - PEEK(B) - PEEK(B) - PEEK(B) - PEEK(B): NEXT
615 COLOR= 14: PLOT 8,G0% -1
620 COLOR= 11: PLOT 7,G0% -1: PLOT 8,G0% -2: PLOT 8,G0%: PLOT 8,G0% -1
625 GG% = G0% -1
630 FOR I = 9 TO 39 STEP 2:GY% = INT(( PDL(0) -128)/40)
640 GG% = GG% -GY%
642 IF GG% <0 THEN GG% = 0
644 IF GG% >39 THEN GG% = 39
650 COLOR= 14: PLOT I,GG%: POKE 0,2.5 *I: POKE 1,5: CALL 771
655 GOSUB 350
660 COLOR= 11: PLOT I,GG%
665 IF I = 35 OR I = 34 THEN IF ABS(GG% -G1%) < = 3 THEN H = G1%:K = 35: GOTO 1000
670 NEXT
680 GOTO 150
800 COLOR= 15: PLOT 32,G1% -1: PLOT 31,G1% -2: PLOT 31,G1%
810 B = -16336: FOR J = 1 TO 6:S = PEEK(B) - PEEK(B) - PEEK(B) - PEEK(B) - PEEK(B): NEXT
815 COLOR= 14: PLOT 31,G1% -1
820 COLOR= 11: PLOT 32,G1% -1: PLOT 31,G1% -2: PLOT 31,G1%: PLOT 31,G1% -1
825 GH% = G1% -1
830 FOR I = 30 TO 0 STEP -2:GX% = INT(( PDL(1) -128)/40)
840 GH% = GH% -GX%
842 IF GH% <0 THEN GH% = 0
844 IF GH% >39 THEN GH% = 39
850 COLOR= 14: PLOT I,GH%: POKE 0,100 -(2.5 *I): POKE 1,5: CALL 771
855 GOSUB 450
860 COLOR= 11: PLOT I,GH%
865 IF I = 4 OR I = 5 THEN IF ABS(GH% -G0%) < = 3 THEN H = G0%:K = 4: GOTO 1000
870 NEXT
880 GOTO 120
1000 REM HIT
1005 IF H <7 THEN H = 7
1006 IF H >32 THEN H = 32
1007 IF K >20 THEN VTAB 21: HTAB 26: FLASH : PRINT "@!#&";: NORMAL : GOTO 1010
1008 VTAB 21: HTAB 12: FLASH : PRINT "@!#&";: NORMAL
1010 FOR J = 0 TO 7: COLOR= 7: HLIN K -J/2,K +J/2 AT H +J: HLIN K -J/2,K +J/2 AT H -J: VLIN H -J,H +J AT K +J/2: VLIN H -J,H +J AT K -J/2
1020 POKE 0,100 -(13 *J): POKE 1,5: CALL 771
1030 COLOR= 11: HLIN K -J/2,K +J/2 AT H +J: HLIN K -J/2,K +J/2 AT H -J: VLIN H -J,H +J AT K +J/2: VLIN H -J,H +J AT K -J/2
1040 NEXT
1045 VTAB 21: HTAB 12: PRINT " ";
1050 IF K >20 THEN S0% = S0% +1: INVERSE : VTAB 23: HTAB 8: PRINT S0%;: NORMAL : GOTO 150
1060 S1% = S1% +1: INVERSE : VTAB 23: HTAB 36: PRINT S1%;: NORMAL : GOTO 120

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ARTILLERY.bas:

0 TEXT : HOME : REM ARTILLERY PRACTICE
1 ONERR GOTO 8
2 GOSUB 68: REM TITLE PAGE
3 DIM E(40)
4 Q = -16336
5 GOSUB 55: REM NEW TERRAIN
6 F = 0
7 GOSUB 45: REM NEW GUN & TARGET
8 REM
9 VTAB 23: HTAB 30: PRINT HIT"/"A;
10 VTAB 21: HTAB 15: PRINT W$;
11 VTAB 21: HTAB 1: POKE 34,20
12 INPUT "POWDER: ";P: VTAB 21: HTAB 15: PRINT W$;
13 IF P = 0 THEN TEXT : END
14 IF P = 999 THEN 5
15 IF P <6 THEN VTAB 22: HTAB 1: PRINT "NOT ENOUGH!";: VTAB 21: HTAB 1: GOTO 12
16 IF P >90 THEN VTAB 22: HTAB 1: PRINT "TOO MUCH!! ";: VTAB 21: HTAB 1: GOTO 12
17 P = P *1.9
18 VTAB 22: HTAB 1
19 INPUT "ELEVATION: ";E: IF E <6 OR E >90 THEN VTAB 23: HTAB 1: PRINT "IMPOSSIBLE ANGLE!";: VTAB 22: HTAB 1: GOTO 19
20 G = -9.8
21 POKE -16368,0
22 E = E *.01745
23 PRINT "PRESS ANY KEY TO FIRE !";: WAIT -16384,128: POKE -16368,0: VTAB 23: HTAB 1: PRINT " ";
24 PX = GX:PY = GY:TM = 1
25 PX = GX + INT((P * COS(E) *TM)/10 +W *TM)
26 PY = GY - INT(P * SIN(E) *TM +G/2 *TM *TM)/10
27 IF PY <1 THEN PY = 1
28 IF PX >279 THEN 31: REM MISSED...
29 XP = INT(PX/7): IF PY > = E(XP) THEN 34: REM HIT GROUND
30 HPLOT PX,PY:TM = TM +1: GOTO 25
31 REM MISSED
32 A = A +1
33 GOTO 8
34 REM HIT THE GROUND...
35 A = A +1
36 PY = E(XP)
37 IF PX = TX THEN VTAB 21: HTAB 27: PRINT "DIRECT HIT!!";:HIT = HIT +2:F = 1: VTAB 23: HTAB 15: GOTO 39
38 IF XP = TX/7 THEN VTAB 21: HTAB 30: PRINT "HIT!!!":HIT = HIT +1:F = 1: GOTO 39
39 REM EXPLOSION...
40 PX = 7 *XP
41 FOR N = 0 TO 10:Z = PEEK(Q): HPLOT PX +N,PY -N: HPLOT PX -N,PY -N: HPLOT PX,PY -N: NEXT N
42 POKE -16368,0
43 IF F = 1 THEN VTAB 23: HTAB 1: PRINT "PRESS ANY KEY";: WAIT -16384,128: POKE -16368,0: GOTO 5
44 GOTO 8
45 REM NEW GUN & TARGET
46 P = 0
47 GX = INT( RND(1) *10 +1):GY = E(GX):GX = GX *7
48 TX = 19 + INT( RND(1) *20 +1):TY = E(TX):TX = TX *7
49 X = GX:Y = GY: GOSUB 52
50 X = TX:Y = TY: GOSUB 52
51 RETURN
52 IF P = 1 THEN 54
53 FOR I = 0 TO 5: HPLOT X -2,Y -I TO X +2,Y -I: NEXT I:P = 1: RETURN
54 HPLOT X,Y TO X,Y -5 TO X +3,Y -3 TO X,Y -2: RETURN
55 REM NEW TERRAIN
56 HOME :W = INT( RND(1) *60) -30: REM WIND
57 IF W >0 THEN W$ = STR$(W) +"->"
58 IF W <0 THEN W$ = "<-" + STR$( ABS(W))
59 IF W = 0 THEN W$ = STR$(W)
60 W$ = " " +W$ +" "
61 SN = SGN(W):W = ((W/9.49) ^2) *SN/3
62 HGR : HCOLOR= 3: HPLOT 0,159 - RND(1) *10
63 FOR I = 1 TO 39:S = S +( RND(1) *20 -12): IF S >60 THEN S = S/2
64 IF S <1 THEN S = -S
65 E(I) = 156 - INT(S): HPLOT TO 7 *I,E(I): NEXT I
66 HPLOT 0,159 TO 279,159
67 RETURN
68 VTAB 8: HTAB 11: PRINT "A R T I L L E R Y": VTAB 10: HTAB 13: PRINT "P R A C T I C E": VTAB 20: HTAB 6: PRINT "WOULD YOU LIKE INSTRUCTIONS ?": GET I$: IF I$ < >"Y" THEN RETURN
69 TEXT : HOME : PRINT " THIS PROGRAM GENERATES ARTILLERY": PRINT : PRINT "PROBLEMS FOR YOUR SOLUTION."
70 PRINT : PRINT " YOU HAVE CONTROL OVER THE ELEVATION": PRINT : PRINT "OF THE BARREL OF THE FIELD PEICE": PRINT : PRINT "IN DEGREES ABOVE THE HORIZON (6 TO 90)"
71 PRINT : PRINT "AND THE AMOUNT OF POWDER TO USE IN": PRINT : PRINT "POUNDS (6 TO 90).
72 PRINT : PRINT " THE DESIGN OF THE TERRAIN IS UNDER": PRINT : PRINT "MY CONTROL, AS IS THE PLACEMENT OF THE": PRINT : PRINT "CANNON AND THE TARGET."
73 PRINT : HTAB 9: PRINT "HIT ANY KEY TO CONTINUE": WAIT -16384,128: POKE -16368,0
74 HOME : PRINT " IF YOU DON'T LIKE A PARTICULAR ": PRINT : PRINT "SET-UP, JUST ENTER '999' WHEN ASKED": PRINT : PRINT "FOR POWDER, AND A NEW SITUATION WILL"
75 PRINT : PRINT "BE CONSTRUCTED.": PRINT : PRINT " WHEN YOU ARE READY TO QUIT, ENTER": PRINT : PRINT "'0' FOR POWDER."
76 PRINT : PRINT " YOUR RECORD OF HITS/ATTEMPTS WILL": PRINT : PRINT "BE SHOWN AT THE BOTTOM OF THE SCREEN."
77 PRINT : PRINT : HTAB 9: PRINT "HIT ANY KEY TO CONTINUE": WAIT -16384,128: POKE -16368,0
78 HOME : PRINT " THE CANNON IS REPRESENTED BY A BLOCK": PRINT : PRINT "ON THE LEFT SIDE OF THE SCREEN, AND THE": PRINT : PRINT "TARGET BY A SMALL FLAG ON THE": PRINT : PRINT "RIGHT."
79 PRINT : PRINT " JUST TO MAKE IT INTERESTING, EACH": PRINT : PRINT "SITUATION WILL HAVE A DIFFERENT": PRINT : PRINT "WIND FACTOR, WITH DIRECTION SHOWN BY"
80 PRINT : PRINT "AN ARROW AND VELOCITY SHOWN IN MPH.": PRINT : PRINT : PRINT : HTAB 15: PRINT "GOOD LUCK": PRINT : PRINT : HTAB 10: PRINT "HIT ANY KEY TO START": WAIT -16384,128: POKE -16368,0
81 RETURN
82 PRINT ""
83 REM
84 REM **********************
85 REM
86 REM THIS PROGRAM WAS
87 REM INSPIRED BY A SIMILAR
88 REM PROGRAM APPEARING IN
89 REM AUGUST 1982 CREATIVE
90 REM COMPUTING MAGAZINE, BY
91 REM JOHN W. RHODES.
92 REM
93 REM APPLE HI-RES VERSION
94 REM BY
95 REM JACK KENNE
96 REM 5046 CASTLE CREEK
97 REM HOUSTON, TEXAS 77053
98 REM JUNE 26, 1982
99 REM
100 REM
101 REM **********************
102 REM
103 REM
104 REM
105 REM

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/CARLOANS.bas:

100 HOME
110 A = 0:B = 0:C = 0:D = 0:E = 0:K = 0
170 PRINT "HOW MUCH ARE YOU FINANCING";: INPUT PZ: PRINT
180 E = P
190 I1 = 10:I3 = 19
200 PRINT
220 L1 = 3
230 HOME : PRINT " ** $"PZ
240 PRINT "YRS % PAYMNT INT TOTAL"
250 IF I1 <1 THEN I1 = I1 *100
260 FOR I2 = I1 TO I3
270 LET I = I2/100
280 FOR L = L1 TO L1 +1:D = L
290 A = 0:B = 0:C = 0:K = 0:P = PZ:E = P
300 P1 = P *(I/12)/(1 -(1/(1 +(I/12)) ^(L *12)))
310 P1 = INT(P1 *100 +.5)/100
320 FOR M = 1 TO L *12
330 P2 = P *I/12
340 P2 = INT(P2 *100 +.5)/100
350 P3 = P1 -P2
360 P = INT((P -P3) *100 +.5)/100
370 A = M +0:B = P1 +B:C = P2 +C
380 NEXT M
400 C = INT(C +.59)
420 B = INT(B +P +.59)
460 I7 = I *100
470 HTAB 2: PRINT D;: HTAB 6: PRINT I7;: HTAB 12: PRINT P1;: HTAB 20: PRINT C;: HTAB 26: PRINT B
480 NEXT : NEXT
490 END

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/DATE.txt:

82 9186

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/DECISION.MAKER.bas:

10 HOME : POKE -16298,0: POKE -16368,0: GOSUB 1000
20 REM A DECISION MAKER
30 CLEAR
40 DIM F$(10),L$(10),F(10),M(10,10),V(10),Z(10): PRINT
50 PRINT "OUT OF SEVERAL ALTERNATIVES."
60 CALL -936: PRINT
70 PRINT TAB( 3)"*** COMPUTERIZED DECISION-MAKER ***"
80 PRINT : PRINT
90 Y$ = "Y": PRINT " I CAN HELP YOU MAKE DECISIONS BY"
100 PRINT "CHOOSING THE BEST POSSIBILITY FOR YOU"
110 PRINT "OUT OF SEVERAL ALTERNATIVES."
120 PRINT
130 PRINT "ALL I NEED TO DO IS ORGANIZE INFORMATIONYOU ALREADY HAVE."
140 PRINT : PRINT " WHICH OF THESE BEST DESCRIBES THE TYPEOF DECISION YOU HAVE TO MAKE?": PRINT
150 PRINT "1-CHOOSE AN ITEM FROM SEVERAL ALTERNA- TIVES."
160 PRINT "2-CHOOSE A COURSE OF ACTION FROM SEVERAL ALTERNATIVES."
170 PRINT : INPUT "WHICH TYPE(1 OR 2) CHOICE DO YOU HAVE TOMAKE?";C
180 IF C <1 OR C >2 THEN 170
190 PRINT : IF C = 1 THEN PRINT " WHAT TYPE OF ITEM IS IT THAT YOU "
200 IF C = 1 THEN PRINT "NEED TO DECIDE UPON?": INPUT S$
210 IF C = 2 THEN S$ = "COURSE OF ACTION"
220 PRINT : PRINT "I WILL NOW NEED A LIST OF EACH ";S$
230 PRINT "THAT YOU ARE CONSIDERING. PLEASE INPUT"
240 PRINT "THEM ONE AT A TIME. THE ORDER IS"
250 PRINT "OF NO PARTICULAR IMPORTANCE.": PRINT
260 INPUT "FIRST, HOW MANY ARE THERE ALTOGETHER?";L0
270 IF L0 > = 2 AND L0 < = 10 THEN 290
280 GOSUB 970: GOTO 260
290 PRINT : FOR I = 1 TO L0: PRINT : PRINT "NUMBER ";I;", PLEASE."
300 INPUT L$(I): NEXT I: PRINT
310 PRINT "O.K., THIS IS THE LIST UNDER CONSIDERA- TION": PRINT
320 FOR I = 1 TO L0: PRINT I; TAB( 5);L$(I): NEXT I: PRINT : GOSUB 980
330 IF B$ < >Y$ THEN 220
340 PRINT : PRINT " NOW, HOW MANY DIFFERENT FACTORS ARE"
350 PRINT "IMPORTANT TO YOU IN CHOOSING A ";S$;"?": INPUT F0
360 IF F0 >1 AND F0 <10 THEN 380
370 GOSUB 970: GOTO 340
380 PRINT : PRINT " I NEED A LIST OF EACH OF THESE FACTORS "
390 FOR I = 1 TO F0: PRINT : PRINT "FACTOR NUMBER ";I: INPUT F$(I): NEXT
400 CALL -936
410 PRINT : PRINT " NOW LOOK AT THE FOLLOWING LIST OF"
420 PRINT "FACTORS YOU HAVE PROVIDED AND DECIDE"
430 PRINT "WHICH IS THE MOST IMPORTANT TO YOU:"
440 PRINT : FOR I = 1 TO F0: PRINT I; TAB( 5);F$(I): NEXT
450 PRINT : PRINT " WHICH FACTOR (BY NUMBER) IS MOST IMPORTANT?"
460 PRINT "(INPUT 0 IF YOU WISH TO CHANGE THE LIST) ": INPUT F2
470 IF F2 = 0 THEN 340
480 IF F2 <1 OR F2 >F0 THEN 450
490 PRINT : PRINT " O.K., SUPPOSE WE HAVE A SCALE OF"
500 PRINT "IMPORTANCE THAT RANGES FROM 0 TO 10."
510 PRINT "LET'S SAY ";F$(F2);" HAS A VALUE OF 10,"
520 PRINT "SINCE IT IS AT THE TOP OF THE SCALE."
530 PRINT "ON THIS SCALE, WHAT VALUE WOULD"
540 PRINT "EACH OF THE OTHER FACTORS HAVE?"
550 PRINT " (DECIMAL NUMBERS ARE O.K.)": PRINT : FOR I = 1 TO F0
560 IF I = F2 THEN 590
570 PRINT F$(I): INPUT F(I): IF F(I) >0 AND F(I) < = 10 THEN 590
580 PRINT " YOUR INPUT IS NO GOOD. TRY AGAIN!": GOTO 570
590 NEXT :F(F2) = 10:C = 0: FOR I = 1 TO F0:C = C +F(I): NEXT : FOR I = 1 TO F0
600 F(I) = F(I)/C: NEXT : PRINT : PRINT "NOW CONSIDER HOW EACH ";S$
610 PRINT "RATES WITH RESPECT TO EACH OF THE"
620 PRINT "FACTORS. WE WILL CONSIDER EACH FACTOR"
630 PRINT "SEPARATELY AND THEN RATE EACH"
640 PRINT S$;" IN TERMS OF THAT FACTOR"
650 PRINT "ONLY.": PRINT
660 PRINT "LET'S CONSIDER ";L$(1);" TO HAVE A"
670 PRINT "VALUE OF 10 ON EACH SCALE."
680 PRINT "THEN EVERY OTHER ";S$
690 PRINT "WILL BE GIVEN A NUMBER HIGHER OR LOWER"
700 PRINT "THAN 10 ACCORDING TO HOW MUCH BETTER"
710 PRINT "OR WORSE THAN ";L$(1);" YOU THINK IT IS.": FOR I = 1 TO F0: PRINT
720 PRINT
730 PRINT "CONSIDERING ";F$(I);" ONLY, AND"
740 PRINT "ASSUMING ";L$(1);" HAS A VALUE OF 10,"
750 PRINT "WHAT VALUE WOULD YOU GIVE TO EACH OF THEFOLLOWING:"
760 PRINT : FOR J = 2 TO L0
770 PRINT L$(J): INPUT M(J,I): IF M(J,I) > = 0 THEN 790
780 PRINT " C'MON, NO NEGATIVE NUMBERS! TRY AGAIN.": GOTO 770
790 NEXT J: PRINT :M(1,I) = 10: NEXT I: FOR I = 1 TO F0:C = 0: FOR J = 1 TO L0
800 C = C +M(J,I): NEXT J: FOR J = 1 TO L0:M(J,I) = M(J,I)/C: NEXT J: NEXT I
810 FOR J = 1 TO L0:V(J) = 0: FOR I = 1 TO F0:V(J) = V(J) +M(J,I) *F(I)
820 NEXT I: NEXT J: FOR I = 1 TO 10:Z(I) = I: NEXT I:C = L0 -1: FOR J = 1 TO L0
830 FOR I = 1 TO C:N1 = Z(I):N2 = Z(I +1): IF V(N1) >V(N2) THEN 850
840 Z(I +1) = N1:Z(I) = N2
850 NEXT I: NEXT J:C1 = Z(1):C2 = Z(2):C = 100/V(C1): FOR J = 1 TO L0
860 V(J) = C *V(J): NEXT : PRINT : PRINT :D = V(C1) -V(C2)
870 PRINT " WELL, YOU BEST CHOICE SEEMS TO BE "
880 PRINT L$(C1);", ";
890 IF D <10 THEN PRINT "BUT IT'S VERY CLOSE."
900 IF D <20 AND D > = 10 THEN PRINT "BY A FAIR MARGIN."
910 IF D > = 20 THEN PRINT "BY A GOOD-SIZED MARGIN."
920 PRINT : PRINT "HERE'S THE FINAL LIST WITH ";L$(C1)
930 PRINT "GIVEN A VALUE OF 100 AND THE OTHERS SET ACCORDINGLY:"
940 PRINT : PRINT : PRINT "RATING ",S$: FOR J = 1 TO L0:C = Z(J)
950 PRINT
960 PRINT V(C),L$(C): NEXT : END
970 PRINT " THE NUMBER MUST BE BETWEEN 2 AND 10": RETURN
980 INPUT " IS THIS CORRECT (YES OR NO)?";A$
990 B$ = LEFT$(A$,1): RETURN
1000 CALL -936: VTAB 5: PRINT "DECISION MAKER"
1010 PRINT : PRINT
1020 PRINT
1030 PRINT : PRINT : PRINT "HAVING A HARD TIME MAKING A DECISION?
1040 PRINT "LET YOUR APPLE HELP YOU."
1050 VTAB 21: PRINT " PRESS 'ESC' TO END"
1060 VTAB 22: PRINT "< PRESS THE SPACE BAR TO CONTINUE...>"
1070 IF PEEK( -16384) = 155 THEN 1100
1080 IF PEEK( -16384) < >160 THEN 1060
1090 POKE -16368,0: HOME : RETURN
1100 POKE -16368,0: HOME : VTAB 10: HTAB 10: PRINT "* * * THE END * * *": END
65535 REM ********************
65535 REM * *
65535 REM * CONTRIBUTED BY *
65535 REM * THE KEYSTONE *
65535 REM * APPLE CORE *
65535 REM *4644 CARLISLE PIKE*
65535 REM *MECHANICSBURG, PA*
65535 REM * 17055 *
65535 REM * *
65535 REM ********************

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/DIVE.BOMBER.bas:

1 HIMEM: 8192
5 DIM B(40,10)
6 DIM HX(9),HY(9)
10 HOME
15 GOSUB 6000
20 PRINT "LOADING SHAPE TABLE"
25 P = 16384
26 POKE 232,0: POKE 233,64
30 READ I$: IF I$ = "END" THEN 250
40 FOR A = 1 TO LEN(I$) -1 STEP 2
50 P$ = MID$ (I$,A,2)
60 H = ASC( LEFT$(P$,1))
70 L = ASC( RIGHT$(P$,1))
80 H = H -48: IF H >9 THEN H = H -7
90 L = L -48: IF L >9 THEN L = L -7
100 POKE P,H *16 +L
105 P = P +1
110 NEXT A
120 GOTO 30
125 DATA "030008001F003700"
130 DATA "252D2C2D2E35353F3F3F3F373535353525252525250500"
140 DATA "25253F3F24242C2D253C3E2627372E2D3536363F3F2E2E00"
150 DATA "1225253C3C37372E2E0500"
160 DATA "END"
250 S1 = 0:S2 = 0:M1 = 0:M2 = 0
255 PRINT "HIT ANY KEY TO BEGIN!"
256 P = PEEK( -16384): IF P <128 GOTO 256
257 POKE -16368,0
258 HOME
260 HGR
270 ROT= 0: SCALE= 1
275 HT = 0
280 FOR X = 1 TO 40
300 READ R: IF R = 0 THEN 405
310 HCOLOR= 1
320 FOR DX = (X -1) *6 TO (X -1) *6 +6
340 HPLOT DX,159 TO DX,159 -R *6
350 NEXT DX
355 FOR Y = 1 TO R:B(X,Y) = 5: NEXT Y
400 HCOLOR= 3
405 FOR Y = R +1 TO 10
410 DRAW 3 AT (X -1) *6 +3,159 -(Y -1) *6 -3
415 B(X,Y) = 1
500 NEXT Y
502 HT = HT +10 -R
505 NEXT X
520 DATA 9,8,7,5,4,3,2,0,0,1,2,3,4,3,3,4,5,6,5,4
530 DATA 4,5,6,5,4,3,3,4,3,2,1,0,0,2,3,4,5,7,8,9
1000 HOME
1003 VTAB 22: PRINT TAB( 33);: INVERSE : PRINT "DIVE";: NORMAL : PRINT ""
1004 VTAB 23: PRINT TAB( 32);: INVERSE : PRINT "BOMBER";: NORMAL : PRINT ""
1005 SW = 1
1010 IF SW = 1 THEN SW = -1:F = 230:T = 10: GOTO 1030
1020 SW = 1:F = 10:T = 230
1030 IF M1 = 5 AND SW = 1 THEN 1010
1040 IF M2 = 5 AND SW = -1 THEN 1010
1200 VTAB 22: IF SW = 1 THEN INVERSE
1210 PRINT "PLAYER #1";: NORMAL : PRINT TAB( 11);"SCORE:";S1; TAB( 21);"MISSES:";M1
1230 VTAB (23): IF SW = -1 THEN INVERSE
1240 PRINT "PLAYER #2";: NORMAL : PRINT TAB( 11);"SCORE:";S2; TAB( 21);"MISSES:";M2
1300 FOR CD = 5 TO 1 STEP -1
1310 VTAB (21): PRINT "COUNTDOWN:";CD
1315 POKE -16368,0
1320 FOR P = 1 TO 300: NEXT P
1330 NEXT CD
1340 VTAB (21): PRINT "
1527 FOR IN = F TO T STEP SW *3
1530 HCOLOR= 3: DRAW 1 AT IN -4,10
1535 DRAW 2 AT IN,25
1540 P = PEEK( -16384): IF P >128 THEN POKE -16368,0: GOTO 2000
1550 HCOLOR= 0
1560 DRAW 1 AT IN -4,10
1570 DRAW 2 AT IN,25
1600 NEXT IN
1700 GOTO 5000
2000 HCOLOR= 0: DRAW 1 AT IN -4,10
2002 DRAW 2 AT IN,25
2003 X = IN
2005 FOR Y = 25 TO 99 STEP 2
2010 HCOLOR= 0: DRAW 2 AT X,Y -2
2020 X = X +SW *1.75
2030 IF X < = 0 THEN X = 240: GOTO 2050
2040 IF X > = 240 THEN X = 0
2050 HCOLOR= 3: DRAW 2 AT X,Y
2060 NEXT Y
2070 HCOLOR= 0: DRAW 2 AT X,99
2080 FOR Y = 99 TO 158 STEP 2
3010 HCOLOR= 0: DRAW 2 AT X,Y -2
3020 IF B( INT(X/6) +1, INT((159 -Y)/6)) >0 THEN 4000
3030 X = X +SW *1.75
3040 HCOLOR= 3: DRAW 2 AT X,Y
3050 NEXT Y
3060 HCOLOR= 0: DRAW 2 AT X,157
3070 GOTO 5000
4000 RX = INT(X/6) +1:RY = INT((159 -Y)/6)
4006 IF B(RX,RY) = 5 THEN 5000
4010 FOR X = 1 TO 9:HX(X) = 0:HY(X) = 0: NEXT X
4015 HP = 1
4020 FOR Y = -1 TO 1: FOR X = -1 TO 1
4025 IF RX +X <1 OR RX +X >40 OR RY +Y <1 OR RY +Y >10 THEN 4100
4030 IF B(RX +X,RY +Y) < >1 THEN 4100
4040 HX(HP) = RX +X:HY(HP) = RY +Y
4050 B(RX +X,RY +Y) = 0
4060 IF SW = 1 THEN S1 = S1 +1: GOTO 4070
4065 S2 = S2 +1
4070 HP = HP +1
4100 NEXT X: NEXT Y
4110 HP = HP -1
4200 FOR FL = 1 TO 10
4210 HCOLOR= 3
4220 FOR FO = 1 TO HP
4230 DRAW 3 AT HX(FO) *6 -3,162 -HY(FO) *6
4240 NEXT FO
4250 HCOLOR= 0
4260 FOR FO = 1 TO HP
4270 DRAW 3 AT HX(FO) *6 -3,162 -HY(FO) *6
4280 NEXT FO
4290 NEXT FL
4500 FS = RX -1:TS = RX +1
4510 IF FS <1 THEN FS = 1
4520 IF TS >40 THEN TS = 40
4550 FOR S = FS TO TS
4560 FOR Y = 2 TO 10
4570 IF B(S,Y) < >1 THEN GOTO 4700
4580 FOR C = Y -1 TO 1 STEP -1
4590 IF B(S,C) < >0 THEN 4615
4600 NEXT C
4610 C = 0
4615 IF C +1 = Y THEN 4700
4620 B(S,C +1) = B(S,Y):B(S,Y) = 0
4630 HCOLOR= 0: DRAW 3 AT S *6 -3,162 -Y *6
4640 HCOLOR= 3: DRAW 3 AT S *6 -3,162 -(C +1) *6
4700 NEXT Y
4800 NEXT S
4810 IF (S1 +S2)/HT = INT((S1 +S2)/HT) THEN 5040
4900 GOTO 1010
5000 IF SW = 1 THEN M1 = M1 +1
5001 IF SW = -1 THEN M2 = M2 +1
5005 IF M1 +M2 <10 THEN 1010
5010 VTAB (21): PRINT "GAME OVER"
5015 :S1 = 0:S2 = 0:M1 = 0:M2 = 0
5020 P = PEEK( -16384): IF P <128 THEN 5020
5030 POKE -16368,0
5040 RESTORE
5050 READ I$: IF I$ = "END" THEN 270
5060 GOTO 5050
6000 PRINT "DIVE BOMBER -- WRITTEN BY RICHARD TODD"
6005 PRINT : PRINT "INSTRUCTIONS:"
6020 PRINT "YOU AND YOUR OPPONENT ARE BOTH PRIVATES"
6030 PRINT "IN THE U.S.ARMY. YOUR MISSIONS ARE THE";
6040 PRINT " SAME. TO CLEAR OUT A MOUNTAIN PASS TO "
6050 PRINT "ALLOW YOUR TROOPS TO GET THROUGH AND"
6060 PRINT "DEFEAT THE ENEMY. YOU ALTERNATELY DROP"
6070 PRINT "BOMBS IN AN ATTEMPT TO CLEAR OUT AS MANY";
6080 PRINT "ROCKS AS POSSIBLE. AS YOUR BOMB FLOATS"
6090 PRINT "ACROSS THE SCREEN, HIT ANY KEY TO DROP"
6100 PRINT "IT. YOU MAY HIT A KEY DURING THE COUNT-";
6110 PRINT "DOWN TO DEPLOY THE BOMB IMMEDIATELY."
6120 PRINT "EACH PLAYER GETS TO MISS 5 TIMES"
6130 PRINT "YOU MISS IF EITHER YOU FAIL TO DESTROY"
6140 PRINT "ANY ROCKS OR YOU DO NOT DROP YOUR BOMB"
6150 PRINT "AT ALL."
6160 PRINT "ANOTHER NOTE: THE BOMB 'WRAPS' AROUND"
6170 PRINT "THE SCREEN, TO ALLOW YOU TO HIT ROCKS"
6180 PRINT "THAT WOULD OTHERWISE BE IMPOSSIBLE TO"
6190 PRINT "HIT."
6200 RETURN

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/FRACTION.PRACTICE.bas:

10 GOTO 1000
19 REM RANDOM NUMBERS
20 N1 = INT( RND(1) *10) +1:N2 = INT( RND(1) *10) +1
25 D1 = INT( RND(1) *10) +1:D2 = INT( RND(1) *10) +1
30 PRINT : PRINT "TYPE IN THE ANSWER AS A SINGLE FRACTION IN LOWEST TERMS.": PRINT : PRINT "USE '/' AS THE LINE BETWEEN THE NUMERATOR AND DENOMINATOR. THEN PRESS 'RETURN'": PRINT
35 RETURN
49 REM REDUCING LOOP
50 FOR J = 2 TO X
60 IF C1/J < > INT(C1/J) THEN 100
70 IF C2/J < > INT(C2/J) THEN 100
80 C1 = C1/J:C2 = C2/J
90 GOTO 60
100 NEXT J
110 B$ = STR$(C1) +"/" + STR$(C2)
120 RETURN
199 REM ANSWER WRONG
200 Y = INT( RND(1) *5) +1: ON Y GOTO 210,220,230,240,250
210 PRINT "SORRY! INCORRECT": GOTO 260
220 PRINT "OOPS!! YOU MUST HAVE TYPED THE ANSWER IN WRONG": GOTO 260
230 PRINT "ERROR!": GOTO 260
240 PRINT "NOPE!": GOTO 260
250 PRINT "WRONG, ";N$
260 PRINT : PRINT "THE CORRECT ANSWER WAS ";B$: RETURN
299 REM ANSWER RIGHT
300 Y = INT( RND(1) *5) +1: ON Y GOTO 310,320,330,340,350
310 PRINT "CORRECT!!!": GOTO 360
320 PRINT "VERY GOOD!": GOTO 360
330 PRINT N$;",": PRINT "YOU MUST HAVE BEEN STUDYING THIS STUFF.": GOTO 360
340 PRINT "YAY!!": GOTO 360
350 PRINT "GOOD JOB!"
360 RETURN
399 REM NUMBER OF PROBLEMS
400 PRINT N$;",": INPUT "HOW MANY PROBLEMS DO YOU WISH TO DO? ";K$:K = VAL(K$): IF K <1 THEN 400
410 TK = TK +K
420 RETURN
500 PRINT : PRINT "PRESS ANY KEY TO CONTINUE. ";: GET Z$: PRINT : RETURN
1000 HOME : FLASH : PRINT "GENERAL MATH PROGRAM: FRACTIONS"
1010 NORMAL : PRINT : PRINT "WRITTEN BY:": PRINT
1020 A$(1) = "CAROL SMITH":A$(2) = "JOE URADNIK":A$(3) = "TONY PACHE"
1030 FOR I = 1 TO 3
1040 A(I) = INT( RND(1) *3) +1
1050 X = A(I): IF B(X) = 1 THEN 1040
1060 B(X) = 1: PRINT A$(X): NEXT I
1070 PRINT : PRINT "COMPUTER MATH 2"
1080 PRINT : PRINT "4 JUNE 1982"
1090 FOR I = 1 TO 2500: NEXT I
1100 HOME
1110 PRINT "FRACTIONS"
1120 PRINT : INPUT "HI! WHAT IS YOUR NAME? TYPE IT IN THEN PRESS 'RETURN' ";N$
1130 HOME
1140 PRINT "HI, ";N$
1150 PRINT
1160 PRINT "WOULD YOU LIKE TO:"
1170 PRINT "1. ADD FRACTIONS"
1180 PRINT "2. SUBTRACT FRACTIONS"
1190 PRINT "3. MULTIPLY FRACTIONS"
1200 PRINT "4. DIVIDE FRACTIONS"
1210 PRINT "5. QUIT"
1220 PRINT : INPUT "TYPE IN THE NUMBER OF THE OPERATION THATYOU WANT TO DO (1-5) THEN PRESS 'RETURN' ";X$:N = VAL(X$)
1230 IF N <1 OR N >5 THEN HOME : GOTO 1160
1240 IF N = 5 THEN 2240
1250 IF N = 3 THEN 1730
1260 IF N = 4 THEN 1980
1270 REM ADDING AND SUBTRACTING LOOP
1280 HOME : GOSUB 400
1290 FOR I = 1 TO K
1300 GOSUB 20
1302 IF N = 2 THEN PRINT N1"/"D1" - "N2"/"D2" = ";: INPUT " ";A$: PRINT : GOTO 1308
1306 PRINT N1"/"D1" + "N2"/"D2" = ";: INPUT " ";A$: PRINT
1308 N1 = N1 *D2:C2 = D1 *D2:N2 = D1 *N2
1310 IF N = 2 THEN C1 = N1 -N2: GOTO 1330
1320 C1 = N1 +N2
1330 IF C1 "Y" THEN 1430
1460 HOME : IF N = 1 THEN 1490
1470 IF N = 2 THEN 1630
1480 REM ADDING EXPLANATION
1490 PRINT "TO ADD FRACTIONS:": PRINT : PRINT "EXAMPLE: 3/4 + 7/8 =": PRINT : PRINT "1. MULTIPLY THE FIRST NUMERATOR BY THE SECOND DEMOMINATOR."
1495 PRINT "3 * 8 = 24"
1500 PRINT : PRINT "2. MULTIPLY THE SECOND NUMERATOR BY THEFIRST DENOMINATOR."
1505 PRINT "7 * 4 = 28": PRINT
1510 PRINT "3. ADD THE TWO NUMBERS TOGETHER TO GET THE NEW NUMERATOR."
1515 PRINT "24 + 28 = 52": PRINT
1520 PRINT "4. MULTIPLY THE DENOMINATORS TOGETHER TO GET THE NEW DENOMINATOR."
1525 PRINT "4 * 8 = 32": PRINT
1530 PRINT "5. REDUCE THE FRACTION."
1535 PRINT "52/32 = 13/8 (THE ANSWER!!)"
1600 GOSUB 500
1610 HOME : NEXT I: GOTO 1160
1620 REM SUBTRACT EXPLANATION
1630 PRINT "TO SUBTRACT FRACTIONS:": PRINT : PRINT "EXAMPLE: 3/4 - 1/8 =": PRINT : PRINT "1. MULTIPLY THE FIRST NUMERATOR BY THE SECOND DENOMINATOR.": PRINT "3 * 8 = 24": PRINT : PRINT "2. MULTIPLY THE SECOND NUMERATOR BY THEFIRST DENOMINATOR."
1635 PRINT "1 * 4 = 4": PRINT
1640 PRINT "3. SUBTRACT THE SECOND ONE FROM THE FIRST TO GET THE NEW NUMERATOR.": PRINT "24 - 4 = 20": PRINT
1650 PRINT "4. MULTIPLY THE TWO DENOMINATORS TOGETHER TO GET THE NEW DENOMINATOR.": PRINT "4 * 8 = 32": PRINT
1660 PRINT "5. REDUCE THE FRACTION.": PRINT "20/32 = 5/8 (THE ANSWER!!)"
1700 GOSUB 500
1710 HOME : NEXT I: GOTO 1160
1720 REM MULTIPLY LOOP
1730 HOME : GOSUB 400
1740 FOR I = 1 TO K
1750 GOSUB 20
1760 PRINT : PRINT N1"/"D1" * "N2"/"D2" = ";: INPUT " ";A$: PRINT
1770 C1 = N1 *N2
1780 C2 = D1 *D2
1790 IF C1 "Y" THEN 1840
1870 REM MULTIPLY EXPLANATION
1880 HOME : PRINT "MULTIPLYING FRACTIONS IS EASY!"
1885 PRINT : PRINT "EXAMPLE: 3/4 * 7/8 ="
1890 PRINT : PRINT "SIMPLY MULTIPLY THE NUMERATORS OF EACH FRACTION TOGETHER TO GET THE NUMERATOR OF THE ANSWER. . ."
1895 PRINT "3 * 7 = 21": PRINT
1900 PRINT ". . .TO GET THE DENOMINATOR OF THE ANSWER, MULTIPLY THE DENOMINATORS OF THETWO FRACTIONS TOGETHER"
1905 PRINT "4 * 8 = 32"
1910 PRINT : PRINT "THEN REDUCE THE FRACTION."
1950 PRINT : PRINT "21/32 CAN'T BE REDUCED, SO IT'S THE ANSWER.": GOSUB 500
1960 HOME : NEXT I: GOTO 1150
1970 REM DIVISION LOOP
1980 HOME : GOSUB 400
1990 FOR I = 1 TO K
2000 GOSUB 20: REM RANDOM NUMBER
2010 PRINT N1"/"D1" / "N2"/"D2" = ";: INPUT " ";A$: PRINT
2020 C1 = N1 *D2
2030 C2 = N2 *D1
2040 IF C1 "Y" THEN 2090
2120 REM DIVIDE EXPLANATION
2130 HOME : INVERSE : PRINT "HOW TO DIVIDE FRACTIONS": NORMAL : PRINT
2140 PRINT "DIVIDING FRACTIONS IS ALMOST LIKE MULTIPLYING THEM."
2145 PRINT : PRINT "EXAMPLE: 3/4 / 7/8 ="
2150 PRINT : PRINT "SIMPLY TURN THE SECOND FRACTION UPSIDE DOWN!": PRINT "(PUT THE DENOMINATOR ON TOP AND THE NUMERATOR ON THE BOTTOM)": PRINT "3/4 * 8/7"
2160 PRINT : PRINT "THEN MULTIPLY AND REDUCE."
2190 PRINT : PRINT "3 * 8 = 24 (NEW NUMERATOR)"
2200 PRINT "4 * 7 = 28 (NEW DENOMIATOR)"
2210 PRINT : PRINT "24/28 = 6/7 (THE ANSWER!)"
2220 GOSUB 500
2230 HOME : NEXT I: GOTO 1150
2239 REM QUIT
2240 HOME : IF TK = 0 THEN 2330
2245 PRINT "YOU GOT ";R;" OUT OF ";TK;" RIGHT, WHICH IS ";
2250 PER = INT((R/TK *100) +.5)
2260 PRINT PER;" PERCENT.": PRINT
2270 FOR I = 1 TO 1500: NEXT I
2280 IF PER >94 THEN PRINT "EXCELLENT!": GOTO 2320
2290 IF PER >85 THEN PRINT "VERY GOOD!": GOTO 2320
2300 IF PER >75 THEN PRINT "KEEP UP THE GOOD WORK.": GOTO 2320
2310 PRINT "YOU'D BETTER STUDY THIS A LITTLE MORE AND TRY AGAIN LATER."
2320 FOR I = 1 TO 2500: NEXT I
2330 PRINT : PRINT "THANK YOU VERY MUCH.": PRINT : PRINT "BYE!"
2340 END
10305 REM
10310 REM VARIABLE CLARIFICATION:
10320 REM A$(I) = NAMES OF PROGRAMMERS FOR RANDOM BILLING
10330 REM I = VARIOUS LOOPS
10340 REM B(X) = RANDOM BILLING
10350 REM N$ = NAME OF USER
10360 REM N AND X$ = OPERATION NUMBERS
10370 REM K$ AND K = NUMBER OF PROBLEMS
10380 REM N1 = FIRST NUMERATOR
10390 REM D1 = FIRST DENOMINATOR
10400 REM N2 = SECOND NUMERATOR
10410 REM D2 = SECOND DENOMINATOR
10420 REM C1 = CORRECT NUMERATOR
10430 REM C2 = CORRECT DENOMINATOR
10435 REM X = SMALLER OF C1 AND C2
10440 REM A$ = INPUT ANSWER
10450 REM B$ = CORRECT ANSWER
10460 REM J = REDUCING LOOP FOR COMMON DENOMINATOR
10470 REM Q$ = ANSWER TO SEEING HOW PROBLEM DONE
10480 REM Y = RANDOM NUMBER FOR CORRECT/INCORRECT REMARK
10490 REM TK = TOTAL PROBLEMS WORKED
10495 REM PER = PERCENT CORRECT
10498 REM ********************
10500 REM THIS PROGRAM WAS
10505 REM
10510 REM WRITTEN AS A
10515 REM
10520 REM COMPUTER MATH 2
10525 REM
10530 REM ASSIGNMENT AT
10535 REM
10540 REM DUNEDIN HIGH SCHOOL
10545 REM
10550 REM DUNEDIN, FLORIDA
10555 REM
10560 REM PLEASE SEND ANY
10570 REM COMMENTS, QUESTIONS,
10580 REM OR IMPROVEMENTS TO:
10585 REM
10590 REM CAROL SMITH
10600 REM 2052 BRENDLA RD.
10610 REM CLEARWATER, FL 33515
10615 REM
10620 REM THANK YOU!!
10630 REM *******************

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/HELLO.bas:

1 REM HELLO
10 D$ = CHR$(4)
30 TEXT : HOME : VTAB 1
32 HTAB 4: INVERSE : PRINT " ": NORMAL
35 HTAB 4: INVERSE : PRINT " WELCOME TO THE SOFTDISK HARVEST ": NORMAL
37 HTAB 4: INVERSE : PRINT " ": NORMAL
40 PRINT : PRINT : HTAB 6: PRINT "THIS PROGRAM IS NAMED HELLO.
50 PRINT : PRINT : HTAB 7: PRINT "IT IS PRELIMINARY TO ";: INVERSE : PRINT "MENU": NORMAL
90 PRINT : PRINT : HTAB 10: PRINT "1 = GETTING BACK TO ";: INVERSE : PRINT "MENU": NORMAL
100 PRINT : HTAB 10: PRINT "2 = ABOUT ";: INVERSE : PRINT "MENU": NORMAL
110 PRINT : HTAB 10: PRINT "3 = LET'S SEE THE ";: INVERSE : PRINT "MENU": NORMAL
112 VTAB 21: HTAB 10: PRINT "SOFTDISK MAGAZETTE"
114 HTAB 11: PRINT "3811 ST. VINCENT"
116 HTAB 8: PRINT "SHREVEPORT, LOUISIANA 71108"
120 VTAB 18: PRINT " WHICH ";: GET R$: PRINT R$
130 IF R$ = "1" GOTO 500
140 IF R$ = "2" GOTO 700
150 IF R$ = "3" THEN PRINT D$"RUN MENU"
160 GOTO 30
500 HOME : VTAB 2
510 INVERSE : PRINT "MENU";: NORMAL : PRINT " LEADS YOU INTO THE HARVEST PROGRAMS"
520 PRINT : PRINT "TO GET BACK TO ";: INVERSE : PRINT "MENU";: NORMAL : PRINT " AFTER ENTERING A"
530 PRINT : PRINT "HARVEST PROGRAM YOU SHOULD HIT RESET"
540 PRINT : PRINT "AND TYPE IN 'RUN MENU'"
550 PRINT : PRINT : PRINT "SOMETIMES A PROGRAM WILL LEAVE THINGS"
560 PRINT : PRINT "MESSED UP AND GIVE YOU AN OUT OF MEMORY"
570 PRINT : PRINT "ERROR."
580 PRINT : PRINT : PRINT "WHEN THAT HAPPENS YOU SHOULD REBOOT."
650 PRINT : PRINT : HTAB 12: INVERSE : PRINT "HIT SPACE BAR ";: GET R$: PRINT D$: GOTO 30
700 HOME : VTAB 2
710 INVERSE : PRINT "MENU";: NORMAL : PRINT " WAS WRITTEN BY DALE SALYER."
720 PRINT : PRINT "DAN TOBIAS ADDED THE NESTED FEATURE."
740 PRINT : PRINT : PRINT : PRINT "YOU CAN ALTER ";: INVERSE : PRINT "MENU";: NORMAL : PRINT " FOR YOUR OWN NEEDS."
760 PRINT : PRINT : PRINT : PRINT "WE SUGGEST YOU MAKE A COPY OF IT ON"
780 PRINT : PRINT "ANOTHER DISK BEFORE EXPERIMENTING."
790 PRINT : PRINT : PRINT : INVERSE : PRINT "MENU";: NORMAL : PRINT " CAN CREATE AN EXEC FILE AND ALTER"
800 PRINT : PRINT "ITSELF."
850 PRINT : HTAB 12: INVERSE : PRINT " HIT SPACE BAR ";: GET R$: PRINT D$: GOTO 30

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/INT.ALERT.PROG.bas:

100 ONERR GOTO 410
110 A$ = "300: 20 EA 03 20 66 D5 N 3F2:00 03 A6 N D7D2G": FOR I = 1 TO LEN(A$): POKE 511 +I, ASC( MID$ (A$,I,1)) +128: NEXT : POKE 72,0: CALL -144
120 REM
130 REM ABOVE SETS UP A ROUTINE
140 REM WHICH MAKES THE PROGRAM
150 REM RESTART WHENEVER THE
160 REM RESET KEY IS PRESSED.
170 REM (FROM "RESETTING RESET"
180 REM BY BOB CLARDY & KEVIN
190 REM KILLION,PAGES 133-135
200 REM 'ALL ABOUT APPLESOFT')
210 REM
220 GOSUB 420
230 HOME : PRINT CHR$(7): GR : VTAB 21
240 BC = INT(15 * RND(1)) +1: COLOR= BC
250 FOR Y = 0 TO 39: HLIN 0,39 AT Y: NEXT
260 PRINT "AN INTRUDER HAS PENETRATED ";: FLASH : PRINT "SECSYS-342": NORMAL : PRINT
270 PRINT TWN$" ";: INVERSE : PRINT "POLICE";: NORMAL : PRINT " AND ";: INVERSE : PRINT "FIRE DEPARTMENT";: NORMAL : PRINT "HAVE BEEN NOTIFIED AND ARE ENROUTE...";
280 CO = INT(16 * RND(1) +1): IF CO = OCO OR CO = BC THEN 280
290 COLOR= CO:OCO = CO
300 READ Y1,Y2,X: IF NOT Y1 THEN 320
310 VLIN Y1,Y2 AT X: GOTO 300
320 RESTORE :T = T +1: IF T < >5 THEN 280
330 T = 0:BC = INT(15 * RND(1)) +1: COLOR= BC: FOR Y = 0 TO 39: HLIN 0,39 AT Y: NEXT : GOTO 230
340 DATA 1,4,0,16,19,0,1,19,1,1,19,2,1,4,3,16,19,3,1,19,5,4,12,6,7,16,7,21,39,7,1,19,8,21,24,8,31,32,8,21,24,9,31,32,9,1,4,10,21,39,10
350 DATA 1,19,11,1,19,12,21,39,12,1,4,13,36,39,13,36,39,14,1,19,15,36,39,15,1,1,16,10,10,16,12,14,16,1,1,17,7,10,17,14,16,17,21,39,17
360 DATA 1,7,18,16,19,18,21,24,18,29,31,18,36,39,18,21,24,19,29,31,19,36,39,19,1,19,20,21,24,20,36,39,20,16,19,21,16,19,22,21,39,22
370 DATA 1,19,23,21,21,23,30,30,23,32,34,23,21,21,24,27,30,24,34,36,24,1,19,25,21,27,25,36,39,25,2,4,26,16,18,26,3,7,27,14,17,27,21,24,27
380 DATA 5,15,28,21,39,28,21,39,29,1,19,30,21,24,30,1,4,31,9,11,31,16,19,31,1,4,32,9,11,32,16,19,32,1,4,33,16,19,33,1,19,35,1,1,36,10,10,36
390 DATA 12,14,36,1,1,37,7,10,37,14,16,37,1,7,38,16,19,38
400 DATA 0,0,0
410 RESUME
420 TWN$ = "WEST HARTFORD": RETURN
430 REM ^ YOUR CITY OR TOWN ^
440 REM NO MORE THAN 13 CHARS
65535 REM JIM GANZ,10/81 & 6/82
65535 REM 82 SPRING LANE
65535 REM W.HARTFORD, CT. 06107
65535 REM
65535 REM CAUTION: THE ONLY WAY
65535 REM TO GET OUT OF THIS
65535 REM ONCE IT HAS BEEN RUN
65535 REM IS TO TURN OFF THE
65535 REM COMPUTER!

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/INTRUDER.ALERT.bas:

0 GOTO 10
5 HTAB 20 - LEN(A$)/2 +1: PRINT A$: RETURN
10 TEXT : HOME
20 INVERSE :A$ = " INTRUDER ALERT! ": GOSUB 5
30 NORMAL : PRINT
40 A$ = "BY JIM GANZ": GOSUB 5
50 PRINT
60 PRINT "JUST HOW SMART ARE BURGLARS ANYWAY?"
70 PRINT "HOPEFULLY, NOT VERY."
80 PRINT
90 PRINT "THE FOLLOWING PROGRAM IS A BOGUS WARNINGSYSTEM THAT GRAPHICALLY BOASTS THAT IT HAS DETECTED AN INTRUDER IN THE HOUSE."
100 PRINT
110 PRINT "IF A BURGLAR COMES ACROSS THIS DISPLAY HE MAY THINK TWICE BEFORE CONTINUING TO GO ABOUT HIS 'BUSINESS.'"
120 PRINT
130 PRINT "CHANGE TWN$ IN LINE 420 TO THE NAME OF YOUR CITY OR TOWN... NOTE THAT YOU CAN'TEXIT THE PROGRAM WITHOUT TURNING THE COMPUTER OFF AND ON."
140 PRINT
150 PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : PRINT " TO RUN, ";: INVERSE : PRINT "ESC";: NORMAL : PRINT " TO QUIT ";
160 POKE -16368,0: GET A$
170 PRINT
180 IF ASC(A$) = 13 THEN PRINT CHR$(4)"RUNINT.ALERT.PROG"
190 IF ASC(A$) = 27 THEN END
200 RUN

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/JFK.bas:

10 HOME
20 PRINT "TURN ON YOUR PRINTER AND PRESS RETURN"
30 INPUT A$
40 PR# 1
100 PRINT SPC( 12);"::::$$$$$$$$$$$$$$$"
110 PRINT SPC( 9);":::::$$$$$$$$$$$$$$$$$$$$$"
120 PRINT SPC( 7);"::::$$$$$$$$$$$$$::$$:::$$$$$$"
130 PRINT SPC( 5)":::$$:$$$$$$$$$$$$$$::$$$$$$$$$$"
140 PRINT " :::$:$$$$$$$$$$$$$$$$$$:$$$$$$$$$$$$
150 PRINT " :::$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$"
160 PRINT " :::$$::$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$"
170 PRINT " ::::$::$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$"
180 PRINT " ::::::$$$$$$$$$$$$$$$$$$$$$$$$$$$:::::$$$"
190 PRINT ":::::$::$$$$$$$$$$$$$$$$$$$$$$:::::::::$$$$"
200 PRINT ":::::::$$$$$$$$$$$$::::::::::::::::$$$$$$$$"
210 PRINT "::::::$:::::::::::::::::::::::::::::$$$$$$"
220 PRINT " :::$$:::::::::::::::::::::::::::::$$$$$$$"
230 PRINT " ::$$$:::::::::::::::::::::::::::::$$$$$$$$"
240 PRINT " $$$$:::::::::::::::::::::::::::::$$$$$$$"
250 PRINT " $$:::::::::::::::::::::::::::::::::$$$$$:"
260 PRINT " $$::::::::::::::::::::$$$$::::::::$$$$$$:"
270 PRINT " $:::::::$$::$$$$:::::$$::::$$$$::::$$$$$$"
280 PRINT " $:$:::::$$:$$$::$$::::$$::$$$$$$:::::$$:$$"
290 PRINT " $:$:::::::$$$$::$::::::::$$$$:::::::::$::$$"
300 PRINT " $$:$$::::::::::::$:::::::::::::::::::::::$$"
310 PRINT " $:$$::::::::::::$:::::::::::::::::::::$::$"
320 PRINT " $:$$::::::::::::$:::::::::::::::::::::$$:$"
330 PRINT " $::::::::::::$$:::::$$:::::::::::::::$$$"
340 PRINT " $::::::::::::$$$$$$$$::::::::::::::::$$"
350 PRINT " ::::::::::::$$$$::::::::::::::::::::$"
360 PRINT " :::::::::::::::::::::::::::::::::::"
370 PRINT " ::::::::::::$$$:$$$:::::::::::::::"
380 PRINT " ::::::::$$$$$$$$$$$::$::::::::::"
390 PRINT " ::::::::$::::::::::$:::::::::::"
400 PRINT " :::::::::$$$$$$$$$$:::::::::::"
410 PRINT " ::::::::::$$$$$$:::::::::::$::"
420 PRINT " $$:::::::::::::::::::::$$:::"
430 PRINT " $$$:::::::::::::::::$$$:::"
440 PRINT " $$$$$:::::::::::$$$$$$:::"
450 PRINT " $$$$$$$$$$$$$$$$$$$$::::"
460 PRINT " $$$$$$$$$$$$$$$$$$::::"
470 PRINT " $$$$$$$$$$$$$:::::"
480 PRINT " $$$$$$$$$$$::::"
490 PRINT " $$$$$$$::::"
500 PRINT " $$$$$$"

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/MEMORY.TEST.bas:

10 GOSUB 200
60 FOR I = IO TO IS:BS = PEEK(I): POKE (I),B%:A% = PEEK(I): IF A% < >B% THEN VTAB I7: PRINT "ERROR AT"I:I7 = I7 +1
70 POKE (I),C%:A% = PEEK(I): IF A% < >C% THEN VTAB I7: PRINT "ERROR AT "I:ER = 1
80 POKE I,BS: VTAB 1: HTAB 1: PRINT I: NEXT
90 IF ER = 1 THEN END
100 PR# 6
200 TEXT : HOME : PRINT "THIS WILL TEST THE RAM IN YOUR APPLE": PRINT "IT SKIPS SOME AREAS DUE TO THE DOS ": PRINT "AND I/O HOOKS AND ALSO TO AVOID": PRINT "CLOBBERING THE PROGRAM ITSELF": PRINT "IT TAKES A WHILE SO IF YOU STOP IT"
210 PRINT "YOU HAVE THE OPTION OF RESTARTING": PRINT "LATER ON": PRINT : PRINT "IF ANY ERRORS ARE ENCOUNTERED": PRINT "THEY ARE LISTED": PRINT "IF EVERYTHING IS OK": PRINT "THE PROGRAM REBOOTS": PRINT "SO LEAVE A DISK IN YOUR DRIVE"
220 PRINT : FLASH : PRINT "HIT ANY KEY": GET A$: NORMAL : HOME
400 B% = 255:IO = 3000:IS = 48000:C% = 0:I7 = 2
410 POKE 34,1
430 PRINT "RESUME OR START": GET A$: IF A$ = "S" THEN 450
440 INPUT "WHERE";IO
450 HOME : HTAB 1: VTAB 1: PRINT " "
500 RETURN

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/MENU.bas:

2 ID$ = "SEPTEMBER 82 SOFTDISK HARVEST"
3 PN$ = "HARVEST.MENU"
5 REM *************************** ** FLEXIBLE MENU PROGRAM ** BY DALE SALYER ** JULY 25, 1981 ** *****************************
7 REM *************************** ** NESTED MENU FEATURE ** ADDED BY DANIEL TOBIAS ** FEBRUARY 6, 1982 ** *****************************
10 D$ = CHR$(13) + CHR$(4):Q$ = CHR$(34):Q1$ = Q$ +"," +Q$
20 DIM DESC$(20,20),CMD$(20,20),FILE$(20,20)
30 DIM NP(20)
40 READ NM: FOR A = 0 TO NM
50 READ NP(A): FOR B = 0 TO NP(A)
60 READ DESC$(A,B),CMD$(A,B),FILE$(A,B)
70 NEXT B,A
80 M = 0
90 GOTO 300
150 K = PEEK( -16384)
160 IF K <128 THEN 150
170 POKE -16368,0:C = K -192
180 IF K = 141 THEN TEXT : HOME : PRINT D$;"CATALOG": END
190 IF K = 160 THEN GOSUB 250: GOTO 150
195 IF K = 187 AND CM$(M,0) < >"" THEN F$ = CM$(M,0): POP : GOTO 900
200 IF K = 155 THEN TEXT : HOME : END
210 IF K = 175 THEN 500
220 IF C <1 OR C >NP(M) THEN 150
222 IF VAL(CMD$(M,C)) >0 OR CMD$(M,C) = "0" THEN POP :F$ = CMD$(M,C): GOTO 900
225 VTAB 19: PRINT CMD$(M,C);FILE$(M,C)
227 TEXT : HOME
230 PRINT D$;CMD$(M,C);FILE$(M,C)
240 END
245 REM ************************* ** PRINT NEXT PAGE OF ** PROGRAMS. ** *****************************
250 HOME : FOR I = OL TO OL +4:VT = (I -OL +1) *2 +6
260 HTAB 3: VTAB VT: PRINT CHR$(64 +I);: HTAB 10: PRINT DESC$(M,I)
270 IF I > = NP(M) THEN OL = 1: RETURN
280 NEXT I
290 OL = OL +5: RETURN
300 REM ************************* ** PROGRAM START ** *****************************
310 TEXT : HOME : INVERSE : PRINT "**** FLEXIBLE MENU : BY DALE SALYER ****NESTED MENU FEATURE ADDED BY DAN TOBIAS ";
320 NORMAL : PRINT "----------------------------------------";ID$;: IF LEN(ID$) <40 THEN PRINT
330 PRINT "----------------------------------------"
332 HTAB 10: VTAB 6: PRINT DESC$(M,0)
335 POKE 34,6
337 INVERSE
340 VTAB 23: HTAB 11: PRINT " CATALOG "
350 VTAB 22: HTAB 11: PRINT " NEXT PAGE "
360 VTAB 21: HTAB 11: PRINT "APE TO BASIC "
370 VTAB 20: HTAB 11: PRINT " / CHANGE THE MENU "
372 P = 19
375 IF CM$(M,0) < >"" THEN VTAB 19: HTAB 11: PRINT " ; PREVIOUS MENU ":P = 18
380 VTAB P: HTAB 11: PRINT "A - "; CHR$(64 +NP(M));" SELECT PROG. "
390 NORMAL : POKE 35,17: REM BOTTOM
400 OL = 1
420 GOSUB 250
430 GOSUB 150
440 END
500 REM ************************* ** ENTER NEW DATA ** *****************************
502 TEXT : HOME : PRINT "(HIT RETURN IF UNCHANGED)": PRINT "ENTER DISK I.D. LINE:": INPUT "";I$: IF I$ < >"" THEN ID$ = I$
503 PRINT : INPUT "NAME TO SAVE THIS PROGRAM UNDER: ";P$: IF P$ < >"" THEN PN$ = P$
505 M = 0:NM = 0
507 FILE$(0,0) = "":CMD$(0,0) = "":DESC$(0,0) = ""
510 TEXT : HOME : HTAB 10: PRINT "DATA STATEMENT ENTRY": POKE 34,3: FOR I = 1 TO 20: HOME
515 PRINT "ENTERING MENU #"M" "DESC$(M,0)
520 VTAB 5: PRINT "NAME OF PROGRAM ": INPUT FILE$(M,I)
524 IF FILE$(M,I) = "QUIT" THEN 600
526 IF FILE$(M,I) = "CAT" THEN PRINT D$;"CATALOG": PRINT : PRINT "PRESS RETURN TO CONTINUE": GET R$: HOME : GOTO 520
528 IF FILE$(M,I) = "" THEN PRINT "THIS WILL BE MENU #";NM +1:NM = NM +1:CMD$(M,I) = STR$(NM):CMD$(NM,0) = STR$(M):FILE$(NM,0) = "":DESC$(NM,0) = "": GOTO 580
530 VTAB 10: PRINT "TYPE OF FILE - XEC, RUN, UN";: INPUT C$
535 C$ = LEFT$(C$,1)
540 IF C$ = "E" THEN CMD$(M,I) = "EXEC ": PRINT : PRINT " EXEC": GOTO 580
550 IF C$ = "B" THEN CMD$(M,I) = "BRUN ": PRINT : PRINT " BRUN": GOTO 580
560 IF C$ = "R" THEN CMD$(M,I) = "RUN ": PRINT : PRINT " RUN": GOTO 580
570 GOTO 530
580 VTAB 15: PRINT "DESCRIPTION (25 CHAR. MAX.) :"
590 VTAB 17: HTAB 1: PRINT "_________________________!": VTAB 17: HTAB 1
595 INPUT DESC$(M,I): IF FILE$(M,I) = "" THEN DESC$(NM,0) = DESC$(M,I)
597 NEXT I
600 NP(M) = I -1
605 IF M

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/NFL.DATA.txt:

54
37
91
32
21
53
34
52
86
34
51
85
52
48
100
36
35
71
46
51
97
42
44
86
52
45
97
45
37
82
37
39
76
37
49
86
35
44
79
41
51
92
36
38
74
36
36
72
29
37
66
36
55
91
40
54
94
40
35
75
43
57
100
43
47
90
40
32
72
61
32
93
43
55
98
48
33
81
40
53
93
47
44
91

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/NFL.MATCHUPS.txt:

1
18
2
27
3
21
22
11
24
6
15
12
4
19
8
20
23
10
9
26
28
14
13
16
17
7
5
25

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/NFL.RANKER.bas:

10 REM ********************** * * * NFL RANKING SYSTEM * * ORIGINAL CONCEPT * * BY JOSEPH M. FEEHAN * * *
15 REM * * RE-ORGANIZED AND * * EXPANDED TO HANDLE * * A WHOLE WEEK'S * * GAMES, IMPROVED THE * * PRINTER OUTPUT, AND *
20 REM ADDED NESTED MENU * * FEATURES. * * BY: * * DALE E. SALYER * * * *************************
45 REM * * *** DATA STATEMENTS*** * *
50 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
60 DATA SUNDAY,MONDAY,TUESDAY,WEDNESDAY,THURSDAY,FRIDAY,SATURDAY
70 DATA ATLANTA,BALTIMORE,BUFFALO,CHICAGO,CINCINNATI,CLEVELAND,DALLAS,DENVER,DETROIT,GREEN BAY,HOUSTON,KANSAS CITY,LOS ANGELES,MIAMI
80 DATA MINNESOTA,NEW ENGLAND,NEW ORLEANS,NEW YORK GIANTS,NEW YORK JETS,OAKLAND,PHILADELPHIA,PITTSBURGH,ST. LOUIS,SAN DIEGO,SAN FRANCISCO,SEATTLE,TAMPA BAY,WASHINGTON
90 REM ONERR STMT GOES HERE.
100 DIM R(28,3),N$(28),MO$(12),DA$(6),MA(14,2),Y(28)
110 DEF FN I(Z) = INT(Z +.5)
120 D$ = CHR$(4):LL = 40
130 PRINT D$;"OPEN NFL.DATA": PRINT D$;"READ NFL.DATA": FOR I = 1 TO 28
140 INPUT R(I,1): INPUT R(I,2): INPUT R(I,3): NEXT I: PRINT D$;"CLOSE NFL.DATA"
150 PRINT D$;"OPEN NFL.MATCHUPS": PRINT D$;"READ NFL.MATCHUPS": FOR I = 1 TO 14
160 INPUT MA(I,0): INPUT MA(I,1): NEXT I: PRINT D$;"CLOSE NFL.MATCHUPS"
170 FOR I = 1 TO 12: READ MO$(I): NEXT I
180 FOR I = 0 TO 6: READ DA$(I): NEXT I
190 FOR I = 1 TO 28: READ N$(I): NEXT I
200 FOR I = 1 TO 28:R(I,0) = I: NEXT I
205 REM * * **** DATE ROUTINE **** * *
210 IF PEEK(1016) >99 OR PEEK(1017) >12 OR PEEK(1018) >31 THEN DT$ = "": GOTO 250
220 YR$ = STR$(1900 + PEEK(1016)):M$ = MO$( PEEK(1017)):DN$ = STR$( PEEK(1018)):WD$ = "": IF PEEK(1019) < = 6 THEN WD$ = DA$( PEEK(1019))
230 DT$ = WD$ +" " +M$ +" " +DN$ +", " +YR$
244 :
245 REM ********************* * * * MAIN MENU * * * ************************
250 TEXT : HOME : HTAB 10: PRINT "NFL RANKING PROGRAM"
260 VTAB 5: PRINT " 1 - INPUT WEEK'S MATCHUPS.": VTAB 7: PRINT " 2 - DISPLAY PREDICTIONS.": VTAB 9: PRINT " 3 - UPDATE RANKINGS.": VTAB 11: PRINT " 4 - DISPLAY RANKINGS.": VTAB 13: PRINT " 5 - SAVE FILES TO DISK.": VTAB 15: PRINT " 6 - END PROGRAM."
270 VTAB 21: PRINT "WHICH OPTION (1-6) : ";: INPUT "";R$:CH = VAL(R$): IF CH <1 OR CH >6 THEN 250
280 ON CH GOTO 500,300,350,400,1050,290
290 IF UPD AND NOT WRIT THEN HOME : VTAB 12: PRINT "YOU HAVE CHANGED SOME RANKINGS AND HAVE NOT SAVED THEM TO DISK.": PRINT : PRINT "DO YOU WANT TO SAVE THEM BEFORE QUITTING?";: INPUT "";R$: IF LEFT$(R$,1) < >"N" THEN GOTO 250
295 TEXT : HOME : VTAB 12: HTAB 16: PRINT "GOOD-BYE": END
300 TEXT : HOME : HTAB 8: PRINT "DISPLAY PREDICTIONS MENU"
310 VTAB 10: PRINT " 1 - PREDICT ALL MATCHUPS.": VTAB 15: PRINT " 2 - PREDICT INDIVIDUAL TEAMS."
320 VTAB 21: PRINT "WHICH OPTION (1-2, RETURN>=NONE) : ";: INPUT "";R$: IF R$ = "" THEN 250
330 CH = VAL(R$): IF CH <1 OR CH >2 THEN 300
340 ON CH GOTO 1250,1440
350 TEXT : HOME : HTAB 10: PRINT "UPDATE RANKINGS MENU"
360 VTAB 10: PRINT " 1 - UPDATE ALL MATCHUPS.": VTAB 15: PRINT " 2 - UPDATE INDIVIDUAL TEAMS."
370 VTAB 21: PRINT "WHICH OPTION (1-2, RETURN>=NONE) : ";: INPUT "";R$: IF R$ = "" THEN 250
380 CH = VAL(R$): IF CH <1 OR CH >2 THEN 350
390 ON CH GOTO 1650,1700
400 TEXT : HOME : HTAB 9: PRINT "DISPLAY RANKINGS MENU"
410 VTAB 6: PRINT " 1 - ALPHABETIC ORDER.": VTAB 10: PRINT " 2 - OFFENSIVE RANK ORDER.": VTAB 14: PRINT " 3 - DEFENSIVE RANK ORDER.": VTAB 18: PRINT " 4 - TOTAL TEAM RANK ORDER."
420 VTAB 21: PRINT "WHICH OPTION (1-4, RETURN>=NONE) : ";: INPUT "";R$: IF R$ = "" THEN 250
430 CH = VAL(R$): IF CH <1 OR CH >4 THEN 400
440 KEY = CH -1: GOTO 750
445 REM * * *** PRINTER INIT. *** * *
450 SLOT = 1: REM PRINTER SLOT
460 PRINT D$;"PR#";SLOT
465 PRINT CHRS$(9);"80N"
470 LL = 80
480 RETURN
495 REM * * *** INPUT MATCHES *** * *
500 TEXT : HOME : VTAB 1: HTAB 13: PRINT "INPUT MATCHUPS": VTAB 2: HTAB (40 - LEN(DT$))/2: PRINT DT$
510 FOR R = 1 TO 28:Y(R) = 0: NEXT R
520 VTAB 3: HTAB 14: PRINT "TEAM NUMBERS"
530 FOR I = 1 TO 14: VTAB 4 +I: HTAB 1: IF I <10 THEN PRINT " ";
540 PRINT I;"- ";N$(I);: HTAB 21: PRINT I +14;"- ";N$(I +14)
550 NEXT I: VTAB 20: HTAB 13: PRINT "GAME #"
560 POKE 34,21
570 FOR Z = 1 TO 14: VTAB 20: HTAB 20: PRINT Z
580 VTAB 22: HTAB 1: CALL -958: INPUT " HOME TEAM # =>";R$:R = VAL(R$)
590 IF R <1 OR R >28 THEN 610
600 IF Y(R) = 0 THEN MA(Z,0) = R:Y(R) = 1: GOTO 620
610 VTAB 23: PRINT "INVALID TEAM # - TRY AGAIN!!": FOR DD = 1 TO 500: NEXT : GOTO 580
620 VTAB 22: HTAB 1: CALL -958: INPUT " AWAY TEAM # =>";R$:R = VAL(R$)
630 IF R <1 OR R >28 THEN 650
640 IF Y(R) = 0 THEN MA(Z,1) = R:Y(R) = 1: GOTO 660
650 VTAB 23: PRINT "INVALID TEAM # - TRY AGAIN!!": FOR DD = 1 TO 500: NEXT : GOTO 620
660 VTAB 22: HTAB 3: CALL -958: PRINT N$(MA(Z,1));" AT ";N$(MA(Z,0))
670 VTAB 23: HTAB 10: PRINT "CORRECT (Y/N) ";: INPUT "";R$:R$ = LEFT$(R$,1)
680 IF R$ = "N" THEN Y(MA(Z,0)) = 0:Y(MA(Z,1)) = 0: GOTO 580
690 VT = MA(Z,0) -14 *(MA(Z,0) >14) +4:HT = 5 +20 *(MA(Z,0) >14)
700 VTAB VT: HTAB HT: PRINT " "
710 VT = MA(Z,1) -14 *(MA(Z,1) >14) +4:HT = 5 +20 *(MA(Z,1) >14)
720 VTAB VT: HTAB HT: PRINT " ": NEXT : FOR R = 1 TO 14:MA(R,2) = 0: NEXT R: GOTO 250
745 REM * * *** RANK DISPLAY *** * *
750 TEXT : HOME : HTAB 12: PRINT "DISPLAY RANKINGS"
760 LL = 40:PR = 0: VTAB 10: PRINT "DO YOU WANT A PRINTOUT? ";: INPUT "";R$:R$ = LEFT$(R$,1): IF R$ = "Y" OR R$ = "Y" THEN PR = 1: GOSUB 450
770 IF NOT KEY THEN 940
780 T1$ = " OFFENSIVE ": IF KEY >1 THEN T1$ = " DEFENSIVE ": IF KEY >2 THEN T1$ = " TOTAL "
785 T$ = "NFL" +T1$ +"RANKING LIST"
790 IF NOT PR THEN HOME
795 POKE 36,(LL - LEN(T$))/2: PRINT T$: IF PR THEN PRINT : IF LEN(DT$) < >0 THEN POKE 36,(LL - LEN(DT$))/2: PRINT DT$: PRINT
800 POKE 36,1 +22 *PR: PRINT "RANK";: POKE 36,6 +22 *PR: PRINT "TOTAL";: POKE 36,12 +22 *PR: PRINT "TEAM NAME";: POKE 36,28 +22 *PR: PRINT "(OFF-DEF)": PRINT
810 IF NOT PR THEN POKE 34,3
820 FOR I = 1 TO 28: FOR H = 1 TO 28
830 L = R(H,KEY): IF R(H,0) = 999 THEN 850
840 IF L > = L1 THEN J = H:L1 = L
850 NEXT H
860 R(J,0) = 999
870 POKE 36,1 +22 *PR: PRINT RIGHT$(" " + STR$(I),2);: POKE 36,7 +22 *PR: PRINT RIGHT$(" " + STR$(R(J,3)),3);: POKE 36,12 +22 *PR: PRINT N$(J);: POKE 36,28 +22 *PR: PRINT "(";R(J,1);" - ";R(J,2);")"
880 IF NOT PR AND I = 18 THEN PRINT : INPUT "PRESS TO SEE REST OF TEAMS.";R$: HOME
890 L1 = 0: NEXT I
900 IF PR THEN PRINT CHR$(12): PRINT D$;"PR#0"
910 PRINT : INPUT "PRESS TO SEE MENU ";R$
920 FOR I = 1 TO 28:R(I,0) = I: NEXT I
930 GOTO 250
940 IF NOT PR THEN HOME
950 T$ = "NFL ALPHABETIC RANKING LIST"
955 POKE 36,(LL - LEN(T$))/2: PRINT T$: IF PR THEN PRINT : IF LEN(DT$) < >0 THEN POKE 36,(LL - LEN(DT$))/2: PRINT DT$: PRINT
960 POKE 36,1 +22 *PR: PRINT "RANK";: POKE 36,6 +22 *PR: PRINT "TOTAL";: POKE 36,12 +22 *PR: PRINT "TEAM NAME";: POKE 36,28 +22 *PR: PRINT "(OFF-DEF)": PRINT
965 IF NOT PR THEN POKE 34,3
970 FOR I = 1 TO 28
980 POKE 36,1 +22 *PR: PRINT RIGHT$(" " + STR$(I),2);: POKE 36,7 +22 *PR: PRINT RIGHT$(" " + STR$(R(I,3)),3);: POKE 36,12 +22 *PR: PRINT N$(I);: POKE 36,28 +22 *PR: PRINT "(";R(I,1);" - ";R(I,2);")"
990 IF NOT PR AND I = 18 THEN PRINT : INPUT "PRESS TO SEE REST OF TEAMS.";R$: HOME
1000 NEXT I
1010 IF PR THEN PRINT CHR$(12): PRINT D$;"PR#0"
1020 PRINT : INPUT "PRESS TO SEE MENU ";R$
1030 FOR I = 1 TO 28:R(I,0) = I: NEXT I
1040 GOTO 250
1045 REM * * **** SAVE FILES **** * *
1050 TEXT : HOME : HTAB 12: PRINT "SAVE FILES MENU"
1060 VTAB 10: PRINT " 1 - MATCHUPS FILE.": VTAB 15: PRINT " 2 - RANKINGS FILE."
1070 VTAB 21: PRINT "WHICH OPTION (1-2,=NONE) : ";: INPUT "";R$: IF R$ = "" THEN 250
1080 CH = VAL(R$): IF CH <1 OR CH >2 THEN 1050
1090 ON CH GOTO 1100,1150
1100 REM PRINT D$;"UNLOCK NFL.MATCHUPS": PRINT D$;"OPEN NFL.MATCHUPS": PRINT D$;"DELETE NFL.MATCHUPS"
1110 PRINT D$;"OPEN NFL.MATCHUPS": PRINT D$;"WRITE NFL.MATCHUPS"
1120 FOR I = 1 TO 14: PRINT MA(I,0): PRINT MA(I,1): NEXT I
1130 PRINT D$;"CLOSE NFL.MATCHUPS": PRINT D$;"LOCK NFL.MATCHUPS"
1140 GOTO 1050
1150 REM PRINT D$;"UNLOCK NFL.DATA": PRINT D$;"OPEN NFL.DATA": PRINT D$;"DELETE NFL.DATA"
1160 PRINT D$;"OPEN NFL.DATA": PRINT D$;"WRITE NFL.DATA"
1170 FOR I = 1 TO 28: PRINT R(I,1): PRINT R(I,2): PRINT R(I,3): NEXT I
1180 PRINT D$;"CLOSE NFL.DATA": PRINT D$;"LOCK NFL.DATA"
1190 WRIT = 1: GOTO 1050
1195 REM * * *** PREDICTIONS *** * *
1200 SA = (R(A,1) -R(B,2))/2 +21
1210 SB = (R(B,1) -R(A,2))/2 +21
1220 DTA = ABS(SA -SB)
1230 RETURN
1250 TEXT : HOME : HTAB 10: PRINT "PREDICT ALL MATCHUPS"
1260 VTAB 12: PRINT "DO YOU WANT A PRINTOUT?";: INPUT "";R$:R$ = LEFT$(R$,1): IF R$ = "Y" OR R$ = "Y" THEN 1350
1270 VTAB 3: CALL -958: FOR G = 1 TO 14:A = MA(G,0):B = MA(G,1)
1280 NA$ = N$(A) +" (HOME)":NB$ = N$(B): GOSUB 1200
1290 IF SA >SB THEN PRINT NA$;" OVER ";NB$: HTAB 25: PRINT "BY ";DTA;" POINTS."
1300 IF (SB >SA) THEN PRINT NB$;" OVER ";NA$: HTAB 25: PRINT "BY ";DTA;" POINTS."
1310 IF SA = SB THEN PRINT NA$;" AND ";NB$: HTAB 25: PRINT "WILL BE TIED."
1320 PRINT : IF G = 5 OR G = 10 THEN PRINT : PRINT "PRESS TO CONTINUE";: INPUT "";R$: VTAB 3: CALL -958
1330 NEXT G: PRINT "PRESS TO CONTINUE";: INPUT "";R$: GOTO 250
1350 GOSUB 450
1360 T$ = "NFL GAME PREDICTIONS": IF DT$ < >"" THEN T$ = T$ +" - " +DT$
1370 POKE 36,(LL - LEN(T$))/2: PRINT T$: PRINT
1380 FOR G = 1 TO 14:A = MA(G,0):B = MA(G,1)
1390 NA$ = N$(A) +" (HOME)":NB$ = N$(B): GOSUB 1200
1400 IF SA >SB THEN PRINT NA$;" OVER ";NB$;" BY ";DTA;" POINTS."
1410 IF (SB >SA) THEN PRINT NB$;" OVER ";NA$;" BY ";DTA;" POINTS."
1420 IF SA = SB THEN PRINT NA$;" AND ";NB$;" WILL BE TIED."
1430 PRINT : NEXT G: PRINT D$;"PR#0": PRINT : PRINT "PRESS TO CONTINUE";: INPUT "";R$: GOTO 250
1440 TEXT : HOME : HTAB 8: PRINT "PREDICT INDIVIDUAL TEAMS"
1450 VTAB 8: CALL -958: PRINT "GIVE ME THE FIRST TEAM'S NAME";: INPUT T$:T = LEN(T$): FOR I = 1 TO 28: IF T$ = LEFT$(N$(I),T) THEN 1470
1460 NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1450
1470 A = I: PRINT "IS THIS THE TEAM - ";N$(A);" ?";: INPUT "";R$: IF LEFT$(R$,1) = "N" THEN 1450
1480 VTAB 8: CALL -958: PRINT "GIVE ME THE SECOND TEAM'S NAME";: INPUT T$:T = LEN(T$): FOR I = 1 TO 28: IF T$ = LEFT$(N$(I),T) THEN 1500
1490 NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1480
1500 B = I: PRINT "IS THIS THE TEAM - ";N$(B);" ?";: INPUT "";R$: IF LEFT$(R$,1) = "N" THEN 1480
1510 NA$ = N$(A):NB$ = N$(B): GOSUB 1200: PRINT : PRINT
1520 IF SA >SB THEN PRINT NA$;" OVER ";NB$: HTAB 25: PRINT "BY ";DTA;" POINTS."
1530 IF (SB >SA) THEN PRINT NB$;" OVER ";NA$: HTAB 25: PRINT "BY ";DTA;" POINTS."
1540 IF SA = SB THEN PRINT NA$;" AND ";NB$: HTAB 25: PRINT "WILL BE TIED."
1550 PRINT : PRINT : PRINT "PRESS TO CONTINUE";: INPUT "";R$: GOTO 250
1600 GOSUB 1200
1610 VTAB 8: CALL -958: PRINT "PLEASE ENTER ";N$(A);"'S": INPUT " SCORE : ";SI$:S1 = VAL(SI$)
1615 VTAB 8: CALL -958: PRINT N$(A);"'S SCORE IS ";S1;" CORRECT? ";: INPUT "";R$: IF LEFT$(R$,1) = "N" THEN 1610
1620 VTAB 12: CALL -958: PRINT "PLEASE ENTER ";N$(B);"'S": INPUT " SCORE : ";SI$:S2 = VAL(SI$)
1625 VTAB 12: CALL -958: PRINT N$(B);"'S SCORE IS ";S2;" CORRECT? ";: INPUT "";R$: IF LEFT$(R$,1) = "N" THEN 1610
1630 R(A,1) = FN I(R(A,1) +((S1 -SA)/4)):R(B,2) = FN I(R(B,2) -((S1 -SA)/4))
1640 R(B,1) = FN I(R(B,1) +((S2 -SB)/4)):R(A,2) = FN I(R(A,2) -((S2 -SB)/4))
1645 R(A,3) = R(A,1) +R(A,2):R(B,3) = R(B,1) +R(B,2): RETURN
1650 TEXT : HOME : HTAB 14: PRINT "UPDATE RATINGS"
1660 FOR G = 1 TO 14:A = MA(G,0):B = MA(G,1)
1670 VTAB 5: HTAB 15: CALL -958: PRINT "GAME # ";G: GOSUB 1600
1680 NEXT G
1690 UPD = 1: GOTO 250
1700 TEXT : HOME : HTAB 4: PRINT "UPDATE INDIVIDUAL TEAM'S RATINGS"
1710 VTAB 8: CALL -958: PRINT "GIVE ME THE FIRST TEAM'S NAME";: INPUT T$:T = LEN(T$): FOR I = 1 TO 28: IF T$ = LEFT$(N$(I),T) THEN 1730
1720 NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1710
1730 A = I: PRINT "IS THIS THE TEAM - ";N$(A);" ?";: INPUT "";R$: IF LEFT$(R$,1) = "N" THEN 1710
1740 VTAB 8: CALL -958: PRINT "GIVE ME THE SECOND TEAM'S NAME";: INPUT T$:T = LEN(T$): FOR I = 1 TO 28: IF T$ = LEFT$(N$(I),T) THEN 1760
1750 NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1740
1760 B = I: PRINT "IS THIS THE TEAM - ";N$(B);" ?";: INPUT "";R$: IF LEFT$(R$,1) = "N" THEN 1740
1770 GOSUB 1600
1780 UPD = 1: GOTO 250
65535 REM ================== ! NFL RANKER PROGRAM ! ! BY ! ! DALE E. SALYER !
65535 REM ! ! RANKER ALGORITHM ! ! BY ! ! JOSEPH M. FEEHAN ! ! ! ====================
65535 REM <*><*><*><*><*><*> < THIS PROGRAM WAS > < ORIGINALLY PRINTED > < IN "NIBBLE" VOL2#7 > < BUT DID NOT HAVE > < ANY CAPABILITY TO >
65535 REM ENTER OR SAVE THE > < WEEKS MATCHUPS OF > < GAMES. THIS AND AN > < EXTENDED MENU OF > < FEATURES HAVE BEEN > < INCORPORATED INTO > < THE PROGRAM. > <*><*><*><*><*><*><*>

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 1.txt:

A-
AB-
AN-
DE-
DIS-
UN-
X
NOT
WITHOUT
AWAY
FROM
DOWN
XXX
ACR
ACRO
X
HEIGHT
HIGH
XXX
AD-
X
TO
TOWARD
AGAINST
XXX
AG-
AC-
X
DO
XXX
AGR
AGRI
AGRO
X
FARM
FIELD
XXX
ALTER-
HETERO-
X
OTHER
DIFFERENT
XXX
AMBI-
AMPHI-
X
BOTH
AROUND
XXX
AMBUL-
X
WALK
XXX
ANA-
X
UP
BACK
AGAIN
XXX
ANIMATO-
ANIM-
X
LIFE
SPIRIT
XXX
ANNU-
ENNI-
X
YEAR
XXX
ANTE-
PRE-
X
BEFORE
AHEAD OF TIME
IN FRONT OF
XXX
ANTHROPO-
VIR-
HOM-
HOMI-
X
MAN
XXX
ANTI
ANT
X
OPPOSING
AGAINST
XXX
AQUA-
HYDRA-
X
WATER
XXX
ARCH-
X
PRINCIPAL
RULER
XXX
ARD-
FERV-
X
GLOW
BURN
XXX
ASTER-
ASTERO-
X
STAR
XXX
AUDI
AUDIT
X
HEAR
LISTEN TO
XXX
AUTO-
X
SELF
SAME
XXX
BELL-
BELLI-
MAR-
MARTI-
X
WAR
XXX
BENE-
EU-
X
WELL
GOOD
XXX
BI-
DU-
DEUT-
DEUTERO-
X
TWO
XXX
BIBLI-
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 2.txt:

BIBLI-
BIBLIO-
LIBR-
X
BOOK
XXX
BIO-
VITA-
X
LIFE
XXX
CAD-
CAS-
X
FALL
XXX
CANT-
CHANT-
X
SING
XXX
CAPT-
CAPIT-
CEPH-
X
HEAD
XXX
CAP-
CEP-
X
TAKE
XXX
CARDI-
CORD-
X
HEART
XXX
CARN
CARNI
X
FLESH
X
CEDE-
CEED-
CESS-
GRESS-
X
GO
MOVE
X
CELER-
X
SPEED
XXX
CENT-
HECT-
X
100
HUNDRED
XXX
CHIRO-
MAN-
MANU-
X
HAND
XXX
CHROMO-
CHROMAT
X
COLOR
XXX
CHRON-
X
TIME
XXX
CID-
CIS-
SECT-
X
CUT
XXX
CIRCUM-
PERI-
X
AROUND
XXX
CIVI-
URB-
POLIT-
POLI-
X
CITY
XXX
CLUD-
CLUS-
X
SHUT
CLOSE
XXX
COGN-
SCI-
X
KNOW
KNOWLEDGE
XXX
CONTRA-
COUNTER-
X
AGAINST
OPPOSED
XXX
CORP-
CORPOR-
X
BODY
XXX
COSM-
COSMO-
X
WORLD
XXX
CRAT-
-CRACY
POT-
X
POWER
POWERFUL
STRENGTH
XXX
CRED-
CREDIT-
X
BELIEVE
XXX
CRESC-
-CREASE
X
GROW
X
CUM-
CO-
COM-
CON-
SYN-
SYM-
SYM-
X
TOGETHER
WITH
X
XZX
T-
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 3.txt:

CUM-
CO-
COM-
CON-
SYN-
SYM-
SYM-
X
TOGETHER
WITH
X
CRYPT-
CRYPTO
X
SECRET
HIDDEN
X
CUR-
CURR-
COURS-
X
RUN
RUNNING
X
DEB-
DEBT-
X
OWE
X
DEC-
X
10
TEN
X
DEMI-
SEMI-
HEMI-
X
HALF
X
DENT-
DONT-
X
TOOTH
X
DEXTER-
DEXTRO-
X
RIGHT HANDED
RIGHT-HANDED
X
DEM-
POPUL-
DEMO-
X
PEOPLE
X
DERM-
X
SKIN
X
DE
DEUS
THEO-
X
GOD
X
DI-
DIA-
X
THROUGH
BETWEEN
APART
ACROSS
X
DICT-
LOQU-
LOCU-
X
SPEAK
SAY
X
DIURN-
DIES
JOUR-
JOURN-
EPHEMER
X
DAY
DAILY
X
DOC-
DOCTRIN-
DOX-
X
TEACH
X
DOM-
DOMIN-
DON
X
RULE
GOVERN
X
DORM-
SOMN-
X
SLEEP
X
DUC-
DUCAT-
DUCT-
X
LEAD
X
DULC-
X
SWEET
X
EPI-
X
UPON
ABOVE
X
EQU-
X
EQUAL
X
E-
EX-
EC-
EF-
X
FROM
OUT
X
FACT-
FECT-
FICT-
-FY
X
MAKE
DO
X
FASC-
X
BUNDLE
BIND
X
FELIX-
FELIC-
X
HAPPY
X
FER-
LAT-
LATE-
PORT-
X
CARRY
BEAR
X
FID-
X
FAITH
TRUST
X
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 4.txt:

FILI-
FILIA-
X
SON
DAUGHTER
X
FIN-
FINI-
TERM-
TERMINO-
X
END
LIMIT
X
FLAGR-
PYR-
X
FLAME
FIRE
X
FLATU-
X
WIND
X
FLECT-
FLEX-
X
BEND
X
FLU-
FLUX-
X
FLOW
X
FOLI-
FOLIA-
X
LEAF
X
FORT-
X
STRONG
STRENGTH
X
FRACT-
RUPT-
X
BREAK
BURST
X
FRATER-
FRATRI-
X
BROTHER
X
FUG-
FUGE-
X
FLEE
DRIVE AWAY
X
FULMIN-
X
LIGHTNING
X
FUND
FUNDA
X
LAY ON THE BOTTOM
X
FUS
FUSE
X
POUR
X
GAM-
X
MARRIAGE
X
GEN-
NASC-
X
BORN
BIRTH
X
GENU
GENUS
GENER-
X
CLASS
KIND
GROUP
X
GEO-
TERR-
TERRA-
X
LAND
EARTH
X
GER-
GEST-
X
CARRY
CARRY ON
WAGE
X
GLOSS-
GLOT-
GLOTT-
X
TONGUE
X
GNOMO-
-GNOS
X
KNOW
X
GRAPH-
GRAM-
X
WRITE
WRITING
X
GRATI-
GRATU-
X
FREE
PLEASING
X
GREG-
X
HERD
FLOCK
X
GYM-
X
NAKED
X
GYN-
GYNEO-
X
WOMAN
X
GYRO-
X
RING
CIRCLE
X
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 5.txt:

HAL-
HALE-
SPIR-
X
BREATH
BREATHE
X
HELI-
HELIX-
HELICO-
X
SPIRAL
X
HELIO-
X
SUN
X
HEM-
HEMA-
SANG-
SANGUI-
X
BLOOD
X
HEPT-
SEPT-
X
7
SEVEN
X
HER-
HES-
X
STICK
CLING
X
HEX-
SEX-
X
6
SIX
X
HIER-
X
SACRED
X
HIPPO-
EQU-
EQUES-
X
HORSE
X
HOMO-
X
SAME
SIMILAR
X
HYPER-
ULTRA-
SUPER-
X
BEYOND
EXCESSIVE
X
HYPO-
SUB-
SUF-
SUP-
X
UNDER
X
IDIO-
X
ONE'S OWN
X
IN-
IM-
X
NOT
INTO
X
EN-
EM-
X
INTO
X
ISO-
X
EQUAL
SAME
X
INTER-
X
BETWEEN
AMONG
X
IT-
ITIN-
X
GO
TRAVEL
X
JACULAT-
JECT-
X
CAST
HURL
X
JUG-
JUNC-
X
JOIN
X
JUR-
JURIS-
X
LAW
JUSTICE
SWEAR
X
KILO-
MIL-
MILLI-
X
1000
THOUSAND
ONE THOUSAND
X
LAC-
LACTO-
X
MILK
X
LACU-
LACUN-
X
EMPTY SPACE
LAKE
X
LAPI-
LAPID-
LITH-
X
STONE
X
LEUCO-
ALB-
X
WHITE
X
LEV-
X
RAISE
X
LOG-
LEX-
X
WORDS
WORD
X
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 6.txt:

LUC-
LUMIN-
PHOTO-
X
LIGHT
X
LUD-
LUS-
X
PLAY
X
LUN-
X
MOON
X
MACRO-
MEGA-
X
GREAT
LARGE
X
MAGNA-
MAGNI-
X
GREAT
X
MAL-
X
EVIL
X
MAND-
X
ORDER
X
MARI
MARINE
X
SEA
X
MATR-
METRO-
X
MOTHER
X
MELIOR-
X
BETTER
X
MERG-
MERS-
X
PLUNGE
SINK
X
METER-
METRI-
X
MEASURE
X
META-
X
AFTER
X
MICRO-
X
SMALL
X
MIGR-
X
TRAVEL
X
MIS-
MISO-
X
HATRED
X
MISS-
MIT-
X
SENT
X
MOB-
MOV-
MOT-
X
MOVE
X
MORPH-
X
FORM
SHAPE
X
MORT-
THANA-
THANATO-
X
DEATH
X
MUT-
X
CHANGE
X
NARCO-
X
NUMBNESS
TORPOR
X
NAUT-
X
SHIP
SAIL
X
NEO-
NOV-
X
NEW
X
NOCTI-
X
NIGHT
X
NOM-
X
ARRANGEMENT
LAWS
X
NON-
NULLI
X
NOT
NONE
X
NOUNC-
NUNCI-
SERT-
X
DECLARE
X
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 7.txt:

ONYM-
NYM-
X
NAME
X
OB-
OC-
OP-
X
AGAINST
OPPOSING
X
OCT-
X
8
X
OMNI-
PAN-
X
ALL
EVERY
X
PARA-
X
BESIDE
NEAR
X
PARL-
X
TALK
SPEAK
X
PATH-
X
SUFFERING
X
PATRI-
X
FATHER
X
PET-
POD-
X
FOOT
X
PEL-
PULS-
X
DRIVE
PUSH
X
PEND-
PENS-
X
HANG
WEIGH
X
PENT-
QUINT-
QUIN-
X
5
X
PER-
X
THROUGH
X
PET-
X
SEEK
ATTACK
X
PETR-
PETRO-
X
STONE
X
PHIL-
PHILO-
X
LOVE
LOVING
X
PHONO-
SON-
X
SOUND
X
PLAC
PLACA
X
PLEASE
APPEASE
X
PLEN
PLENT
X
FULL
FULLNESS
X
PLI-
PLIC-
X
FOLD
X
PON-
POS
POSIT-
X
PLACE
PUT
X
POST-
X
AFTER
X
POTOM-
X
RIVER
X
PRIM
PRIM0
X
FIRST
X
PRO-
X
FORWARD
FOR
BEFORE
X
QUADR-
TETR-
X
4
X
RE-
X
BACK
AGAIN
X
XZX
IN
X
XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOT 8.txt:

REG-
REGAL-
X
KING
RULE
X
RETRO-
X
BACKWARD
BEHIND
X
ROG-
X
ASK
DECLARE
X
RUBE-
RUBI-
X
RED
X
SANCT-
SACR-
X
HOLY
X
SCRIB-
SCRIPT-
X
WRITE
WRITTEN
X
SCHIZO-
SCHIS-
X
SPLIT
X
SE-
X
APART
AWAY
X
SECUT-
SEQU-
X
FOLLOW
X
SED-
SEDI-
X
SIT
X
SEMIN-
X
SEED
X
SEN-
SENEX-
X
OLD
X
SEPTI-
X
ROTTED
INFECTED
X
SERV-
X
KEEP
SAVE
X
SIST-
STIT-
X
SET
STAND
X
SPEC-
SPECT-
SPIC-
X
SEE
LOOK
X
TAIN-
TEN-
X
HOLD
X
TELE-
X
FAR
DISTANT
X
THERM-
THERMO-
X
HEAT
X
TRACT-
X
DRAG
PULL
DRAW
X
TRANS-
X
ACROSS
BEYOND
X
VEN-
VENT-
X
COME
X
VERT-
VERS-
VOL-
VOLV-
X
TURN
X
VI
VIA
X
ROAD
X
VINC-
VICT-
X
CONQUER
X
VID-
VIS-
X
SEE
X
VOK-
VOC-
VOCAT-
X
CALL
X
VOL-
VOLUN-
X
WISH
WILL
X
XZX

XZX

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/ROOTS.&.PREFIXES.bas:

10 TEXT
20 HOME
30 D$ = CHR$(4)
40 OP$ = D$ +"OPEN "
50 RD$ = D$ +"READ "
60 DIM A$(33,10),B$(33,10),C$(33),D$(33,10)
70 INVERSE : GOSUB 1300
80 PRINT "ON WHICH SHEET WOULD YOU LIKE TO BE"
90 PRINT "TESTED:"
100 PRINT "1. A- THROUGH BI-
110 PRINT "2. BIBLI- THROUGH CRESC-
120 PRINT "3. CUM- THROUGH FID-"
130 PRINT "4. FILI- THROUGH GYRO-
140 PRINT "5. HAL- THROUGH LOG-
150 PRINT "6. LUC- THROUGH NOUNC-
160 PRINT "7. ONYM- THROUGH RE-
170 PRINT "8. REG- THROUGH VOL-
180 POKE -16368,0
182 G = PEEK( -16384) -176
190 IF G <1 OR G >8 THEN 182
200 GOSUB 1300
202 X = 0
204 PRINT "HERE IS A SNEAK PREVIEW OF SOME WORDS"
205 POKE 34,1
206 NORMAL
210 PRINT OP$;"ROOT ";G
220 PRINT RD$;"ROOT ";G
225 INVERSE
230 X = X +1
240 Z = 0
250 Z = Z +1
260 INPUT A$(X,Z)
270 IF A$(X,Z) = "X" THEN 300
280 IF A$(X,Z) = "XZX" THEN 370
290 GOTO 250
300 Z = 0
310 Z = Z +1
320 INPUT B$(X,Z)
330 IF B$(X,Z) = "XXX" OR B$(X,Z) = "X" THEN 350
340 GOTO 310
350 L$ = LEFT$(A$(X,1) +" ",15) + LEFT$(B$(X,1) +" ",12) + LEFT$(B$(X,2) +" ",12)
355 PRINT L$
360 GOTO 230
370 XX = X -1: PRINT D$;"CLOSE ROOT ";G
380 FOR X = 1 TO XX:C = INT( RND(8) *XX) +1
390 FOR Z = 1 TO 10
400 R$ = A$(X,Z):A$(X,Z) = A$(C,Z):A$(C,Z) = R$
410 R$ = B$(X,Z):B$(X,Z) = B$(C,Z):B$(C,Z) = R$
420 NEXT Z
430 NEXT X
440 PRINT
450 FOR Z = 1 TO XX
460 POKE -16368,0
470 GOSUB 1300
480 DE$ = ""
490 PRINT "QUESTION #";Z
500 PRINT R;" RIGHT"
510 PRINT W;" WRONG"
520 C = INT( RND(8) *6) +1
530 IF A$(Z,C) = "X" OR A$(Z,C) = "" THEN 520
540 PRINT : PRINT : PRINT TAB( 15);A$(Z,C)
550 PRINT : PRINT : PRINT
560 GOSUB 1360
570 PRINT : PRINT
580 IF DE$ = "" THEN 620
590 FOR Y = 1 TO 5
600 IF DE$ = B$(Z,Y) THEN 740
610 NEXT Y
620 PRINT "WRONG": FOR PQ = 1 TO 300: NEXT PQ
630 W = W +1
640 C$(W) = A$(Z,C)
650 FOR Y = 1 TO 5
660 D$(W,Y) = B$(Z,Y)
670 NEXT Y
680 PRINT : PRINT "THE CORRECT ANSWERS ARE...."
690 FOR PQ = 1 TO 100: NEXT PQ
700 FOR J = 1 TO 5
710 IF B$(Z,J) = "XXX" OR B$(Z,J) = "X" THEN 810
720 PRINT B$(Z,J): NEXT J
730 GOTO 810
740 PRINT "RIGHT":R = R +1: FOR PQ = 1 TO 200: NEXT PQ
750 IF B$(Z,2) = "XXX" OR B$(Z,2) = "X" THEN 820
760 PRINT : PRINT "THE OTHER CHOICES WERE..."
770 FOR PQ = 1 TO 150: NEXT PQ
780 FOR J = 1 TO 5
790 IF B$(Z,J) = "XXX" OR B$(Z,J) = "X" THEN 810
800 PRINT B$(Z,J): NEXT J
810 PRINT : PRINT "PRESS THE SPACE BAR TO CONTINUE": GET A$
820 NEXT Z
830 GOSUB 1300
840 PRINT "TOTAL SCORE....."
850 PRINT INT((R/(R +W)) *100);"% RIGHT"
860 PRINT INT((W/(R +W)) *100);"% WRONG"
870 PRINT : PRINT "PRESS 'A' TO PRACTICE AGAIN WITH THE"
880 PRINT : PRINT "WORDS YOU MISSED."
890 PRINT : PRINT "PRESS 'S' TO END"
900 GET A$
910 IF A$ = "S" THEN END
920 FOR Z = 1 TO 2
930 GOSUB 1300
940 PRINT ; TAB( 13);"SECOND CHANCE"
950 PRINT "QUESTION #";Z;" OUT OF ";W
960 PRINT R;" RIGHT": PRINT W" WRONG"
970 PRINT : PRINT
980 PRINT ; TAB( 15);C$(Z)
990 PRINT
1000 GOSUB 1360
1010 PRINT : PRINT
1020 IF DE$ = "" THEN 1060
1030 FOR J = 1 TO 5
1040 IF DE$ = D$(Z,J) THEN 1140
1050 NEXT J
1060 PRINT "WRONG AGAIN!!!!"
1080 PRINT : PRINT "THE CORRECT ANSWERS ARE..."
1090 FOR H = 1 TO 5
1100 IF D$(Z,H) = "X" OR D$(Z,H) = "XXX" THEN 1220
1110 PRINT D$(Z,H)
1120 NEXT H
1130 GOTO 1220
1140 PRINT "RIGHT!!"
1150 R = R +1:W = W -1
1160 IF D$(Z,2) = "XXX" OR D$(Z,2) = "X" THEN 1220
1170 PRINT : PRINT "THE OTHER CORRECT CHOICES ARE..."
1180 FOR H = 1 TO 5
1190 IF D$(Z,H) = "XXX" OR D$(Z,H) = "X" THEN 1220
1200 PRINT D$(Z,H)
1210 NEXT H
1220 FOR H = 1 TO 1500: NEXT H
1230 NEXT Z
1250 GOSUB 1300
1260 PRINT "TOTAL SCORE....."
1270 PRINT : PRINT INT((R/(R +W)) *100);"% RIGHT"
1280 PRINT : PRINT INT((W/(R +W)) *100);"% WRONG"
1290 END
1300 FOR X = 1 TO 23
1310 VTAB X
1320 PRINT " "
1330 NEXT X
1340 VTAB 1: HTAB 1
1350 RETURN
1360 PRINT "ENTER DEFENITION ";
1370 DE$ = ""
1380 GET W$
1390 IF ASC(W$) = 13 THEN 1520
1400 IF ASC(W$) < >8 THEN 1500
1410 IF LEN(DE$) >1 THEN 1440
1420 IF LEN(DE$) = 1 THEN DE$ = "": GOTO 1450
1430 GOTO 1380
1440 DE$ = LEFT$(DE$, LEN(DE$) -1)
1450 PS = POS(0)
1460 HTAB PS
1470 PRINT " ";
1480 HTAB PS
1490 GOTO 1380
1500 IF LEN(DE$) >20 THEN PRINT "";: GOTO 1380
1505 PRINT W$;
1510 DE$ = DE$ +W$: GOTO 1380
1520 RETURN

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/SALYER.HELLO.bas:

10 REM DATE-KEEPER HELLO PROGRAM
11 MENU$ = "MENU"
12 DIM MO$(12),WE$(7),ND(12)
13 CENT = 19: REM INT(YEAR/100)
15 GOSUB 350: REM INITIALIZE
20 D$ = CHR$(4): ONERR GOTO 80
30 PRINT D$"OPEN DATE"
40 PRINT D$"READ DATE"
50 INPUT DR$
60 PRINT D$"CLOSE"
70 YR$ = LEFT$(DR$,2):M$ = MID$ (DR$,3,2):DA$ = MID$ (DR$,5,2):WD$ = RIGHT$(DR$,1)
80 YEAR = CENT *100 + VAL(YR$):MO = VAL(M$):DA = VAL(DA$):WD = VAL(WD$)
90 DT$ = MO$(MO) +" " +DA$ +", " + STR$(YEAR)
100 TEXT : HOME : PRINT " DOS 3.3 MASTER";: HTAB 27: PRINT WE$(WD): HTAB (39 - LEN(DT$)): PRINT DT$: VTAB 4: POKE 34,3
110 POKE 216,0: POKE 1016, VAL(YR$): POKE 1017,MO: POKE 1018,DA: POKE 1019,WD
120 VTAB 5: PRINT " TO CHANGE DATE, PRESS 'D'"
130 VTAB 7: PRINT " FOR A CATALOG, PRESS 'C'"
140 VTAB 9: PRINT " FOR A MENU OF PROGRAMS, PRESS 'M'"
150 VTAB 11: PRINT " TO RETURN TO BASIC, PRESS ANY OTHER KEY ... ";
160 GET A$: PRINT : IF A$ = "D" THEN 200
170 IF A$ = "M" THEN HOME : PRINT D$;"RUN ";MENU$: END
180 IF A$ = "C" THEN HOME : PRINT D$;"CATALOG": END
190 HOME : TEXT : VTAB 5: END
200 HOME : INVERSE : PRINT " A LEAVES AS ABOVE ... ": NORMAL : PRINT : PRINT
210 VTAB 10: PRINT "ENTER MONTH NO. (1-12) : ";:NH = 12:NL = 1: GOSUB 400: IF LEN(A$) = 0 THEN VTAB 10: HTAB 26: PRINT M$: GOTO 230
220 M$ = RIGHT$(" " +A$,2):MO = VAL(M$)
230 VTAB 13: PRINT "ENTER DAY OF MONTH (1-";ND(MO);") : ";:NH = ND(MO):NL = 1: GOSUB 400: IF LEN(A$) = 0 THEN VTAB 13: HTAB 29: PRINT DA$: GOTO 250
240 DA$ = RIGHT$(" " +A$,2):DA = VAL(DA$)
250 VTAB 16: PRINT "ENTER YEAR AS 2 DIGITS : ";CENT;:NH = 99:NL = 0: GOSUB 400: IF LEN(A$) = 0 THEN VTAB 16: HTAB 28: PRINT YR$: GOTO 270
260 YR$ = RIGHT$("0" +A$,2):YEAR = CENT *100 + VAL(YR$)
270 DD$ = MO$(MO) +" " +DA$ +", " + STR$(YEAR)
280 VTAB 19: PRINT "NEW DATE IS ";DD$;" (Y/N)? ";: GET A$: PRINT A$
290 IF A$ = "N" THEN 200
300 WD = FN WEEKDAY(YEAR):WD$ = STR$(WD)
310 DR$ = YR$ +M$ +DA$ +WD$
320 GOSUB 490: GOTO 80
325 REM
330 REM ********************
331 REM * *
332 REM * LIMITATION OF *
333 REM * THE PROGRAM IS *
334 REM * THAT THE ERROR *
335 REM * ROUTINE DOES NOT *
336 REM * KNOW ABOUT LEAP *
337 REM * YEARS AND WILL *
338 REM * BLINDLY ACCEPT *
339 REM * FEB. 29 ON A NON *
340 REM * LEAP YEAR. *
341 REM * *
342 REM ********************
343 REM
350 FOR I = 1 TO 12: READ MO$(I),ND(I): NEXT I
355 DATA JANUARY,31,FEBRUARY,29,MARCH,31,APRIL,30,MAY,31,JUNE,30,JULY,31,AUGUST,31,SEPTEMBER,30,OCTOBER,31,NOVEMBER,30,DECEMBER,31
360 FOR I = 0 TO 6: READ WE$(I): NEXT I
365 DATA SUNDAY,MONDAY,TUESDAY,WEDNESDAY,THURSDAY,FRIDAY,SATURDAY
370 DEF FN WEEKDAY(YEAR) = FN W(N) +( INT( - FN W(N)/7) *7) +6
380 DEF FN W(N) = (MO <3) *(365 *YE +DA +31 *(MO -1) + INT((YE -1)/4) - INT(3/4 *( INT((YE -1)/100) +1))) +(MO >2) *(365 *YE +DA +31 *(MO -1) - INT(.4 *MO +2.3) + INT(YE/4) - INT(3/4 *( INT(YE/100) +1)))
390 RETURN
395 REM ERROR CHECK ROUTINE
400 VT = PEEK(37):HT = PEEK(36): CALL -868: INPUT "";A$: IF LEN(A$) = 0 THEN 430
410 V = VAL(A$): IF V < = NH AND V > = NL THEN 430
420 VTAB VT +3: INVERSE : PRINT " MUST BE BETWEEN ";NL;" AND ";NH;" ": NORMAL : FOR X = 1 TO 1600: NEXT X: VTAB VT +3: CALL -868: VTAB VT +1: HTAB HT +1: GOTO 400
430 RETURN
450 REM SAVE DATE FILE
490 PRINT D$"UNLOCK DATE"
500 PRINT D$"OPEN DATE"
510 PRINT D$"WRITE DATE"
520 PRINT DR$
530 PRINT D$"CLOSE"
540 PRINT D$"LOCK DATE"
550 RETURN
65535 REM THE DATE IS SAVED IN LOCATIONS 1016 - 1019, AS FOLLOWS:
65535 REM YEAR (0-99) IN 1016 MONTH (1-12) IN 1017 DATE (1-31) IN 1018 DAY (0-6) IN 1019
65535 REM DAY IS A CODE FOR THE WEEKDAY WITH 0 BEING SUNDAY AND 6 BEING SATURDAY.
65535 REM
65535 REM *******************
65535 REM * WRITTEN BY: *
65535 REM * DALE E. SALYER *
65535 REM * THORNTON, COLO. *
65535 REM * ORIGINAL IDEA - *
65535 REM * APPEARED IN: *
65535 REM * NIBBLE VOL. 2 *
65535 REM * NO. 5, PG. 79 *
65535 REM * BY: DON RAVEY *
65535 REM * DATE FUNCTIONS *
65535 REM *FROM PROGRAMMERS *
65535 REM * LIBRARY FROM: *
65535 REM * TELEPHONE SOFT- *
65535 REM * WARE CONNECTION *
65535 REM *******************

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/SPACE CHASER HIGH SCORE.txt:

340

RENTALLON

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/SPACE.CHASER.bas:

10 REM *OPENING TITLE
20 TEXT : HOME : CLEAR
25 VTAB 6
30 FLASH
40 PRINT " **** **** **** **** **** ";
50 PRINT " * * * * * * * ";
60 PRINT " **** **** **** * *** ";
70 PRINT " * * * * * * ";
80 PRINT " **** * * * **** **** ";
90 PRINT : PRINT
100 PRINT " **** * * **** **** **** **** ";
110 PRINT " * * * * * * * * * ";
120 PRINT " * * * * * * * * * ";
130 PRINT " * **** **** **** *** **** ";
140 PRINT " * * * * * * * ** ";
150 PRINT " * * * * * * * * * ";
160 PRINT " **** * * * * **** **** * * ";
170 NORMAL
180 PRINT : PRINT : PRINT : PRINT
190 REM *MY LOGO
200 PRINT "THIS PROGRAM WAS DEVELOPED BY"
210 FOR BJ = 1 TO 3000: NEXT : GR : COLOR= 9
220 HLIN 5,13 AT 2: HLIN 5,13 AT 10: HLIN 5,13 AT 19: VLIN 3,9 AT 14: VLIN 11,18 AT 14: PLOT 16,19: VLIN 2,19 AT 4: VLIN 11,17 AT 14
230 HLIN 18,27 AT 10: VLIN 11,27 AT 23: PLOT 18,25: PLOT 19,26: HLIN 20,22 AT 27: PLOT 25,27
240 HLIN 29,37 AT 22: VLIN 23,38 AT 33: PLOT 35,38
250 FOR BJ = 1 TO 3000: NEXT : TEXT : HOME
260 REM *START OF GAME - INSTRUCTIONS
270 PRINT "HIT ANY KEY TO CONTINUE": GET ANS$
280 HOME
290 SPEED= 255
300 PRINT "DO YOU NEED INSTRUCTIONS?": GET F$
310 IF LEFT$(F$,1) = "Y" THEN HOME : GOTO 340
320 IF LEFT$(F$,1) < >"Y" THEN 450
330 GOTO 300
340 PRINT TAB( 14);"INSTRUCTIONS"
350 PRINT TAB( 14);"------------"
360 PRINT
370 PRINT "THE IDEA OF THIS GAME IS TO AVOID THE CHASER . THIS IS ACCOMPLISHED BY KEEPINGYOUR SPACE VEHICLE (THE PURPLE ONE ON THE RIGHT) AWAY FROM THE CHASER (THE LIGHT BLUE ONE TO THE LEFT OF SCREEN) ."
380 PRINT : PRINT : PRINT
390 PRINT "TO MOVE YOUR SHIP PRESS THE KEY AS SHOWN"
400 PRINT " UP"
401 PRINT " I"
402 PRINT " (I)"
404 PRINT " I"
405 PRINT "LEFT-(J)- -(K)-RIGHT"
415 PRINT " I"
420 PRINT " (M)"
425 PRINT " I"
430 PRINT " DOWN"
440 FOR A = 1 TO 1500: NEXT A: VTAB 23
450 PRINT "DO YOU WANT ME TO SHUT UP?";: GET Z$: IF LEFT$(Z$,1) = "Y" THEN QT = 1
460 REM *SET FUEL AND NEXT SCREEN
470 HOME : GR
480 CLEAR
490 FE = 5000
500 FE = FE +3500 -(100 *N):N = N +1
510 ON N GOSUB 520,520,520,520,520
520 GR
530 COLOR= 15
540 HLIN 0,39 AT 0: HLIN 0,39 AT 39
550 HLIN 5,18 AT 5: HLIN 23,36 AT 5
560 HLIN 9,18 AT 9: HLIN 23,32 AT 9
570 HLIN 13,18 AT 18: HLIN 23,28 AT 18
580 HLIN 13,18 AT 23: HLIN 23,28 AT 23
590 HLIN 9,18 AT 32: HLIN 23,32 AT 32
600 HLIN 5,18 AT 36: HLIN 23,36 AT 36
610 VLIN 0,39 AT 0: VLIN 0,39 AT 39
620 VLIN 5,18 AT 5: VLIN 23,36 AT 5
630 VLIN 9,18 AT 9: VLIN 23,32 AT 9
640 HLIN 13,28 AT 13: HLIN 13,28 AT 28
650 VLIN 9,18 AT 32: VLIN 23,32 AT 32
660 VLIN 5,18 AT 36: VLIN 23,36 AT 36
670 PLOT 20,21: PLOT 20,20: PLOT 21,20: PLOT 21,21
680 COLOR= 12
690 PLOT 3,3: PLOT 6,3: PLOT 9,3: PLOT 12,3: PLOT 15,3: PLOT 18,3: PLOT 21,3: PLOT 24,3: PLOT 27,3: PLOT 30,3: PLOT 33,3: PLOT 36,3: PLOT 38,3
700 PLOT 3,6: PLOT 3,9: PLOT 3,12: PLOT 3,15: PLOT 3,18: PLOT 3,21: PLOT 3,24: PLOT 3,27: PLOT 3,30: PLOT 3,33: PLOT 3,36: PLOT 3,38
710 PLOT 3,38: PLOT 6,38: PLOT 9,38: PLOT 12,38: PLOT 15,38: PLOT 18,38: PLOT 21,38: PLOT 24,38: PLOT 27,38: PLOT 30,38: PLOT 33,38: PLOT 36,38: PLOT 38,38
720 PLOT 38,6: PLOT 38,9: PLOT 38,12: PLOT 38,15: PLOT 38,18: PLOT 38,21: PLOT 38,24: PLOT 38,27: PLOT 38,30: PLOT 38,33: PLOT 38,36
730 PLOT 7,7: PLOT 7,10: PLOT 7,13: PLOT 7,16: PLOT 7,25: PLOT 7,28: PLOT 7,31: PLOT 7,34
740 PLOT 20,3: PLOT 20,38
750 PLOT 11,11: PLOT 11,14: PLOT 11,17: PLOT 11,20: PLOT 11,21: PLOT 11,24: PLOT 11,27: PLOT 11,30: PLOT 11,34
760 PLOT 14,11: PLOT 14,16: PLOT 14,15: PLOT 14,20: PLOT 14,21: PLOT 14,25: PLOT 14,26: PLOT 14,30: PLOT 14,34
770 PLOT 17,7: PLOT 17,11: PLOT 17,15: PLOT 17,16: PLOT 17,20: PLOT 17,21: PLOT 17,25: PLOT 17,26: PLOT 17,30: PLOT 17,34
780 PLOT 20,5: PLOT 20,8: PLOT 20,11: PLOT 20,15: PLOT 20,16: PLOT 20,25: PLOT 20,26: PLOT 20,30: PLOT 20,34
790 PLOT 21,5: PLOT 21,8: PLOT 21,11: PLOT 21,15: PLOT 21,16: PLOT 21,25: PLOT 21,26: PLOT 21,30: PLOT 21,34
800 PLOT 24,7: PLOT 24,11: PLOT 24,15: PLOT 24,16: PLOT 24,20: PLOT 24,21: PLOT 24,25: PLOT 24,26: PLOT 24,30: PLOT 24,34
810 PLOT 27,7: PLOT 27,11: PLOT 27,15: PLOT 27,16: PLOT 27,20: PLOT 27,21: PLOT 27,25: PLOT 27,26: PLOT 27,30: PLOT 27,34
820 PLOT 30,7: PLOT 30,11: PLOT 30,15: PLOT 30,16: PLOT 30,20: PLOT 30,21: PLOT 30,25: PLOT 30,26: PLOT 30,30: PLOT 30,34
830 PLOT 34,7: PLOT 34,10: PLOT 34,13: PLOT 34,16: PLOT 34,16: PLOT 34,25: PLOT 34,28: PLOT 34,31: PLOT 34,34
840 PLOT 11,7: PLOT 14,7: PLOT 17,7
850 PLOT 6,20: PLOT 6,21: PLOT 8,20: PLOT 8,21: PLOT 33,20: PLOT 33,21: PLOT 35,20: PLOT 35,21
860 HTAB 10: INVERSE : PRINT "GET READY!!"
870 NORMAL
880 REM *READ FROM TEXT FILE CURRENT HIGH SCORER'S NAME AND SCORE.
890 D$ = CHR$(4): REM *CTRL-D
900 PRINT D$;"OPEN SPACE CHASER HIGH SCORE"
910 PRINT D$;"READ SPACE CHASER HIGH SCORE"
920 INPUT HS,HS$
930 PRINT D$;"CLOSE SPACE CHASER HIGH SCORE"
940 REM *MAIN PROGRAM
950 PRINT : PRINT : PRINT
960 A = 2:B = 20:C = 37:D = 20
970 COLOR= 7: PLOT A,B
980 COLOR= 3: PLOT C,D
990 FOR T = 1 TO 20: NEXT T
1000 COLOR= 0
1010 PLOT C,D
1020 IF CO = 12 THEN DC = 12
1030 COLOR= DC: PLOT A,B
1040 DC = 0
1050 Q = PEEK( -16384)
1060 IF Q >127 THEN POKE -16368,0
1070 IF Q >127 THEN Q$ = CHR$(Q -128)
1080 FE = FE -5
1090 IF FE <0 THEN PRINT "FUEL GONE!": GOTO 1380
1100 IF XX = 1500 *N THEN 500
1110 VTAB 22: PRINT "SCORE= ";XX; TAB( 14);"FUEL= ";FE
1120 VTAB 23: INVERSE : FLASH : PRINT "HIGH SCORE= ";HS;" BY ";HS$
1125 NORMAL
1130 IF Q$ = "I" THEN D = D -1
1140 IF Q$ = "M" THEN D = D +1
1150 IF Q$ = "J" THEN C = C -1
1160 IF Q$ = "K" THEN C = C +1
1170 IF Q$ < >"I" AND Q$ < >"J" AND Q$ < >"K" AND Q$ < >"M" THEN FE = FE +4
1180 CL = SCRN( C,D)
1190 IF CL = 15 THEN GOSUB 1490
1200 IF CL = 12 THEN XX = XX +10: VTAB 1: GOSUB 1780
1210 IF A C THEN FG = 2:A = A -1
1230 CR = SCRN( A,B)
1240 IF CR = 15 THEN GOSUB 1540
1250 FG = 0
1260 IF B D THEN FG = 4:B = B -1
1280 CO = SCRN( A,B)
1290 IF CO = 15 THEN GOSUB 1540
1300 IF A = C AND B = D THEN 1380
1310 GOTO 970
1320 IF C > AT HENFG = 1:A = A +1
1330 IF C < AT HENFG = 2:A = A -1
1340 IF D >B THEN FG = 3:B = B +1
1350 IF D HS THEN GOTO 1620
1450 PRINT "DO YOU WANT ANOTHER TRY ? ";: GET B$
1460 IF LEFT$(B$,1) = "N" THEN END
1470 IF LEFT$(B$,1) = "Y" THEN HOME : GOTO 450
1480 GOTO 1430
1490 IF Q$ = "I" THEN D = D +1
1500 IF Q$ = "M" THEN D = D -1
1510 IF Q$ = "J" THEN C = C +1
1520 IF Q$ = "K" THEN C = C -1
1530 RETURN
1540 IF FG = 1 THEN A = A -1
1550 IF FG = 2 THEN A = A +1
1560 IF FG = 3 THEN B = B -1
1570 IF FG = 4 THEN B = B +1
1580 FG = 0
1590 RETURN
1600 REM *STOP CHASER PICKING UP DOTS
1610 GOTO 1050
1620 D$ = CHR$(4): REM *CTRL-D
1630 INPUT "YOUR NAME , CHAMPION !!";CHAMP$
1640 PRINT D$;"OPEN SPACE CHASER HIGH SCORE"
1650 PRINT D$;"WRITE SPACE CHASER HIGH SCORE"
1660 PRINT XX
1670 PRINT CHAMP$
1680 PRINT D$;"CLOSE SPACE CHASER HIGH SCORE"
1690 VTAB 22: PRINT "YOU HAVE DONE WELL , CHAMP ."
1700 VTAB 23: PRINT "HERE IS YOUR MEDAL -"
1710 PRINT "ADMIRE IT FOR A WHILE ..."
1720 GR
1730 COLOR= 9: VLIN 10,19 AT 16: VLIN 10,19 AT 17: VLIN 10,19 AT 24: VLIN 10,19 AT 25: COLOR= 12: VLIN 10,19 AT 18: VLIN 10,19 AT 19: VLIN 10,19 AT 22: VLIN 10,19 AT 23
1740 COLOR= 13: VLIN 10,29 AT 20: VLIN 10,29 AT 21: HLIN 18,23 AT 22: HLIN 18,23 AT 23: HLIN 18,23 AT 26: HLIN 18,23 AT 27: HLIN 16,25 AT 24: HLIN 16,25 AT 25
1750 COLOR= 9: PLOT 20,24: PLOT 21,24: PLOT 20,25: PLOT 21,25
1760 FOR BJ = 1 TO 3000: NEXT BJ
1770 GOTO 1450
1780 IF QT = 0 THEN RETURN
1790 FOR BJ = 1 TO 4:X = PEEK( -16336) - PEEK( -16336) - PEEK( -16336) - PEEK( -16336): NEXT : RETURN

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/SUPER.SCORES.bas:

20 REM +----------------------+ : SUPERSCORES PROGRAM : : : : ^ ^ BY : : ' ' : : O BRAD GREEN : : : +----------------------+
25 REM +----------------------- : : : COPYRIGHT 1982 : : : : WRITTEN 05-22-1982 : : : : * * * * * * * : +----------------------+
30 REM LAST UPDATE- 06-04-1982
31 REM
50 REM **PIDGEONS**
51 REM A-FORNEXT LOOPS
52 REM D$-DAY STRING
53 REM DT$()-RECORD DATE
54 REM F-SORT FLAG
55 REM G$-GET SRING
56 REM GM$-GAME STRING
57 REM ID$-INPUT DATE
58 REM IG$-IMPUT GAME
59 REM IH$-INPUT HIGH SCORE
60 REM IP$-INPUT PUBLISHER
61 REM IW$-INPUT RECORD WINNER
62 REM KE-KEY DEPRESSED
63 REM M$-MONTH
64 REM PB$-PUBLISHER
65 REM PL$-PLAYER
66 REM Q$-ANY OL' STRING
67 REM RT-RECORD TOTAL
68 REM SC$-SCORE
69 REM SF$-SAVE FLAG
70 REM TD$-TODAY'S DATE
71 REM T$-TEMP PIDGEON HOLE
72 REM X-ARRAY VARIABLE
73 REM Y$-YEAR
74 REM Z-FORNEXT LOOP
80 DIM GM$(100)
82 DIM PB$(100)
84 DIM SC$(100)
86 DIM PL$(100)
88 DIM DT$(100)
199 REM **HEADER**
200 POKE 34,0: POKE 35,24: SPEED= 255: HOME
230 INVERSE
240 FOR A = 1 TO 3
250 VTAB A: FOR Z = 1 TO 20: PRINT "V^";: NEXT
260 NEXT A: NORMAL
270 Q$ = " SUPERSCORES PROGRAM BY BRAD GREEN "
280 VTAB 2: HTAB 20 - INT(( LEN(Q$)/2)): PRINT Q$
285 REM **ENTER DATE**
290 VTAB 6: PRINT "PLEASE ENTER TODAY'S NUMERIC DATE."
300 VTAB 10: INPUT "MONTH ";M$
310 IF VAL(M$) <1 OR VAL(M$) >12 THEN 300
320 IF LEN(M$) = 1 THEN LET M$ = "0" +M$
330 VTAB 10: HTAB 7: PRINT M$
340 REM
350 VTAB 12: INPUT "DAY ";D$
360 IF VAL(D$) <1 OR VAL(D$) >31 THEN 350
370 IF LEN(D$) = 1 THEN LET D$ = "0" +D$
380 VTAB 12: HTAB 7: PRINT D$
390 REM
400 VTAB 14: INPUT "YEAR ";Y$
410 IF LEN(Y$) < >2 THEN 400
420 IF VAL(Y$) <82 THEN 400
430 REM
440 LET TD$ = M$ +"-" +D$ +"-" +Y$
450 VTAB 17: PRINT "CORRECT?(Y/N) ";: INVERSE : PRINT "Y": NORMAL : WAIT -16384,128: GET G$: PRINT CHR$(13)
460 IF G$ = "N" THEN 200
600 REM **LOAD FILE**
610 ONERR GOTO 1000
620 PRINT CHR$(4);"VERIFY SUPERSCORES.FILE"
630 POKE 216,0
640 PRINT CHR$(4);"OPEN SUPERSCORES.FILE"
650 PRINT CHR$(4);"READ SUPERSCORES.FILE"
660 PRINT
670 INPUT RT
680 FOR I = 1 TO RT
690 INPUT GM$(I)
700 INPUT PB$(I)
710 INPUT SC$(I)
720 INPUT PL$(I)
730 INPUT DT$(I)
740 NEXT I
750 PRINT CHR$(4);"CLOSE SUPERSCORE.FILE"
1000 REM **SCREEN**
1010 POKE 216,0
1020 GOSUB 7000
1030 VTAB 14
1040 X = X +1
1045 IF RT = 0 THEN PRINT "PRESS A TO ADD A FILE"
1050 IF X >RT THEN X = 1: PRINT "======"
1060 SPEED= 200
1070 HTAB 1: PRINT GM$(X);: HTAB 20: PRINT SC$(X);: HTAB 31: PRINT DT$(X)
1080 HTAB 1: PRINT PB$(X);: HTAB 20: PRINT PL$(X)
1090 SPEED= 255
1100 PRINT
1110 IF PEEK( -16384) <128 THEN 1040
1120 LET KEY = PEEK( -16384)
1130 POKE -16368,0
1140 IF KEY = 160 THEN 2000
1150 IF KEY = 193 THEN 3000
1160 IF KEY = 196 THEN 4000
1170 IF KEY = 208 THEN 5000
1180 IF KEY = 209 THEN 8000
1190 GOTO 1040
1200 END
2000 REM **SINGLE STEP**
2010 POKE -16368,0
2020 IF PEEK( -16384) <128 THEN 2020
2030 POKE -16368,0
2040 GOTO 1040
2050 END
3000 REM **ADD**
3010 SFLAG = 1
3020 POKE 34,0: POKE 35,6
3030 HOME
3040 VTAB 1: INVERSE : PRINT "ADD RECORD": NORMAL
3050 VTAB 3: PRINT "GAME (Q ESCAPES)": VTAB 3: HTAB 6: INPUT IG$
3060 IF IG$ = "Q" THEN 1020
3070 IF IG$ = "" THEN 3050
3080 VTAB 3: HTAB 20: INPUT "PUBLISHER? ";IP$
3090 VTAB 4: INPUT "HIGH SCORE? ";IH$
3100 IF IH$ = "" THEN 3090
3110 VTAB 5: INPUT "PLAYER NAME? ";IW$
3115 VTAB 6: PRINT "CORRECT? (Y/N)";: GET G$: PRINT CHR$(13);: IF G$ = "N" THEN 3030
3120 IF LEN(IG$) >18 THEN LET IG$ = LEFT$(IG$,18)
3130 IF LEN(IP$) >18 THEN IP$ = LEFT$(IP$,18)
3140 IF LEN(IH$) >8 THEN IH$ = LEFT$(IH$,8)
3150 IF LEN(IW$) >18 THEN IW$ = LEFT$(IW$,18)
3160 REM **UPDATE**
3170 FOR I = 1 TO RT
3180 IF IG$ = GM$(I) THEN 3210
3190 NEXT I
3200 GOTO 3320
3210 HOME
3220 PRINT "THE CURRENT RECORD IS: "
3230 VTAB 3: PRINT GM$(I);: HTAB 20: PRINT SC$(I);: HTAB 31: PRINT DT$(I)
3240 VTAB 4: HTAB 1: PRINT PB$(I);: HTAB 20: PRINT PL$(I)
3250 LET GM$(I) = IG$
3260 LET PB$(I) = IP$
3270 LET SC$(I) = IH$
3280 LET DT$(I) = TD$
3290 LET PL$(I) = IW$
3300 GOTO 3390
3310 REM **APPEND**
3320 RT = RT +1
3330 LET GM$(RT) = IG$
3340 LET PB$(RT) = IP$
3350 LET SC$(RT) = IH$
3360 LET DT$(RT) = TD$
3370 LET PL$(RT) = IW$
3380 IF RT = 1 THEN 1020
3390 REM **SORT**
3400 F = 0
3410 FOR I = 1 TO RT -1
3420 IF GM$(I) < = GM$(I +1) THEN 3590
3430 LET T$(1) = GM$(I)
3440 LET T$(2) = PB$(I)
3450 LET T$(3) = SC$(I)
3460 LET T$(4) = PL$(I)
3470 LET T$(5) = DT$(I)
3480 LET GM$(I) = GM$(I +1)
3490 LET PB$(I) = PB$(I +1)
3500 LET SC$(I) = SC$(I +1)
3510 LET PL$(I) = PL$(I +1)
3520 LET DT$(I) = DT$(I +1)
3530 LET GM$(I +1) = T$(1)
3540 LET PB$(I +1) = T$(2)
3550 LET SC$(I +1) = T$(3)
3560 LET PL$(I +1) = T$(4)
3570 LET DT$(I +1) = T$(5)
3580 F = 1
3590 NEXT I
3600 IF F = 1 THEN GOTO 3400
3610 GET G$: PRINT CHR$(13)
3620 GOTO 1020
4000 REM **DELETE**
4010 POKE 34,0: POKE 35,6
4020 SFLAG = 1
4030 HOME
4040 VTAB 1: INVERSE : PRINT "DELETE RECORD": NORMAL
4050 VTAB 3: INPUT "GAME? ";IG$
4060 IF IG$ = "" THEN 3050
4070 FOR I = 1 TO RT
4080 IF IG$ = GM$(I) THEN 4130
4090 NEXT I
4100 VTAB 5: PRINT "NOT FOUND"
4110 GET G$: PRINT CHR$(13)
4120 GOTO 1020
4130 VTAB 3: CALL -868: PRINT GM$(I);: HTAB 20: PRINT SC$(I);: HTAB 31: PRINT DT$(I)
4140 VTAB 4: HTAB 1: PRINT PB$(I);: HTAB 20: PRINT PL$(I)
4150 VTAB 6: PRINT "DO YOU WISH TO DELETE THIS?(Y/N)";
4160 GET G$: PRINT CHR$(13)
4170 IF G$ < >"Y" AND G$ < >"N" THEN 4150
4180 IF G$ = "N" THEN 1020
4190 RT = RT -1
4200 FOR X = I TO RT
4210 LET GM$(X) = GM$(X +1)
4220 LET PB$(X) = PB$(X +1)
4230 LET SC$(X) = SC$(X +1)
4240 LET PL$(X) = PL$(X +1)
4250 LET DT$(X) = DT$(X +1)
4260 NEXT X
4270 GOTO 1020
5000 REM **PRINT-OUT**
5010 POKE 34,0: POKE 35,6
5020 IF PEEK( -16128) = 0 THEN HOME : VTAB 3: HTAB 7: INVERSE : PRINT "PRINTER NOT INSTALLED": NORMAL :: GOTO 1020
5030 HOME
5040 VTAB 1: INVERSE : PRINT "PRINTOUT": NORMAL
5050 VTAB 3: PRINT "IF THE PRINTER IS READY THEN HIT RETURN"
5060 VTAB 4: PRINT "OTHERWISE HIT Q"
5070 VTAB 4: WAIT -16384,128: GET G$: PRINT CHR$(13): IF G$ < > CHR$(13) AND G$ < >"Q" THEN 5070
5080 IF G$ = "Q" THEN 1020
5090 PRINT : PRINT CHR$(4);"PR# 1": PRINT CHR$(9)"80N"
5100 PRINT "SUPERSCORES PROGRAM BY BRAD GREEN TODAY'S DATE ";TD$
5110 PRINT
5120 PRINT " GAME PUBLISHER SCORE PLAYER DATE"
5130 PRINT "_____________________________________________________________________________"
5140 FOR I = 1 TO RT
5150 HTAB 1: PRINT GM$(I);: HTAB 20: PRINT PB$(I);: HTAB 40: PRINT SC$(I); TAB( 10 -( LEN(SC$(I))));PL$(I); TAB( 20 -( LEN(PL$(I))));DT$(I)
5160 NEXT I
5170 PRINT : PRINT CHR$(4);"PR# 0"
5180 GOTO 1020
5999 END
7000 REM **MENU OF TOP**
7010 POKE 34,0: POKE 35,24: HOME
7020 VTAB 1: PRINT "A)DD D)ELETE P)RINT Q)UIT SPACEBAR-STOP"
7030 VTAB 4: PRINT "GAME HIGH SCORE DATE "
7040 VTAB 5: PRINT "PUBLISHER";: HTAB 20: PRINT "PLAYER"
7050 VTAB 7: PRINT "_______________________________________"
7060 VTAB 8: POKE 34,8
7070 RETURN
8000 REM **QUIT-SAVE**
8005 PRINT
8010 POKE 34,0: POKE 35,24
8020 POKE -16368,0
8030 IF SFLAG <1 THEN END
8032 ONERR GOTO 8037
8035 PRINT CHR$(4);"UNLOCK SUPERSCORES.FILE"
8037 POKE 216,0
8040 PRINT CHR$(4);"OPEN SUPERSCORES.FILE"
8050 PRINT CHR$(4);"DELETE SUPERSCORES.FILE"
8060 PRINT CHR$(4);"OPEN SUPERSCORES.FILE"
8070 PRINT CHR$(4);"WRITE SUPERSCORES.FILE"
8080 PRINT RT
8090 FOR I = 1 TO RT
8100 PRINT GM$(I)
8110 PRINT PB$(I)
8120 PRINT SC$(I)
8130 PRINT PL$(I)
8140 PRINT DT$(I)
8150 NEXT I
8160 PRINT CHR$(4);"CLOSE SUPERSCORES.FILE"
8170 PRINT CHR$(4);"LOCK SUPERSCORES.FILE"
9000 REM +--------------------+ : : : NOTES ON : : : : SUPERSCORES : : : : : +--------------------+
9010 REM WHEN ENTERING DATA, PLEASE DONT USE COMMAS OR COLONS BECAUSE DEAR OLE APPLE WONT READ PAST THE COMMAS.
9020 REM WHEN ALL THE HIGH SCORES FINISH LISTING, THEY START OVER. THE ======== MARKS THE BEGINNING. TO STOP THE LISTING JUST HIT THE SPACE BAR
9030 REM A)DD IS THE SAME AS CHANGE AN OLD RECORD. HOWEVER; IN ORDER TO CHANGE AN OLD SCORE, YOU HAVE TO SPELL IT RIGHT.

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/SUPERSCORES.FILE.txt:

1
SNEAKERS
????
2000
JIM
09-07-82

Text found in Soft_Disk_Magazine_September_1992_Side_2.dsk/UFO.II.bas:

10 TEXT : HOME : CLEAR
20 SPEED= 255
25 S = -16336
30 A$ = "UFO II": GOSUB 7000
31 A$ = "WRITTEN BY LARRY SELTZER": GOSUB 7000
32 PRINT
33 A$ = "BASED UPON A PROGRAM WRITTEN BY": GOSUB 7000
34 A$ = "RAYMOND J. KERNAY": GOSUB 7000
37 A$ = "FOR": GOSUB 7000
39 A$ = "CREATIVE COMPUTING": GOSUB 7000
40 A$ = "MORRISTOWN, NEW JERSEY": GOSUB 7000
50 VTAB 10
60 PRINT "DO YOU WANT INSTRUCTIONS "
62 VTAB 12: HTAB 1: PRINT "====>"
63 VTAB 12: HTAB 6: GET A$: PRINT A$
70 IF A$ = "N" THEN 1000
80 IF A$ = "Y" THEN 100
90 PRINT CHR$(7)
95 GOTO 63
100 POKE 35,24
110 HOME
160 PRINT "THE INFORMATION YOU ARE ABOUT TO": PRINT : PRINT "RECEIVE IS CLASSIFIED ";: FLASH : PRINT "TOP SECRET": NORMAL
170 FOR X = 1 TO 500: NEXT X: PRINT : PRINT
180 PRINT : PRINT "THIS IS THE YEAR 2080...": PRINT
190 PRINT "CIVILIZATION AS YOU KNEW IT HAS BEEN": PRINT : PRINT "DESTROYED BY STRANGE CREATURES NEVER ": PRINT
200 PRINT "BEFORE SEEN BY MAN."
210 PRINT : PRINT "THEY HAVE REDUCED NATIONS TO RUBBLE IN": PRINT : PRINT "A MASSIVE SPACE WAR."
220 GOSUB 8000
240 PRINT "YOU ARE NOW THE CAPTAIN OF THE SPACE": PRINT : PRINT "SHIP 'VOYAGER', WHOSE SOLE PURPOSE IS"
250 PRINT : PRINT "TO SAFE GUARD YOUR 150 PASSENGERS...THE"
260 PRINT : PRINT "SOLE SURVIVORS OF THE PLANET EARTH"
270 PRINT : PRINT : PRINT "MISSION: FIND A PLANET SUITABLE FOR": PRINT : PRINT "YOUR COLONISTS"
280 PRINT : PRINT "PROBLEM: THE ENEMY STILL EXISTS"
290 GOSUB 8000
300 PRINT "YOUR SHIP'S BATTERIES CONTAIN 10,000": PRINT : PRINT "UNITS OF ENERGY, WHICH IS THE MOST THEY": PRINT : PRINT "CAN SAFELY HOLD AT ANY ONE TIME."
310 PRINT : PRINT "WHEN YOU RUN OUT OF ENERGY, THE ALIENS": PRINT : PRINT "WILL DESTROY YOU."
320 GOSUB 8000
410 POKE 35,24: CALL -936: HTAB 15: PRINT "WEAPONRY": PRINT
420 PRINT "#";: HTAB 3: PRINT "DESCRIPTION";
430 HTAB 25: PRINT "RANGE"
440 PRINT "- ------------"; TAB( 25);"-----"
450 PRINT "1"; TAB( 3);"HEAVY GUNS"; TAB( 25);"0-25000"
460 PRINT "2"; TAB( 3);"PHOTON TORPEDOES"; TAB( 25);"1000-200000"
470 PRINT "3"; TAB( 3);"LASERS"; TAB( 25);"UNLIMITED"
480 PRINT : PRINT ; TAB( 16);"OPTIONS": PRINT
490 PRINT "4"; TAB( 3);"APPROACH"
500 PRINT "5"; TAB( 3);"RETREAT"
510 PRINT "6 BY TYPING 6, YOU CAN LOSE YOUR TURN"
520 PRINT " AND GAIN 500 UNITS OF POWER"
530 PRINT " BUT YOU CANNOT INPUT COMMAND 6"
540 PRINT " WHEN YOU HAVE FULL POWER"
550 PRINT "7"; TAB( 3);"RECALL OF COMMANDS"
560 PRINT "8"; TAB( 3);"REPORT OF EACH SHIP'S STATUS"
570 PRINT "9"; TAB( 3);"SELF-DESTRUCT"
580 IF C = 7 THEN 1210
590 GOSUB 8000
630 PRINT "THE FOLLOWING ARE DESCRIPTIONS OF YOUR": PRINT : PRINT "WEAPONS, WHICH ARE IDENTICAL IN EVERY": PRINT : PRINT "WAY TO THOSE OF THE ALIEN"
640 PRINT : PRINT "HEAVY GUNS":LG = 10: GOSUB 3800
650 PRINT "SUPPLY :AS LONG AS POWER LASTS"
660 PRINT "FUEL DRAIN :10 UNITS"
670 PRINT "DAMAGE TO ENEMY :100 UNITS"
680 PRINT : PRINT : PRINT "PHOTON TORPEDOES":LG = 16: GOSUB 3800
690 PRINT "SUPPLY :10 TORPEDOES"
700 PRINT "FUEL DRAIN :NONE"
710 PRINT "DAMAGE TO ENEMY :1500 UNITS"
720 GOSUB 8000
730 PRINT "LASERS":LG = 6: GOSUB 3800
740 PRINT "SUPPLY :AS LONG AS POWER LASTS"
750 PRINT "FUEL DRAIN :VARIABLE, PICKED BY YOU"
760 PRINT "DAMAGE TO ENEMY :FUEL DRAIN X % OF RANGE";
770 PRINT "(FROM 50% TO 150% OF FUEL DRAIN IS SPENT";: PRINT "ON ENEMY)"
780 PRINT : PRINT "THE CLOSER YOU ARE TO THE ENEMY, THE": PRINT : PRINT "MORE HE'LL BE DAMAGED BY YOUR LASERS"
790 GOSUB 8000
800 PRINT "SELF-DESTRUCT":LG = 13: GOSUB 3800
810 PRINT : PRINT "THE SELF-DESTRUCT MECHANISM SHOULD ONLY": PRINT : PRINT "BE USED IN AN EMERGENCY"
820 PRINT : PRINT "WHEN THE SHIP BLOWS UP, THE ENEMY": PRINT : PRINT "SUFFERS LOSSES EQUAL TO YOUR TOTAL"
830 PRINT : PRINT "POWER PLUS 500 X EACH PHOTON TORPEDO": PRINT : PRINT "THIS RESULT IS THEN MULTIPLIED BY A "
840 PRINT : PRINT "NUMBER BETWEEN .4 AND 1, DEPENDING ON": PRINT : PRINT "YOUR RANGE"
850 GOSUB 8000
860 PRINT "BOTH SHIPS ARE ON THE SAME MISSION, SO": PRINT : PRINT "UNFORTUNATELY, YOU EACH MUST KILL THE": PRINT : PRINT "OTHER TO WIN."
870 PRINT : PRINT : PRINT "THIS IS A RECORDED MESSAGE.": PRINT : PRINT "BY THE TIME YOU FINISH READING THIS,"
880 PRINT : PRINT "EARTH WILL BE DEAD"
890 PRINT : FLASH : PRINT "GOOD LUCK": NORMAL
900 GOSUB 8000
1000 PT = 10:PT(1) = 10
1010 SPEED= 255
1020 PRINT "THIS IS COMPUTER CONTROL..."
1022 PRINT : PRINT "WHAT IS YOUR NAME?"
1023 PRINT : INPUT "===>";N$
1030 CALL -936:P = 10000:P(1) = 10000:A = INT( RND(1) *200000) +1
1040 PRINT "ENTER SELF-DESTRUCT PASSWORD, ";N$
1045 PRINT : INPUT "===>";SF$
1050 HOME
1060 B = 900000
1070 PRINT "LEAVING PLANETARY ORBIT ON AUTO PILOT"
1080 PRINT : PRINT "ENEMY SHIP CLOSING FAST": PRINT : PRINT "RANGE :";B;: HTAB 20: FLASH : PRINT "OUT OF RANGE": NORMAL
1090 VTAB 5: HTAB 8: PRINT " "
1100 FOR B = 900000 TO A STEP -1234
1110 VTAB 5: HTAB 8: PRINT B;" ": NEXT B
1120 VTAB 5: HTAB 20: FLASH : PRINT "IN RANGE";: NORMAL : PRINT " "
1130 VTAB 5: HTAB 8: PRINT A
1140 PRINT : PRINT : PRINT "AUTO PILOT OFF"
1200 POKE 35,18
1210 PRINT : PRINT "WHAT ";: GOSUB 4100: PRINT "ARE ";: GOSUB 4100: PRINT "YOUR ";: GOSUB 4100
1220 PRINT "ORDERS, ";: GOSUB 4100: PRINT "CAPTAIN ";: GOSUB 4100: PRINT N$;"?": GOSUB 4100
1230 GET A$
1240 C = VAL(A$)
1250 IF C = 0 THEN C = 7
1260 O = INT( RND(8) *2) +1
1270 IF C <1 OR C >9 THEN 1230
1280 CALL -936
1290 CV = 1
1500 ON C GOTO 1510,1610,1710,1820,1850,1890,410,1940,4500
1510 PRINT : IF A < = 25000 THEN 1540
1520 PRINT : PRINT "RANGE HAS TO BE 25000 MILES OR LESS": PRINT : PRINT "CURRENT RANGE IS ";A;" MILES"
1530 GOTO 1200
1540 P = P -10: PRINT "GUNS FIRED ";: GOSUB 3500
1550 IF O = 1 THEN 1570
1560 PRINT "MISSED": GOTO 1920
1570 PRINT "DIRECT HIT!": GOSUB 3900
1580 LL = A * -1/10000 +7/2
1590 PRINT "ENEMY LOSSES "; INT(LL *100);" UNITS"
1600 P(1) = P(1) -LL *100: GOTO 1920
1610 PRINT : IF PT >0 THEN 1630
1620 PRINT "CAPTAIN, WE HAVE NO MORE TORPEDOES": GOTO 1200
1630 IF A >1000 THEN 1650
1640 PRINT "WE ARE TOO CLOSE TO USE OUR TORPEDOES": PRINT : PRINT "WITHOUT DAMAGE TO OUR SHIP": GOTO 1200
1650 PT = PT -1: PRINT "TORPEDOES LAUNCHED";: GOSUB 3600
1660 IF O = 1 THEN 1680
1670 PRINT "MISSED": GOTO 1920
1680 PRINT "DIRECT HIT": GOSUB 3900
1690 PRINT "ENEMY LOSSES 1500 UNITS"
1700 P(1) = P(1) -1500: GOTO 1920
1710 INPUT "ENERGY TO FIRE?";E
1720 IF E < = 0 THEN 1210
1730 IF P -E < = 0 THEN 1750
1740 P = P -E: GOTO 1760
1750 PRINT "CAPTAIN, WE ONLY HAVE ";P: GOTO 1200
1760 PRINT "LAZERS FIRED";: GOSUB 3700
1770 IF O = 1 THEN 1790
1780 PRINT "MISSED": GOTO 1920
1790 PRINT "DIRECT HIT":LL = A * -1/200000 +1.5: GOSUB 3900
1800 PRINT "ENEMY LOSSES ";LL *E;" UNITS"
1810 P(1) = P(1) -LL *E: GOTO 1920
1820 B = RND(1) *20000 +10000:A = A -B:P = P -B/1000
1830 IF A <1 THEN 3000: GOTO 1920
1840 GOTO 1920
1850 B = RND(1) *20000 +10000:A = A +B:P = P -B/1000
1860 IF A >200000 THEN 1880
1870 GOTO 1920
1880 PRINT "CAPTAIN, AT THIS RANGE WE CANNOT REACH THE ENEMY WITH ANY OF OUR GUNS": GOTO 1920
1890 IF P > = 10000 THEN 1910
1900 P = P +500: GOTO 1920
1910 PRINT "CAPTAIN, OUR FUEL TANKS CANNOT HOLD ANY MORE ENERGY":P = 10000: GOTO 1920
1920 PRINT : IF P(1) < = 0 THEN P(1) = 0
1930 IF C(1) = 1 THEN GOSUB 5500
1940 F(1) = 0:CV = 7: GOSUB 6000
1950 PRINT : IF C = 8 THEN 2180
1960 IF P(1) <1 THEN 2390
1970 IF P(1) <500 THEN 2250
1980 Z = INT( RND(1) *2) +1:F(1) = 0: IF Z < >2 THEN 2220
1990 O = INT( RND(1) *2) +1
2000 X = INT( RND(1) *3) +1
2010 ON X GOTO 2020,2080,2130
2020 E1 = INT(P(1) *.1 + INT(A/5000)):P(1) = P(1) -E1
2030 PRINT "ENEMY FIRES LAZERS";: GOSUB 3700
2040 IF O = 1 THEN 2060
2050 PRINT "MISSED!": GOTO 2180
2060 PRINT "DIRECT HIT":LL = A * -1/200000 +1.5:P = P -LL *E1: GOSUB 3900
2070 PRINT LL *E1;" UNIT LOSS FROM ENEMY": GOTO 2180
2080 IF PT(1) = 0 THEN 2000
2090 PT(1) = PT(1) -1: PRINT "ENEMY FIRES": PRINT "PHOTON TORPEDOES";: GOSUB 3600
2100 IF O = 1 THEN 2120
2110 PRINT "MISSED!": GOTO 2180
2120 P = P -1500: PRINT "DIRECT HIT": GOSUB 3900: GOTO 2180
2130 IF A >25000 THEN 2000
2140 P(1) = P(1) -10: PRINT "ENEMY FIRES": PRINT "HEAVY GUNS";: GOSUB 3500
2150 IF O = 1 THEN 2170
2160 PRINT "MISSED!": GOTO 2180
2170 PRINT "DIRECT HIT": GOSUB 3900
2180 IF P < = 0 THEN P = 0
2190 CV = 15: PRINT : PRINT :F(1) = F(1) +1: GOSUB 6000
2200 IF P <1 THEN 2440
2210 IF F(1) = 1 THEN 1200
2220 X = INT( RND(3) *3) +1
2230 ON X GOTO 2240,2260,2310
2240 IF P(1) >10000 THEN 2220
2250 P(1) = P(1) +500: PRINT "ENEMY SHIP RESTING AND GAINING 500 UNITS OF ENERGY": GOTO 2190
2260 IF A <24000 THEN 2220
2270 B = RND(1) *20000 +10000:A = A -B:P(1) = P(1) -B/1000
2280 PRINT "ENEMY SHIP APPROACHING": PRINT : PRINT "CURRENT RANGE :";A
2290 FOR X = 1 TO 75: NEXT X: IF A < = 0 THEN 3000
2300 GOTO 2190
2310 B = RND(1) *20000 +10000:A = A +B:P(1) = P(1) -B/1000: IF A >200000 THEN A = 200000
2320 PRINT "ENEMY SHIP RETREATING": PRINT : PRINT "CURRENT RANGE :";A: GOTO 2190
2330 IF P < = 0 OR A <0 THEN 2350
2340 GOTO 2190
2350 IF A < = 0 THEN 3000
2360 PRINT : PRINT : PRINT "ENEMY IS VICTOR"
2370 S$ = "LIFE SUPPORT FADING..."
2380 FOR X = 1 TO 22: PRINT MID$ (S$,X,1);: FOR Y = 1 TO X *50: NEXT Y: NEXT X: GOTO 2450
2390 SPEED= 175: PRINT : PRINT "ENEMY'S SHIP IS WITHOUT POWER.": PRINT "SENSERS DO NOT PICK UP ANY LIFE FORMS."
2400 FLASH
2410 PRINT "MISSION SUCCESSFUL!!!!"
2420 NORMAL
2430 PRINT "CONGRATULATIONS ";N$: GOTO 2450
2440 GOTO 2360
2450 PRINT : INPUT "AGAIN (Y/N) ===>";N$
2470 IF N$ = "N" THEN END
2480 IF N$ = "Y" THEN 10
2490 GOTO 2460
2930 GOTO 3190
2980 GOTO 2410
3000 CALL -936:S = -16336
3010 FLASH
3020 GOSUB 3060
3030 VTAB 1: HTAB 1: INVERSE : SPEED= 210: GOSUB 3070
3040 HTAB 1: VTAB 1: NORMAL : GOSUB 3070
3050 GOTO 3170
3060 POKE 35,24: CALL -936
3070 POKE 35,24
3080 PRINT "***** ******* ******* ** **"
3090 PRINT "** ** ** ** ** ** *** ***"
3100 PRINT "** ** ** ** ** ** ** * **"
3110 PRINT "***** ** ** ** ** ** **"
3120 PRINT "** ** ** ** ** ** ** **"
3130 PRINT "** ** ** ** ** ** ** **"
3140 PRINT "***** ******* ******* ** **"
3150 GOSUB 4000
3160 RETURN
3170 SPEED= 255: PRINT : PRINT : PRINT "*** COLLISION ***"
3180 PRINT : PRINT "BOTH SHIPS DESTROYED"
3190 PRINT : PRINT "THAT WAS A DUMB THING TO DO ";N$;"!!!": PRINT
3200 PRINT "YOUR MISSION WAS TO PROTECT YOUR": PRINT : PRINT "PASSENGERS, NOT GET THEM KILLED"
3210 GOTO 2450
3220 END
3500 FOR X = 1 TO 10: FOR Y = 1 TO 16: NEXT Y: PRINT ".";:SO = PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S): NEXT X: RETURN
3600 FOR X = 1 TO 10: FOR Y = 1 TO 90: NEXT Y: PRINT "#";
3610 FOR YY = 1 TO 5:S0 = PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S): NEXT YY: NEXT X: RETURN
3700 FOR X = 1 TO 10: FOR Y = 1 TO 30: NEXT Y: PRINT "-";
3710 FOR YY = 1 TO 8:SO = PEEK(S) - PEEK(S): NEXT YY: NEXT X: RETURN
3800 FOR X = 1 TO LG: PRINT "-";: NEXT X: PRINT : RETURN
3900 FOR X = 1 TO 10: FOR XX = 1 TO 10:SO = PEEK(S): NEXT XX: FOR Y = 1 TO 20: NEXT Y:SI = PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S): NEXT X: RETURN
4000 FOR X = 1 TO 15: FOR XX = 1 TO 10:SO = PEEK(S): NEXT XX: FOR YY = 1 TO 20: NEXT YY:SO = PEEK(S) - PEEK(S): NEXT X: RETURN
4100 FOR XX = 1 TO 10:SO = PEEK(S): NEXT XX: FOR YY = 1 TO 50: NEXT YY:SO = PEEK(S) - PEEK(S): RETURN
4200 FOR X = 1 TO 40:SO = PEEK(S) - PEEK(S): NEXT X: FOR X = 1 TO 30: NEXT X
4210 FOR Y = 1 TO 30: NEXT Y
4220 FOR X = 1 TO 35:SO = PEEK(S): NEXT X
4230 FOR Y = 1 TO 20: NEXT Y: RETURN
4500 INPUT "ENTER SELF-DESTRUCT PASSWORD";SD$
4510 IF SD$ = SF$ THEN 4530
4520 GOTO 1200
4530 TEXT : HOME : FLASH
4540 FOR YX = 1 TO 30: HTAB 13: VTAB 2: PRINT "EVACUATE SHIP"
4550 IF YX = 4 THEN 4590
4560 IF YX > = 21 THEN 4640
4570 IF YX > = 15 THEN 4610
4580 GOTO 4650
4590 VTAB 3: PRINT : PRINT "ALL PASSENGERS TO EMERGENCY PODS"
4600 GOTO 4650
4610 VTAB 3: PRINT : NORMAL : PRINT " ": VTAB 3: FLASH : PRINT
4620 PRINT "PODS WILL LAUNCH IN T-MINUS ";20 -YX
4630 GOTO 4650
4640 VTAB 3: PRINT : NORMAL : PRINT " ": VTAB 3: FLASH : PRINT : HTAB 13: PRINT "PODS LAUNCHED"
4650 GOSUB 4200: NEXT YX
4660 HTAB 13: VTAB 2: PRINT "SHIP EVACUATED": NORMAL
4670 PRINT : PRINT "ALL PASSENGERS ARE LOADED IN EMERGENCY"
4680 PRINT : PRINT "PODS AND ARE A SAFE DISTANCE FROM SHIP"
4690 PRINT : PRINT "PRESS KEY '9' AND THE SHIP WILL DETONATE"
4700 CC = PEEK( -16384)
4710 IF CC = 185 THEN 4740
4720 GOSUB 4200
4730 GOTO 4700
4740 POKE -16368,0: CALL -936: GOSUB 3060
4750 LL = A * -.6/200000 +1
4760 EL = LL *(P +PT *500)
4770 P(1) = P(1) -EL: IF P(1) < = 0 THEN 4900
4780 PRINT : PRINT : PRINT "ENEMY STILL HAS POWER": FOR X = 1 TO 200
4790 PRINT : PRINT "FIRES LASERS";
4800 GOSUB 3700
4810 PRINT "DIRECT HIT": GOSUB 3900
4820 PRINT : PRINT "ALL PODS DESTROYED"
4830 GOTO 3190
4900 DI = INT( RND(8) *20000) +1
4910 IF P < = DI THEN 4950
4920 PRINT N$;" YOU DESTROYED THE ENEMY, BUT YOU "
4925 PRINT : PRINT "DON'T HAVE ENOUGH FUEL TO MAKE IT TO"
4928 PRINT : PRINT "A PLANET..."
4930 GOTO 3190
4950 PRINT : PRINT "NOT ONLY DID YOU DESTROY THE ENEMY, "
4960 PRINT : PRINT "BUT YOU SAFELY GUIDED YOUR PASSENGERS"
4970 PRINT : PRINT "TO A PLANET."
4980 GOTO 2430
5500 IF A RR THEN 5530
5520 A = RR:C(1) = 0
5530 PRINT "SHIP ADVANCING TO ";A
5540 RETURN
5550 A = A +15000:P = P -15: IF A 10000 THEN P = 10000
6060 IF P(1) >10000 THEN P(1) = 10000
6070 VTAB 22: CALL -868
6080 VTAB 22: PRINT "POWER"; TAB( 12);":";P(1); TAB( 20);"POWER"; TAB( 32);":";P
6090 VTAB 23: CALL -868
6100 VTAB 23: PRINT "TORPEDOES"; TAB( 12);":";PT(1); TAB( 20);"TORPEDOES"; TAB( 32);":";PT
6110 VTAB CV +1
6120 POKE 35,18
6130 RETURN
7000 PRINT TAB( (40 - LEN(A$))/2);A$
7010 RETURN
8000 VTAB 24
8010 PRINT "TO CONTINUE, PLEASE PRESS THE ";
8020 FLASH
8030 PRINT "SPACE BAR";
8040 NORMAL
8050 IF PEEK( -16384) < >160 THEN 8050
8060 POKE -16368,0
8070 HOME
8080 RETURN