Notes

Disk info for RIC_Programs_20.dsk:

File Name: riag_011_RIC_Programs_20/RIC_Programs_20.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 3840
Used Space (bytes): 139520
Physical Size (KB): 140
Free Space (KB): 3
Used Space (KB): 136
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 15
Used Sectors: 545
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for RIC_Programs_20.dsk:

riag_011_RIC_Programs_20/RIC_Programs_20.dsk DISK VOLUME #254
A 011 LOGO
* B 003 CURSORS
* B 007 ]SMALL STANDARD
* B 018 ]WESTERN
A 011 HELLO
B 042 INTBASIC
* B 006 LOADER.OBJ0
I 020 GAME OF LIFE
* I 003 APPLESOFT
* B 042 FPBASIC
I 021 STAY AFLOAT
I 005 ANDROMEDA STRAIN
I 050 CASINOII
A 052 SABOTAGE
* I 022 BENEATH APPLE MANOR
* I 047 BAM1
* B 005 BAMSUB
I 041 SEX ROLE
A 008 BURNOUT
B 050 INTBASICA
A 003 HELLO1
A 008 HELLO2
A 006 HELLOB
DOS 3.3 format; 3,840 bytes free; 139,520 bytes used.

Text found in RIC_Programs_20.dsk/ANDROMEDA STRAIN.int:

0 REM BY DANIEL A. WAXER 10-77
1 POKE -16298,0:CALL -936:RT= RND (2)
2 CALL -936:GR
3 RN= RND (20)+1
4 FOR QW=30 TO 1 STEP -2
5 COLOR= RND (16)
6 W=QW
7 IF QW>20 THEN W=20
10 FOR X=W TO 20
15 IF RT THEN 30
20 FOR SER=0 TO 9
24 SE= PEEK (-16336):NEXT SER
30 FOR A=W TO 2*X-1
45 PLOT X,39-A:PLOT X,A
46 PLOT 39-X,39-A:PLOT 39-X,A
47 PLOT A,X:PLOT 39-A,X:PLOT A,39-X:PLOT 39-A,39-X
48 IF NOT RND (RN) THEN COLOR= RND (16)
50 NEXT A
65 COLOR= RND (16)
67 FOR SER=0 TO 9
68 SE= PEEK (-16336):NEXT SER
70 NEXT X
105 COLOR= RND (16)
110 FOR X=20 TO W+1 STEP -1
120 IF RT THEN 140
132 FOR SER=0 TO 9
134 SE= PEEK (-16336)+ PEEK (-16336)
136 NEXT SER
140 FOR A=2*X-1 TO W+1 STEP -1
145 PLOT X,39-A:PLOT X,A
146 PLOT 39-X,39-A:PLOT 39-X,A
147 PLOT A,X:PLOT 39-A,X:PLOT A,39-X:PLOT 39-A,39-X
148 IF NOT RND (RN) THEN COLOR= RND (16)
150 NEXT A
165 COLOR= RND (16)
167 FOR SER=0 TO 9
168 SE= PEEK (-16336)+ PEEK (-16336)
169 NEXT SER
170 NEXT X
175 NEXT QW
180 INPUT "DO YOU WANT TO SEE AGAIN (Y/N) ",AP$
190 IF AP$="Y" THEN 2
10000 PR # 6
65535 REM COPYRIGHT DANIEL A. WAXER 1978

Text found in RIC_Programs_20.dsk/APPLESOFT.int:

10 TEXT :CALL -936:DIM A$(40)
20 D$="":REM CTRL-D
30 VTAB 2:A$="APPLE II":GOSUB 1000
40 VTAB 4:A$="DOS VERSION 3.3 SYSTEM MASTER":GOSUB 1000
50 VTAB 7:A$="JANUARY 1, 1983":GOSUB 1000
60 PRINT D$;"BLOAD LOADER.OBJ0"
70 CALL 4096
80 VTAB 10:CALL -958:A$="COPYRIGHT APPLE COMPUTER,INC. 1980,1982":GOSUB 1000
90 C= PEEK (-1101):IF C<>6 THEN GOTO 100:PRINT
95 POKE 50,127:A$="BE SURE CAPS LOCK IS DOWN":GOSUB 1000: POKE 50,255
100 PRINT D$;"INT"
1000 REM CENTER STRING A$
1010 B=20-( LEN(A$)/2):IF B=0 THEN B=1
1020 TAB B:PRINT A$:RETURN

Text found in RIC_Programs_20.dsk/BAM1.int:

0 TEXT
2 POKE -16298,0:CALL -936
5 IF ENTERED=1 THEN 20:ENTERED=1
10 DIM COM$(30),RTN(30)
16 DIM AC(3),WC(2)
20 COM$="ABEHIKLNORSTWXZ123456789D0"
40 RTN(1)=23000:RTN(2)=22000:RTN(3)=21000:RTN(4)=29000:RTN(5)=25000:RTN(6)=22000:RTN(7)=24000:RTN(8)=21000
Listing error: possible embedded machine code.

Text found in RIC_Programs_20.dsk/BURNOUT.bas:

5 REM BURNOUT BY FLANAGAN
6 REM PROGRAM WRITTEN 2/27/80
7 REM FOR THE FACULTY OF THE BEHAVIORAL AND
8 REM SOCIAL SCIENCE DEPARTMENT
10 G$ = "": REM BELL
20 HOME : FOR I = 1 TO 13:Y = INT( RND(1) *30) +1:X = INT( RND(1) *22) +1
30 HTAB Y: VTAB X: FLASH
40 PRINT "B";G$;"U";G$;"R";G$;"N";G$;"O";G$;"U";G$;"T";G$
50 NORMAL : HOME : NEXT
60 HOME : PRINT TAB( 6);"A SELF DIAGNOSIS INSTRUMENT"
70 VTAB 10: PRINT "PEOPLE CAN COMPUTE THEIR BURNOUT SCORE": PRINT "BY COMPLETING THE FOLLOWING": PRINT "QUESTIONNAIRE."
80 VTAB 24: HTAB 30: INPUT ">RETURN>> ";X$
100 HOME : PRINT "PLEASE USE THIS SCALE"
105 PRINT
110 PRINT TAB( 10)" 1. NEVER"
120 PRINT TAB( 10)" 2. ONCE IN A GREAT WHILE"
130 PRINT TAB( 10)" 3. RARELY"
140 PRINT TAB( 10)" 4. SOMETIMES"
150 PRINT TAB( 10)" 5. OFTEN"
160 PRINT TAB( 10)" 6. USUALLY"
170 PRINT TAB( 10)" 7. ALWAYS"
180 PRINT : PRINT "HOW OFTEN DO YOU EXPERIENCE: ": PRINT
200 READ X,S$: IF X = 99 THEN 500
210 VTAB 14: CALL -958: PRINT G$: PRINT S$
215 PRINT : INPUT "ENTER A NUMBER THEN PRESS ";SC
216 IF SC >7 OR SC <1 THEN PRINT "BE SERIOUS": FOR D = 1 TO 1000: NEXT : GOTO 210
220 IF X = 3 OR X = 6 OR X = 19 OR X = 20 THEN 235
230 A = SC +A: GOTO 200
235 B = SC +B: GOTO 200
500 HOME : FOR I = 1 TO 10: PRINT G$: NEXT
505 T = ((32 -B) +A)/21
510 PRINT TAB( 9)"YOUR SCORE IS ";T
520 FOR D = 1 TO 500: NEXT
530 PRINT : IF T < = 3 THEN PRINT TAB( 15);"DOING WELL": GOTO 600
540 PRINT : IF T < = 4 THEN PRINT TAB( 11);"EXAMINE YOUR LIFE": GOTO 600
550 PRINT : IF T < = 5 THEN PRINT TAB( 14);"CHANGE JOBS": GOTO 600
560 PRINT TAB( 16);"SEEK HELP"
600 FOR M = 1 TO 2000: NEXT M: PR# 6
1000 DATA 1,BEING TIRED
1001 DATA 2,FEELING DEPRESSED
1002 DATA 3,HAVING A GOOD DAY
1003 DATA 4,BEING PHYSICALLY EXHAUSTED
1004 DATA 5,BEING EMOTIONALLY EXHAUSTED
1005 DATA 6, BEING HAPPY
1006 DATA 7, BEING 'WIPED OUT'
1007 DATA 8, FEELING 'BURNED OUT'
1008 DATA 9, BEING UNHAPPY
1009 DATA 10,FEELING RUNDOWN
1010 DATA 11, FEELING TRAPPED
1011 DATA 12, FEELING WORTHLESS
1012 DATA 13, BEING WEARY
1013 DATA 14, BEING TROUBLED
1014 DATA 15, FEELING DISILLUSIONED AND RESENTFUL
1015 DATA 16, FEELING WEAK
1016 DATA 17, FEELING HOPELESS
1017 DATA 18, FEELING REJECTED
1018 DATA 19, FEELING OPTIMISTIC
1019 DATA 20, FEELING ENERGETIC
1020 DATA 21, FEELING ANXIOUS
1021 DATA 99,END

Text found in RIC_Programs_20.dsk/CASINOII.int:

