Notes

Disk info for RIC_Programs_54.dsk:

File Name: riag_011_RIC_Programs_54/RIC_Programs_54.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 33280
Used Space (bytes): 110080
Physical Size (KB): 140
Free Space (KB): 32
Used Space (KB): 107
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 130
Used Sectors: 430
Tracks On Disk: 35
Sectors On Disk: 16



Text found in RIC_Programs_54.dsk/CURSORS.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 0C 00 20 00 47 00 59 00 5B 00 68 00 75 00 82 00 .. .G.Y. [.h.u...
$000010 95 00 9B 00 9B 00 9B 00 9B 00 00 00 00 00 00 00 ........ ........
$000020 09 2D 2D 15 3F 3F 3F 17 2D 2D 2D 2D 3E 3F 3F 3F .--.???. ---->???
$000030 37 2D 2D 2D 2D 3E 3F 3F 3F 37 2D 2D 2D 2D 1E 3F 7---->?? ?7----.?
$000040 3F 3F 0E 2D 2D 96 00 09 2D 2D 15 15 36 36 1E 1E ??.--... --..66..
$000050 3F 3F 1C 1C 24 24 0C 05 00 1D 00 36 36 36 2E 2D ??..$$.. ...666.-
$000060 2D 24 24 24 3C 3F 3F 00 12 36 36 2D 2D 25 24 3C -$$$ $000070 3F 3F 18 08 00 2E 68 49 29 B6 92 32 3F DB 1B 27 ??....hI )6.2?[.'
$000080 04 00 92 92 92 92 92 2D 2D 2D 2D 25 C0 C0 C0 C0 .......- ---%@@@@
$000090 C0 C0 C0 1B 00 2D 3E 37 2D 05 00 0D 16 1F 07 00 @@@..->7 -.......
$0000A0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000B0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000C0 00 00 00 00 00 00 00 00 A0 00 A5 3C C9 00 D0 02 ........ .%.@ %>I.P.F?
$0000E0 C6 3E A5 40 C9 00 D0 02 C6 41 C6 40 A5 3D C5 3F F>%@I.P. FAF@%=E?
$0000F0 D0 E2 A5 3C C5 3E D0 DC 60 D8 A0 00 4C 2C FE .. Pb%P\ `X .L,~
** END **

Text found in RIC_Programs_54.dsk/DISK LABELER.bas:

3 TEXT : HOME
4 VTAB 10: FLASH
5 PRINT "PRINTER NEEDS TO BE TURNED ON": PRINT "PRESS ANY KEY WHEN IT IS.": GET KEY$
6 NORMAL
10 PR# 1
15 PRINT CHR$(29)
19 PR# 0
90 LOMEM: PEEK(175) + PEEK(176) *256 +200
95 TEXT : HOME
97 D$ = CHR$(13) + CHR$(4):BELL$ = CHR$(7) + CHR$(7)
98 SLOT = 1
99 PRNT$ = "PR#" + STR$(SLOT)
100 VTAB 5
110 A$ = "***************************************": GOSUB 7000
115 PRINT : PRINT
120 A$ = "CATALOG LABELS PRINTING PROGRAM": GOSUB 7000
130 PRINT : PRINT
140 A$ = "INSTALLING MACHINE CODE": GOSUB 7000
150 PRINT : PRINT
500 GOSUB 1000: IF ER THEN 900
510 GOSUB 2000
520 GOSUB 5000
600 HOME : VTAB 10
610 A$ = "TYPE Y TO PRINT A LABEL": GOSUB 7000
620 PRINT :A$ = "HIT N TO EXIT": GOSUB 7000
630 GET A$: IF A$ = "N" THEN 900
635 IF A$ < >"Y" THEN 600
640 GOSUB 6000
650 GOTO 600
900 PRINT : PRINT : PRINT :A$ = "PROGRAM TERMINATED": GOSUB 7000: PRINT BELL$;BELL$;
997 PR# 6
1000 REM
1010 DOS = PEEK(978)
1015 FUNC = DOS *256 +4248
1030 A1 = PEEK(FUNC):A2 = PEEK(FUNC +1):A3 = PEEK(FUNC +2)
1035 ER = 0
1040 IF A1 = 32 AND A2 +A3 *256 = FUNC -444 THEN 1060
1045 ER = 255
1050 HOME : VTAB 10
1055 PRINT BELL$:A$ = "STANDARD DOS": GOSUB 7000
1056 PRINT : PRINT :A$ = "NOT RESIDENT IN THIS MACHINE": GOSUB 7000
1060 RETURN
1160 A$ = "***************************************": GOSUB 7000
2000 REM
2010 RTN = PEEK(175) + PEEK(176) *256 +5:LNGTH = 149
2020 FOR I = RTN TO RTN +LNGTH
2040 READ A
2045 IF A <0 THEN A = ABS(A) +DOS
2050 POKE I,A
2060 NEXT I
2075 A = RTN +112
2080 POKE RTN +86, INT(A/256): POKE RTN +85,A - INT(A/256) *256
2090 RETURN
3000 REM MACHINE LANGUAGE CODE AND DECIMAL
3010 DATA 32,220,-14,169,255,141,249,-24,32,247,175,169
3015 DATA 3
3020 DATA 141,206,3,169
3025 DATA 8
3030 DATA 141,207,3,169,141,32,237,253,24,32,17,-19
3035 DATA 176,62,162,0,142,156,-22,189,198,-23,240,52,48
3040 DATA 43,189,200,180,41,127,160,7,10,10,176,3,136,208,250,185
3045 DATA 167,-22,32,237,253,169,186,32,237,253,232,232,232,160
3050 DATA 23
3055 DATA 189,198,-23,32,237,253,232,136,16,246,32,112,16,32
3060 DATA 48,-21,144,198,176,189,169,141,32,237,253,206,207,3
3065 DATA 208,246,76,127,-22,0,0,0,0,0,169,252,32,237,253
3070 DATA 206,206,3,208,25,169, 141,32 ,237,253,169
3075 DATA 3
3080 DATA 141,206,3,206,207,3,208,10,169,141,32,237,253,169
3085 DATA 8
3090 DATA 141,207,3,96,0,0
4010 POKE FUNC,76: POKE FUNC +2, INT(RTN/256): POKE FUNC +1,RTN - INT(RTN/256) *256
4020 RETURN
4510 POKE FUNC,A1: POKE FUNC +1,A2: POKE FUNC +2,A3
4520 RETURN
5000 REM
5015 HOME : VTAB 5
5020 A$ = "DO LABELS NEED TO BE": GOSUB 7000
5030 PRINT :A$ = "INSTALLED AND POSITIONED": GOSUB 7000
5040 PRINT :A$ = "IN PRINTER? ": GOSUB 7000
5050 GET A$: IF A$ = "N" THEN 5300
5060 IF A$ < >"Y" THEN 5050
5070 PRINT : PRINT
5100 A$ = "POSITION TOP OF FIRST LABEL": GOSUB 7000
5110 PRINT :A$ = "IN FRONT OF PRINT HEAD AND ": GOSUB 7000
5120 PRINT :A$ = "TYPE Y ": GOSUB 7000
5130 GET A$: IF A$ < >"Y" THEN 5015
5140 PRINT D$;PRNT$
5150 PRINT CHR$(29);
5160 PRINT "IS THIS FIRST LINE ON LABEL? "
5165 GET A$
5170 IF A$ = "N" THEN 5150
5175 IF A$ < >"Y" THEN 5165
5190 PRINT : PRINT : PRINT : PRINT : PRINT : PRINT : PRINT
5200 PRINT CHR$(4)"PR#0"
5300 RETURN
6000 REM
6010 GOSUB 4010
6015 PRINT CHR$(29)
6020 PRINT D$;PRNT$;
6030 PRINT D$"CATALOG";
6040 PRINT D$"PR#0"
6050 GOSUB 4510
6060 RETURN
7000 REM PRINTS A$ IN CENTER OF SCREEN
7010 HTAB INT((40 - LEN(A$))/2) +1
7015 PRINT A$
7030 RETURN

Text found in RIC_Programs_54.dsk/DUNKING GAME.bas:

10 REM THE DUNKING MACHINE
20 BK = 0:MG = 1:BL = 2:BB = 6:LB = 7:OG = 9:AQ = 14:WH = 15: REM COLORS (MG=MAGENTA,BB=BLUE)
30 ONERR GOTO 6000
40 GOSUB 4000: REM TITLE
50 GOSUB 5000: REM TONE POKES
55 ST = 1: GR : GOTO 1350
1000 REM MAIN LOOP
1010 X = 10 * RND(1) + PDL(0)/9.11 +2:Y = 22 * RND(1) +(255 - PDL(1))/11.1 +2
1020 X = X -(X -37) *(X >37)
1025 Y = Y -(Y -37) *(Y >37)
1030 IF INT(10 * RND(1)) = 5 THEN GOSUB 2020: REM SHIFT EYES
1040 IF INT(10 * RND(1)) = 5 THEN GOSUB 2050: REM TALK
1050 REM STORE BACKGROUND COLORS
1060 C(1) = SCRN( X -2,Y):C(2) = SCRN( X -1,Y):C(3) = SCRN( X +1,Y):C(4) = SCRN( X +2,Y):C(5) = SCRN( X,Y +2):C(6) = SCRN( X,Y +1):C(7) = SCRN( X,Y -1):C(8) = SCRN( X,Y -2)
1070 COLOR= 1
1080 REM DRAW SIGHT
1090 HLIN X -2,X -1 AT Y: HLIN X +1,X +2 AT Y: VLIN Y -1,Y -2 AT X: VLIN Y +1,Y +2 AT X
1100 POKE 768,(X +Y) *3: POKE 769,4: CALL 770
1110 REM BUTTON?
1120 FOR TI = 0 TO 5
1130 IF PEEK( -16286) >127 OR PEEK( -16287) >127 THEN 1190
1140 NEXT
1150 REM REDRAW BACKGROUND
1160 COLOR= C(1): PLOT X -2,Y: COLOR= C(2): PLOT X -1,Y: COLOR= C(3): PLOT X +1,Y: COLOR= C(4): PLOT X +2,Y: COLOR= C(5): PLOT X,Y +2: COLOR= C(6): PLOT X,Y +1
1170 COLOR= C(7): PLOT X,Y -1: COLOR= C(8): PLOT X,Y -2
1180 GOTO 1010
1190 POKE 768,5: FOR TI = 1 TO 5: POKE 769,4: CALL 770: NEXT
1200 TRY = TRY +1
1210 IF SCRN( X,Y) = 9 THEN 1260
1220 POKE 768,255: FOR TI = 1 TO 50: POKE 769,3: CALL 770: NEXT
1230 IF TRY = 3 THEN TRY = 0: GOSUB 2090: GOTO 1350
1240 GOTO 1160
1250 REM DUNK HIM!
1260 DUNK = 1
1270 FOR TI = 0 TO 3
1280 FOR T = 255 TO 75 STEP -10: POKE 768,T: POKE 769,8: CALL 770: NEXT
1290 NEXT TI
1300 RESTORE
1310 FOR TI = 0 TO 5: READ X,Y: POKE 768,X: POKE 769,Y: CALL 770: NEXT
1320 GOSUB 2240
1330 POKE 768,200: FOR TI = 1 TO 15: POKE 769,40: CALL 770: NEXT
1340 PLSC = PLSC +1:TRY = 0
1350 HOME : IF ST THEN 1370
1370 INVERSE : PRINT " CURRENT SCORE: ";: NORMAL
1380 IF VS >PL THEN FLASH
1390 HTAB 14: PRINT "JACK NIFE... "VSC
1400 IF PLSC VS THEN FLASH
1420 HTAB 14: PRINT "PLAYER...... "PLSC
1425 IF ST THEN ST = 0: INVERSE : POKE 2039,32: GOTO 1460
1430 INVERSE : INPUT "DO YOU WANT TO TRY AGAIN (Y/N)? ";AP$: IF AP$ = "N" THEN PRINT CHR$(4);"RUN HELLO"
1432 PRINT "PRESS PADDLE BUTTON TO TRY AGAIN";: POKE 2039,32
1440 IF PEEK( -16286) >127 OR PEEK( -16287) >127 THEN 1460
1450 GOTO 1440
1460 VTAB 24: HTAB 1: PRINT SPC( 39);:DUNK = 0: GOSUB 3020
1470 GOTO 1000
2000 REM ANIMATION
2010 REM SHIFT EYES
2020 COLOR= 11: IF SCRN( 12,6) = 2 THEN PLOT 12,6: PLOT 14,6: COLOR= 2: PLOT 11,6: PLOT 13,6: RETURN
2030 PLOT 11,6: PLOT 13,6: COLOR= 2: PLOT 12,6: PLOT 14,6: RETURN
2040 REM CHATTER
2050 IF SCRN( 12,9) = 1 THEN COLOR= 11: HLIN 12,13 AT 9: RETURN
2060 FOR TI = 1 TO 8 * RND(1) +5
2070 COLOR= 1: HLIN 12,13 AT 9: POKE 768,150 + INT(100 * RND(1)): POKE 769, INT(3 * RND(1)) +1: CALL 770: COLOR= 11: HLIN 12,13 AT 9
2080 NEXT : RETURN
2090 REM RAISE ARMS
2095 COLOR= C(1): PLOT X -2,Y: COLOR= C(2): PLOT X -1,Y: COLOR= C(3): PLOT X +1,Y: COLOR= C(4): PLOT X +2,Y: COLOR= C(5): PLOT X,Y +2: COLOR= C(6): PLOT X,Y +1
2096 COLOR= C(7): PLOT X,Y -1: COLOR= C(8): PLOT X,Y -2
2100 COLOR= 4: HLIN 6,15 AT 15
2110 COLOR= 7: VLIN 12,14 AT 16: HLIN 7,9 AT 14: HLIN 8,9 AT 13: PLOT 9,12
2120 COLOR= 12: VLIN 10,11 AT 10: VLIN 10,11 AT 15: VLIN 8,11 AT 9: VLIN 7,10 AT 8: VLIN 7,8 AT 7
2130 VLIN 8,11 AT 16: VLIN 7,10 AT 17: VLIN 7,8 AT 18
2140 COLOR= 11: HLIN 7,8 AT 6: PLOT 8,5: PLOT 17,5
2150 FOR T = 1 TO 6
2160 COLOR= 11: HLIN 17,18 AT 6
2170 COLOR= 1: HLIN 12,13 AT 9
2180 IF DUNK THEN RETURN
2190 POKE 768,0: FOR TI = 1 TO 20: POKE 769,2: CALL 770: NEXT
2200 COLOR= 11: HLIN 12,13 AT 9
2210 FOR TI = 1 TO 50: NEXT : NEXT
2220 VSC = VSC +1: RETURN
2230 REM DUNKING ANIMATION
2240 GOSUB 2100
2250 COLOR= LB: VLIN 17,27 AT 36: COLOR= BK: VLIN 16,27 AT 35
2260 COLOR= WH: VLIN 18,26 AT 34: COLOR= OG: VLIN 19,25 AT 33
2270 COLOR= LB: VLIN 16,27 AT 35
2280 PLOT 34,27: PLOT 28,17: PLOT 22,22
2290 COLOR= BK: VLIN 15,26 AT 34
2300 PLOT 33,16: PLOT 28,28: PLOT 22,23
2310 COLOR= WH: VLIN 19,25 AT 33
2320 PLOT 29,27: PLOT 33,17
2330 PLOT 30,19: COLOR= OG: PLOT 30,26
2340 COLOR= BK: PLOT 28,29: PLOT 29,28
2350 PLOT 29,18
2360 COLOR= LB: PLOT 28,18: PLOT 29,17
2370 PLOT 22,23: PLOT 23,22
2380 COLOR= 4: PLOT 24,22
2390 COLOR= BK: PLOT 22,25: PLOT 23,24: PLOT 24,23
2400 COLOR= WH: PLOT 30,26
2410 COLOR= OG: VLIN 19,24 AT 32
2420 COLOR= BK: PLOT 27,21: COLOR= LB: PLOT 27,22
2430 COLOR= WH: PLOT 32,25
2440 REM
2450 COLOR= LB: PLOT 3,23: COLOR= MG: PLOT 21,23
2460 COLOR= LB: PLOT 4,22: COLOR= MG: PLOT 22,22
2470 COLOR= LB: PLOT 5,21: COLOR= MG: PLOT 23,21
2480 COLOR= MG: HLIN 4,8 AT 24
2490 PLOT 11,24: HLIN 14,18 AT 24
2500 HLIN 20,21 AT 24
2510 COLOR= LB: VLIN 23,24 AT 4: COLOR= MG: VLIN 23,24 AT 22
2520 COLOR= LB: VLIN 22,24 AT 5: COLOR= MG: VLIN 22,23 AT 23
2530 COLOR= MG: HLIN 6,8 AT 25
2540 PLOT 11,25: HLIN 14,18 AT 25: HLIN 20,21 AT 25
2550 REM
2560 COLOR= MG: VLIN 21,25 AT 9: COLOR= AQ: VLIN 26,27 AT 9
2570 COLOR= BB: VLIN 21,27 AT 11
2580 COLOR= BL: VLIN 21,27 AT 12
2590 COLOR= MG: VLIN 20,27 AT 13
2600 COLOR= BB: VLIN 21,27 AT 14: VLIN 20,27 AT 15
2610 REM
2620 COLOR= LB: FOR Y = 4 TO 9: HLIN 6,20 AT Y: NEXT : COLOR= 4: HLIN 6,20 AT 10
2630 COLOR= LB: FOR Y = 11 TO 14: HLIN 7,19 AT Y: NEXT
2640 FOR Y = 16 TO 19: HLIN 7,18 AT Y: NEXT
2650 COLOR= MG: FOR Y = 20 TO 25: HLIN 10,15 AT Y: NEXT
2660 COLOR= AQ: FOR Y = 26 TO 28: HLIN 10,15 AT Y: NEXT
2670 FOR T = 0 TO 49: COLOR= AQ
2680 VLIN 28,5 * RND(1) AT 22 * RND(1) +2
2690 TI = PEEK( -16336)
2700 COLOR= 4: HLIN 2,18 AT 15: PLOT 20,14: PLOT 21,13: PLOT 22,12: PLOT 23,11: VLIN 15,28 AT 19
2710 NEXT : RETURN
3000 REM SET UP GRAPHICS
3010 GR
3020 COLOR= 7: FOR Y = 0 TO 33: HLIN 0,39 AT Y: NEXT : COLOR= 8: FOR Y = 34 TO 39: HLIN 0,39 AT Y: NEXT : COLOR= 4: VLIN 15,39 AT 1: VLIN 15,39 AT 19: HLIN 2,18 AT 15: HLIN 2,18 AT 39
3021 PLOT 2,14: PLOT 3,13: PLOT 4,12: PLOT 5,11: PLOT 6,10
3030 VLIN 10,24 AT 6: PLOT 20,14: PLOT 21,13: PLOT 22,12: PLOT 23,11: PLOT 24,10
3040 HLIN 7,23 AT 10: VLIN 11,34 AT 24
3050 COLOR= 14: FOR Y = 29 TO 38: HLIN 2,18 AT Y: NEXT
3060 HLIN 3,18 AT 28: HLIN 4,18 AT 27: HLIN 5,18 AT 26: HLIN 6,18 AT 25
3070 FOR Y = 25 TO 34: HLIN 20,23 AT Y: NEXT
3080 HLIN 20,22 AT 35: HLIN 20,21 AT 36: PLOT 20,37
3085 COLOR= 4: PLOT 20,38: PLOT 21,37: PLOT 22,36: PLOT 23,35
3090 COLOR= 1: HLIN 6,18 AT 20: HLIN 20,23 AT 20: HLIN 5,18 AT 21: HLIN 20,22 AT 21: HLIN 4,18 AT 22: HLIN 20,21 AT 22: HLIN 3,18 AT 23: PLOT 20,23
3100 COLOR= 0: HLIN 22,27 AT 22: VLIN 18,26 AT 28: VLIN 18,26 AT 36: HLIN 28,36 AT 17: HLIN 28,36 AT 27
3110 COLOR= 15: FOR Y = 18 TO 26: HLIN 29,35 AT Y: NEXT
3120 COLOR= 9: FOR Y = 19 TO 25: HLIN 30,34 AT Y: NEXT
3150 REM DRAW JACK
3160 COLOR= 6: VLIN 21,27 AT 9: HLIN 10,15 AT 19
3170 VLIN 21,27 AT 10: HLIN 11,14 AT 5: HLIN 12,13 AT 4
3180 VLIN 21,27 AT 12: VLIN 21,27 AT 13
3190 HLIN 10,11 AT 20: HLIN 13,14 AT 20
3200 COLOR= 2: VLIN 21,22 AT 11
3210 VLIN 21,22 AT 14: PLOT 12,20: VLIN 20,22 AT 15
3220 COLOR= 12: FOR Y = 16 TO 18: HLIN 10,15 AT Y: NEXT
3230 FOR Y = 12 TO 14: HLIN 10,15 AT Y: NEXT
3240 HLIN 11,14 AT 11: VLIN 12,14 AT 9: VLIN 13,14 AT 8: PLOT 7,14: VLIN 12,14 AT 16
3250 COLOR= 11: HLIN 12,13 AT 10: PLOT 10,6: PLOT 15,6
3260 FOR Y = 6 TO 9: HLIN 11,14 AT Y: NEXT : HLIN 6,7 AT 15: HLIN 12,13 AT 15
3270 COLOR= 2: PLOT 12,6: PLOT 14,6: COLOR= 8: HLIN 11,14 AT 8
3280 RETURN
4000 REM INSTRUCTIONS
4010 TEXT : HOME : VTAB 5
4020 HTAB 11: FLASH : PRINT " THE DUNKING MACHINE "
4030 NORMAL : PRINT
4040 HTAB 16: PRINT "BY JIM GANZ"
4050 PRINT : PRINT
4060 PRINT : PRINT "USE PADDLES 1 AND 2 TO CONTROL SIGHT,": PRINT
4070 PRINT "PRESS EITHER BUTTON TO FIRE. YOU HAVE 3": PRINT
4080 PRINT "TRIES BEFORE YOU LOSE. <<>>"
4090 VTAB 20: INPUT "PRESS 'RETURN' TO BEGIN";A$
4100 RETURN
5000 REM POKE TONE ROUTINE
5010 FOR T = 1 TO 12: READ TI: NEXT : FOR T = 770 TO 790: READ TI: POKE T,TI: NEXT
5020 RETURN
5030 REM TONE & MUSIC DATA
5040 DATA 170,80,170,70,200,80,150,80,170,100,200,120,173,48,192,136,208,5,206,1,3,240,9,202,208,245,174,0,3,76,2,3,96
6000 NORMAL : TEXT : HOME : TEXT : END
7000 REM
7010 REM
7020 REM "THE DUNKING MACHINE"
7030 REM
7040 REM A LOW-RES
7050 REM ANIMATED GAME
7060 REM FOR ONE PLAYER
7070 REM
7080 REM BY JIM GANZ
7090 REM
7100 REM FEB, 1981
7110 REM
7120 REM REQUIREMENTS:
7130 REM APPLESOFT ][ AND
7140 REM GAME PADDLES
7150 REM
7160 REM CLASSIFIED
7170 REM -PUBLIC DOMAIN-
7180 REM NOVEMBER, 1981
7190 REM
7200 REM PLEASE RETAIN LINES
7210 REM 7000-7230
7220 REM IN ALL COPIES.
7230 REM -THANK YOU!!

Text found in RIC_Programs_54.dsk/FAMILY FINANCE.bas:

0 GOTO 40
1 REM **************************
2 REM * FAMILY FINANCE *
3 REM * COPYRIGHT (C) 1980 *
4 REM * KURT G. SCHUMACHER *
5 REM * ARLINGTON HEIGHTS, IL *
6 REM * DONATED BY AUTHOR TO *
7 REM * NORTHERN ILLINOIS AUG *
8 REM * DECLARED PUBLIC DOMAIN *
9 REM **************************
10 VTAB 24: CALL -868:EF = 0: RETURN : REM ERASE ERROR MSG
20 FOR Q = 1 TO LEN(Q$):QQ$ = MID$ (Q$,Q,1)
23 IF QQ$ = "+" OR QQ$ = "-" OR QQ$ = "." THEN 27
24 IF ASC(QQ$) >47 OR ASC(QQ$) <58 THEN 27
25 VTAB 24: PRINT G$;"PLEASE ENTER A NUMBER";:EF = 1: RETURN
27 NEXT Q: RETURN
30 VTAB 24: PRINT G$;"NUMBER OUT OF RANGE - PLEASE REENTER";: RETURN
40 TEXT : CLEAR : SPEED= 255: GOSUB 1400
50 HOME
60 PRINT "F A M I L Y F I N A N C E"
70 PRINT : PRINT " 0) END PROGRAM"
80 PRINT : PRINT " 1) LOAD FILE FROM DISK"
90 PRINT : PRINT " 2) SAVE FILE TO DISK"
100 PRINT : PRINT " 3) ENTER BUDGET DATA"
110 PRINT : PRINT " 4) DISPLAY BUDGET DATA"
120 VTAB 14: PRINT : INPUT "ENTER FUNCTION NUMBER (0-4): ";Q$
123 GOSUB 10
125 GOSUB 20: IF EF = 1 THEN 120
127 N = VAL(Q$)
130 IF N = 0 THEN 170
140 IF N <1 OR N >4 THEN GOSUB 30: GOTO 120
150 ON N GOSUB 230,330,400,700
160 GOTO 50
170 HOME : IF NOT CH THEN PRINT CHR$(4);"RUN HELLO"
180 PRINT "THE DATA CURRENTLY IN MEMORY HAS"
185 PRINT "BEEN CHANGED, BUT NOT SAVED.": PRINT
190 INPUT "DO YOU WISH TO SAVE IT? (Y/N) ";Q$
200 IF Q$ = "Y" THEN 330
210 IF Q$ < >"N" THEN PRINT G$: GOTO 190
220 HOME : PRINT CHR$(4);"RUN HELLO"
230 HOME : IF NOT CH THEN 280
240 PRINT "THE DATA IN CURRENTLY IN MEMORY HAS"
245 PRINT "BEEN CHANGED, BUT NOT SAVED.": PRINT
250 INPUT "DO YOU WISH TO SAVE IT? (Y/N) ";Q$
260 IF Q$ = "Y" THEN 330
270 IF Q$ < >"N" THEN PRINT G$: GOTO 250
280 INPUT "ENTER YEAR: ";F$
285 F$ = "BUDGET FILE." +F$
290 BL$ = "BLOAD " +F$ +",A"
300 & A%(0,0,0)
310 PRINT D$;BL$; PEEK(936) +256 * PEEK(937)
320 RETURN
330 HOME
340 INPUT "ENTER YEAR: ";F$
345 F$ = "BUDGET FILE." +F$
350 BS$ = "BSAVE " +F$ +",A":L$ = ",L"
360 LN = 32 *18 *13 *2
370 & A%(0,0,0)
380 PRINT D$;BS$; PEEK(936) +256 * PEEK(937);L$;LN
385 CH = 0
390 RETURN
400 HOME
410 VTAB 1: PRINT "ENTER MONTH (1-12):"
420 VTAB 2: PRINT "ENTER DAY (1-31):"
430 FOR I = 1 TO 9: VTAB I +3
440 PRINT I;") ";A$(I): NEXT I
450 FOR I = 10 TO 17: VTAB I -9 +3: HTAB 20
460 PRINT I;") ";A$(I): NEXT I
470 VTAB 20: PRINT "ENTER CATEGORY (1-17):"
480 VTAB 21: PRINT "ENTER AMOUNT:"
485 VTAB 23: PRINT "('0' RETURNS TO NEXT HIGHER ENTRY)
490 VTAB 1: HTAB 21: CALL -868: PRINT CHR$(95); CHR$(95)
491 VTAB 1: HTAB 21: INPUT "";Q$
493 GOSUB 10
495 GOSUB 20: IF EF = 1 THEN 490
497 M = VAL(Q$)
500 IF M = 0 THEN RETURN
510 IF M <1 OR M >12 THEN GOSUB 30: GOTO 490
520 VTAB 2: HTAB 19: CALL -868: PRINT CHR$(95); CHR$(95)
521 VTAB 2: HTAB 19: INPUT "";Q$
523 GOSUB 10
525 GOSUB 20: IF EF = 1 THEN 520
527 D = VAL(Q$)
530 IF D = 0 THEN 490
540 IF D <1 OR D >31 THEN GOSUB 30: GOTO 520
550 VTAB 20: HTAB 24: CALL -868: PRINT CHR$(95); CHR$(95)
551 VTAB 20: HTAB 24: INPUT "";Q$
553 GOSUB 10
555 GOSUB 20: IF EF = 1 THEN 550
557 C = VAL(Q$)
560 IF C = 0 THEN 520
570 IF C <1 OR C >17 THEN GOSUB 30: GOTO 550
580 VTAB 21: HTAB 15: FOR I = 1 TO 6: PRINT CHR$(95);: NEXT I
581 VTAB 21: HTAB 15: INPUT "";Q$
583 GOSUB 10
585 GOSUB 20: IF EF = 1 THEN 580
587 N = VAL(Q$)
590 IF N = 0 THEN 610
600 N1 = N1 +N: VTAB 21: HTAB 27: PRINT "TOTAL = ";N1;: GOTO 580
610 N1 = N1 +.5:N% = N1
620 A%(D,C,M) = A%(D,C,M) +N%
630 A%(0,C,M) = A%(0,C,M) +N%
640 IF C = 1 THEN 670
650 A%(D,0,M) = A%(D,0,M) +N%
660 A%(0,0,M) = A%(0,0,M) +N%
670 N1 = 0: REM CLEAR TOTAL
680 CH = 1: REM SET DATA CHANGED FLAG
690 GOTO 550
700 HOME
705 PRINT : PRINT " 0) RETURN"
710 PRINT : PRINT " 1) MONTHLY"
720 PRINT : PRINT " 2) YEARLY"
730 VTAB 8: HTAB 1: INPUT "ENTER DISPLAY TYPE (0-2): ";Q$
733 GOSUB 10
735 GOSUB 20: IF EF = 1 THEN 730
737 N = VAL(Q$)
740 IF N = 0 THEN RETURN
745 IF N <0 OR N >2 THEN GOSUB 30: GOTO 730
750 ON N GOSUB 770,1040
760 GOTO 700
770 HOME
780 VTAB 2: HTAB 1: INPUT "ENTER MONTH (1-12) OR '0' TO RETURN: ";Q$
783 GOSUB 10
785 GOSUB 20: IF EF = 1 THEN 780
787 M = VAL(Q$)
790 IF M = 0 THEN RETURN
800 IF M <1 OR M >12 THEN GOSUB 30: GOTO 780
810 HOME : PRINT M$(M)
820 FOR I = 1 TO 17: VTAB I +2: PRINT A$(I): NEXT I
830 VTAB 21: PRINT "TOTL"
840 VTAB 1:HT = 36:L = 5
850 HTAB HT: PRINT "TOTL"
860 FOR I = 1 TO 17:F$ = STR$(A%(0,I,M))
870 VTAB I +2: HTAB HT: PRINT " ": VTAB I +2: GOSUB 1370
880 NEXT I
890 F$ = STR$(A%(0,0,M))
891 VTAB 21: HTAB HT: PRINT " ": VTAB 21: GOSUB 1370
900 D = 1:L = 4
910 HT = 1: FOR J = D TO D +5
920 HT = HT +5
930 VTAB 1: HTAB HT +1: PRINT " ": VTAB 1: HTAB HT +1: PRINT J
940 FOR I = 1 TO 17:F$ = STR$(A%(J,I,M))
950 VTAB I +2: HTAB HT: PRINT " ": VTAB I +2: GOSUB 1370
960 NEXT I
970 F$ = STR$(A%(J,0,M))
971 VTAB 21: HTAB HT: PRINT " ": VTAB 21: GOSUB 1370
980 NEXT J
990 VTAB 23: HTAB 1: INPUT "ENTER DAY (1-31) OR '0' TO RETURN: ";Q$
993 GOSUB 10
995 GOSUB 20: IF EF = 1 THEN 990
997 D = VAL(Q$)
1000 IF D = 0 THEN RETURN
1010 IF D <1 OR D >31 THEN GOSUB 30: GOTO 990
1020 IF D >26 THEN D = 26
1030 GOTO 910
1040 HOME
1050 PRINT "COMPUTING YEARLY TOTALS..."
1060 FOR M = 1 TO 12
1070 FOR C = 1 TO 17
1080 Y%(M,C) = A%(0,C,M)
1090 Y%(0,C) = Y%(0,C) +Y%(M,C)
1100 IF C = 1 THEN 1130
1110 Y%(M,0) = Y%(M,0) +Y%(M,C)
1120 Y%(0,0) = Y%(0,0) +Y%(M,C)
1130 NEXT C
1140 NEXT M
1145 HOME
1150 FOR C = 1 TO 17: VTAB C +2: PRINT A$(C): NEXT C
1160 VTAB 21: PRINT "TOTL"
1170 HT = 35:L = 6: VTAB 1: HTAB HT +1: PRINT "TOTL"
1180 FOR C = 1 TO 17
1190 F$ = STR$(Y%(0,C)): VTAB C +2: HTAB HT: PRINT " "
1200 VTAB C +2: GOSUB 1370: NEXT C
1210 F$ = STR$(Y%(0,0)): VTAB 21: GOSUB 1370
1220 M = 1
1230 HT = 0:L = 5
1240 FOR I = M TO M +3:HT = HT +7
1250 VTAB 1: HTAB HT +1: PRINT M$(I)
1260 FOR C = 1 TO 17
1270 F$ = STR$(Y%(I,C)): VTAB C +2: HTAB HT: PRINT " "
1280 VTAB C +2: GOSUB 1370: NEXT C
1290 F$ = STR$(Y%(I,0)): VTAB 21: HTAB HT: PRINT " "
1300 VTAB 21: GOSUB 1370
1310 NEXT I
1320 VTAB 23: HTAB 1: INPUT "ENTER MONTH (1-12) OR '0' TO RETURN: ";Q$
1323 GOSUB 10
1325 GOSUB 20: IF EF = 1 THEN 1320
1327 M = VAL(Q$)
1330 IF M = 0 THEN RETURN
1340 IF M <1 OR M >12 THEN GOSUB 30: GOTO 1320
1350 IF M >9 THEN M = 9
1360 GOTO 1230
1370 IF F$ = "0" THEN 1390
1380 HTAB HT +L - LEN(F$): PRINT F$: RETURN
1390 HTAB HT +L -1: PRINT ".": RETURN
1400 DIM A%(31,17,12),A$(17),M$(12),Y%(12,17)
1405 FOR I = 1 TO 17: READ A$(I): NEXT I
1410 DATA "INCM","MORT","FOOD","CAR"
1420 DATA "MED","CLTH","HOBY","ENTR"
1430 DATA "TRNS","HOME","BOOK","GAS"
1440 DATA "TELE","ELEC","UTIL","INSR","MISC"
1450 FOR I = 1 TO 12: READ M$(I): NEXT I
1460 DATA "JAN","FEB","MAR","APR"
1470 DATA "MAY","JUN","JUL","AUG"
1480 DATA "SEP","OCT","NOV","DEC"
1490 CH = 0: REM DATA CHANGED FLAG
1500 D$ = CHR$(4): REM CTRL-D
1510 PRINT D$;"NOMON C,I,O"
1520 G$ = CHR$(7): REM CTRL-G
1530 REM
1540 REM THE FOLLOWING ROUTINE IS FROM THE MAY, 1980
1550 REM ISSUE OF CALL APPLE.
1560 REM IT PROVIDES THE ADDRESS OF THE FIRST ELEMENT
1570 REM IN AN ARRAY THROUGH THE '&' FUNCTION.
1580 REM THIS IS USED IN THE ROUTINES TO LOAD AND SAVE
1590 REM THE ARRAY TO DISK
1600 REM
1610 FOR I = 1 TO 10: READ N: POKE 937 +I,N: NEXT I
1620 DATA 32,227,223,141,168,3,140,169,3,96
1630 POKE 1013,76: POKE 1014,170: POKE 1015,3
1650 RETURN

Text found in RIC_Programs_54.dsk/FATHOM-X.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 06 00 0E 00 A5 00 0B 01 70 01 A3 01 B6 01 09 09 ....%... p.#.6...
$000010 09 09 29 09 09 09 09 29 09 09 09 09 11 1B 1B 1B ..)....) ........
$000020 1B 1B 1F 3B 1F 3F 1B 1F 1B 1B 1B 13 09 09 09 09 ...;.?.. ........
$000030 29 09 2D 29 0D 29 09 09 09 09 11 3B 1B 1B 1B 1B ).-).).. ...;....
$000040 1F 3F 3F 3F 1F 1F 1B 1B 1B 13 29 2D 0D 29 2D 2D .???.... ..)-.)--
$000050 2D 2D 2D 2D 2D 09 09 29 11 1B 3B 1B 1B 3B 3F 3F -----..) ..;..;??
$000060 3F 3F 3F 3F 1B 1B 1F 13 2D 2D 2D 2D 2D 2D 2D 2D ????.... --------
$000070 2D 2D 2D 2D 2D 2D 35 1B 3F 3F 3F 3F 3F 3F 3F 3F ------5. ????????
$000080 3F 3F 3F 3F 3F 17 09 2D 2D 2D 2D 2D 2D 2D 2D 2D ?????..- --------
$000090 2D 2D 2D 09 11 1B 1B 1B 1B 1B 1B 1B 1B 1B 1B 1B ---..... ........
$0000A0 1B 1B 1B 13 00 09 09 09 09 09 2D 09 09 09 11 1B ........ ..-.....
$0000B0 1B 1B 1B 3B 1B 1B 1B 1B 13 09 09 09 09 09 0D 09 ...;.... ........
$0000C0 09 09 11 1B 1B 1B 3B 3F 3F 1B 1B 1B 13 09 09 09 ......;? ?.......
$0000D0 09 2D 2D 0D 09 09 11 1B 1B 1B 3F 3F 3F 1F 1B 1B .--..... ..???...
$0000E0 13 2D 2D 2D 2D 2D 2D 2D 2D 2D 35 3B 3F 3F 3F 3F .------- --5;????
$0000F0 3F 3F 3F 1B 37 09 09 29 2D 2D 2D 2D 2D 0D 11 1B ???.7..) -----...
$000100 1B 1B 1B 1B 1B 1B 1B 1B 13 00 09 09 09 29 0D 09 ........ .....)..
$000110 09 09 09 11 1B 1B 1B 1B 1B 3B 1B 1B 1B 13 09 09 ........ .;......
$000120 09 09 0D 09 09 09 09 11 1B 1B 1B 1B 3B 3F 3F 1B ........ ....;??.
$000130 1B 13 09 09 09 2D 2D 0D 09 09 09 11 1B 1B 1B 1B .....--. ........
$000140 3F 3F 3F 1F 1B 13 2D 2D 2D 2D 2D 2D 2D 2D 2D 35 ???...-- -------5
$000150 3F 1B 3F 3F 3F 3F 3F 3F 3F 17 09 29 2D 2D 2D 2D ?.?????? ?..)----
$000160 2D 0D 09 11 1B 1B 1B 1B 1B 1B 1B 1B 1B 13 00 29 -....... .......)
$000170 09 09 09 11 1B 1F 1B 1B 13 09 0D 09 09 11 1B 3B ........ .......;
$000180 1B 3B 13 0D 29 09 0D 31 3B 1B 1F 1F 17 09 0D 2D .;..)..1 ;......-
$000190 29 11 1B 3F 1B 3F 13 09 29 2D 0D 11 1B 1B 3F 1B )..?.?.. )-....?.
$0001A0 13 00 09 0D 1A 3B 13 09 0D 1A 3F 17 2D 2D 3E 3F .....;.. ..?.-->?
$0001B0 37 2D 2D 06 00 09 0D 1A 3F 17 2D 2D 3E 3F 37 09 7--..... ?.-->?7.
$0001C0 0D 1A 3F 17 2D 29 06 00 .. .. .. .. .. .. .. .. ..?.-)..
** END **

Text found in RIC_Programs_54.dsk/FID TUTORIAL.bas:

1 HOME : PRINT " F I D APPLE II FILE DEVELOPER": PRINT "---=--=--=-----=====-==-====-=========--": POKE 34,3: HOME :S = 1:Q$ = CHR$(34)
5 GOSUB 10: GOSUB 481: GOSUB 31: GOSUB 481: GOSUB 54: GOSUB 481: GOSUB 74: GOSUB 481: GOSUB 86: GOSUB 481: GOSUB 104: GOSUB 481: GOSUB 126: GOSUB 481: GOSUB 144: GOSUB 481: GOSUB 160: GOSUB 481: GOSUB 180: GOSUB 481: GOSUB 196: GOSUB 481: GOSUB 212: GOSUB 481: GOSUB 229: GOSUB 481: GOSUB 243: GOSUB 481: GOSUB 266: GOSUB 481: GOSUB 287: GOSUB 481: GOSUB 306: GOSUB 481: GOSUB 322: GOSUB 481: GOSUB 336: GOSUB 481
7 GOSUB 350: GOSUB 481: GOSUB 370: GOSUB 481: GOSUB 380: GOSUB 481: GOSUB 397: GOSUB 481: GOSUB 418:: GOSUB 481: GOSUB 430: GOSUB 481: GOSUB 448: GOSUB 481: GOSUB 462:A$ = "PRESS ANY KEY TO RETURN TO SOFTDISK": GOSUB 483: TEXT : PRINT : PRINT CHR$(4)"RUNKICK.IT.OFF"
10 PRINT "AMONG THE HALF-DOZEN UTILITY PROGRAMS":S = 1: PRINT : PRINT "INCLUDED ON YOUR SYSTEM MASTER": PRINT : PRINT "DISKETTE IS A FILE CALLED "Q$"FID"Q$".": PRINT : PRINT "IT IS PERHAPS THE MOST VERSATILE OF"
18 PRINT : PRINT "ALL THOSE UTILIIES, YET IS ONLY GIVEN": PRINT : PRINT "SIX PAGES OF DESCRIPTION IN THE DOS": PRINT : PRINT "MANUAL.": PRINT : PRINT " IF YOU ALREADY KNOW ALL ABOUT FID,"
26 PRINT : PRINT "THEN PRESS RETURN. OTHERWISE...": PRINT : RETURN
31 PRINT " THIS DISCUSSION IS FOR THOSE OF YOU":S = 0: PRINT : PRINT "WHO HAVE NOT YET DISCOVERED JUST HOW": PRINT : PRINT "VERSATILE FID IS.": PRINT : PRINT " FID CAN:"
39 PRINT : PRINT " 1) COPY FILES": PRINT " 2) REPORT UNUSED DISK SPACE": PRINT " 3) VERIFY, LOCK, UNLOCK, & DELETE": PRINT " 4) CATALOG DISKS": PRINT : PRINT : PRINT "LET'S LOOK AT EACH OF THESE CATEGORIES"
47 PRINT : PRINT "INDIVIDUALLY.": PRINT : PRINT : PRINT : RETURN
54 PRINT "CATALOG DISKS:": PRINT : PRINT " THIS FUNCTION DOES NOTHING YOU": PRINT : PRINT "CAN'T DO BY TYPING IN "Q$"CATALOG"Q$".": PRINT : PRINT "IT IS MAINLY USEFUL WHEN YOU ARE USING": PRINT
62 PRINT "SOME OF THE OTHER FUNCTIONS AND WISH": PRINT : PRINT "TO LOOK AT THE CATALOG TO SEE WHAT": PRINT : PRINT "PROGRESS YOU HAVE MADE, OR WHAT STILL": PRINT : PRINT "NEEDS TO BE DONE.": PRINT
70 PRINT : PRINT : RETURN
74 PRINT "VERIFY, LOCK, UNLOCK, & DELETE FILES:": PRINT : PRINT " THIS, AGAIN IS NOTHING YOU CAN'T DO": PRINT : PRINT "BY YOURSELF, BUT WITH FID'S HELP, YOU": PRINT : PRINT "CAN DO IT MUCH FASTER, AND WITH VERY": PRINT
82 PRINT "FEW KEYPRESSES.": PRINT : RETURN
86 PRINT " THESE BENEFITS COME FROM FID'S": PRINT : PRINT "ABILITY TO ACT ON GROUPS OF FILES, AS": PRINT : PRINT "WELL AS ONE FILE AT A TIME. IF YOU": PRINT : PRINT "WANTED TO DELETE THE FILE "Q$"RUBICON"Q$"": PRINT
94 PRINT "FROM THE CATALOG, YOU WOULD SELECT <6>": PRINT : PRINT "AND WHEN PROMPTED FOR THE FILE NAME": PRINT : PRINT "YOU COULD ENTER "Q$"RUBICON"Q$", AND THE": PRINT : PRINT "FILE WOULD BE DELETED.": PRINT
102 RETURN
104 PRINT " THAT PROCESS REALLY DOESN'T GAIN": PRINT : PRINT "YOU ANYTHING, THOUGH. THE ADVANTAGE": PRINT : PRINT "OF USING FID COMES FROM THE FACT THAT": PRINT : PRINT "YOU ARE ABLE TO USE "Q$"WILDCARD"Q$"": PRINT
112 PRINT "CHARACTERS WHEN YOU INPUT THE FILE'S": PRINT : PRINT "NAME.": PRINT : PRINT " THE WILDCARD CHARACTER IS THE "Q$"="Q$"": PRINT : PRINT "(EQUALS SIGN). YOU CAN REPLACE ANY": PRINT
120 PRINT "PART, OR PARTS, OR ALL OF A FILE NAME": PRINT : PRINT "WITH "Q$"="Q$". ": PRINT : RETURN
126 PRINT " THIS IS HOW THE WILDCARD CAN BE": PRINT : PRINT "USED:": PRINT : PRINT " USING THE "Q$"RUBICON"Q$" EXAMPLE, YOU": PRINT : PRINT " COULD SIMPLY ENTER "Q$"RUB="Q$", OR": PRINT
134 PRINT " "Q$"=CON"Q$", OR "Q$"=BIC="Q$", OR "Q$"R=B=N"Q$"": PRINT : PRINT " FOR THE FILE NAME, AND THE FILE": PRINT : PRINT " NAMED RUBICON WOULD SURELY BE": PRINT : PRINT " DELETED (UNLESS IT WAS LOCKED).": PRINT
142 RETURN
144 PRINT " BUT WAIT! IF THERE WAS A FILE": PRINT : PRINT " NAMED "Q$"RUBIC'S CUBE"Q$", OR "Q$"XCON"Q$",": PRINT : PRINT " OR "Q$"FLICK MY BIC"Q$", OR "Q$"RIBBON"Q$"": PRINT : PRINT " ON THE DISK, IT COULD BE DELETED": PRINT
152 PRINT " ALONG WITH RUBICON, DEPENDING ON": PRINT : PRINT " WHERE YOU PUT YOUR WILDCARD": PRINT : PRINT " CHARACTER.": PRINT : RETURN
160 PRINT " THE SOLUTION ? WHEN FID ASKS IF": PRINT : PRINT " YOU WANT PROMPTING, ANSWER "Q$"Y"Q$".": PRINT : PRINT " THEN IT WILL DISPLAY EACH FILE NAME": PRINT : PRINT " THAT MATCHES YOUR WILDCARD SETUP AND": PRINT
168 PRINT " GIVE YOU A CHANCE TO SELECT IT (BY": PRINT : PRINT " ENTERING "Q$"Y"Q$"), OR BYPASS IT (BY": PRINT : PRINT " ENTERING "Q$"N"Q$"), OR JUMP BACK TO": PRINT : PRINT " FID'S MENU (BY ENTERING "Q$"Q"Q$"). FID": PRINT
176 PRINT " WILL REJECT ANY OTHER RESPONSE.": PRINT : RETURN
180 PRINT " OF COURSE, THE WILD CARD IS MOST": PRINT : PRINT " USEFUL IF YOU WANT TO ACT ON A GROUP": PRINT : PRINT " OF FILES. YOU COULD LOCK ALL FILES": PRINT : PRINT " BEGINNING WITH "Q$"SOFTDISK"Q$" BY": PRINT
188 PRINT " CHOOSING <5> FROM FID'S MENU, AND": PRINT : PRINT " ENTERING "Q$"SOFTDISK="Q$" AS THE FILE": PRINT : PRINT " NAME.": PRINT : RETURN
196 PRINT " IF YOU USE "Q$"="Q$" AS THE ENTIRE": PRINT : PRINT " FILE NAME, FID WILL SELECT ALL THE": PRINT : PRINT " FILES ON THE DISK.": PRINT : PRINT : PRINT " THE WILDCARD CAN BE USED TO LOCK,"
204 PRINT : PRINT "UNLOCK, VERIFY, DELETE, AND COPY": PRINT : PRINT "FILES.": PRINT : PRINT : RETURN
212 PRINT " WHICH BRINGS US TO COPY:": PRINT : PRINT : PRINT "WITHOUT FID, OR SOME SIMILAR UTILITY, ": PRINT : PRINT "THE ONLY KINDS OF FILES YOU COULD": PRINT : PRINT "EASILY MOVE FROM ONE DISK TO ANOTHER"
220 PRINT : PRINT "WOULD BE PROGRAM FILES, VIA THE "Q$"LOAD"Q$: PRINT : PRINT "AND "Q$"SAVE"Q$" COMMANDS, AND BINARY": PRINT : PRINT "FILES, WITH "Q$"BLOAD"Q$" AND "Q$"BSAVE"Q$".": PRINT : RETURN
229 PRINT " BUT LOADING AND SAVING FILES IS A": PRINT : PRINT "CUMBERSOME PROCESS; BLOADING AND": PRINT : PRINT "BSAVING (USUALLY PRONOUNCED BEE-LOAD &": PRINT : PRINT "BEE-SAVE) IS PRONE TO ERROR; AND TEXT": PRINT
237 PRINT "FILE TRANSFER CANNOT BE DONE WITHOUT": PRINT : PRINT "HELP OF A PROGRAM LIKE FID.": PRINT : RETURN
243 PRINT : PRINT " USING FID, YOU CAN COPY VIRTUALLY": PRINT : PRINT "ANY FILES FROM ONE DISK TO ANOTHER.": PRINT : PRINT "IF YOU CAN VERIFY THE FILE, YOU CAN": PRINT : PRINT "COPY IT. ALTHOUGH IT IS EASIEST TO"
251 PRINT : PRINT "COPY USING TWO DISK DRIVES, FID WORKS": PRINT : PRINT "FINE WITH JUST ONE.": PRINT : PRINT " USE THE WILDCARD CHARACTER THE SAME": PRINT : PRINT "WAY WITH "Q$"<1> COPY FILES"Q$" AS YOU DO"
259 PRINT : PRINT "WITH ANY OF THE OTHER FILE-ORIENTED": PRINT : PRINT "OPTIONS.": PRINT : RETURN
266 PRINT : PRINT " FID'S COPY OPTION CAN BE USED WHEN": PRINT : PRINT "COPYA FAILS: THE USUAL REASON COPYA": PRINT : PRINT "WILL FAIL IS A BAD SPOT ON THE SOURCE": PRINT : PRINT "DISK. USING FID, YOU CAN VERIFY ALL"
274 PRINT : PRINT "THE FILES ON THE SOURCE DISK (SELECT": PRINT : PRINT "FUNCTION "Q$"<8> VERIFY"Q$", AND SELECT ALL": PRINT : PRINT "FILES ("Q$"="Q$").) THOSE THAT HAVE I/O": PRINT : PRINT "ERRORS WILL BE UN-COPIABLE. ALL THE"
282 PRINT : PRINT "REST CAN BE TRANSFERRED TO A FRESH": PRINT : RETURN
287 PRINT "PREVIOUSLY INITIALIZED DISK USING": PRINT : PRINT "FID'S COPY COMMAND. SOMETIMES THE BAD": PRINT : PRINT "SPOT WAS ON AN UNUSED PART OF THE DISK": PRINT : PRINT "OR IN THE DISK OPERATING SYSTEM (THE": PRINT
295 PRINT "OUTERMOST THREE DISK TRACKS). IF THAT": PRINT : PRINT "IS THE CASE, THE FID DESTINATION DISK": PRINT : PRINT "SHOULD BE AS GOOD AS THE ORIGINAL WAS": PRINT : PRINT "WHEN IT WAS INTACT.": PRINT
303 PRINT : RETURN
306 PRINT " SPACE ON DISK:": PRINT : PRINT "NORMALLY, ON A FRESHLY INITIALIZED": PRINT : PRINT "DISK, THERE ARE JUST UNDER 500 USABLE": PRINT : PRINT "SECTORS FOR YOUR FILES TO FILL UP.": PRINT
314 PRINT "64 SECTORS ARE USED TO HOLD THE DISK": PRINT : PRINT "OPERATING SYSTEM, CATALOG, AND THE": PRINT : PRINT "VOLUME-TABLE-OF-CONTENTS ("Q$"VTOC"Q$").": PRINT : RETURN
322 PRINT "INSIDE THE VTOC IS A CHART (UPDATED": PRINT : PRINT "EVERY TIME YOU CHANGE ANY FILE) THAT": PRINT : PRINT "KEEPS TRACK OF WHICH PARTS OF THE": PRINT : PRINT "DISK HAVE BEEN USED FOR STORAGE AND": PRINT
330 PRINT "WHICH ARE EMPTY. FID READS THE VTOC": PRINT : PRINT "AND DISPLAYS THE RESULT OF ITS COUNT.": PRINT : RETURN
336 PRINT " THAT'S FID. IF YOU'VE NEVER USED IT": PRINT : PRINT "AT ALL, PERHAPS YOU SHOULD EXPERIMENT": PRINT : PRINT "WITH IT FOR A WHILE. GET A COUPLE OF": PRINT : PRINT "DISKS WITH UNIMPORTANT FILES ON THEM": PRINT
344 PRINT "AND PRACTICE ALL THE COMMANDS. THE": PRINT : PRINT "EXPERIENCE CHOULD BE REWARDING.": PRINT : RETURN
350 PRINT "": PRINT " GREETINGS, EXPERT FID USER.": PRINT : PRINT "HOW OFTEN HAVE YOU WISHED....": PRINT : PRINT " -- THAT YOU COULD INITIALIZE A FRESH": PRINT " DISK WITHOUT LEAVING FID AND THEN": PRINT " HAVING TO BRUN IT AGAIN?"
358 PRINT : PRINT " -- THAT YOU COULD RENAME FILES WHILE": PRINT " USING FID?": PRINT : PRINT " -- THAT WHEN YOU USED THE WILDCARD": PRINT " CHARACTER, YOU COULD RESPOND WITH": PRINT " SINGLE KEY-PRESSES INSTEAD OF": PRINT " "Q$"Y-RETURN"Q$", "Q$"N-RETURN"Q$", OR"
366 PRINT " "Q$"Q-RETURN"Q$"?": PRINT : RETURN
370 PRINT " AT LAST YOUR WISHES HAVE BEEN": PRINT : PRINT "GRANTED!": PRINT : PRINT " WISH #1 & #2 (INITIALIZE & RENAME)": PRINT : PRINT "BOTH WORK THE SAME WAY:": PRINT
378 RETURN
380 PRINT " EXIT FID BY SELECTING "Q$"<9> QUIT"Q$" ": PRINT : PRINT "FROM THE MENU, OR BY RESETTING. THEN": PRINT : PRINT "USE ANY OF THE DOS HOUSEKEEPING": PRINT : PRINT "COMMANDS (INIT, RENAME, VERIFY, LOCK,": PRINT
388 PRINT "UNLOCK, & DELETE) IN THEIR NORMAL": PRINT : PRINT "MANNER. WHEN YOU HAVE FINISHED, TYPE": PRINT : PRINT ""Q$"CALL 2051"Q$". FID WILL START RUNNING": PRINT : PRINT "AGAIN.": RETURN
397 PRINT : PRINT " THAT'S BECAUSE FID IS BLOADED INTO": PRINT : PRINT "MEMORY AT ADDRESS 2051, AND NONE OF": PRINT : PRINT "THE HOUSEKEEPING COMMANDS HAVE ANY": PRINT : PRINT "EFFECT ON THAT AREA."
405 PRINT : PRINT " HOWEVER, IF YOU SHOULD ACCIDENTALLY": PRINT : PRINT "(OR DELIBERATELY) ENTER A NUMBER, OR A": PRINT : PRINT "PROGRAM LINE, FID WOULD BE BLOWN AWAY,": PRINT : PRINT "AND YOU COULD NOT INVOKE IT BY A"
413 PRINT : PRINT ""Q$"CALL 2051"Q$".": PRINT : RETURN
418 PRINT : PRINT : PRINT " WISH #3 (SINGLE KEYPRESS FILE": PRINT : PRINT "SELECTION) IS A BIT MORE COMPLICATED,": PRINT : PRINT "BUT MUCH MORE SATISFYING IN THE LONG": PRINT
426 PRINT "RUN THAN WISH #1 OR #2.": PRINT : RETURN
430 PRINT : PRINT " HERE'S WHAT TO DO:": PRINT : PRINT " 1: BRUN FID (FOUND ON YOUR SYSTEM": PRINT " MASTER DISKETTE)": PRINT : PRINT " 2: COPY THESE FILES TO A DISKETTE": PRINT " WITH AT LEAST 50 FREE SECTORS:"
438 PRINT " FID (FROM SYSTEM MASTER)": PRINT " FID.TO.FIDGET.PATCH (FROM THIS": PRINT TAB( 31)"DISK)": PRINT " 3: RESET THE COMPUTER": PRINT : PRINT " 4: TYPE "Q$"EXEC FID.TO.FIDGET.PATCH"Q$: PRINT : PRINT " THAT'S ALL.": PRINT
446 RETURN
448 PRINT : PRINT " THEN THE DISK DRIVE WILL WHIR FOR A": PRINT : PRINT "MINUTE, SOME PROMPTS ("Q$"]"Q$") WILL BE": PRINT : PRINT "PRINTED, AND THE DISK DRIVE WILL STOP": PRINT : PRINT "SPINNING. IF YOU LOOK IN THE DISKETTE"
456 PRINT : PRINT "CATALOG YOU SHOULD FIND A NEW FILE:": PRINT : PRINT ""Q$"FIDGET"Q$".": RETURN
462 PRINT : PRINT " FIDGET WORKS THE SAME AS FID, WITH": PRINT : PRINT "THIS EXCEPTION: WHEN YOU USE THE": PRINT : PRINT "WILDCARD CHARACTER, AND ANSWER "Q$"YES"Q$"": PRINT : PRINT "YOU WANT PROMPTING, YOU ONLY NEED TO"
470 PRINT : PRINT "PRESS ONE KEY TO VERIFY THAT YOU WANT": PRINT : PRINT "TO PERFORM A TRANSACTION: THE RETURN": PRINT : PRINT "KEY IS SUPERFLUOUS.": PRINT : PRINT " TRY IT, YOU'LL LIKE IT."
478 PRINT : PRINT : PRINT TAB( 22)"JIM WEILER": RETURN
481 RESTORE : READ K: FOR A = 1 TO RND(1) *K +1: READ A$: NEXT : IF S THEN A$ = "SPACE KEY"
482 A$ = "PRESS THE " +A$
483 VTAB 24: HTAB 21 - LEN(A$)/2: PRINT A$;: GET K$: IF S = 1 AND K$ = CHR$(13) THEN POP :S = NOT S: HOME : GOTO 7
486 HOME : RETURN
487 DATA 9: DATA PIANO KEY,FLORIDA KEYS,FRANCIS SCOTT KEY,AS-CII,KEYSTONE COPS,FRONT DOOR KEY,CHURCH KEY,CAR KEYS,KEYHOLE

Text found in RIC_Programs_54.dsk/FID.TO.FIDGET.PATCH.txt:

BLOAD FID
CALL-151
800:20 53 1A
C1E:00 03
C2F:A9 87 20 ED FD EA EA D0 E5
1563:8D C5
1566:D2 CF D2 AE
15FF:8D CF CB A0
1619:8D C4
1624:8D C4 C9 D3 CB A0 D7 D2 C9 D4 C5
162F:A0 C4 C9 D3 C1 C2 CC
163A:8D CC CF C3 CB C5 C4 AE AE AE AE
1647:8D C9 AF CF A0 C5
170D:C6 C9 C4 C7 C5 D4 A0 D6 C5 D2 D3
1718:C9 CF CE A0 CD A0 A0
17E4:8D CE CF D4 A0 C4 CF CE C5
1A51:C5 D8 A2 00 BD 61 1A 9D 00 03 E8
1A5C:E0 14 D0 F5 60 20 0C FD 8D 00 02
1A67:EA EA EA A9 8D 8D 01 02 A9 00 8D
1A72:02 02 60 C5
BSAVE FIDGET,A$800,L$1275
3D3G
1HOME
2?"FIDGET HAS BEEN CREATED":?:?
3?"PRESS TO TRY TO RETURN TO"
4?"SOFTDISK"
5GETK$:IFASC(K$)<>13THEN 5
6?:?CHR$(4)"RUNKICK.IT.OFF"
RUN

Text found in RIC_Programs_54.dsk/FULL FATHOM FIVE.bas:

10 I = J = SS = T = S = M = SK = TM
20 PRINT CHR$(4);"OPEN FATHOM SCORE,L10"
30 PRINT CHR$(4);"READ FATHOM SCORE,R1"
40 INPUT HS
50 PRINT CHR$(4);"CLOSE FATHOM SCORE"
500 DIM XDC(5),YDC(5)
510 DIM XT(5),YT(5),XS(5),YS(5)
800 D = 0:S = 0:T = 0:OO = 0
810 YS(1) = 80:YS(2) = 60:YS(3) = 140:YS(4) = 100:YS(5) = 120
820 FOR I = 1 TO 10
830 R1 = INT(5 * RND(1)) +1:R2 = INT(5 * RND(1)) +1
840 TEMP = YS(R1):YS(R1) = YS(R2):YS(R2) = TEMP
850 NEXT I
900 GOSUB 5000
1000 REM MOVE SHIP
1020 P = PDL(0): IF P <120 THEN 1100
1040 IF P >134 THEN 1200
1060 GOTO 1500
1100 REM MOVE SHIP LEFT
1110 IF SS <12 THEN 1140
1115 NS = INT((120 -P)/10)
1120 HCOLOR= 0: DRAW 1 AT SS,20:SS = SS -NS: HCOLOR= 3: DRAW 1 AT SS,20
1140 GOTO 1500
1200 REM MOVE SHIP RIGHT
1210 IF SS >240 THEN 1500
1215 NS = INT((P -134)/10)
1220 HCOLOR= 0: DRAW 1 AT SS,20:SS = SS +NS: HCOLOR= 3: DRAW 1 AT SS,20
1500 REM SHIP FIRE?
1510 IF D >5 THEN 2000
1520 P = PEEK( -16287): IF P < = 127 THEN 2000
1530 POKE -16368,0
1540 HCOLOR= 3: DRAW 5 AT SS +15,30
1560 D = D +1
1570 FOR I = 1 TO 5
1572 IF XDC(I) = 0 THEN M = I:I = 5
1575 NEXT I
1580 XDC(M) = SS +15:YDC(M) = 30
2000 REM MOVE SUBS
2010 IF S = 0 THEN 2500
2020 FOR I = 1 TO 5
2025 IF XS(I) = 0 THEN 2200
2030 HCOLOR= 0:SH = 2.5 -.5 *DS(I): DRAW SH AT XS(I),YS(I)
2031 IF RND(1) <.06 OR RND(1) >.94 THEN DS(I) = -1 *DS(I)
2040 XS(I) = XS(I) +DS(I) *5
2060 IF XS(I) <10 THEN DS(I) = -1 *DS(I):XS(I) = 10
2080 IF XS(I) >255 THEN DS(I) = -1 *DS(I):XS(I) = 255
2100 HCOLOR= 6:SH = 2.5 -.5 *DS(I): DRAW SH AT XS(I),YS(I)
2200 NEXT I
2500 REM MOVE WEAPONRY
2520 IF D = 0 THEN 2820
2540 FOR I = 1 TO 5
2545 IF XDC(I) = 0 THEN 2800
2550 HCOLOR= 0: DRAW 5 AT XDC(I),YDC(I)
2560 YDC(I) = YDC(I) +10
2580 HCOLOR= 3: DRAW 5 AT XDC(I),YDC(I)
2600 IF YDC(I) <141 THEN 2800
2620 HCOLOR= 0: DRAW 5 AT XDC(I),YDC(I):XDC(I) = 0:D = D -1
2800 NEXT I
2820 IF T = 0 THEN 3000
2840 FOR I = 1 TO 5
2850 IF XT(I) = 0 THEN 2990
2860 HCOLOR= 0: DRAW 6 AT XT(I),YT(I):YT(I) = YT(I) -10: HCOLOR= 3: DRAW 6 AT XT(I),YT(I)
2990 NEXT I
3000 REM SHIP HIT?
3020 FOR I = 1 TO 5
3030 IF XT(I) = 0 THEN 3190
3040 IF YT(I) >30 THEN 3190
3050 IF ABS(SS -XT(I) +13) >14 THEN 3100
3055 HT = XT(I)
3060 HCOLOR= 5: DRAW 4 AT HT,21::Q = 200:E = 100: GOSUB 10000: DRAW 4 AT HT,16: GOSUB 10000: DRAW 4 AT HT -5,12: GOSUB 10000: DRAW 4 AT HT +2,9
3080 OO = 1:I = 5: GOTO 3190
3100 HCOLOR= 0: DRAW 6 AT XT(I),YT(I):T = T -1
3120 HCOLOR= 6: DRAW 4 AT XT(I),19: FOR BB = 1 TO 100: NEXT BB
3140 HCOLOR= 0: DRAW 4 AT XT(I),19:XT(I) = 0
3190 NEXT I
3195 IF OO = 1 THEN HTAB 11: FLASH : PRINT "SHIP DESTROYED!": NORMAL : GOTO 6000
3200 REM SUB HIT?
3205 IF D = 0 OR S = 0 THEN 3500
3210 FOR I = 1 TO 5
3220 IF XS(I) = 0 THEN 3490
3230 FOR J = 1 TO 5
3240 IF XDC(J) = 0 THEN 3480
3260 IF YS(I) < >YDC(J) THEN 3480
3280 IF ABS(XDC(J) -XS(I) -9) >10 THEN 3480
3300 HCOLOR= 5:SH = 2.5 -.5 *DS(I): DRAW SH AT XS(I),YS(I)
3310 SC = SC +1: VTAB 23: HTAB 25: PRINT "SUB HITS: ": HTAB 35: VTAB 23: INVERSE : PRINT SC: NORMAL
3320 Q = 250:E = 50: GOSUB 10000
3340 HCOLOR= 0: DRAW 5 AT XDC(J),YDC(J):XDC(J) = 0:D = D -1
3360 DRAW SH AT XS(I),YS(I):XS(I) = 0:S = S -1
3480 NEXT J
3490 NEXT I
3500 REM SUB FIRE?
3520 IF S = 0 THEN 4000
3540 FOR I = 1 TO 5
3560 IF XS(I) = 0 THEN 3900
3580 IF XT(I) >0 THEN 3900
3600 IF ABS(SS -XS(I)) >15 +YS(I)/5 THEN 3900
3610 IF RND(1) >.8 THEN 3900
3620 XT(I) = XS(I) +10:YT(I) = YS(I) -10
3640 HCOLOR= 3: DRAW 6 AT XT(I),YT(I)
3660 T = T +1
3900 NEXT I
4000 REM SUB APPEAR?
4020 IF S >4 THEN 4500
4040 R = RND(1): IF R >.3 AND R ": REM CTRL D
5010 IF PEEK(770) = 77 THEN 5025
5015 POKE 770,77
5020 PRINT D$;"BLOAD FATHOM-X,A16384"
5025 GOSUB 32000
5030 POKE 232,0: POKE 233,64
5032 TEXT
5033 GOSUB 13000: VTAB 21: INPUT "SELECT A SKILL LEVEL (1=EASY...8=LETHAL) ";SK
5034 VTAB 23: INPUT "LENGTH OF GAME (100-500 'SECONDS') ";TA$
5035 LE = SK
5036 IF SK <1 OR SK >8 THEN 5033
5038 SK = .31 +.01 *(1.7 ^(SK -1))
5040 HOME : HGR
5050 ROT= 0: SCALE= 1
5060 HCOLOR= 6: HPLOT 0,29 TO 279,29
5070 HCOLOR= 3
5080 DRAW 1 AT 130,20
5090 SS = 130
5095 SC = 0:TM = 0
5100 VTAB 21: HTAB 3: PRINT "HIT PDL (0) TO FIRE DEPTH CHARGE"
5105 VTAB 23: HTAB 14: PRINT "LEVEL ";LE
5110 VTAB 23: HTAB 25: PRINT "SUB HITS: ": HTAB 35: VTAB 23: INVERSE : PRINT SC: NORMAL
5120 RETURN
6000 HTAB 15: PRINT "GAME OVER!": GET ROBERT$: PRINT ROBERT$: PRINT : PRINT "WANT TO PLAY AGAIN? Y/N ": GET ROBERT$: PRINT ROBERT$
6010 IF HS >SC THEN 6030
6020 IF HS & SPEED": PRINT " CONTROL OF YOUR SUB DESTROYER"
13020 PRINT : PRINT "HIT PDL (0) BUTTON TO LAUNCH A ": PRINT " DEPTH CHARGE "
13030 PRINT : PRINT "WATCH OUT FOR THOSE TRICKY SUBS": PRINT " AND THEIR TORPEDOES!"
13040 PRINT : PRINT "PREVIOUS HIGH SCORE HAS BEEN ";HS
32000 POKE 776,255: POKE 777,255: POKE 778,173: POKE 779,48: POKE 780,192: POKE 781,136: POKE 782,208: POKE 783,5: POKE 784,206: POKE 785,9: POKE 786,3: POKE 787,240
32010 POKE 788,9: POKE 789,202: POKE 790,208: POKE 791,245: POKE 792,174: POKE 793,8: POKE 794,3: POKE 795,76: POKE 796,10: POKE 797,3: POKE 798,96: RETURN
267 p HIMEM: LOAD ));?)-));???)-)-------);;??????--------------5?????????????------------
2313 -;;??--???---------5;???????7)-----
10505 ;;??--???---------5????????)-----
2313 ;;)1;-)??)-?
15130 ?-->?7--
16154 -->?7?-)