Notes

Disk info for 015_Disk_Catalog_Programs.dsk:

File Name: riag_010_015_Disk_Catalog_Programs/015_Disk_Catalog_Programs.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 41984
Used Space (bytes): 101376
Physical Size (KB): 140
Free Space (KB): 41
Used Space (KB): 99
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 164
Used Sectors: 396
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for 015_Disk_Catalog_Programs.dsk:

riag_010_015_Disk_Catalog_Programs/015_Disk_Catalog_Programs.dsk DISK VOLUME #254
* A 008 APPLE GROUP -- N.J.
* A 017 LIBRARY REVIEW
* B 000 LIBRARY REVIEW.OBJ
* A 011 LIBRARY REVIEW INSTRUCTIONS
* A 018 LIB. REV. 3 COL PRINTER
* A 013 LIB.REV 4 COL PRINTER
* I 017 DISK CAT FOR LIB.REVIEW
* A 004 CORRECTOR
* T 097 CLUB (36-69)
* T 086 CLUB (1-35)
T 021 DISKFILE.AS
* B 006 B.MASTER.CATALOG 48K
* B 006 MC HEADER
* A 022 MASTER CATALOG
DOS 3.3 format; 41,984 bytes free; 101,376 bytes used.

Text found in 015_Disk_Catalog_Programs.dsk/APPLE GROUP -- N.J..bas:

5 POKE 770,173: POKE 771,48: POKE 772,192: POKE 773,136: POKE 774,208: POKE 775,4: POKE 776,198: POKE 777,7: POKE 778,240
10 POKE 779,8: POKE 780,202: POKE 781,208: POKE 782,246: POKE 783,166: POKE 784,6: POKE 785,76: POKE 786,2: POKE 787,3: POKE 788,96
15 TEXT : CALL -936: GR
20 COLOR= 12: VLIN 1,4 AT 24: VLIN 2,7 AT 23: VLIN 3,8 AT 22: VLIN 4,9 AT 21: VLIN 6,10 AT 20
25 HLIN 13,16 AT 10: HLIN 24,27 AT 10: HLIN 12,18 AT 11: HLIN 22,28 AT 11: HLIN 11,29 AT 12: HLIN 11,29 AT 13
30 COLOR= 13: FOR I = 14 TO 17: HLIN 10,30 AT I: NEXT
35 FOR I = 18 TO 25: IF I = 19 THEN COLOR= 9
40 IF I = 24 THEN COLOR= 1
45 HLIN 9,31 AT I: NEXT
50 FOR I = 26 TO 30: IF I = 29 THEN COLOR= 3
55 HLIN 10,30 AT I: NEXT
60 FOR I = 31 TO 33: HLIN 11,29 AT I: NEXT
65 COLOR= 2: FOR I = 34 TO 36: HLIN 12,28 AT I: NEXT
70 HLIN 13,27 AT 37: HLIN 14,19 AT 38: HLIN 21,26 AT 38: HLIN 15,18 AT 39: HLIN 22,25 AT 39
75 S = 200:T = 255:F = 2: GOSUB 245
135 VTAB 21: HTAB 14: PRINT "APPLE GROUP-N.J."
140 VTAB 22: HTAB 13: PRINT "MEMBER OF ACG-N.J."
145 FOR J = 1 TO 1500: NEXT J
150 TEXT : CALL -936: VTAB 3
155 PRINT " ** APPLE GROUP -- N.J. ** DOS 3.3 **": PRINT : PRINT
156 PRINT : PRINT "C/O ACGNJ": PRINT "1776 RARITAN ROAD": PRINT "SCOTCH PLAINS,N.J. 07076"
157 PRINT : HTAB 15: PRINT "-LIBRARIAN-": PRINT
158 PRINT "BILL KERR"
159 PRINT "20 MEADOWBROOK DR": PRINT "SOMERVILLE, N.J. 08876 (201) 359 8821"
160 PRINT : PRINT "PLEASE ADVISE OF ANY DIFFICULTIES IN RUNNING THE PROGRAMS LISTED. THANK YOU.": PRINT
195 F = 0:S = 100:T = 200: GOSUB 245
204 VTAB 23: POKE 50,63: HTAB 8: PRINT "HIT ANY KEY TO CONTINUE": POKE 50,255
205 IF PEEK( -16384) <127 THEN 205
208 POKE -16368,0: HOME
210 CALL -936: VTAB 7: PRINT "DO YOU WISH ": PRINT : HTAB 5: PRINT "1 DISK CATALOGER ": PRINT : HTAB 5: PRINT "2 LIBRARY REVIEW INSTRUCTIONS"
212 PRINT : HTAB 5: PRINT "3 LIBRARY REVIEW - 2 COLUMN PRINTER": PRINT : HTAB 5: PRINT "4 LIBRARY REVIEW - 3 COLUMN PRINTER": PRINT : HTAB 5: PRINT "5 LIBRARY REVIEW - 4 COLUMN PRINTER"
213 PRINT : PRINT "PLEASE SELECT ONE BY NUMBER (1-5) ";: INPUT A$:A = VAL(A$): IF A <1 OR A >5 THEN 210
220 ON A GOTO 400,500,600,700,800
245 X = 0
255 POKE 6,113: POKE 7,S +50: CALL 770
265 POKE 6,101: POKE 7,S +20: CALL 770
275 POKE 6,127: POKE 7,S: CALL 770
285 POKE 6,255: POKE 7,S: CALL 770
295 POKE 6,170: POKE 7,T: CALL 770
305 X = X +1: IF X = 1 AND F = 2 THEN RETURN
315 IF X = 2 THEN RETURN
325 GOTO 255
400 PRINT "RUN DISK CAT FOR LIB.REVIEW"
500 PRINT "RUN LIBRARY REVIEW INSTRUCTIONS"
600 PRINT "RUN LIBRARY REVIEW"
700 PRINT "RUN LIB. REV. 3 COL PRINTER"
800 PRINT "RUN LIB.REV 4 COL PRINTER"