3 POKE -16298,0:CALL -936
5 POKE 50,63:TEXT :CALL -936
10 VTAB 1:TAB 2:PRINT " ";:TAB 9:PRINT " ";:TAB 17:PRINT " ";:TAB 25:PRINT " ";:TAB 33:PRINT " "
15 PRINT " ";:TAB 5:PRINT " ";:TAB 9:PRINT " ";:TAB 13:PRINT " ";:TAB 17:PRINT " ";:TAB 21:PRINT " ";:TAB 25:PRINT " ";:TAB 33:PRINT " "
20 PRINT " ";:TAB 9:PRINT " ";:TAB 17:PRINT " ";:TAB 25:PRINT " ";:TAB 33:PRINT " "
25 PRINT " ";:TAB 5:PRINT " ";:TAB 9:PRINT " ";:TAB 17:PRINT " ";:TAB 25:PRINT " ";:TAB 33:PRINT " "
30 PRINT " ";:TAB 5:PRINT " ";:TAB 7:PRINT " ";:TAB 9:PRINT " ";:TAB 15:PRINT " ";:TAB 17:PRINT " ";
35 TAB 23:PRINT " ";:TAB 25:PRINT " ";:TAB 31:PRINT " ";:TAB 33:PRINT " ";:TAB 39:PRINT " "
40 POKE 50,255:PRINT
45 PRINT "A P P L E":TAB 2:PRINT "P U R I X"
50 TAB 3:PRINT "P G O B C":TAB 4:PRINT "L E G R H"
55 TAB 5:PRINT "E T R A A":TAB 14:PRINT "S A R N"
60 TAB 15:PRINT "O M Y G":TAB 16:PRINT "U";:TAB 40:PRINT "E";
65 TAB 17:PRINT "N":TAB 18:PRINT "D"
70 POKE 50,63:PRINT :PRINT :TAB 10:PRINT " ":TAB 10:PRINT " P R E S E N T S ":TAB 10:PRINT " "
75 POKE 50,255
80 FOR I=1 TO 4000:NEXT I
100 TEXT :CALL -936
110 VTAB 2:TAB 10:PRINT "A.P.P.L.E. PRESENTS:"
120 VTAB 8:TAB 10:PRINT "CASINO GAMEPAK #1"
130 VTAB 10:PRINT "1 GRAVITY PINBALL":PRINT "2 BLACKJACK":PRINT "3 ONE ARM BANDIT"
135 PRINT "4 QUIT"
140 VTAB 20:CALL -868:INPUT "WHICH GAME # ",I
145 IF I=4 THEN PR # 6
150 IF I<1 OR I>3 THEN 140
160 GOTO I*1000
1000 GOTO 1550:REM FAST GRAVITY PINBALL
1010 X=X+OX:Y=Y+OY/30:IF X>39 THEN X=39:IF X<0 THEN X=0:IF Y>39 THEN Y=39:IF Y<0 THEN Y=0
1020 OY=OY+6:REM STRENGTH OF GRAVITY
1030 GOSUB 1410:REM UPDATE FLIPPERS
1040 CO= SCRN(X,Y)
1050 COLOR= BA:PLOT X,Y
1060 IF X=0 OR X=39 THEN 1220
1070 IF Y=0 THEN 1230
1080 IF CO=BG THEN 1170
1090 IF CO=BLR THEN GOSUB 1540
1100 IF CO=BTP THEN HIT=20:IF CO=BLR THEN HIT=15:IF CO=BCT THEN HIT=10:IF CO=BDB THEN HIT=25:IF CO=BSM THEN HIT=50:IF CO=BIS THEN HIT=25
1110 IF CO=BSI THEN HIT=5:IF CO=BSB THEN HIT=75
1120 IF DB=1 THEN HIT=HIT+HIT
1130 IF CO=BTP OR CO=BLR OR CO=BCT THEN 1240
1140 IF CO=BSM OR CO=BIS THEN 1240
1150 IF CO=BSI OR CO=BSB THEN 1240
1160 IF CO=BDB THEN 1520
1170 IF Y=39 THEN 1200
1180 COLOR= CO:PLOT X,Y:HIT=0:GOTO 1010
1190 COLOR= CO:PLOT X,Y
1200 IF CO#FL THEN 1340
1210 OY=- RND (5)-OY:OX= RND (5)-2:W= PEEK (-16336)- PEEK (-16336):HIT=3:GOTO 1250
1220 W= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336):OX=OX*-1:GOTO 1180
1230 W= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336):OY=30:GOTO 1180
1240 OX= RND (5)-2:OY= RND (180)-90:IF OX=0 AND OY<10 AND OY>-10 THEN 1240
1250 SC=SC+HIT:CALL -936:VTAB 22:TAB 14:PRINT "SCORE= ";SC;:TAB 27:PRINT "BALLS LEFT= ";LE;:GOSUB 1310
1260 VTAB 22:PRINT "POINTS=";HIT
1270 P=160-(2*HIT):IF P<14 THEN P=14
1280 FOR Z=1 TO 3: POKE 0,P: POKE 1,20+ RND (20)
1290 CALL 2
1300 NEXT Z:GOTO 1180
1310 IF DB=0 THEN 1320:IF DB=1 THEN 1330
1320 VTAB 23:TAB 10:PRINT "HIT ANY KEY FOR NEXT BALL":RETURN
1330 POKE 50,63:VTAB 23:TAB 10:PRINT "DOUBLE POINTS WHEN LIT": POKE 50,255:RETURN
1340 POKE 0,200: POKE 1,100:CALL 2
1350 COLOR= CO:PLOT X,Y
1360 IF LE#0 THEN 1780
1370 PRINT "END OF GAME ":INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y OR N) ",Q$:IF Q$="Y" THEN 1610
1380 FOR M=1 TO 2000:NEXT M:PR # 6
1390 POKE 2,173: POKE 3,48: POKE 4,192: POKE 5,136: POKE 6,208: POKE 7,4: POKE 8,198: POKE 9,1: POKE 10,240
1400 POKE 11,8: POKE 12,202: POKE 13,208: POKE 14,246: POKE 15,166: POKE 16,0: POKE 17,76: POKE 18,2: POKE 19,0: POKE 20,96:RETURN
1410 IF PEEK (-16287)>127 OR PEEK (-16384)=174 OR PEEK (-16384)=190 THEN 1460
1420 IF PEEK (-16286)>127 OR PEEK (-16384)=188 OR PEEK (-16384)=172 THEN 1480
1430 POKE -16368,0:RT=RT-1:IF RT=4 THEN 1500
1440 LT=LT-1:IF LT=4 THEN 1510
1450 RETURN
1460 IF RT>0 THEN 1430
1470 RT=9:COLOR= FL:HLIN 22,38 AT 39:GOTO 1420
1480 IF LT>0 THEN 1430
1490 LT=9:COLOR= FL:HLIN 1,17 AT 39:GOTO 1430
1500 COLOR= 0:HLIN 22,38 AT 39:GOTO 1440
1510 COLOR= 0:HLIN 1,17 AT 39:GOTO 1450
1520 GOSUB 1530:VTAB 23: POKE 50,63:TAB 10:PRINT "DOUBLE POINTS WHEN LIT": POKE 50,255:DB=1:GOTO 1240
1530 COLOR= DBL:HLIN 19,20 AT 31:HLIN 19,20 AT 32:HLIN 19,20 AT 33:RETURN
1540 COLOR= BDB:HLIN 19,20 AT 31:HLIN 19,20 AT 32:HLIN 19,20 AT 33:DB=0:RETURN
1550 TEXT :CALL -936: POKE -16298,0
1560 HIT=10:GOSUB 1390
1570 DIM A$(35),B$(35),Q$(5)
1580 VTAB 8:PRINT "TO SHOOT A BALL, HIH<]RE.' ON THE KEYBOARD."
1600 PRINT :PRINT :PRINT :PRINT "HIT ANY KEY TO START":CALL -715
1610 CALL -936:BG=13:BA=0:BO=6:BTP=1:BLR=9:BCT=2:BTM=4:BSM=11:BDB=12:DBL=15:BIS=14:BSI=3:BSB=8:FL=7
1620 GR :FOR N=0 TO 39:COLOR= BG:HLIN 0,39 AT N:NEXT N
1630 COLOR= BO:HLIN 0,39 AT 0:VLIN 0,39 AT 0:VLIN 0,39 AT 39
1640 COLOR= 0:HLIN 1,17 AT 39:HLIN 22,38 AT 39
1650 COLOR= BTP:HLIN 19,20 AT 3:PLOT 18,4:PLOT 21,4:PLOT 17,5:PLOT 22,5:PLOT 18,6
1660 PLOT 21,6:HLIN 19,20 AT 7:COLOR= BIS:HLIN 19,20 AT 5
1670 COLOR= BLR:PLOT 8,12:PLOT 7,13:PLOT 9,13:PLOT 6,14:PLOT 10,14:PLOT 7,15:PLOT 9,15:PLOT 8,16
1680 PLOT 31,12:PLOT 30,13:PLOT 32,13:PLOT 29,14:PLOT 33,14:PLOT 30,15:PLOT 32,15:PLOT 31,16
1690 COLOR= BCT
1700 HLIN 17,22 AT 21:HLIN 17,22 AT 27:VLIN 22,26 AT 16:VLIN 22,26 AT 23
1710 COLOR= BIS:HLIN 19,20 AT 23:HLIN 19,20 AT 25:PLOT 18,24:PLOT 21,24
1720 COLOR= BIS
1730 HLIN 19,20 AT 5:COLOR= BSM:PLOT 8,31:PLOT 31,31
1740 COLOR= BDB:HLIN 19,20 AT 31:HLIN 19,20 AT 32:HLIN 19,20 AT 33
1750 COLOR= BSI:VLIN 9,25 AT 1:VLIN 9,25 AT 4:VLIN 9,25 AT 35:VLIN 9,25 AT 38
1760 COLOR= BSB:PLOT 2,16:PLOT 37,16
1770 SC=0:LE=5:HIT=0
1780 X= RND (38)+1:Y=38:OX= RND (5)-2:OY=-100
1790 CALL -715:LE=LE-1
1800 CALL -936:VTAB 22:PRINT "POINTS=";HIT;:TAB 14: POKE 50,255:PRINT "SCORE=";SC;:TAB 27:PRINT "BALLS LEFT=";LE
1810 GOTO 1010
2000 CLR
2010 DIM Z(52):TEXT :CALL -936:VTAB 4:TAB 9:PRINT "APPLE CASINO BLACKJACK":PRINT :PRINT "USE THE FOLLOWING COMMANDS":PRINT
2020 PRINT "H=HIT":PRINT "S=STAY":PRINT "D=DOUBLE":PRINT "X=SPLIT(ONE ALLOWED)":PRINT "0=ZERO BET EXITS GAME"
2030 PRINT :PRINT "PLEASE INPUT YOUR TOTAL STAKE";
2040 INPUT S:IF S>100 THEN 2060:IF S<1 THEN 5
2050 CALL -936:FOR I=0 TO 60:PRINT "CHEAP !!! ";:NEXT I:PRINT :FOR I=0 TO 1000:NEXT I:GOTO 2060
2060 IF S<1 THEN 2930:GR :VTAB 23:PRINT "STAKE IS ";S;" ENTER YOUR BET ";
2070 FOR L=1 TO 25:X= PEEK (-16336):NEXT L:INPUT B
2080 IF B>S THEN 2940:IF B=0 THEN 5
2090 GOSUB 2910:COLOR= 4:FOR L=1 TO 38:HLIN 0,39 AT L:NEXT L
2100 COLOR= 8:HLIN 0,39 AT 0:HLIN 0,39 AT 39:FOR L=1 TO 52:Z(L)=0:NEXT L
2110 D=0:P1=0:P2=0:DA=0:PA1=0:PA2=0:PL=0
2120 REM DEALERS TWO CARDS
2130 X=2:Y=2:GOSUB 2680:D=D+T:DA=DA+W:F=W:GOSUB 2700:X=8:GOSUB 2680:DC=C:D=D+T:DA=DA+W:X=2:Y=11
2140 GOSUB 2680:IF X=2 THEN E=C:P1=P1+T:PA1=PA1+W:GOSUB 2700:X=X+6:IF X=8 THEN GOTO 2140
2150 IF F#1 THEN GOTO 2200:VTAB 22:PRINT "DO YOU WANT INSURANCE? Y=YES N=NO":INPUT A$
2160 GOSUB 2910
2170 IF A$#"Y" THEN GOTO 2200:IF D#21 THEN GOTO 2180:S=S+B:G=4:GOSUB 2890:GOTO 2210
2180 S=S-B/2:VTAB 22:PRINT "YOU LOST INSURANCE BET"
2190 FOR L=1 TO 1000:NEXT L:GOSUB 2910
2200 IF D#21 THEN GOTO 2220:S=S-B:G=1:GOSUB 2890
2210 X=8:Y=2:C=DC:GOSUB 2700:GOTO 2090
2220 IF P1#21 THEN GOTO 2300:S=S+B+B/2:G=4:FOR L=1 TO 100
2230 COLOR= 13:IF L MOD 2=0 THEN COLOR= 1:IF L=100 THEN COLOR= 4
2240 HLIN 14,18 AT 15:VLIN 16,20 AT 18:HLIN 15,17 AT 20:VLIN 21,23 AT 15:HLIN 16,18 AT 23
2250 X= PEEK (-16336)- PEEK (-16336)
2260 VLIN 15,24 AT 24:VLIN 15,24 AT 25:HLIN 14,17 AT 16:VLIN 17,19 AT 17:HLIN 14,16 AT 19:VLIN 20,24 AT 14:HLIN 14,18 AT 24
2270 NEXT L:GOSUB 2890:GOTO 2090
2280 REM DOUBLE
2290 VTAB 22:PRINT "YOU CAN NOT SPLIT":FOR L=1 TO 1000:NEXT L:GOSUB 2910
2300 INPUT "H,S,D OR X ?",A$:GOSUB 2910:IF A$#"D" THEN GOTO 2340:B=2*B:X=14:GOSUB 2680:P1=P1+T:PA1=PA1+W:GOSUB 2700
2310 IF P1<22 THEN GOTO 2580:IF PA1>0 THEN GOTO 2320:GOTO 2530
2320 PA1=PA1-1:P1=P1-10:GOTO 2310
2330 REM SPLIT
2340 IF A$="S" THEN GOTO 2580
2350 IF A$#"X" THEN GOTO 2500
2360 IF C#E THEN GOTO 2290:P1=P1/2:P2=P1:X=2:Y=19:GOSUB 2680:C=E:GOSUB 2700:X=8:Y=11
2370 GOSUB 2680:P1=P1+T:PA1=PA1+W:GOSUB 2700
2380 IF P1<22 THEN GOTO 2400:IF PA1>0 THEN GOTO 2390:G=2:GOSUB 2890:PL=1:S=S-B:P1=0:GOTO 2410
2390 PA1=PA1-1:P1=P1-10:GOTO 2380
2400 IF E=1 THEN GOTO 2410:INPUT "H OR S ?",A$:GOSUB 2910:X=X+6:IF A$="H" THEN GOTO 2370
2410 X=8:Y=19
2420 GOSUB 2680:P2=P2+T:PA2=PA2+W:GOSUB 2700
2430 IF P2<22 THEN GOTO 2480:IF PA2>0 THEN GOTO 2470:IF P1#0 THEN GOTO 2450:COLOR= 15:HLIN 14,17 AT 37:HLIN 14,17 AT 38:GOTO 2460
2440 GOTO 2580
2450 G=2:GOSUB 2890
2460 S=S-B:PL=PL+1:P2=0:IF PL=2 THEN GOTO 2210:GOTO 2580
2470 PA2=PA2-1:P2=P2-10:GOTO 2430
2480 IF E=1 THEN GOTO 2580:INPUT "H OR S ?",A$:GOSUB 2910:X=X+6:IF A$="H" THEN GOTO 2420:GOTO 2580
2490 REM STANDARD CALL
2500 GOSUB 2680:P1=P1+T:PA1=PA1+W:GOSUB 2700
2510 IF P1<22 THEN GOTO 2550:IF PA1>0 THEN GOTO 2540
2520 G=2:GOSUB 2890:S=S-B:GOTO 2210
2530 VTAB 21:S=S-B:G=2:GOSUB 2890:GOTO 2210
2540 PA1=PA1-1:P1=P1-10:GOTO 2510
2550 IF A$="D" THEN GOTO 2580:X=X+6:INPUT "H OR S ? ",A$:GOSUB 2910:IF A$="H" THEN GOTO 2500
2560 IF A$="D" THEN B=2*B:IF A$="D" THEN GOTO 2500
2570 REM DEALERS HAND
2580 C=DC:X=8:Y=2:GOSUB 2700:GOTO 2600
2590 IF D>16 THEN GOTO 2620:X=X+6:GOSUB 2680:D=D+T:DA=DA+W:GOSUB 2700
2600 IF D<22 THEN GOTO 2590:IF DA>0 THEN GOTO 2610:D=0:GOTO 2620
2610 D=D-10:DA=DA-1:GOTO 2600
2620 IF P1=0 THEN GOTO 2660:X1=2660:IF P1>D THEN GOTO 2640:IF P1=D THEN GOTO 2650
2630 S=S-B:G=1:GOSUB 2890:GOTO X1
2640 S=S+B:G=4:GOSUB 2890:GOTO X1
2650 G=3:GOSUB 2890:X1=26140:FOR L=1 TO 1500:NEXT L
2660 IF X1#2090 THEN X1=2060:IF P2=0 THEN GOTO X1:IF P2>D THEN GOTO 2640:IF P2#D THEN GOTO 2630:G=3:GOSUB 2890:FOR L=1 TO 1000:NEXT L:GOTO 2090
2670 REM CARD FACE DISPLAY
2680 COLOR= 6:FOR L=Y TO Y+6:HLIN X,X+4 AT L:NEXT L
2690 H= RND (52):C=H/4+1:IF Z(H+1)=1 THEN GOTO 2690:Z(H+1)=1:T=C:IF C>10 THEN T=10:IF C=1 THEN T=11:W=0:IF T=11 THEN W=1:RETURN
2700 COLOR= 0:GOTO 2700+C*10
2710 PLOT X+2,Y+3:GOTO 2850
2720 PLOT X+1,Y+1:VLIN Y+1,Y+3 AT X+2:VLIN Y+3,Y+5 AT X+1:PLOT X+2,Y+5:RETURN
2730 PLOT X+2,Y+3:HLIN X+1,X+2 AT Y+5:GOTO 2860
2740 VLIN Y+1,Y+3 AT X+1:PLOT X+2,Y+3:GOTO 2870
2750 HLIN X+1,X+3 AT Y+1:HLIN X+1,X+3 AT Y+3:HLIN X+1,X+3 AT Y+5:PLOT X+1,Y+2:PLOT X+3,Y+4:RETURN
2760 VLIN Y+1,Y+5 AT X+1:VLIN Y+3,Y+5 AT X+3:PLOT X+2,Y+3:PLOT X+2,Y+5:RETURN
2770 GOTO 2860
2780 PLOT X+2,Y+3:GOTO 2840
2790 VLIN Y+2,Y+3 AT X+1:PLOT X+2,Y+3:GOTO 2860
2800 VLIN Y+1,Y+5 AT X:VLIN Y+1,Y+5 AT X+2:VLIN Y+1,Y+5 AT X+4:PLOT X+3,Y+1:PLOT X+3,Y+5:RETURN
2810 HLIN X+1,X+3 AT Y+1:VLIN Y+2,Y+5 AT X+2:PLOT X+1,Y+5:RETURN
2820 HLIN X+3,X+4 AT Y+6:GOTO 2840
2830 VLIN Y+1,Y+5 AT X+1:PLOT X+2,Y+3:PLOT X+3,Y+2:PLOT X+3,Y+4:PLOT X+4,Y+1:PLOT X+4,Y+5:RETURN
2840 PLOT X+2,Y+5
2850 VLIN Y+1,Y+5 AT X+1
2860 HLIN X+1,X+3 AT Y+1
2870 VLIN Y+1,Y+5 AT X+3
2880 RETURN
2890 G=G*9-4:COLOR= 1:HLIN G,G+3 AT 37:HLIN G,G+3 AT 38:PRINT "HIT RETURN FOR NEXT BET":CALL -676:RETURN
2900 GOTO 2920:REM MENU
2910 CALL -936:VTAB 21:PRINT "LOSE BUST PUSH WIN":RETURN :PR # 6
2920 FOR M=1 TO 2000:NEXT M:PR # 6
2930 CALL -936:VTAB 21:TAB 10:PRINT "SORRY, NO CREDIT.":VTAB 22:TAB 10:PRINT "YOU'LL HAVE TO LEAVE!":FOR I=1 TO 2000:NEXT I:GOTO 100
2940 CALL -936:VTAB 21:PRINT "YOU ONLY HAVE $";S;".00 LEFT -- TRY AGAIN!":GOTO 2060
3000 CLR
3010 REM "ONE ARMED BANDIT" BY
3020 REM KARL GANDERS
3030 REM 02/20/78
3040 DIM W1SYM$(20),W2SYM$(20),W3SYM$(20),PAYOFF$(27)
3050 DIM PAYAMT(9),SYM$(1)
3060 W1SYM$="OBLCWOWCBOLWOBDCWOBL"
3070 W2SYM$="LCBCLWDCOWLCBLCBWOCB"
3080 W3SYM$="ODLBWLOLDOBLBWBDLWOD"
3090 PAYOFF$="CC-C--OODBBOLLLWWDOOOWWWDDD"
3100 PAYAMT(1)=5:PAYAMT(2)=3:PAYAMT(3)=6:PAYAMT(4)=8:PAYAMT(5)=10:PAYAMT(6)=15
3110 PAYAMT(7)=18:PAYAMT(8)=20:PAYAMT(9)=200
3120 REM PUT GOSUB TO DRAW MACHINE HERE
3130 GOSUB 3920
3140 CALL -936:GR
3150 X= PEEK (-16384)
3160 POKE -16368,0
3170 IF X<=127 THEN 3150
3180 IF X=155 THEN 5
3190 X=0:TTL=TTL-1
3200 X= RND (3)
3210 R= RND (20):FOR Q=R TO R+5+ RND (5):S1=Q MOD 20+1:H=1:V=10:SYM$=W1SYM$(S1,S1)
3220 COLOR= 0:FOR T=21 TO 10 STEP -1:HLIN 1,12 AT T:NEXT T:GOSUB 3500:NEXT Q:X= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
3230 X= RND (3)
3240 R= RND (20):FOR Q=R TO R+5+ RND (5):S2=Q MOD 20+1:H=14:V=10:SYM$=W2SYM$(S2,S2)
3250 COLOR= 0:FOR T=21 TO 10 STEP -1:HLIN 14,25 AT T:NEXT T:GOSUB 3500:NEXT Q:X= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
3260 X= RND (3)
3270 R= RND (20):FOR Q=R TO R+5+ RND (5):S3=Q MOD 20+1:H=27:V=10:SYM$=W3SYM$(S3,S3)
3280 COLOR= 0:FOR T=21 TO 10 STEP -1:HLIN 27,38 AT T:NEXT T:GOSUB 3500:NEXT Q:X= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
3290 FOR I=1 TO 27 STEP 3
3300 IF PAYOFF$(I,I)#W1SYM$(S1,S1) THEN 3450
3310 IF PAYOFF$(I+1,I+1)="-" THEN 3330
3320 IF PAYOFF$(I+1,I+1)#W2SYM$(S2,S2) THEN 3450
3330 IF PAYOFF$(I+2,I+2)="-" THEN 3350
3340 IF PAYOFF$(I+2,I+2)#W3SYM$(S3,S3) THEN 3450
3350 VTAB 21:TAB 1
3360 PRINT "YOU WIN $";PAYAMT((I+3-1)/3);" "
3370 TTL=TTL+PAYAMT((I+3-1)/3)
3380 PRINT "TOTAL =$";TTL;" "
3390 RINGS=PAYAMT((I+3-1)/3)
3400 FOR X=1 TO RINGS
3410 PRINT "";
3420 FOR Q=1 TO 50:NEXT Q
3430 NEXT X
3440 GOTO 3150
3450 NEXT I
3460 VTAB 21:TAB 1
3470 PRINT "YOU LOSE $1 "
3480 PRINT "TOTAL =$";TTL;" "
3490 GOTO 3150
3500 IF SYM$="C" THEN 3560
3510 IF SYM$="O" THEN 3630
3520 IF SYM$="B" THEN 3690
3530 IF SYM$="L" THEN 3750
3540 IF SYM$="W" THEN 3790
3550 IF SYM$="D" THEN 3870
3560 COLOR= 4:HLIN H+5,H+8 AT V
3570 HLIN H+5,H+10 AT V+1:HLIN H+8,H+11 AT V+2:HLIN H+10,H+11 AT V+3
3580 COLOR= 8:HLIN H+6,H+7 AT V+2:PLOT H+5,V+3:VLIN V+3,V+4 AT H+8
3590 COLOR= 1:HLIN H+2,H+3 AT V+3:HLIN H+1,H+4 AT V+4:HLIN H,H+4 AT V+5:HLIN H,H+3 AT V+6:HLIN H,H+3 AT V+7:HLIN H+1,H+3 AT V+8
3600 HLIN H+6,H+8 AT V+5:HLIN H+5,H+9 AT V+6:HLIN H+5,H+10 AT V+7:HLIN H+5,H+10 AT V+8:HLIN H+5,H+10 AT V+9
3610 HLIN H+6,H+9 AT V+10:HLIN H+7,H+8 AT V+11
3620 RETURN
3630 COLOR= 9
3640 HLIN H+4,H+7 AT V+1
3650 HLIN H+3,H+8 AT V+2:HLIN H+2,H+9 AT V+3:HLIN H+1,H+10 AT V+4:HLIN H+1,H+10 AT V+5:HLIN H+1,H+10 AT V+6
3660 HLIN H+1,H+10 AT V+7:HLIN H+1,H+10 AT V+8:HLIN H+2,H+9 AT V+9
3670 HLIN H+3,H+8 AT V+10:HLIN H+4,H+7 AT V+11
3680 RETURN
3690 COLOR= 6:HLIN H+5,H+6 AT V+1:HLIN H+5,H+6 AT V+2:HLIN H+4,H+7 AT V+3
3700 HLIN H+3,H+8 AT V+5:HLIN H+3,H+8 AT V+6
3710 HLIN H+2,H+9 AT V+8:HLIN H+2,H+9 AT V+9
3720 COLOR= 2:HLIN H+4,H+7 AT V+4:HLIN H+3,H+8 AT V+7
3730 COLOR= 7:PLOT H+4,V+10
3740 RETURN
3750 COLOR= 13:HLIN H+5,H+6 AT V+1:HLIN H+4,H+7 AT V+2:HLIN H+4,H+8 AT V+3:HLIN H+3,H+9 AT V+4
3760 HLIN H+1,H+10 AT V+5:HLIN H+2,H+10 AT V+6:HLIN H+2,H+9 AT V+7
3770 HLIN H+2,H+8 AT V+8:HLIN H+3,H+8 AT V+9:HLIN H+4,H+7 AT V+10
3780 RETURN
3790 COLOR= 4:HLIN H+6,H+8 AT V+1:HLIN H+3,H+8 AT V+2:HLIN H+1,H+7 AT V+4:HLIN H+1,H+6 AT V+5:HLIN H+1,H+7 AT V+6
3800 HLIN H+2,H+8 AT V+8:HLIN H+2,H+8 AT V+9
3810 HLIN H+5,H+10 AT V+10
3820 COLOR= 12:HLIN H+2,H+7 AT V+3:HLIN H+2,H+7 AT V+7
3830 COLOR= 9:PLOT H+7,V+5:VLIN V+3,V+7 AT H+8:VLIN V+1,V+9 AT H+9:VLIN V+2,V+8 AT H+10:
3840 COLOR= 4:VLIN V+2,V+9 AT H+11
3850 COLOR= 0:PLOT H+10,V+3:PLOT H+8,V+4:PLOT H+9,V+7
3860 RETURN
3870 COLOR= 3:VLIN V+2,V+8 AT H+1:VLIN V+2,V+8 AT H+2:VLIN V+2,V+8 AT H+3:VLIN V+2,V+8 AT H+5:VLIN V+2,V+8 AT H+7
3880 VLIN V+2,V+8 AT H+9:VLIN V+2,V+8 AT H+10:VLIN V+2,V+8 AT H+11:PLOT H+6,V+2:PLOT H+6,V+5
3890 COLOR= 0:PLOT H+2,V+3:PLOT H+2,V+7:PLOT H+3,V+5:PLOT H+10,V+3:PLOT H+11,V+5:VLIN V+7,V+8 AT H+10
3900 COLOR= 5:HLIN H+1,H+11 AT V+10
3910 RETURN
3920 CALL -936
3930 PRINT :PRINT :PRINT " WELCOME TO MR. SY S CASINO IN LAS VEGAS"
3940 PRINT :PRINT "OUR SLOT MACHINES ARE THE MOST GENEROUS":PRINT "ON THE STRIP. THIS ONE PAYS MORE THAN"
3950 PRINT " 97% OF ITS TAKE !!!":PRINT
3960 PRINT "THE PAYOFFS ARE AS FOLLOWS:":PRINT :
3970 PRINT "CHERRY ANY ANY =$ 3";
3980 PRINT "CHERRY CHERRY ANY =$ 5";
3990 PRINT "ORANGE ORANGE BAR =$ 6";
4000 PRINT "BELL BELL ORANGE =$ 8";
4010 PRINT "LEMON LEMON LEMON =$ 10";
4020 PRINT "WATERMELON WATERMELON BAR =$ 15";
4030 PRINT "ORANGE ORANGE ORANGE =$ 18";
4040 PRINT "WATERMELON WATERMELON WATERMELON =$ 20";
4050 PRINT "BAR BAR BAR =$200"
4060 PRINT "TO QUIT, HIT Q"
4070 INPUT "**** READY? HIT RETURN.",Z$
4075 IF Z$="Q" THEN 2920
4080 RETURN
65535 REM