Text found in 015_Disk_Catalog_Programs.dsk/LIBRARY REVIEW.bas:

10 HIMEM: 37090: TEXT : PRINT "NOMONC": HOME
16 POKE 1013,76: POKE 1014,0: POKE 1015,145:TN$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ ":D$ = CHR$(13) + CHR$(4)
17 PRINT D$"BLOAD LIBRARY REVIEW.OBJ"
20 GOTO 600
70 REM PRINTER ROUTINE
72 HOME : VTAB 10: INPUT "TURN ON THE PRINTER AND SET PAPER";A$
74 PR# 1
76 GOSUB 84
78 FOR I = 1 TO NPG: PRINT PR$(I);: POKE 36,40: PRINT PR$(I +58)
80 IF INT(I/58) = I/58 THEN I = I +58: PRINT : PRINT : PRINT : GOSUB 84
82 NEXT I: PR# 0: RETURN
84 REM HEADER
86 PRINT : PRINT : PRINT "VOL TYPE PROGRAM";: POKE 36,40: PRINT "VOL TYPE PROGRAM"
88 FOR J = 1 TO 79: PRINT "-";: NEXT J: PRINT "-": PRINT : RETURN
100 REM FIND PROG OR VOLUME
110 NA$ = "PROGRAM NAME:": HOME : VTAB 10
120 PRINT TAB( 3)"FIND VOLUME # OR PROGRAM? (V OR P):"
130 IF PEEK( -16384) <127 THEN 130
131 VL = PEEK( -16384): IF VL = 208 THEN 150
132 IF VL < >214 THEN 130
133 NA$ = "VOLUME NUMBER"
150 POKE -16368,0
170 VTAB 12: PRINT "PLEASE INPUT "NA$: HTAB 5: INPUT RS$
190 IF VL = 214 AND LEN(RS$) >3 THEN 170
200 IF VL = 141 THEN RETURN
208 GOSUB 210: GOTO 220
210 HOME : VTAB 24: CALL -868: HTAB 15: FLASH : PRINT "SEARCHING";: NORMAL : POKE 35,23: RETURN
211 POKE 35,24: VTAB 24: CALL -868: HTAB 13: INVERSE : PRINT "MORE? (Y OR N)";: NORMAL : RETURN
220 IF VL = 208 THEN 270
221 IF LEN(RS$) = 1 THEN RS$ = "00" +RS$
222 IF LEN(RS$) = 2 THEN RS$ = "0" +RS$
230 NU% = 0: FOR J = 1 TO NPG: IF LEFT$(PR$(J),3) < >RS$ THEN 260
231 NU% = NU% +1: IF NU% = 1 THEN HOME : VTAB 3
232 PRINT PR$(J): IF NU% < >18 THEN 260
240 GOSUB 211
241 IF PEEK( -16384) <127 THEN 241
244 VL = PEEK( -16384): POKE -16368,0: IF VL = 206 THEN RETURN
245 IF VL < >217 THEN 241
246 NU% = 0: GOSUB 210
260 NEXT J: GOTO 320
270 NU% = 0: FOR J = 1 TO NPG: IF MID$ (PR$(J),7,1) < > LEFT$(RS$,1) THEN NEXT
271 IF J = NPG +1 THEN 310
272 IF MID$ (PR$(J),7, LEN(RS$)) < >RS$ THEN NEXT
273 IF J = NPG +1 THEN 320
277 NU% = NU% +1: IF NU% = 1 THEN HOME : VTAB 3
278 PRINT PR$(J): IF NU% < >18 THEN 300
279 GOSUB 210
280 IF PEEK( -16384) <127 THEN 280
284 VL = PEEK( -16384): POKE -16368,0: IF VL = 206 THEN RETURN
285 IF VL < >217 THEN 280
286 NU% = 0: GOSUB 211
300 NEXT
301 GOTO 320
310 IF MID$ (PR$(J),7, LEN(RS$)) = RS$ THEN PRINT PR$(NPG)
320 POKE 35,24: VTAB 24: CALL -868: HTAB 8: INVERSE : PRINT "FINISHED-RETURN FOR MENU";: NORMAL
321 IF PEEK( -16384) < >141 THEN 321
322 POKE -16368,0: RETURN
590 REM PROGRAM MENU
600 TEXT :NPG = 1:MX = 1200: DIM PR$(MX)
610 HOME : ONERR GOTO 910: NORMAL
620 VTAB 5: PRINT TAB( 6)"L I B R A R Y R E V I E W": PRINT
630 PRINT TAB( 13)"BY HILLY FUCHS": PRINT
640 PRINT TAB( 11)"APPLE GROUP - N.J.": PRINT : PRINT : PRINT
650 PRINT TAB( 5)"R -- READ PROGRAM FILE FROM DISK"
660 PRINT TAB( 5)"C -- CATALOG A DISK"
670 PRINT TAB( 5)"L -- LIST PROGRAMS"
680 PRINT TAB( 5)"S -- SORT PROGRAMS"
700 PRINT TAB( 5)"F -- FIND PROGRAM OR DISK VOLUME"
701 PRINT TAB( 5)"E -- EXIT"
702 PRINT TAB( 5)"P -- PRINTER"
710 VTAB 24: HTAB 13: INVERSE : PRINT "ENTER CHOICE?";: NORMAL : GET AN$
720 IF AN$ = "R" THEN GOSUB 1000: GOTO 610
721 IF AN$ = "C" THEN GOSUB 2000: GOTO 610
722 IF AN$ = "L" THEN GOSUB 3000: GOTO 610
723 IF AN$ = "S" THEN GOSUB 4000: GOTO 610
724 IF AN$ = "P" THEN GOSUB 70: GOTO 610
725 IF AN$ = "F" THEN GOSUB 100: GOTO 610
726 IF AN$ = "E" THEN TEXT : HOME : END
728 GOTO 710
1000 REM READ DATA FROM DISK
1010 ONERR GOTO 1020
1015 HOME : PRINT D$;"CATALOG"
1020 PRINT : PRINT : PRINT "ENTER PROGRAM FILE NAME: ": INPUT FLE$: IF FLE$ <"A" THEN RETURN
1030 PRINT : PRINT "REPLACE OR APPEND TO MEMORY? (R OR A):"
1040 GET AN$
1050 IF AN$ = "R" THEN BPG = 1: GOSUB 5000: GOTO 1100
1060 IF AN$ = "A" THEN BPG = NPG +1: GOTO 1100
1070 GOTO 1040
1100 PRINT D$"OPEN"FLE$
1110 PRINT D$"READ"FLE$
1115 INPUT DT$: INPUT PG$:PG = VAL(PG$)
1117 ONERR GOTO 1122
1120 IF AN$ = "R" THEN NPG = PG: GOTO 1130
1121 IF AN$ = "A" THEN NPG = NPG +PG: IF NPG < = MX THEN GOTO 1130
1122 HOME : VTAB 12: FLASH : PRINT "TOO MANY PROGRAMS WITH APPEND - SORRY!": FOR J = 1 TO 2500: NEXT J: NORMAL : PRINT D$"CLOSE"FLE$: RETURN
1130 POKE 34,0: HOME : PRINT "LOADING: "; LEFT$(FLE$,19); TAB( 29);"PROG: ";PG: PRINT "--------------------------------------"
1140 POKE 34,2: VTAB 3
1150 FOR J = BPG TO NPG: INPUT PR$(J): PRINT PR$(J): NEXT J
1160 PRINT D$"CLOSE"FLE$
1162 IF AN$ = "R" THEN 1170
1165 TEXT : HOME : PRINT "FILE: -APPENDED-"; TAB( 29);"PROG: ";NPG: PRINT "--------------------------------------": POKE 34,2: RETURN
1170 TEXT : HOME : PRINT "FILE: "; LEFT$(FLE$,19); TAB( 29);"PROG: ";NPG: PRINT "--------------------------------------": POKE 34,2
1180 RETURN
2000 REM PERFORM CATALOG
2010 HOME : POKE 35,23
2015 PRINT D$"CATALOG"
2030 POKE 35,24: VTAB 24: HTAB 10: INVERSE : PRINT "PRESS RETURN FOR MENU";: NORMAL
2040 IF PEEK( -16384) < >141 THEN 2040
2050 POKE -16368,0: RETURN
3000 REM LIST PROGRAM FILE
3010 FOR J = 1 TO NPG STEP 19: HOME : VTAB 4: FOR K = 0 TO 18: PRINT PR$(J +K): NEXT K: VTAB 24: PRINT " (RETURN FOR MENU,<- BACK,-> FORWARD)?";
3020 GET AN$: IF ASC(AN$) = 13 THEN RETURN
3030 IF ASC(AN$) = 21 THEN 3070
3050 IF ASC(AN$) < >8 THEN 3020
3060 J = J -38: IF J < -18 THEN J = -18
3070 NEXT J
3071 POKE 37,23: POKE 36,0: CALL -868: HTAB 12: FLASH : PRINT "(RETURN FOR MENU)": NORMAL
3072 IF PEEK( -16384) < >141 THEN 3072
3073 POKE -16368,0
3080 RETURN
4000 REM SORT PROGRAM FILE
4010 HOME : VTAB 9
4020 PRINT "CHOOSE YOUR SELECTION CRITERIA:": PRINT
4030 PRINT TAB( 5)"1 -- SORT BY VOLUME NUMBER": PRINT
4040 PRINT TAB( 5)"2 -- SORT BY PROGRAM NAME": PRINT
4050 PRINT TAB( 5)"3 -- SORT BY TYPE OF PROGRAM": PRINT : PRINT
4060 HTAB 14: INVERSE : PRINT "YOUR CHOICE?": NORMAL
4070 IF PEEK( -16384) <127 THEN 4070
4071 VL = PEEK( -16384): IF VL >176 AND VL <180 THEN 4079
4072 IF VL = 141 THEN RETURN
4073 POKE -16368,0: GOTO 4070
4079 POKE -16368,0
4080 PRINT : PRINT : FLASH : PRINT "SORTING....": NORMAL
4090 IF VL >177 THEN 4110
4100 & SRT#(PR$,0,NPG,1,3,A,7,36,A): RETURN
4110 IF VL >178 THEN 4130
4120 & SRT#(PR$,0,NPG,7,36,A): RETURN
4130 & SRT#(PR$,0,NPG,5,1,A,7,36,A)
4140 RETURN
5000 FOR J = 1 TO NPG:PR$(J) = "": NEXT :J = FRE(0): RETURN
20000 REM BY HILLY FUCHS FOR APPLE GROUP- N.J. PUBLIC DOMAIN