COPYRIGHT (C) 1978 BY APPLE PUGETSOUND PROGRAM LIBRARY EXCHANGE

Text found in RIC_Programs_20.dsk/CURSORS.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 0C 00 20 00 47 00 59 00 5B 00 68 00 75 00 82 00 .. .G.Y. [.h.u...
$000010 95 00 9B 00 9B 00 9B 00 9B 00 00 00 00 00 00 00 ........ ........
$000020 09 2D 2D 15 3F 3F 3F 17 2D 2D 2D 2D 3E 3F 3F 3F .--.???. ---->???
$000030 37 2D 2D 2D 2D 3E 3F 3F 3F 37 2D 2D 2D 2D 1E 3F 7---->?? ?7----.?
$000040 3F 3F 0E 2D 2D 96 00 09 2D 2D 15 15 36 36 1E 1E ??.--... --..66..
$000050 3F 3F 1C 1C 24 24 0C 05 00 1D 00 36 36 36 2E 2D ??..$$.. ...666.-
$000060 2D 24 24 24 3C 3F 3F 00 12 36 36 2D 2D 25 24 3C -$$$ $000070 3F 3F 18 08 00 2E 68 49 29 B6 92 32 3F DB 1B 27 ??....hI )6.2?[.'
$000080 04 00 92 92 92 92 92 2D 2D 2D 2D 25 C0 C0 C0 C0 .......- ---%@@@@
$000090 C0 C0 C0 1B 00 2D 3E 37 2D 05 00 0D 16 1F 07 00 @@@..->7 -.......
$0000A0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000B0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000C0 00 00 00 00 00 00 00 00 A0 00 A5 3C C9 00 D0 02 ........ .%.@ %>I.P.F?
$0000E0 C6 3E A5 40 C9 00 D0 02 C6 41 C6 40 A5 3D C5 3F F>%@I.P. FAF@%=E?
$0000F0 D0 E2 A5 3C C5 3E D0 DC 60 D8 A0 00 4C 2C FE .. Pb%P\ `X .L,~
** END **

Text found in RIC_Programs_20.dsk/GAME OF LIFE.int:

0 POKE -16298,0:GOSUB 2000
5 TEXT
10 CALL -936
20 VTAB 10:TAB 15
30 PRINT "GAME OF LIFE"
40 VTAB 20:TAB 8
50 PRINT "CONCEIVED BY JOHN CONWAY AND"
60 VTAB 22:TAB 8
70 PRINT "POPULARIZED BY MARTIN GARDNER"
80 FOR I=1 TO 2000
90 NEXT I
95 GOSUB 1000
100 DIM OLD(N2N2)
110 DIM NEW(N2N2)
120 FOR I=1 TO N2N2
130 OLD(I)=0
140 NEW(I)=0
150 NEXT I
155 CALL -936
160 GR
170 COLOR= 15
180 FOR I=VT TO VB
190 HLIN HL,HR AT I
200 NEXT I
210 DIM LINE$(50)
211 C= RND (14)+1
212 COLOR= C
214 FOR I=1 TO N
215 VTAB 23
216 PRINT "0 0 1 1 2 2 3 3 3";
217 VTAB 24:TAB 1
218 PRINT "1 5 0 5 0 5 0 5 9";
219 VTAB 22:TAB 1
220 PRINT " "
230 VTAB 21:TAB HL+1
240 PRINT "ENTER LINE ";I
245 TAB HL+1
250 INPUT LINE$
260 L= LEN(LINE$)
270 IF L=0 THEN 320
275 IF L>N THEN 219
280 FOR J=1 TO L
290 IF ASC(LINE$(J,J))=160 THEN 315
300 NEW(N2*I+J+1)=1
310 PLOT J-1+HL,I-1+VT
315 NEXT J
320 NEXT I
330 GEN=0
335 VTAB 21:TAB 1
336 CALL -958
340 VTAB 22:TAB 15
350 PRINT "GENERATION ";GEN
360 VTAB 24:TAB 7
370 PRINT "NOW COMPUTING NEXT GENERATION";
380 REM SET OLD=NEW
390 FOR I=1 TO N2N2
400 OLD(I)=NEW(I)
410 NEXT I
420 CALL -198
430 REM COMPUTE NEXT GEN
440 FOR I=N4 TO NEND
450 COUNT=0
460 COUNT=COUNT+OLD(I-1)
470 COUNT=COUNT+OLD(I+1)
480 COUNT=COUNT+OLD(I-N3)
490 COUNT=COUNT+OLD(I-N2)
500 COUNT=COUNT+OLD(I-N1)
510 COUNT=COUNT+OLD(I+N3)
520 COUNT=COUNT+OLD(I+N2)
530 COUNT=COUNT+OLD(I+N1)
540 IF COUNT<2 OR COUNT>3 THEN 580
550 IF COUNT=2 AND OLD(I)=0 THEN 580
560 NEW(I)=1
570 GOTO 590
580 NEW(I)=0
590 IF I MOD 200=0 THEN CALL -198
600 NEXT I
610 REM FIX UP EDGES
615 CALL -198
620 FOR I=1 TO N
630 NEW(N2*I)=0
640 NEW(N2*I+1)=0
650 NEXT I
655 CALL -198
660 REM PLOT NEW GEN
665 COLOR= 15
666 FOR I=VT TO VB
667 HLIN HL,HR AT I
668 NEXT I
670 B= RND (14)+1
680 IF B=C THEN 670
690 C=B
700 COLOR= C
701 GEN=GEN+1
702 VTAB 21:TAB 1:CALL -958
703 VTAB 22:TAB 15
704 PRINT "GENERATION ";GEN
710 FOR I=1 TO N
720 FOR J=1 TO N
730 IF NEW(N2*I+J+1)=1 THEN PLOT J-1+HL,I-1+VT
740 NEXT J
750 NEXT I
760 CALL -198
780 GOTO 335
1000 CALL -936
1005 DIM A$(5)
1010 INPUT "DO YOU WANT TO SKIP DESCRIPTION OF LIFE? IF SO, TYPE Y FOLLOWED BY 'RETURN'.",A$
1015 IF LEN(A$)=0 THEN 1030
1020 IF A$(1,1)="Y" THEN 1500
1030 CALL -936
1040 PRINT "JOHN CONWAY IS A MATHEMATICIAN AT THE"
1045 PRINT
1050 PRINT "UNIVERSITY OF CAMBRIDGE. WHILE HIS"
1055 PRINT
1060 PRINT "WORK HAS BEEN IN PURE MATHEMATICS, HE"
1065 PRINT
1070 PRINT "IS ALSO KNOWN FOR PRODUCING WORKS IN"
1075 PRINT
1080 PRINT "RECREATIONAL MATH."
1100 PRINT
1110 PRINT "CONWAY DEVELOPED LIFE IN THE LATE 60'S."
1115 PRINT
1120 PRINT "THE RULES OF THE GAME WERE PUBLISHED IN"
1125 PRINT
1130 PRINT "MARTIN GARDNER'S 'MATHEMATICAL GAMES'"
1135 PRINT
1140 PRINT "SECTION OF THE OCTOBER, 1970 ISSUE OF"
1145 PRINT
1150 PRINT "SCIENTIFIC AMERICAN. IT IS RECOMMENDED"
1155 PRINT
1160 PRINT "READING FOR ANYONE WISHING TO LEARN MORE"
1165 PRINT
1170 PRINT "ABOUT THE GAME OF LIFE.";
1180 FOR I=1 TO 15000
1190 NEXT I
1200 CALL -936
1210 PRINT "THE BASIC IDEA IS TO START WITH A SIMPLE"
1212 PRINT "PATTERN OF COUNTERS ON A CHECKERBOARD."
1214 PRINT
1216 PRINT "(THE CHECKERBOARD IS INFINITE.) THEN"
1218 PRINT
1220 PRINT "A SIMPLE SET OF GENETIC LAWS FOR BIRTHS,"
1224 PRINT "DEATHS AND SURVIVALS IS APPLIED TO THE"
1226 PRINT
1228 PRINT "INITIAL PATTERN TO FORM THE NEXT"
1230 PRINT
1232 PRINT "GENERATION."
1234 PRINT
1236 PRINT "SIMPLE PATTERNS WILL GROW AND CHANGE FOR"
1238 PRINT
1240 PRINT "A LONG TIME BEFORE ENDING IN ONE OF "
1242 PRINT
1244 PRINT "THREE WAYS:"
1246 PRINT " 1. FADING AWAY TO NOTHING"
1248 PRINT " 2. SETTLING INTO AN UNCHANGING PATTERN"
1250 PRINT " 3. ENTERING AN OSCILLATING PATTERN";
1252 FOR I=1 TO 15000
1254 NEXT I
1256 CALL -936
1258 PRINT "CONWAY'S GENETIC LAWS ARE SIMPLE:"
1260 PRINT
1262 PRINT " 1. SURVIVALS. EVERY COUNTER WITH TWO"
1264 PRINT " OR THREE NEIGHBORING COUNTERS"
1266 PRINT " SURVIVES FOR THE NEXT GENERATION."
1268 PRINT
1270 PRINT " 2. DEATHS. EACH COUNTER WITH FOUR OR"
1272 PRINT " MORE NEIGHBORS DIES FROM OVER-"
1274 PRINT " POPULATION. EVERY COUNTER WITH ONE"
1276 PRINT " NEIGHBOR OR NONE DIES FROM "
1278 PRINT " ISOLATION."
1280 PRINT
1282 PRINT " 3. BIRTHS. EACH EMPTY CELL ADJACENT TO"
1284 PRINT " EXACTLY THREE NEIGHBORS-NO MORE,"
1286 PRINT " NO FEWER-IS A BIRTH CELL. A COUNTER"
1288 PRINT " IS PLACED ON IT IN THE NEXT"
1290 PRINT " GENERATION."
1292 PRINT
1294 PRINT "(NOTE THAT EACH CELL HAS EIGHT "
1296 PRINT "NEIGHBORING CELLS.)"
1298 FOR I=1 TO 17000
1300 NEXT I
1302 CALL -936
1304 PRINT "THE APPLE VERSION OF LIFE MAY BE "
1306 PRINT
1308 PRINT "PLAYED ON ANY SIZE CHECKERBOARD UP TO "
1310 PRINT
1312 PRINT "40 BY 40. THE PROGRAM IS LONG RUNNING,"
1314 PRINT
1316 PRINT "HOWEVER. EACH SUCCEEDING GENERATION ON"
1318 PRINT
1320 PRINT "A 40 BY 40 BOARD TAKES ABOUT 3 MINUTES"
1322 PRINT
1324 PRINT "TO COMPUTE. INTERESTING DISPLAYS CAN"
1326 PRINT
1328 PRINT "BE GENERATED ON A 7 BY 7 BOARD."
1334 PRINT
1336 PRINT "BEGIN BY SPECIFYING THE BOARD SIZE."
1338 PRINT
1340 PRINT "REMEMBER, 40 IS MAXIMUM. THEN SET"
1342 PRINT
1344 PRINT "UP AN INITIAL PATTERN LINE BY LINE."
1346 PRINT
1348 PRINT "THE SPACE BAR LEAVES A CELL BLANK WHILE"
1350 PRINT
1352 PRINT "ANY KEY WILL PLACE A COUNTER ON A CELL.";
1354 FOR I=1 TO 15000
1356 NEXT I
1358 CALL -936
1360 GOTO 1500
1500 CALL -936
1510 INPUT "ENTER SIZE OF CHECKERBOARD",N
1512 IF N<41 AND N>0 THEN 1520
1513 PRINT :PRINT "SIZE MUST BE BETWEEN 1 AND 40":PRINT
1514 GOTO 1510
1520 N2=N+2
1530 N2N2=N2*N2
1540 VT=(41-N)/2
1550 VB=(N+39)/2
1560 HL=(41-N)/2
1570 HR=(N+39)/2
1580 N1=N+1
1590 N3=N+3
1600 N4=N+4
1610 NEND=N2*N1-1
1620 RETURN
2000 CALL -936
2100 VTAB 5:PRINT "TITLE: GAME OF LIFE"
2200 PRINT "BY: MARTIN GARDNER & JOHN CONWAY"
2300 PRINT "DATE: 7-79":PRINT
2400 PRINT "ANOTHER IN OUR 'LIFE' SERIES, THIS ONE":PRINT "WITH A DESCRIPTION OF LIFE!"
2500 VTAB 20:PRINT "PRESS ESC TO END":PRINT
2600 PRINT "<< PRESS THE SPACE BAR TO CONTINUE >>"
2700 IF PEEK (-16384)=27 THEN 3000
2800 CALL -756:IF PEEK (-16384)<>32 THEN 2000
2900 RETURN
3000 POKE -16298,0:CALL -936:PR # 6

Text found in RIC_Programs_20.dsk/HELLO.bas:

1 FOR A = 1 TO 500: NEXT A: TEXT : HOME
2 D$ = ""
105 GOTO 5000
107 HOME
110 PRINT "DO YOU WANT TO:": PRINT : PRINT : PRINT : PRINT
120 PRINT " 1. LOAD A PROGRAM": PRINT
130 PRINT " 2. RUN A PROGRAM": PRINT
140 PRINT " 3. END FOR NOW": PRINT
145 FLASH
150 INPUT "ENTER A NUMBER (1, 2, OR 3) ";A
155 NORMAL
160 IF A <1 THEN PRINT "NUMBER MUST BE GREATER THAN 0": FOR M = 1 TO 5000: NEXT M: HOME : GOTO 110
170 IF A >3 THEN PRINT "NUMBER MUST BE LESS THAN 3": FOR M = 1 TO 5000: NEXT M: HOME : GOTO 110
180 IF A = 1 THEN 1000
190 IF A = 2 THEN 1000
200 IF A = 3 THEN END
1000 HOME
1010 PRINT TAB( 18)"MENU"
1020 PRINT : PRINT : PRINT
1030 PRINT " 1. GAME OF LIFE"
1040 PRINT " 2. STAY AFLOAT"
1050 PRINT " 3. ANDROMEDA STRAIN"
1060 PRINT " 4. GRAVITY PINBALL"
1070 PRINT " 5. BLACKJACK"
1080 PRINT " 6. ONE ARMED BANDIT"
1090 PRINT " 7. SABOTAGE"
1100 PRINT " 8. BENEATH APPLE MANOR"
1120 PRINT " 9. SEX ROLE"
1130 PRINT " 10. BURNOUT"
1140 PRINT : PRINT : INPUT "ENTER A NUMBER FROM 1 TO 10 ";B
1150 IF B <1 THEN PRINT "NUMBER LESS THAN 1--REENTER": FOR M = 1 TO 5000: NEXT M: GOTO 1000
1160 IF B >10 THEN PRINT "NUMBER GREATER THAN 10--REENTER": FOR M = 1 TO 5000: NEXT M: GOTO 1000
1170 IF A = 1 AND B = 1 THEN PRINT D$;"LOAD GAME OF LIFE"
1180 IF A = 1 AND B = 2 THEN PRINT D$;"LOAD STAY AFLOAT"
1190 IF A = 1 AND B = 3 THEN PRINT D$;"LOAD ANDROMEDA STRAIN"
1200 IF A = 1 AND B = 4 THEN PRINT D$;"LOAD CASINOII"
1300 IF A = 1 AND B = 5 THEN PRINT D$;"LOAD CASINOII"
1400 IF A = 1 AND B = 6 THEN PRINT D$;"LOAD CASINOII"
1500 IF A = 1 AND B = 7 THEN PRINT D$;"LOAD SABOTAGE"
1600 IF A = 1 AND B = 8 THEN PRINT D$;"LOAD BENEATH APPLE MANOR"
1610 IF A = 1 AND B = 9 THEN PRINT D$;"LOAD SEX ROLE"
1620 IF A = 1 AND B = 10 THEN PRINT D$;"LOAD BURNOUT"
1630 IF A = 2 AND B = 1 THEN PRINT D$;"RUN GAME OF LIFE"
1640 IF A = 2 AND B = 2 THEN PRINT D$;"RUN STAY AFLOAT"
1650 IF A = 2 AND B = 3 THEN PRINT D$;"RUN ANDROMEDA STRAIN"
1660 IF A = 2 AND B = 4 THEN PRINT D$;"RUN CASINOII"
1670 IF A = 2 AND B = 5 THEN PRINT D$;"RUN CASINOII"
1680 IF A = 2 AND B = 6 THEN PRINT D$;"RUN CASINOII"
1690 IF A = 2 AND B = 7 THEN PRINT D$;"RUN SABOTAGE"
1700 IF A = 2 AND B = 8 THEN PRINT D$;"RUN BENEATH APPLE MANOR"
1710 IF A = 2 AND B = 9 THEN PRINT D$;"RUN SEX ROLE"
1720 IF A = 2 AND B = 10 THEN PRINT D$;"RUN BURNOUT"
5000 CLEAR : HOME : PRINT "WHICH COMPUTER DO YOU HAVE? ": PRINT : PRINT : PRINT :D$ = ""
5010 PRINT "1. II OR II+ WITH LANGUAGE CARD"
5020 PRINT : PRINT : PRINT "2. IIE"
5022 PRINT
5023 PRINT : FLASH : PRINT "INPUT A 3 IF INTEGER ALREADY LOADED": NORMAL
5027 PRINT : PRINT : PRINT
5030 PRINT : INPUT "ENTER A 1 OR 2 FOR YOUR MACHINE ";C
5040 IF C <0 OR C >3 THEN PRINT "YOU GOOFED": FOR M = 1 TO 2000: NEXT M: GOTO 5000
5050 IF C = 1 THEN PRINT D$;"RUN HELLOB"
5060 IF C = 2 THEN PRINT D$;"RUN HELLO1"
6000 GOTO 107
0
5220

Text found in RIC_Programs_20.dsk/HELLO1.bas:

10 TEXT : HOME
20 D$ = CHR$(4): REM CTRL-D
60 PRINT D$;"BLOAD LOADER.OBJ0"
70 CALL 4096: REM FAST LOAD IN INTEGER BASIC
80 VTAB 10: CALL -958
90 C = PEEK( -1101)
100 PRINT CHR$(4);"RUN HELLO2"

Text found in RIC_Programs_20.dsk/HELLO2.bas:

107 HOME
110 PRINT "DO YOU WANT TO:": PRINT : PRINT : PRINT : PRINT
120 PRINT " 1. LOAD A PROGRAM": PRINT
130 PRINT " 2. RUN A PROGRAM": PRINT
140 PRINT " 3. END FOR NOW": PRINT
145 FLASH
150 INPUT "ENTER A NUMBER (1, 2, OR 3) ";A
155 NORMAL
160 IF A <1 THEN PRINT "NUMBER MUST BE GREATER THAN 0": FOR M = 1 TO 5000: NEXT M: HOME : GOTO 110
170 IF A >3 THEN PRINT "NUMBER MUST BE LESS THAN 3": FOR M = 1 TO 5000: NEXT M: HOME : GOTO 110
180 IF A = 1 THEN 1000
190 IF A = 2 THEN 1000
200 IF A = 3 THEN END
1000 HOME
1010 PRINT TAB( 18)"MENU"
1020 PRINT : PRINT : PRINT
1030 PRINT " 1. GAME OF LIFE"
1040 PRINT " 2. STAY AFLOAT"
1050 PRINT " 3. ANDROMEDA STRAIN"
1060 PRINT " 4. GRAVITY PINBALL"
1070 PRINT " 5. BLACKJACK"
1080 PRINT " 6. ONE ARMED BANDIT"
1090 PRINT " 7. SABOTAGE"
1100 PRINT " 8. BENEATH APPLE MANOR"
1120 PRINT " 9. SEX ROLE"
1130 PRINT " 10. BURNOUT"
1140 PRINT : PRINT : INPUT "ENTER A NUMBER FROM 1 TO 10 ";B
1150 IF B <1 THEN PRINT "NUMBER LESS THAN 1--REENTER": FOR M = 1 TO 5000: NEXT M: GOTO 1000
1160 IF B >10 THEN PRINT "NUMBER GREATER THAN 10--REENTER": FOR M = 1 TO 5000: NEXT M: GOTO 1000
1165 D$ = ""
1170 IF A = 1 AND B = 1 THEN PRINT D$;"LOAD GAME OF LIFE"
1180 IF A = 1 AND B = 2 THEN PRINT D$;"LOAD STAY AFLOAT"
1190 IF A = 1 AND B = 3 THEN PRINT D$;"LOAD ANDROMEDA STRAIN"
1200 IF A = 1 AND B = 4 THEN PRINT D$;"LOAD CASINOII"
1300 IF A = 1 AND B = 5 THEN PRINT D$;"LOAD CASINOII"
1400 IF A = 1 AND B = 6 THEN PRINT D$;"LOAD CASINOII"
1500 IF A = 1 AND B = 7 THEN PRINT D$;"LOAD SABOTAGE"
1600 IF A = 1 AND B = 8 THEN PRINT D$;"LOAD BENEATH APPLE MANOR"
1610 IF A = 1 AND B = 9 THEN PRINT D$;"LOAD SEX ROLE"
1620 IF A = 1 AND B = 10 THEN PRINT D$;"LOAD BURNOUT"
1630 IF A = 2 AND B = 1 THEN PRINT D$;"RUN GAME OF LIFE"
1640 IF A = 2 AND B = 2 THEN PRINT D$;"RUN STAY AFLOAT"
1650 IF A = 2 AND B = 3 THEN PRINT D$;"RUN ANDROMEDA STRAIN"
1660 IF A = 2 AND B = 4 THEN PRINT D$;"RUN CASINOII"
1670 IF A = 2 AND B = 5 THEN PRINT D$;"RUN CASINOII"
1680 IF A = 2 AND B = 6 THEN PRINT D$;"RUN CASINOII"
1690 IF A = 2 AND B = 7 THEN PRINT D$;"RUN SABOTAGE"
1700 IF A = 2 AND B = 8 THEN PRINT D$;"RUN BENEATH APPLE MANOR"
1710 IF A = 2 AND B = 9 THEN PRINT D$;"RUN SEX ROLE"
1720 IF A = 2 AND B = 10 THEN PRINT D$;"RUN BURNOUT"
0
5220

Text found in RIC_Programs_20.dsk/HELLOB.bas:

10 REM -- DOS 3.3 HELLO
20 REM
30 TEXT : PRINT
40 HOME
50 REM
60 REM
70 REM
80 REM --POKE LANGUAGE CARD FINDER
90 POKE 768,0: POKE 769,173: POKE 770,0: POKE 771,224: POKE 772,72: POKE 773,173: POKE 774,129: POKE 775,192: POKE 776,104:
95 POKE 777,72: POKE 778,205: POKE 779,0: POKE 780,224: POKE 781,208: POKE 782,35: POKE 783,173: POKE 784,131: POKE 785,192:
100 POKE 786,173: POKE 787,131: POKE 788,192: POKE 789,169: POKE 790,165: POKE 791,141: POKE 792,0: POKE 793,208: POKE 794,205:
105 POKE 795,0: POKE 796,208: POKE 797,208: POKE 798,19: POKE 799,74: POKE 800,141: POKE 801,0: POKE 802,208: POKE 803,205:
110 POKE 804,0: POKE 805,208: POKE 806,208: POKE 807,10: POKE 808,173: POKE 809,129: POKE 810,192: POKE 811,173: POKE 812,129:
115 POKE 813,192: POKE 814,169: POKE 815,1: POKE 816,208: POKE 817,2: POKE 818,169: POKE 819,0: POKE 820,141: POKE 821,0:
120 POKE 822,3: POKE 823,104: POKE 824,205: POKE 825,0: POKE 826,224: POKE 827,240: POKE 828,3: POKE 829,173: POKE 830,128:
125 POKE 831,192: POKE 832,96:
155 CALL 769
160 IF PEEK(768) < >1 THEN 250
170 REM
180 REM --IF THERE, LOAD INTG AND PA#1
190 REM
200 REM
210 PRINT CHR$(4);"BLOAD INTBASICA,A$D000"
220 REM --WRITE PROTECT THE CARD
230 A = PEEK( -16254): REM $C082
240 GOTO 300
250 REM
260 REM --NO CARD OR CAN'T RELOAD
270 REM
280 IF PEEK(768) = 0 THEN 300
290 PRINT : PRINT "...LANGUAGE CARD CANNOT BE RELOADED": PRINT " UNTIL THE SYSTEM IS REBOOTED..."
300 PRINT CHR$(4);"RUN HELLO2"

Text found in RIC_Programs_20.dsk/LOGO.bas:

50 FLAG = 0
51 FT$(1) = ""
52 FT$(2) = "]SMALL STANDARD"
53 FT$(3) = "]WESTERN"
54 UL$ = "@"
55 ONERR GOTO 450
56 GOTO 170
90 T$ = "":LC = 0: FOR I = 1 TO LEN(A$):J = ASC( MID$ (A$,I,1)): IF J < >UL THEN T$ = T$ + CHR$(J +LC *(J >63 AND J <96)): NEXT :A$ = T$: GOTO 100
95 LC = LC +32 -64 *(LC = 32): NEXT :A$ = T$
99 REM PRINT ROUTINE:
100 POKE 232,L1(FT): POKE 233,L2(FT): IF LEN(FT3$) THEN PRINT D$;"BLOAD ";FT3$;",A";LOC(3):FT$(3) = FT3$:FT3$ = "": RETURN
105 X = 7 *HT -6:Y = 8 *VT -8: ROT= RT *16: IF CL <8 THEN BG = CL: HCOLOR= BG:CL = 8: HPLOT 0,0: CALL 62454:VT = 1:HT = 1:FT = 1: RETURN
110 IF CT THEN X = 0:YT = 176:XR = 0: HCOLOR= BG: FOR Z = 1 TO LEN(A$): DRAW ASC( MID$ (A$,Z,1)) -T1 AT X,YT: DRAW 99: CALL 62923:XR = XR + PEEK(224): NEXT :X = (280 -XR)/2
120 HCOLOR= HC: DRAW 100 AT X,Y: FOR Z = 1 TO LEN(A$): DRAW ASC( MID$ (A$,Z,1)) -T1: XDRAW 99: NEXT : CALL 62923:XO = X:X = PEEK(224) + PEEK(225) *TF:CT = 0:RT = 0:HT = (X +6)/7: IF NOT (IN) THEN RETURN
130 POKE 232,0: POKE 233,64:XR = X:YB = 8 * PEEK(LO(FT) +1):SC = XR -XO: IF SC <256 THEN SCALE= SC: ROT= 0: FOR I = Y -(Y >0) TO Y +YB: XDRAW 3 AT XO,I: NEXT : GOTO 150
140 SCALE= YB: ROT= 16: FOR I = X TO XR: XDRAW 3 AT I,Y: NEXT
150 ROT= 0: SCALE= 1:IN = 0: RETURN
170 SCALE= 1: ROT= 0:CL = 8: HCOLOR= 3:TF = 256:T1 = 31:TXT = 49235:FULL = 49234:HIRES = 49232:UL = ASC(UL$):G$ = CHR$(7):D$ = CHR$(13) + CHR$(4)
180 J = 768: FOR I = 1 TO 3:LOC(I) = PEEK(J) + PEEK(J +1) *256:L1(I) = PEEK(J):L2(I) = PEEK(J +1):J = J +2: NEXT : REM STORE.FONT.LOCATIONS
190 REM FONT LOAD ROUTINE:
200 IF FLAG >0 THEN 500
220 PRINT D$;"BLOAD CURSORS,A16384":LOC(1) = 16640: FOR I = 1 TO 3
230 IF LEN(FT$(I)) THEN PRINT D$;"BLOAD ";FT$(I);",A";LOC(I)
240 LOC(I +1) = LOC(I) + PEEK(43616) + PEEK(43617) *256: NEXT
250 J = 768: FOR I = 1 TO 3:X = LOC(I): POKE J,X - INT(X/256) *256:L1(I) = PEEK(J): POKE J +1, INT(X/256):L2(I) = PEEK(J +1):J = J +2: NEXT : GOTO 500
399 REM HT CALCULATOR:
400 TEXT : VTAB 24: PRINT :Q$ = CHR$(34): PRINT "CENTER FINDER": PRINT "-------------": PRINT "FONT: ";FT: PRINT "COPY: "Q$A$Q$:X = 0:YT = 176:XR = 0: HCOLOR= BG: PRINT : POKE 232, PEEK(766 +2 *FT): POKE 233, PEEK(767 +2 *FT)
405 IF NOT LEN(A$) OR (FT <1 OR FT >3) THEN PRINT CHR$(7);"SPECIFY FONT NUMBER (FT=#)": PRINT "AND COPY (A$="Q$"WORDS"Q$"),": PRINT "AND GOTO 400 AGAIN.": VTAB 11: PRINT "FOR EXAMPLE, TYPE:": PRINT : PRINT "FT=1:A$="Q$"TITLE"Q$":GOTO 400": END
410 FOR I = 1 TO LEN(A$): DRAW ASC( MID$ (A$,I,1)) -31 AT X,YT: DRAW 99: CALL 62923:XR = XR + PEEK(224): NEXT :X = (280 -XR)/2:HT = (X +6)/7: PRINT "FOR HTAB, LET HT="; INT(HT *10)/10: IF HT <1 THEN FLASH : VTAB 7: PRINT CHR$(7)" COPY TOO LONG ";: CALL -958
420 NORMAL : END
450 LINE = PEEK(218) + PEEK(219) *256:TYPE = PEEK(222): HOME : POKE TXT,0: VTAB 21: IF TYPE <255 THEN PRINT CHR$(7);"CODE-";TYPE;" ERROR IN LINE #";LINE: END
499 REM MAIN PROGRAM:
500 HC = 3:HT = 1:VT = 1:FT = 1:CT = 0:IN = 0:CL = 8:RT = 0:FT3$ = "": HGR : POKE FULL,0: REM STARTING DEFAULTS
514 HT = 14:VT = 4:FT = 3:A$ = "P": GOSUB 100
516 HT = 16:VT = 6:FT = 3:A$ = "M": GOSUB 100
518 HT = 18:VT = 8:FT = 3:A$ = "Enterprises": GOSUB 100
519 HT = 3:VT = 19:FT = 2:A$ = "Copying or Reproduction of any part of": GOSUB 100
520 CT = 1:VT = 20:FT = 2:A$ = "The Disk Management Program is Prohibited": GOSUB 100
530 HT = 3:VT = 21:FT = 2:A$ = "Copyright (c) 1983. P.M. Enterprises All": GOSUB 100
535 VT = 22:HT = 3:FT = 2:A$ = "Rights Reserved.": GOSUB 100
600 FOR CT = 1 TO 8000: NEXT CT: TEXT : HOME : PRINT CHR$(4);"RUN HELLO"

Text found in RIC_Programs_20.dsk/SABOTAGE.bas:

10 TEXT : HOME : DIM T$(47)
20 DIM M(42,8)
30 DIM O(14)
60 REM INITIALIZE TEXT AND MOVE M-TRICES
90 PRINT "WELCOME TO THE GAME OF SABOTAGE."
100 INPUT "WOULD YOU LIKE INSTRUCTIONS?";C$
120 IF LEFT$(C$,1) = "Y" THEN GOSUB 5050
130 FOR I = 1 TO 47
140 READ T$(I)
150 NEXT I
160 FOR I = 1 TO 42
170 FOR J = 1 TO 8
180 READ M(I,J)
190 NEXT J
200 NEXT I
220 REM INITIALIZE OTHER VARIABLES
230 REM **
240 REM ** P = CURRENT POSITION C = NO. OF ITEMS CARRIED
250 REM BBH5 THEN P1 = P1 -5
700 IF O(14) = 99 AND P2 >5 THEN P2 = P2 -5
710 IF O(11) = 99 AND P1 = 0 THEN 3680
720 IF O(14) = 99 AND P2 = 0 THEN 3680
730 IF T1 >400 THEN 2960
740 IF T1 >350 THEN 3840
750 IF T1 >200 THEN 3740
760 IF F0 = 1 THEN T2 = T2 -5
770 IF T2 <0 THEN T2 = 0
780 IF F0 = 0 THEN 800
790 IF T2 >0 THEN 840
800 IF F9 = 0 THEN 820
810 IF P >21 THEN 2900
820 IF P <18 THEN 2900
830 IF P = 38 THEN 1700
840 IF P = 28 THEN 3590
850 IF F0 = 1 THEN PRINT "OXYGEN REMAINING: ";T2;" MINUTES"
860 PRINT "PRESENT LOCATION STATUS: YOU ARE"
870 FOR I = M(P,7) TO M(P,8)
880 PRINT T$(I)
890 NEXT I
900 PRINT "##"
920 REM ** DISPLAY ANY OBJECTS PRESENT
940 IF P = 2 THEN 1920
950 FOR I = 1 TO 14
960 IF O(I) < >P THEN 990
970 GOSUB 4410
980 PRINT "THERE IS ";B$;" HERE"
990 NEXT I
1000 GOTO 2000
1020 REM ** READ AND PROCESS INPUT
1040 INPUT B$
1050 I = 0
1060 IF LEN(B$) < >1 GOTO 1320
1070 IF B$ = "N" THEN I = 1
1080 IF B$ = "S" THEN I = 2
1090 IF B$ = "E" THEN I = 3
1100 IF B$ = "W" THEN I = 4
1110 IF B$ = "U" THEN I = 5
1120 IF B$ = "D" THEN I = 6
1130 IF B$ = "Q" THEN 6200
1140 IF I = 0 THEN 1570
1150 IF M(P,I) = 0 THEN 1270
1160 IF M(P,I) = 99 THEN 2940
1170 Q = M(P,I)
1180 IF P = 12 THEN 3060
1190 IF P = 13 THEN 3180
1200 IF P = 22 THEN 3310
1210 IF P = 23 THEN 3420
1220 IF P = 29 THEN 3470
1230 R = P:P = Q
1250 IF P = 35 THEN V = V +1
1260 GOTO 650
1270 PRINT "YOU CAN'T GO IN THAT DIRECTION!"
1280 GOTO 1040
1300 REM ** PROCESS WORDS
1320 C$ = LEFT$(B$,3)
1330 IF C$ = "LOO" THEN 650
1340 IF C$ = "DES" THEN 650
1350 IF C$ = "GET" THEN 2190
1360 IF C$ = "TAK" THEN 2190
1370 IF C$ = "KEE" THEN 2190
1380 IF C$ = "DRO" THEN 2580
1390 IF C$ = "LEA" THEN 2580
1400 IF C$ = "PUT" THEN 2580
1410 IF C$ = "INV" THEN 2780
1420 IF C$ = "QUI" THEN 6200
1430 IF C$ = "END" THEN 6200
1440 IF C$ = "TRA" THEN 1750
1450 IF C$ = "DIG" THEN 1860
1460 IF C$ = "DEB" THEN 1610
1470 IF C$ = "FUE" THEN 4030
1480 IF C$ = "REA" THEN 4250
1490 IF C$ = "DEA" THEN 3890
1500 IF C$ = "BLA" THEN 4110
1510 IF C$ = "UP" THEN 1640
1520 IF C$ = "DOW" THEN 1640
1530 IF C$ = "NOR" THEN 1640
1540 IF C$ = "SOU" THEN 1640
1550 IF C$ = "EAS" THEN 1640
1560 IF C$ = "WES" THEN 1640
1570 PRINT "INVALID COMMAND!"
1580 GOTO 1040
1590 PRINT "I CAN'T PROCESS YOUR REQUEST!"
1600 GOTO 1040
1610 PRINT "ENTER LOCATION": INPUT P
1630 GOTO 650
1640 D$ = B$:B$ = D$
1660 GOTO 1070
1680 REM ** PROCESS ENTRY TO HANGER FROM AIR LOCK
1700 IF P < >39 THEN 2900
1710 GOTO 840
1730 REM ** PROCESS TRANSPORT COMMAND
1750 IF P < >36 THEN 1800
1760 IF O(8) = 99 THEN 1590
1770 P = O(8)
1780 PRINT "BEAMING IN PROCESS"
1790 GOTO 650
1799 IF R < >39 THEN 2900
1800 IF P < >O(8) THEN 1590
1810 P = 36
1820 GOTO 1780
1840 REM ** PROCESS DIG COMMAND
1860 IF P < >10 THEN 1590
1870 O(9) = 10
1880 GOTO 940
1900 REM ** DROP ILLUMINATOR IF AT OVERLOOK
1920 IF O(4) < >99 THEN 950
1930 O(4) = 100
1940 PRINT "YOU DROPPED YOUR ILLUMINATOR! YOU"
1950 PRINT "CAN'T RETRIEVE IT."
1960 GOTO 950
1980 REM ** PROCESS ROBOT
2000 IF O(5) = 28 THEN O(5) = 35
2010 IF O(5) = 42 THEN O(5) = 28
2020 IF O(5) = 41 THEN O(5) = 42
2030 IF O(5) = 27 THEN O(5) = 41
2040 IF O(5) = 25 THEN O(5) = 27
2050 IF O(5) < >35 THEN 2090
2060 IF P < >28 THEN 1040
2070 M(28,1) = 35: GOTO 1040
2090 IF O(5) < >32 THEN 1040
2100 IF P < >32 THEN 1040
2110 O(5) = 25
2120 IF O(13) = 99 THEN 1040
2130 PRINT "ROBOT FAILS TO RECOGNIZE YOU. IT"
2140 PRINT "FIRES A PHASOR WEAPON AT YOU!"
2150 GOTO 2980
2160 REM **
2170 REM ** PROCESS GET OR TAKE COMMANDS
2190 GOSUB 4590
2200 IF I >0 THEN 2260
2210 IF I <0 THEN 2240
2220 PRINT "I DON'T RECOGNIZE "; RIGHT$(B$, LEN(B$) -J);"."
2230 GOTO 1040
2240 PRINT "WHAT ITEM?"
2250 GOTO 1040
2260 IF O(I) < >P THEN 2370
2270 IF C >5 THEN 2390
2280 IF I = 5 THEN 2410
2290 IF I = 10 THEN 2430
2300 IF I = 11 THEN 2460
2310 IF I = 14 THEN 2490
2320 C = C +1
2330 O(I) = 99
2340 IF I = 3 THEN F0 = 1
2350 PRINT "O.K."
2360 GOTO 1040
2370 PRINT "THERE IS NO "; RIGHT$(B$, LEN(B$) -J);" HERE!"
2380 GOTO 1040
2390 PRINT "YOU CAN'T CARRY ANY MORE!"
2400 GOTO 1040
2410 PRINT "YOU CAN'T CARRY A ROBOT!"
2420 GOTO 1040
2430 PRINT "YOU CAN'T GET THE MESSAGE, IT'S"
2440 PRINT "ON THE TERMINAL SCREEN."
2450 GOTO 1040
2460 IF O(14) = 99 THEN 2520
2470 O(11) = 99
2480 GOTO 2320
2490 IF O(11) = 99 THEN 2520
2500 O(14) = 99
2510 GOTO 2320
2520 PRINT "YOU CAN'T HAVE MORE THAN ONE"
2530 PRINT "POWER SUPPLY."
2540 GOTO 1040
2550 REM **
2560 REM ** PROCESS DROP OR LEAVE COMMAND
2580 GOSUB 4590
2590 IF I >0 THEN 2620
2600 IF I <0 THEN 2240
2610 GOTO 2220
2620 IF O(I) < >99 THEN 2690
2630 C = C -1
2640 O(I) = P
2650 IF I = 3 THEN F0 = 0
2660 IF I = 11 THEN 2710
2670 IF I = 14 THEN 2710
2680 GOTO 2350
2690 PRINT "YOU DON'T HAVE "; RIGHT$(B$, LEN(B$) -J);"!"
2700 GOTO 1040
2710 IF P <22 THEN 2870
2720 IF P = 38 THEN 2870
2730 IF F9 = 1 THEN 2870
2740 GOTO 2350
2750 REM **
2760 REM ** PROCESS INVENTORY COMMAND
2780 FOR I = 1 TO 14
2790 IF O(I) < >99 THEN 2820
2800 GOSUB 4410
2810 PRINT "YOU HAVE ";B$;"."
2820 NEXT I
2830 GOTO 1040
2840 REM **
2850 REM ** TERMINATION PROCESSING
2870 PRINT "YOU HAVE NO POWER OR POWER PACK."
2880 PRINT "YOU HAVE FROZEN TO DEATH."
2890 GOTO 2980
2900 PRINT "OXYGEN REQUIRED HERE, NONE AVAILABLE."
2910 GOTO 2980
2920 PRINT "A NUCLEAR DETONATION HAS JUST OCCURRED."
2930 GOTO 2980
2940 PRINT "YOU HAVE FALLEN TO YOUR DEATH."
2950 GOTO 2980
2952 PRINT "YOU HAVE BEEN ZAPPED BY THE LASER."
2954 GOTO 2980
2960 PRINT "THE MOON BASE HAS JUST BEEN DESTROYED"
2970 PRINT "BY A LARGE ASTEROID."
2980 PRINT "YOU HAVE FAILED TO SURVIVE."
2990 PRINT "DO YOU WISH TO TRY AGAIN?"
3000 INPUT D$
3010 IF LEFT$(D$,1) = "Y" THEN 320
3020 GOTO 6200
3030 REM **
3040 REM ** METEOR SHOWER
3060 IF M(P,I) < >13 THEN 1230
3070 IF F2 = 1 THEN 1230
3080 PRINT "THERE IS A METEOR SHOWER, YOUR SPACE"
3090 PRINT "SUIT HAS DEVELOPED A LEAK!"
3100 GOSUB 4890
3110 IF I < >2 THEN 2980
3120 PRINT "YOUR SUIT IS NOW SEALED."
3130 F2 = 1
3140 GOTO 1230
3150 REM **
3160 REM ** LOCKED SHED
3180 IF M(P,I) < >22 THEN 1230
3190 IF F1 = 1 THEN 1230
3200 PRINT "THE SHED IS LOCKED!"
3210 GOSUB 4890
3220 IF I < >1 THEN 3260
3230 PRINT "YOU ARE IN THE SHED AIR LOCK."
3240 F1 = 1
3250 GOTO 1230
3260 PRINT "YOUR ATTEMPT FAISL."
3270 GOTO 1040
3280 REM **
3290 REM ** DARK VENTILATOR SHAFT
3310 IF M(P,I) < >23 THEN 1230
3320 IF F4 = 1 THEN 1230
3330 PRINT "IT IS DANGEROUS TO PROCEED IN THE DARK!"
3340 GOSUB 4890
3350 IF I < >4 THEN 2940
3360 PRINT "THE SHAFT IS NOW ILLUMINATED."
3370 F4 = 1
3380 GOTO 1230
3390 REM **
3400 REM ** SHAFT WITH NO ILLUMINATOR
3420 IF O(4) < >99 THEN 2940
3430 GOTO 1230
3440 REM **
3450 REM ** LASER BEAM
3470 IF M(P,I) < >37 THEN 1230
3480 IF F3 = 1 THEN 1230
3490 PRINT "THERE IS A LASER BEAM HERE. PASSAGE NOT"
3500 PRINT "POSSIBLE WITH BEAM PRESENT."
3510 GOSUB 4890
3520 IF I < >12 THEN 2952
3530 PRINT "THE BEAM IS NOW DEFLECTED."
3540 F3 = 1
3550 GOTO 1230
3560 REM **
3570 REM ** BLOWN SEAL IN SPACE STATION
3590 IF R < >29 THEN 850
3600 IF F9 = 1 THEN 850
3610 F9 = 1
3620 PRINT "YOU HAVE JUST BLOWN AN AIR SEAL IN"
3630 PRINT "THE SPACE STATION."
3640 GOTO 850
3650 REM **
3660 REM ** POWER REQUIRED TESTING
3680 IF P <22 THEN 2870
3690 IF F9 = 1 THEN 2870
3700 GOTO 730
3710 REM **
3720 REM ** EXPOSE DEACTIVATOR
3740 IF F5 = 1 THEN 760
3750 O(6) = 14
3760 M(2,8) = M(2,7)
3770 M(14,8) = M(14,7)
3780 M(14,4) = 2
3790 F5 = 1
3800 GOTO 760
3810 REM **
3820 REM ** DETONATE BOMB
3840 IF F7 = 0 THEN 2920
3850 GOTO 760
3860 REM **
3870 REM ** DEACTIVATE BOMB
3890 IF O(6) < >99 THEN 3940
3900 IF O(7) < >99 THEN 3980
3910 F7 = 1
3920 PRINT "BOMB IS NOW DEACTIVATED."
3930 GOTO 1040
3940 PRINT "YOU HAVE NOTHING TO DO IT WITH!"
3950 GOTO 1040
3960 PRINT "THERE IS NOTHING TO DO IT TO!"
3970 GOTO 1040
3980 PRINT "YOU CAN'T DO IT FROM HERE!"
3990 GOTO 1040
4000 REM **
4010 REM ** FUEL ROCKET
4030 IF P < >19 THEN 3980
4040 IF O(9) < >99 THEN 3940
4050 O(9) = 98
4060 PRINT "FUEL IS NOW LOADED."
4070 GOTO 1040
4080 REM **
4090 REM ** BLASTOFF
4110 IF P < >21 THEN 3980
4120 IF O(9) < >98 THEN 4200
4130 IF F7 = 1 THEN 4160
4140 PRINT "REPAIRS NOT YET COMPLETE."
4150 GOTO 1040
4160 PRINT "CONGRATULATIONS. YOU HAVE JUST BLASTED"
4170 PRINT "OFF AND ARE ON YOUR WAY TO EARTH."
4180 PRINT "YOUR ESCAPE TIME: ";T1;" MINUTES."
4190 GOTO 2990
4200 PRINT "YOUR SPACE CRAFT HAS NO FUEL!"
4210 GOTO 1040
4220 REM **
4230 REM ** COMPUTER READOUT
4250 IF P < >35 THEN 3980
4260 GOSUB 4590
4270 IF I < >10 THEN 3960
4280 IF V < >0 THEN 4320
4290 PRINT "BOMB DE-ACTIVATOR LOCATED SOMEWHERE EAST"
4300 PRINT "OF SPACE STATION, ON MOON'S SURFACE."
4310 GOTO 4360
4320 IF V < >1 THEN 4350
4330 PRINT "LOCAL FUEL SOURCE: DILITHIUM CRYSTAL."
4340 GOTO 4360
4350 PRINT "DILITHIUM FOUND IN SOFT SURFACES."
4360 IF F7 = 1 THEN PRINT "SPACECRAFT REPAIRS COMPLETED."
4370 GOTO 1040
4380 REM **
4390 REM ** SUBROUTINE TO DESCRIBE ITEMS AT LOCATION
4410 IF I = 1 THEN B$ = "AN ELECTRONIC KEY"
4420 IF I = 2 THEN B$ = "SEALANT"
4430 IF I = 3 THEN B$ = "AN OXYGEN MODULE"
4440 IF I = 4 THEN B$ = "AN ILLUMINATOR"
4450 IF I = 5 THEN B$ = "A ROBOT"
4460 IF I = 6 THEN B$ = "A DEACTIVATOR"
4470 IF I = 7 THEN B$ = "A NUCLEAR BOMB"
4480 IF I = 8 THEN B$ = "A TRANSPORTER UNIT"
4490 IF I = 9 THEN B$ = "DILITHIUM CRYSTALS"
4500 IF I = 10 THEN B$ = "A COMPUTER MESSAGE"
4510 IF I = 11 THEN B$ = "A POWER UNIT"
4520 IF I = 12 THEN B$ = "A MIRROR"
4530 IF I = 13 THEN B$ = "A CODED BADGE"
4540 IF I = 14 THEN B$ = "A POWER PACK"
4550 RETURN
4560 REM **
4570 REM ** SUBROUTINE TO CONVERT AN ITEM TO A NUMERIC VALUE
4590 FOR J = 1 TO LEN(B$)
4600 IF MID$ (B$,J,1) = " " THEN 4640
4610 NEXT J
4620 I = -1
4630 RETURN
4640 C$ = MID$ (B$,J +1,3)
4650 I = 0
4660 IF C$ = "ELE" THEN I = 1
4670 IF C$ = "KEY" THEN I = 1
4680 IF C$ = "SEA" THEN I = 2
4690 IF C$ = "OXY" THEN I = 3
4700 IF C$ = "MOD" THEN I = 3
4710 IF C$ = "ILL" THEN I = 4
4720 IF C$ = "ROB" THEN I = 5
4730 IF C$ = "DEA" THEN I = 6
4740 IF C$ = "NUC" THEN I = 7
4750 IF C$ = "BOM" THEN I = 7
4760 IF C$ = "TRA" THEN I = 8
4770 IF C$ = "DIL" THEN I = 9
4780 IF C$ = "CRY" THEN I = 9
4790 IF C$ = "COM" THEN I = 10
4800 IF C$ = "MES" THEN I = 10
4810 IF C$ = "UNI" THEN I = 11
4820 IF C$ = "MIR" THEN I = 12
4830 IF C$ = "BAD" THEN I = 13
4840 IF C$ = "PAC" THEN I = 14
4850 RETURN
4860 REM **
4870 REM ** SUBROUTINE TRY COMMAND
4890 INPUT B$
4900 C$ = LEFT$(B$,3)
4910 IF C$ = "TRY" THEN 4950
4920 IF C$ = "USE" THEN 4950
4930 I = -1
4940 RETURN
4950 GOSUB 4590
4960 IF I <1 THEN 5050
4970 IF O(I) = 99 THEN RETURN
4980 PRINT "YOU DON'T HAVE "; RIGHT$(B$, LEN(B$) -J);"!"
4990 GOTO 4930
5000 PRINT "YOUR ATTEMPT FAILS"
5010 GOTO 4930
5020 REM **
5030 REM ** INSTUCTIONS
5050 PRINT "YOU HAVE CRASH LANDED ON THE "
5060 PRINT "EARTH'S MOON. YOU HAVE LIMITED"
5070 PRINT "SUPPLIES AND TIME IN WHICH TO "
5080 PRINT "SURVIVE. TO TRAVEL, YOU MAY "
5090 PRINT "ENTER DIRECTIVES SUCH AS NORTH"
5100 PRINT "OR N, AS WELL AS S, E, W, AND "
5110 PRINT "U, AND D (UP AND DOWN). YOU "
5120 PRINT "WILL ENCOUNTER VARIOUS ITEMS "
5130 PRINT "AND SITUATIONS DURING YOUR "
5140 PRINT "TRAVELS. TO COMMUNICATE, ENTER"
5150 PRINT "COMMANDS (VERBS), FOLLOWED BY "
5160 PRINT "OBJECT NAMES, IF APPLICABLE. "
5170 PRINT "FOR EXAMPLE, GET XXX, LEAVE, "
5180 PRINT "USE, AND INVENTORY."
5190 PRINT
5200 PRINT "ONCE YOU HAVE SURVIVED, THE "
5210 PRINT "OBJECT THEN IS TO ACHIEVE THE "
5220 PRINT "OPTIMUM SURVIVAL TIME."
5230 PRINT "GOOD LUCK!!"
5240 RETURN
5250 REM **
5260 REM ** LOCATION DESCRIPTIONS
5280 DATA "AT MARE SERENITATIS."
5290 DATA "ON RIM OF POSIDONIUS."
5300 DATA "TOTAL DARKNESS TO EAST."
5310 DATA "TWIXT DAWES AND PLINIUS."
5320 DATA "AT PASS IN HAEMUS MINS."
5330 DATA "AT CRATER MANILUS."
5340 DATA "AT MARE VAPORUM."
5350 DATA "AT MT. EUDOXUS."
5360 DATA "INSIDE ARISTOTELES."
5370 DATA "IN CHANGING AREA."
5380 DATA "IN LACUS SOMNIORUM."
5390 DATA "IN LACUS MORTIS"
5400 DATA "THE SURFACE IS VERY SOFT HERE."
5410 DATA "AT EAST SIDE OF MARE IMBRIUM."
5420 DATA "AT THE BASE OF PLATO CRATER."
5430 DATA "A SHINY OBJECT IS SEEN WEST."
5440 DATA "BEFORE A METAL SHED."
5450 DATA "A SIGN READS VENT. SHAFT #2."
5460 DATA "EAST OF MARE SERENITATIS."
5470 DATA "THERE IS TOTAL DARKNESS."
5480 DATA "AT CRASH SITE OF A SPACE CRAFT."
5490 DATA "THE SHIP ENTRANCE IS BEFORE YOU."
5500 DATA "AT THE CENTER OF MARE IMBRIUM."
5510 DATA "IN THE AIR LOCK CHAMBER OF THE SHIP."
5520 DATA "IN THE AFT CARGO AND FUEL STORGE ROOM."
5530 DATA "IN THE ENGINE ROOM OF THE SPACECRAFT."
5540 DATA "IN THE SHIP'S CONTROL ROOM."
5550 DATA "IN AN AIR LOCK CHAMBER."
5560 DATA "INSIDE A VENTILLATOR SHED A LADDER"
5570 DATA "LEADS DOWN INTO A LARGE METAL SHAFT."
5580 DATA "IN A VENTILLATOR PASSAGE."
5590 DATA "IN A VENTILLATOR OPENING."
5600 DATA "THROUGH THE OPENING A LIT PASSAGEWAY CAN BE SEEN."
5610 DATA "IN A LIGHTED SPACE STATION CORRIDOR."
5620 DATA "IN THE SPACE STATION INFIRMARY."
5630 DATA "IN THE RECREATION ROOM AND LIBRARY."
5640 DATA "IN THE MESS HALL."
5650 DATA "ABANDONED FOOD TRAYS ARE STILL ON THE TABLES."
5660 DATA "IN THE STORAGE ROOM AND SUPPLY AREA."
5670 DATA "IN THE SLEEPING QUARTERS."
5680 DATA "IN AN ELEVATOR AT SUBSURFACE LEVEL."
5690 DATA "IN AN ELEVATOR AT SURFACE LEVEL."
5700 DATA "IN THE STATION CONTROL CENTER."
5710 DATA "IN THE TRANSPORTER ROOM."
5720 DATA "IN THE SPACE STATION LABORATORY."
5730 DATA "IN THE HANGER AREA."
5740 DATA "THE LAUNCH AREA IS JUST SOUTH OF HERE."
5750 REM **
5760 REM ** MOVEMENT AND TEXT POINTER MATRIX
5780 DATA 07,04,02,15,00,00,01,01
5790 DATA 09,03,14,01,00,00,02,03
5800 DATA 02,05,14,04,00,00,04,04
5810 DATA 01,05,03,00,00,00,05,05
5820 DATA 04,00,03,06,00,00,06,06
5830 DATA 00,00,05,00,00,00,07,07
5840 DATA 08,01,09,11,00,00,08,08
5850 DATA 00,07,10,00,00,00,09,09
5860 DATA 10,02,14,07,00,00,11,11
5870 DATA 00,09,14,08,00,00,12,13
5880 DATA 12,15,07,16,00,00,14,14
5890 DATA 00,11,00,13,00,00,15,16
5900 DATA 00,16,12,22,00,00,17,18
5910 DATA 99,99,99,99,00,00,19,20
5920 DATA 11,18,01,00,00,00,21,22
5930 DATA 17,16,07,16,00,00,23,23
5940 DATA 16,17,11,17,00,00,23,23
5950 DATA 15,19,00,00,00,00,24,24
5960 DATA 18,00,20,00,00,00,25,25
5970 DATA 00,00,00,19,21,00,26,26
5980 DATA 00,00,00,00,00,20,27,27
5990 DATA 00,00,13,00,00,23,29,30
6000 DATA 24,00,00,00,22,00,31,31
6010 DATA 25,23,00,00,00,00,32,33
6020 DATA 27,26,33,32,24,00,34,34
6030 DATA 25,00,30,31,00,00,34,34
6040 DATA 34,25,41,00,00,00,34,34
6050 DATA 00,29,42,36,00,00,34,34
6060 DATA 28,38,40,37,00,00,34,34
6070 DATA 00,00,00,26,00,00,35,35
6080 DATA 00,00,26,00,00,00,36,36
6090 DATA 00,00,25,00,00,00,37,38
6100 DATA 00,00,00,25,00,00,40,40
6110 DATA 00,27,00,00,00,00,39,39
6120 DATA 00,28,00,00,24,00,43,43
6130 DATA 00,00,28,00,00,00,44,44
6140 DATA 00,00,29,00,00,00,45,45
6150 DATA 29,00,39,00,00,00,46,47
6160 DATA 40,00,00,38,00,00,28,28
6170 DATA 00,39,00,29,00,00,10,10
6180 DATA 00,00,00,27,42,00,41,41
6190 DATA 00,00,00,28,00,41,42,42
6195 DATA 00,00,00,00,00,00,00,00
6200 PRINT "BETTER LUCK NEXT TIME!": FOR M = 1 TO 2000: NEXT M: PR# 6

Text found in RIC_Programs_20.dsk/SEX ROLE.int:

0 DIM DAVE$(10)
20 POKE 2,173: POKE 3,48: POKE 4,192: POKE 5,136: POKE 6,208: POKE 7,4: POKE 8,198: POKE 9,1: POKE 10,240
30 POKE 11,8: POKE 12,202: POKE 13,208: POKE 14,246: POKE 15,166: POKE 16,0: POKE 17,76: POKE 18,2: POKE 19,0: POKE 20,96
50 DIM Q$(100),A$(150),N$(30)
60 CALL -936:VTAB 8
65 TAB (16): POKE 50,127:PRINT "SEX";:TAB (20):PRINT "ROLE": POKE 50,255:PRINT :PRINT
70 TAB (14):PRINT "COPYRIGHT BY"
75 PRINT :TAB (11):PRINT "CREATIVE COMPUTING"
80 TAB (13):PRINT "P.O. BOX 789-M"
85 TAB (6):PRINT "MORRISTOWN, NEW JERSEY 07960"
90 FOR I=1 TO 2000:NEXT I
100 CALL -936
110 A$="HELLO, WHAT IS YOUR FIRST NAME?":PRINT :GOSUB 31000:INPUT N$
120 IF LEN(N$)=0 THEN N$="ANONYMOUS PERSON"
130 CALL -936:PRINT :A$="HELLO ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT ",":PRINT
133 A$="DO YOU NEED INSTRUCTIONS?":GOSUB 31000:INPUT A$:IF A$(1,1)="N" THEN 1000
134 IF A$(1,1)="Y" THEN 137
135 A$="ANSWER YES OR NO PLEASE.":GOSUB 31000:PRINT :PRINT :GOTO 133
137 CALL -936:PRINT :PRINT
140 A$="MY NAME IS TERRY. FROM MY NAME YOU":GOSUB 31000:PRINT :PRINT
150 A$="CANNOT TELL WHETHER I AM MALE OR":GOSUB 31000:PRINT :PRINT
160 A$="FEMALE. THAT'S BECAUSE I AM":GOSUB 31000:PRINT :PRINT
170 A$="ANDROGYNOUS.":GOSUB 31000:PRINT :PRINT :PRINT
180 A$="DO YOU KNOW WHAT THE WORD ANDROGYNOUS":GOSUB 31000:PRINT :PRINT :A$="MEANS?":GOSUB 31000
190 INPUT A$:CALL -936:IF A$(1,1)="Y" THEN 250
193 IF A$(1,1)="N" THEN 200
195 A$="PLEASE ANSWER YES OR NO.":GOSUB 31000:PRINT :PRINT :GOTO 180
200 PRINT :PRINT :A$="WELL ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT ",":PRINT :PRINT
210 A$="IT TURNS OUT THAT NOT MANY PEOPLE":GOSUB 31000:PRINT :PRINT
220 A$="KNOW THE WORD.":GOSUB 31000:PRINT :PRINT
230 GOTO 270
250 PRINT :PRINT :A$="VERY GOOD ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT ",":PRINT :PRINT
260 A$="THE WORD ANDROGYNY ISN'T COMMONLY USED.":GOSUB 31000:PRINT :PRINT
270 A$="THE WORD ANDROGYNY COMES FROM THE":GOSUB 31000:PRINT :PRINT
280 A$="ROOTS ANDRO (MALE) AND GYNE (FEMALE).":GOSUB 31000:PRINT :PRINT
290 A$="TRADITIONALLY, CERTAIN PERSONALITY":GOSUB 31000:PRINT :PRINT
300 A$="CHARACTERISTICS HAVE BEEN CLASSIFIED":GOSUB 31000:PRINT :PRINT
310 A$="AS EITHER MASCULINE OR FEMININE.":GOSUB 31000:PRINT :PRINT :PRINT
320 PRINT "HIT ANY KEY TO CONTINUE."
330 X= PEEK (-16384)
340 IF X<128 THEN 330
350 POKE -16368,0
360 CALL -936
370 PRINT :PRINT :A$="EXAMPLES OF TRADITIONALLY MALE":GOSUB 31000:PRINT
380 A$="CHARACTERISTICS INCLUDE:":GOSUB 31000:PRINT :PRINT
390 A$=" -ASSERTIVENESS":GOSUB 31000:PRINT :PRINT
400 A$=" -SELF-RELIANCE":GOSUB 31000:PRINT :PRINT
410 A$=" -AMBITION":GOSUB 31000:PRINT :PRINT :PRINT
420 A$="SOME OF THE TRADITIONALLY FEMININE":GOSUB 31000:PRINT
430 A$="CHARACTERISTICS INCLUDE:":GOSUB 31000:PRINT :PRINT
440 A$=" -UNDERSTANDING":GOSUB 31000:PRINT :PRINT
450 A$=" -GENTLENESS":GOSUB 31000:PRINT :PRINT
460 A$=" -SENSITIVITY":GOSUB 31000:PRINT :PRINT :PRINT
470 PRINT "HIT ANY KEY"
472 X= PEEK (-16384):IF X<128 THEN 472
475 POKE -16368,0
480 CALL -936:PRINT :A$="WE SHOULD ALL REALIZE THAT THESE":GOSUB 31000:PRINT :PRINT
490 A$="ARE STEREOTYPES, AND NOT NECESSARILY":GOSUB 31000:PRINT :PRINT
500 A$="ANYTHING MORE. THERE IS NOTHING":GOSUB 31000:PRINT :PRINT
510 A$="THAT IS ESPECIALLY FEMININE ABOUT":GOSUB 31000:PRINT :PRINT
520 A$="SENSITIVITY. BOTH MEN AND WOMEN":GOSUB 31000:PRINT :PRINT
530 A$="SHOULD BE SENSITIVE TO THE NEEDS":GOSUB 31000:PRINT :PRINT
540 A$="OF OTHER PEOPLE.":GOSUB 31000:PRINT :PRINT :PRINT
550 PRINT "HIT ANY KEY"
560 X= PEEK (-16384):IF X<128 THEN 560
570 POKE -16368,0
580 CALL -936:PRINT
590 A$="IN ANY CASE, ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT ",":PRINT :PRINT
600 A$="THIS IS WHY THE PHRASE 'ANDROGYNOUS":GOSUB 31000:PRINT :PRINT
610 A$="PERSONALITY' HAS BECOME MORE READILY":GOSUB 31000:PRINT :PRINT
620 A$="ACCEPTED TODAY. WE ARE BEGINNING":GOSUB 31000:PRINT :PRINT
630 A$="TO BREAK THROUGH SOME OF THE CRUST":GOSUB 31000:PRINT :PRINT
640 A$="THAT HAS CLOUDED THE ISSUE OF SEX":GOSUB 31000:PRINT :PRINT
650 A$="ROLES FOR SO LONG.":GOSUB 31000:PRINT :PRINT :PRINT
660 PRINT "HIT ANY KEY"
670 X= PEEK (-16384):IF X<128 THEN 670
680 POKE -16368,0:CALL -936:PRINT
690 A$="MANY PEOPLE ARE JUST NOW BEGINNING TO":GOSUB 31000:PRINT :PRINT
700 A$="REALIZE THAT EACH OF US SHOULD HAVE":GOSUB 31000:PRINT :PRINT
710 A$="BOTH MALE AND FEMALE CHARACTERISTICS":GOSUB 31000:PRINT :PRINT
720 A$="TO SOME DEGREE.":GOSUB 31000:PRINT :PRINT :PRINT
730 A$="WHAT WE HAVE DONE HERE IS TO PUT":GOSUB 31000:PRINT :PRINT
740 A$="TOGETHER A LITTLE EXERCISE SO THAT":GOSUB 31000:PRINT :PRINT
750 A$="YOU CAN SEE WHERE YOU STAND ON":GOSUB 31000:PRINT :PRINT
760 A$="TRADITIONAL SEX ROLE CHARACTERISTICS.":GOSUB 31000:PRINT :PRINT
770 A$="DO YOU WANT TO PLAY?":GOSUB 31000:INPUT A$:IF A$(1,1)="Y" THEN 850
775 IF A$(1,1)="N" THEN 780
777 A$="PLEASE ANSWER YES OR NO.":GOSUB 31000:PRINT :PRINT :GOTO 770
780 CALL -936:PRINT
790 A$="ARE YOU SURE?":GOSUB 31000:INPUT A$:IF A$(1,1)="N" THEN 850
795 IF A$(1,1)="Y" THEN 800
797 A$="ANSWER YES OR NO PLEASE.":GOSUB 31000:PRINT :PRINT :GOTO 790
800 CALL -936:PRINT "SORRY YOU FEEL THAT WAY":PR # 6
810 GOTO 1960
850 CALL -936:PRINT
855 A$="I'M GLAD YOU WANT TO PLAY, AND":GOSUB 31000:PRINT :PRINT
860 A$="I THINK YOU WILL HAVE FUN. FIRST":GOSUB 31000:PRINT :PRINT
870 A$="OF ALL, YOU SHOULD UNDERSTAND":GOSUB 31000:PRINT :PRINT
875 A$="THAT THIS IS ONLY A GAME AND THAT":GOSUB 31000:PRINT :PRINT
880 A$="YOU SHOULD NOT TAKE IT TOO SERIOUSLY.":GOSUB 31000:PRINT :PRINT
885 A$="YOU CANNOT PASS OR FAIL THIS TEST.":GOSUB 31000:PRINT :PRINT :PRINT
890 PRINT "HIT ANY KEY."
895 X= PEEK (-16384):IF X<128 THEN 895
897 POKE -16368,0
900 CALL -936:PRINT
905 A$="THE TEST CONSISTS OF 20 MULTIPLE":GOSUB 31000:PRINT :PRINT
910 A$="CHOICE QUESTIONS. HERE IS":GOSUB 31000:PRINT :PRINT
915 A$="A SAMPLE QUESTION:":GOSUB 31000:PRINT :PRINT
920 FOR I=1 TO 1000:NEXT I
925 Q$="HOW OFTEN ARE YOU AGGRESSIVE":GOSUB 30000
930 FOR I=1 TO 1000:NEXT I
935 A$="YOU ANSWER BY TYPING THE FIRST LETTER":GOSUB 31000:PRINT
940 A$="OF THE MOST APPROPRIATE RESPONSE.":GOSUB 31000:PRINT :PRINT "HIT ANY KEY."
955 X= PEEK (-16384):IF X<128 THEN 955
957 POKE -16368,0
960 CALL -936:PRINT
965 A$="DO NOT USE THE RETURN KEY. SIMPLY":GOSUB 31000:PRINT :PRINT
970 A$="TYPE THE KEY OF THE LETTER.":GOSUB 31000:PRINT :PRINT :PRINT
975 A$="FOR EXAMPLE, IF YOUR RESPONSE TO":GOSUB 31000:PRINT :PRINT
977 A$="THE SAMPLE QUESTION WAS 'SOMETIMES',":GOSUB 31000:PRINT :PRINT
980 A$="THEN TYPE 'S'.":GOSUB 31000:PRINT :PRINT :PRINT
983 A$="USE ONLY THE LETTERS U,S,Q,A OR D.":GOSUB 31000:PRINT :PRINT
985 A$="AFTER 20 QUESTIONS, I'LL TELL HOW":GOSUB 31000:PRINT :PRINT
988 A$="YOU DID.":GOSUB 31000:PRINT :PRINT :PRINT "HIT ANY KEY TO BEGIN."
990 X= PEEK (-16384):IF X<128 THEN 990
995 POKE -16368,0
1000 M=0:F=0
1005 PRINT :PRINT :PRINT
1010 Q$="HOW OFTEN ARE YOU AGGRESSIVE?"
1020 N=1:GOSUB 30000:GOSUB 10000:M=M+AV
1030 Q$="HOW OFTEN ARE YOU AMBITIOUS?"
1040 N=2:GOSUB 30000:GOSUB 10000:M=M+AV
1050 Q$="HOW OFTEN ARE YOU ASSERTIVE?"
1060 N=3:GOSUB 30000:GOSUB 10000:M=M+AV
1070 Q$="HOW ATHLETIC ARE YOU?"
1080 N=4:GOSUB 30000:GOSUB 10000:M=M+AV
1090 Q$="HOW AFFECTIONATE ARE YOU?"
1100 N=5:GOSUB 30000:GOSUB 10000:F=F+AV
1110 A$="ISN'T THIS SCIENTIFIC LOOKING?"
1120 GOSUB 15000
1130 Q$="HOW COMPETITIVE ARE YOU?"
1140 N=6:GOSUB 30000:GOSUB 10000:M=M+AV
1150 Q$="HOW COMPASSIONATE ARE YOU?"
1160 N=7:GOSUB 30000:GOSUB 10000:F=F+AV
1170 Q$="HOW GENTLE ARE YOU?"
1180 N=8:GOSUB 30000:GOSUB 10000:F=F+AV
1190 Q$="HOW LOVING TOWARD CHILDREN ARE YOU?"
1200 N=9:GOSUB 30000:GOSUB 10000:F=F+AV
1210 Q$="HOW DOMINANT ARE YOU?"
1220 N=10:GOSUB 30000:GOSUB 10000:M=M+AV
1230 A$="AREN'T COMPUTERS FUN?"
1240 GOSUB 15000
1250 Q$="HOW LOYAL ARE YOU?"
1260 N=11:GOSUB 30000:GOSUB 10000:F=F+AV
1270 Q$="HOW SENSITIVE TO OTHERS ARE YOU?"
1280 N=12:GOSUB 30000:GOSUB 10000:F=F+AV
1290 Q$="HOW FORCEFUL ARE YOU?"
1300 N=13:GOSUB 30000:GOSUB 10000:M=M+AV
1310 Q$="HOW INDEPENDENT ARE YOU?"
1320 N=14:GOSUB 30000:GOSUB 10000:M=M+AV
1330 Q$="HOW SYMPATHETIC ARE YOU?"
1340 N=15:GOSUB 30000:GOSUB 10000:F=F+AV
1350 A$="PHI=SIN(OMEGA)**2+2*SQRT(... OOPS! EXCUSE ME. WRONG PROGRAM."
1360 GOSUB 15000
1370 Q$="HOW UNDERSTANDING ARE YOU?"
1380 N=16:GOSUB 30000:GOSUB 10000:F=F+AV
1390 Q$="HOW WARM ARE YOU?"
1400 N=17:GOSUB 30000:GOSUB 10000:F=F+AV
1410 Q$="HOW SELF-RELIANT ARE YOU?"
1420 N=18:GOSUB 30000:GOSUB 10000:M=M+AV
1430 Q$="HOW TENDER ARE YOU?"
1440 N=19:GOSUB 30000:GOSUB 10000:F=F+AV
1450 Q$="HOW WILLING ARE YOU TO TAKE A STAND?"
1460 N=20:GOSUB 30000:GOSUB 10000:M=M+AV
1470 A$="OK, THAT'S IT. GIVE ME A MOMENT TO ADD THINGS UP."
1480 GOSUB 15000
1490 PRINT :A$="WELL ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT ",":PRINT
1500 A$="NOW THAT YOU HAVE ANSWERED THE":GOSUB 31000:PRINT :PRINT
1510 A$="QUESTIONS, I WILL TRY TO EXPLAIN":GOSUB 31000:PRINT :PRINT
1520 A$="HOW YOU DID. EACH OF THE ANSWERS":GOSUB 31000:PRINT :PRINT
1530 A$="HAD A POINT VALUE ASSIGNED TO IT":GOSUB 31000:PRINT :PRINT
1540 A$="AS FOLLOWS:":GOSUB 31000:PRINT :PRINT
1550 A$=" USUALLY NOT 1 POINT":GOSUB 31000:PRINT
1560 A$=" SOMETIMES 2 POINTS":GOSUB 31000:PRINT
1570 A$=" QUITE OFTEN 3 POINTS":GOSUB 31000:PRINT
1580 A$=" ALMOST ALWAYS 4 POINTS":GOSUB 31000:PRINT
1590 A$=" DON'T KNOW 0 POINTS":GOSUB 31000:PRINT :PRINT :PRINT "HIT ANY KEY."
1595 X= PEEK (-16384):IF X<128 THEN 1595
1597 POKE -16368,0
1600 CALL -936:PRINT
1610 A$="EACH QUESTION HAD A KEY WORD THAT":GOSUB 31000:PRINT :PRINT
1620 A$="HAS TRADITIONALLY BEEN CALLED":GOSUB 31000:PRINT :PRINT
1630 A$="EITHER MASCULINE OR FEMININE.":GOSUB 31000:PRINT :PRINT
1640 A$="BASED ON YOUR ANSWERS, YOUR POINTS":GOSUB 31000:PRINT :PRINT
1650 A$="WERE SCORED FOR BOTH MALE AND":GOSUB 31000:PRINT :PRINT
1660 A$="FEMALE CHARACTERISTICS.":GOSUB 31000:PRINT :PRINT :PRINT "HIT ANY KEY."
1670 X= PEEK (-16384):IF X<128 THEN 1670
1680 POKE -16368,0
1690 CALL -936:PRINT
1700 A$="IN YOUR CASE, ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT :PRINT
1710 X=ABS (M-F)
1720 IF X>10 THEN 1800
1730 A$="THE DIFFERENCE BETWEEN THE SCORES":GOSUB 31000:PRINT :PRINT
1735 A$="ON THE TWO SETS OF CHARACTERISTICS":GOSUB 31000:PRINT :PRINT
1740 A$="IS LESS THAN TEN. THIS INDICATES":GOSUB 31000:PRINT :PRINT
1745 A$="YOU HAVE AN ANDROGYNOUS PERSONALITY.":GOSUB 31000:PRINT :PRINT
1750 A$="THIS MEANS THAT YOU HAVE A FULLER":GOSUB 31000:PRINT :PRINT
1760 A$="RANGE OF CHARACTERISTICS AVAILABLE":GOSUB 31000:PRINT :PRINT
1770 A$="TO YOU TO MEET ALL SITUATIONS.":GOSUB 31000:PRINT :PRINT
1775 A$="CONGRATULATIONS!":GOSUB 31000:PRINT :PRINT :PRINT "HIT ANY KEY."
1780 X= PEEK (-16384):IF X<128 THEN 1780
1785 POKE -16368,0
1790 GOTO 1860
1800 IF F>M THEN 1840
1810 A$="YOUR RESPONSES INDICATE SLIGHTLY":GOSUB 31000:PRINT :PRINT
1820 A$="MORE EVIDENCE OF TRADITIONALLY MALE":GOSUB 31000:PRINT :PRINT
1825 A$="CHARACTERISTICS THAN FEMALE.":GOSUB 31000:PRINT :PRINT
1830 PRINT "HIT ANY KEY."
1835 X= PEEK (-16384):IF X<128 THEN 1835
1837 POKE -16368,0:GOTO 1860
1840 A$="YOUR RESPONSES INDICATE SLIGHTLY":GOSUB 31000:PRINT :PRINT
1845 A$="MORE EVIDENCE OF TRADITIONALLY FEMALE":GOSUB 31000:PRINT :PRINT
1850 A$="CHARACTERISTICS THAN MALE.":GOSUB 31000:PRINT :PRINT
1855 PRINT "HIT ANY KEY."
1857 X= PEEK (-16384):IF X<128 THEN 1857
1859 POKE -16368,0
1860 CALL -936:PRINT
1865 A$="WHATEVER THE RESULTS, ":GOSUB 31000:A$=N$:GOSUB 31000:PRINT ",":PRINT
1870 A$="YOU SHOULD REALIZE THAT STEREOTYPED":GOSUB 31000:PRINT :PRINT
1875 A$="CHARACTERISTICS REALLY HAVE VERY":GOSUB 31000:PRINT :PRINT
1880 A$="LITTLE MEANING TODAY. BOTH MEN AND":GOSUB 31000:PRINT :PRINT
1885 A$="WOMEN SHOULD SOMETIMES BE COMPETITIVE,":GOSUB 31000:PRINT :PRINT
1890 A$="ASSERTIVE AND SENSITIVE. IN VIEW":GOSUB 31000:PRINT :PRINT
1895 A$="OF THIS, YOU SHOULD ALSO REALIZE":GOSUB 31000:PRINT :PRINT
1900 A$="THAT BEING TYPED AS EITHER MASCULINE":GOSUB 31000:PRINT :PRINT
1905 A$="OR FEMIMINE BASED ON THESE":GOSUB 31000:PRINT :PRINT
1910 A$="TRAITS ALSO HAS VERY LITTLE MEANING.":GOSUB 31000:PRINT :PRINT
1915 PRINT "HIT ANY KEY."
1920 X= PEEK (-16384):IF X<128 THEN 1920
1925 POKE -16368,0
1930 CALL -936:PRINT
1935 A$="IN ANY CASE, I HOPE YOU HAD FUN.":GOSUB 31000:PRINT :PRINT
1940 FOR EASY=1 TO 2500:NEXT EASY
1945 TEXT :CALL -936:VTAB 9:TAB 6:PRINT "WOULD YOU LIKE ANOTHER RUN ";
1946 INPUT DAVE$:IF DAVE$="Y" OR DAVE$="YES" THEN PRINT "RUN SEX ROLE"
1965 PR # 6
10000 X= PEEK (-16384)
10010 IF X<128 THEN 10000
10020 POKE -16368,0
10030 IF X=196 THEN 10100
10040 IF X=213 THEN 10110
10050 IF X=211 THEN 10120
10060 IF X=209 THEN 10130
10070 IF X=193 THEN 10140
10080 POKE 0,200: POKE 1,255:CALL 2
10090 POKE 0,255: POKE 0,255:CALL 2
10091 PRINT "PLEASE ANSWER U,S,Q,A OR D":FOR I=1 TO 2000:NEXT I:GOSUB 30000
10095 GOTO 10000
10100 AV=0:GOSUB 20000:RETURN
10110 AV=1:GOSUB 20000:RETURN
10120 AV=2:GOSUB 20000:RETURN
10130 AV=3:GOSUB 20000:RETURN
10140 AV=4:GOSUB 20000:RETURN
15000 REM GRAPHIC TIME WASTER
15010 GR
15020 FOR I=0 TO 39
15030 J= RND (40)
15040 COLOR= RND (16)
15050 VLIN J,39 AT I
15060 POKE 0, RND (256): POKE 1,30:CALL 2
15070 NEXT I
15080 PRINT :PRINT A$
15090 FOR I=1 TO 2000:NEXT I
15095 TEXT :CALL -936
15100 RETURN
20000 FOR I=250 TO 10 STEP -20
20010 POKE 0,I: POKE 1,30:CALL 2
20020 POKE 0,I-10: POKE 1,30:CALL 2
20025 NEXT I
20030 RETURN
30000 REM PRINTS QUESTIONS
30010 CALL -936
30020 VTAB 2:PRINT "---------------------------------------"
30030 PRINT :PRINT "SEX ROLE TEST QUESTION # ";N
30040 PRINT :PRINT "---------------------------------------"
30045 PRINT
30050 PRINT :PRINT Q$
30055 PRINT
30060 PRINT :PRINT " (U)SUALLY NOT"
30070 PRINT " (S)OMETIMES"
30080 PRINT " (Q)UITE OFTEN"
30090 PRINT " (A)LMOST ALWAYS"
30100 PRINT " (D)ON'T KNOW"
30110 PRINT :PRINT "---------------------------------------"
30120 PRINT :PRINT :RETURN
31000 REM SLO-PRINT SUB
31010 FOR I=1 TO LEN(A$)
31020 PRINT A$(I,I);
31030 IF I#(I/5)*5 THEN 31040
31035 POKE 0, RND (255): POKE 1,30:CALL 2
31040 NEXT I
31045 POKE 0, RND (255): POKE 1,30:CALL 2
31050 RETURN