Notes

Disk info for 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk:

File Name: riag_008_029_-_Interesting_Programs_-_Library_of_Dave_Angell_-_1983/029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 37888
Used Space (bytes): 105472
Physical Size (KB): 140
Free Space (KB): 37
Used Space (KB): 103
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 148
Used Sectors: 412
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk:

riag_008_029_-_Interesting_Programs_-_Library_of_Dave_Angell_-_1983/029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk DISK VOLUME #254
A 002 HELLO
B 002 HEADING
A 052 RECIPE FILE 1.3
T 002 RF.BEVERAGES
T 002 RF.BREADS
T 002 RF.FISH
T 005 RF.DESSERTS
T 002 RF.HORS D'OEUVRES
T 002 RF.MEAT
T 002 RF.POULTRY
T 002 RF.SOUPS
T 002 RF.VEGETABLES
T 002 RF.OTHER
A 016 ANNIVERSARY CALENDAR
T 002 ANN
A 075 FINANCIAL PROGRAMS
T 083 WORDS.DAT
B 012 WORD.FMT
A 038 WORD.POWER
B 012 WORD.FMT32
A 019 HOROSCOPE
A 012 TELEPHONE LIST
DOS 3.3 format; 37,888 bytes free; 105,472 bytes used.

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/ANN.txt:

2
BETTINA DEL SESTO
JUL 10
BIRTHDAY
DAVE ANGELL
MAY 8 1927
BIRTHDAY

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/ANNIVERSARY CALENDAR.bas:

70 DIM MO$(12),NA$(100),DA$(100),OC$(100),A(100)
80 FOR X = 1 TO 12: READ MO$(X): NEXT X
85 ONERR GOTO 2990
90 D$ = CHR$(4): GOSUB 10100
100 POKE 33,40: POKE 32,0: POKE 34,0: POKE 35,23:SW = 0:NU = 0: HOME : GOSUB 110: GOTO 140
110 HOME : FOR X = 1 TO 39: HTAB X: PRINT "A";: NEXT X: PRINT
120 FOR X = 2 TO 21: VTAB X: PRINT "A";: HTAB 39: PRINT "A": NEXT X
130 FOR X = 1 TO 39: HTAB X: PRINT "A";: NEXT X: POKE 33,36: POKE 32,2: POKE 34,1: POKE 35,21: RETURN
140 VTAB 4: HTAB 7: PRINT "ANNIVERSARY CALENDAR": PRINT : PRINT : HTAB 7: PRINT "1 - DISPLAY BY MONTH": PRINT
150 HTAB 7: PRINT "2 - SELECT BY NAME": PRINT : HTAB 7: PRINT "3 - ADD TO CALENDAR": PRINT
160 HTAB 7: PRINT "4 - CHANGE CALENDAR": PRINT : HTAB 7: PRINT "5 - DELETE FROM CALENDAR": PRINT : HTAB 7: PRINT "6 - QUIT"
170 VTAB 20: PRINT "SELECT BY NUMBER 1,2,3,4,5 OR 6 ";: GET A: PRINT
180 IF A <1 OR A >6 THEN PRINT "": GOTO 170: REM CTRL G
190 ON A GOTO 1000,2000,3000,4000,5000,6000
1000 REM LIST MONTHS FOR PERUSAL
1010 HOME
1030 VTAB 4: FOR X = 1 TO 6: HTAB 5: PRINT X;" ";MO$(X): PRINT : NEXT X: PRINT
1040 VTAB 4: FOR X = 7 TO 12: HTAB 20: PRINT X;" ";MO$(X): PRINT : NEXT X: PRINT
1050 VTAB 18: HTAB 1: PRINT "SELECT MONTH BY NUMBER. (1 TO 12)";: GET I: PRINT
1060 IF I <0 OR I >12 THEN 1050
1070 HOME :LE = LEN(MO$(I)): HTAB (36 -LE)/2: PRINT MO$(I):
1080 CC$ = LEFT$(MO$(I),3): PRINT : FOR X = 1 TO L: IF CC$ = LEFT$(DA$(X),3) THEN GOSUB 1100
1090 NEXT X: GOTO 1200
1100 REM LIST NAMES
1110 NU = NU +1: PRINT DA$(X);: HTAB 19: PRINT NA$(X)
1120 RETURN
1200 VTAB 21: HTAB 5: PRINT "PRESS ANY KEY TO CONTINUE. ";: GET K$: GOTO 100
2000 : HOME
2010 VTAB 3: HTAB 11: PRINT "SELECT BY NAME"
2020 VTAB 10: HTAB 9: PRINT "I'LL NEED THE NAME."
2030 VTAB 13: HTAB 9: INPUT "-> ";A$
2040 VTAB 20: HTAB 4: PRINT "THANK YOU, ONE MINUTE PLEASE!"
2050 VTAB 13: HTAB 11: PRINT SPC( 15);: VTAB 10: HTAB 8: PRINT SPC( 20);: VTAB 13: HTAB 8: PRINT SPC( 28);:
2060 FOR I = 1 TO L: IF NA$(I) = A$ THEN GOTO 2100
2065 NEXT I: IF SW = 1 THEN 2090
2070 VTAB 10: HTAB 8: PRINT "I CANNOT FIND THAT NAME!": PRINT : HTAB 4: PRINT "CHECK AGAIN I MAY HAVE MISSED IT.":SW = 1
2080 FOR X = 1 TO 2500: NEXT X: GOTO 2000
2090 VTAB 10: HTAB 7: PRINT "NO LUCK THIS TIME EITHER.": FOR X = 1 TO 2500: NEXT X: GOTO 100
2100 HOME : GOSUB 3500
2105 VTAB 3: HTAB 11: PRINT "ENTRY DISPLAY"
2110 VTAB 7: HTAB 10: PRINT NA$(I): VTAB 11: HTAB 20: PRINT DA$(I): VTAB 15: HTAB 16: PRINT OC$(I)
2120 VTAB 20: HTAB 3: PRINT "IS THIS THE ENTRY YOU WANT ";:
2130 INPUT K$: IF LEFT$(K$,1) = "Y" GOTO 2190
2140 VTAB 20: CALL -868: HTAB 6: PRINT ">>> LET'S TRY AGAIN <<<": FOR X = 1 TO 1000: NEXT X: GOTO 2000
2190 IF FL = 1 THEN GOTO 5110
2200 VTAB 20: CALL -868: HTAB 6: PRINT "GLAD I WAS ABLE TO HELP. "
2210 FOR X = 1 TO 1500: NEXT X: GOTO 100
2990 SW = 1
3000 : HOME
3010 VTAB 3: HTAB 4: PRINT "ADD NEW INFORMATION CALENDAR": FOR X = 4 TO 31: HTAB X: PRINT "=";: NEXT X: PRINT
3020 GOSUB 3500:L = L +1: VTAB 7: HTAB 10: INPUT NA$(L): VTAB 11: HTAB 20: INPUT DA$(L): VTAB 15: HTAB 16: INPUT OC$(L)
3025 IF SW = 1 THEN SW = 0: GOSUB 10000: GOTO 100
3030 VTAB 20: HTAB 8: PRINT "I'LL REMEMBER THESE.": FOR X = 1 TO 1000: NEXT X: GOSUB 10000: GOTO 100
3500 VTAB 7: HTAB 2: PRINT "NAME-----": VTAB 11: HTAB 2: PRINT "DATE TO REMEMBER---": VTAB 15: HTAB 2: PRINT "OCCASION-------": RETURN
4000 HOME
4010 VTAB 3: HTAB 8: PRINT "RECORD CHANGE PROGRAM."
4020 VTAB 10: HTAB 8: PRINT "I'LL NEED THE NAME."
4030 VTAB 13: HTAB 8: INPUT "-> ";A$
4040 VTAB 19: HTAB 4: PRINT "THANK YOU, ONE MINUTE PLEASE!"
4050 VTAB 13: HTAB 10: PRINT SPC( 15);: VTAB 10: HTAB 8: PRINT SPC( 20);: VTAB 13: HTAB 8: PRINT SPC( 28);:
4060 FOR X = 1 TO 1500: NEXT X
4070 FOR I = 1 TO L: IF NA$(I) = A$ THEN K = I: GOTO 4100
4075 NEXT I: IF SW = 1 THEN 4090
4080 VTAB 10: HTAB 8: PRINT "I CANNOT FIND THAT NAME!": PRINT : HTAB 4: PRINT "CHECK AGAIN I MAY HAVE MISSED IT.":SW = 1
4085 FOR X = 1 TO 2500: NEXT X: GOTO 4000
4090 VTAB 10: HTAB 7: PRINT "NO LUCK THIS TIME EITHER.": FOR X = 1 TO 2500: NEXT X: GOTO 100
4100 GOSUB 3500
4105 VTAB 19: HTAB 3: PRINT SPC( 30);:
4110 VTAB 7: HTAB 10: PRINT NA$(I): VTAB 11: HTAB 20: PRINT DA$(I): VTAB 15: HTAB 16: PRINT OC$(I)
4120 VTAB 8: HTAB 4: INPUT "CHANGE TO -> ";NA$(K): VTAB 12: HTAB 4: INPUT "CHANGE TO -> ";DA$(K): VTAB 16: HTAB 4: INPUT "CHANGE TO -> ";OC$(K)
4130 VTAB 20: HTAB 6: PRINT "WILL THIS BE ALRIGHT";: INPUT K$
4140 IF LEFT$(K$,1) = "Y" THEN GOSUB 10000: GOTO 100
4150 HOME : VTAB 6: PRINT "WOULD YOU LIKE TO TRY AGAIN? ": INPUT " -> ";ANS$: IF LEFT$(ANS$,1) = "Y" THEN 4020
4160 GOTO 100
5000 HOME : VTAB 5: FOR K = 9 TO 26: HTAB K: PRINT "*";: NEXT : PRINT
5010 HTAB 9: SPEED= 50: PRINT "* W A R N I N G! *": FOR K = 9 TO 26: HTAB K: PRINT "*";: NEXT K: PRINT : SPEED= 255: PRINT
5020 PRINT : PRINT : PRINT " THIS SECTION WILL REMOVE A NAME PERMAMENTLY FROM YOUR RECORDS.": PRINT
5030 PRINT : PRINT " IF YOU WISH TO CONTINUE TYPE 'YES' AND 'RETURN'. TO RETURN TO LISTING HIT ANY KEY AND 'RETURN'.";:
5040 INPUT K$: IF K$ = "YES" THEN GOTO 5100
5050 GOTO 100
5100 FL = 1: HOME : GOTO 2020
5110 FL = 0:S = I:NA$(S) = "":DA$(S) = "":OC$(S) = ""
5120 M = 0: FOR N = 1 TO L
5130 IF NA$(N) = "" AND DA$(N) = "" THEN GOTO 5160
5140 M = M +1
5150 NA$(M) = NA$(N):DA$(M) = DA$(N):OC$(M) = OC$(N)
5160 NEXT N
5170 GOSUB 10000
5180 GOTO 100
6000 HOME : VTAB 10: HTAB 8: PRINT "GLAD TO BE OF SERVICE": POKE 32,0: POKE 33,40: POKE 34,0: POKE 35,23
6010 FOR Z = 1 TO 1000: NEXT Z: HOME : END
7000 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
10000 PRINT D$;"OPEN ANN "
10010 PRINT D$;"DELETE ANN "
10020 PRINT D$;"OPEN ANN "
10030 PRINT D$;"WRITE ANN "
10040 PRINT L
10050 FOR Z = 1 TO L
10060 PRINT NA$(Z): PRINT DA$(Z): PRINT OC$(Z)
10070 NEXT Z
10080 PRINT D$;"CLOSE ANN "
10090 RETURN
10100 PRINT D$;"OPEN ANN "
10110 PRINT D$;"READ ANN "
10120 INPUT L
10130 FOR Z = 1 TO L
10140 INPUT NA$(Z),DA$(Z),OC$(Z)
10150 NEXT Z
10160 PRINT D$;"CLOSE ANN "
10170 RETURN

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/FINANCIAL PROGRAMS.bas:

10 REM ********************** * *
20 REM * FINANCIAL.WIZARD *
30 REM * * ********************** : :
40 REM --------------------
50 REM DOCUMENTATION.MODULE
60 REM --------------------
70 REM Z =MENU SELECTOR Y$=YES/NO SELECTOR
80 REM P =INITIAL INVESTMENT I =INTEREST RATE
90 REM N =COMP.PERIODS/YEAR Y =NUMBER OF YEARS
100 REM T =CALCULATED VALUE R =REGULAR DEPOSIT
110 REM K =DEPREC.PERCENTAGE D =DEPREC.AMOUNT
120 REM X =COUNTER FROM 1-5 X$=CONTINUE LISTING
130 REM S =SALVAGE VALUE Q =TOTAL INTEREST
140 REM SP$=SCREEN/PRINTER
150 REM A,B,C,D,F,J,L,A$,BO =VALUE EXCHANGERS
160 REM -------------------
170 REM HOUSEKEEPING.MODULE
180 REM -------------------
190 REM DIM A$(5),X$(5),Y$(5)
200 REM ----------------------
210 REM ACKNOWLEDGEMENT.MODULE
220 REM ---------------------- :
230 REM *********************
240 REM * UPDATED & REBUILT *
250 REM * ENTIRELY BY *
260 REM * THOMAS R. PIPER *
270 REM * CENTERVILLE, IOWA *
280 REM * OCTOBER, 1982 *
290 REM ********************* :
300 REM -------------------
310 REM MAIN.CONTROL.MODULE
320 REM -------------------
330 REM
340 REM INITIAL.INTRODUCTION
350 GOSUB 520
360 REM MASTER.MENU.SELECTOR
370 GOSUB 620
380 REM CLR SCREEN, DRAW LINE
390 GOSUB 4370: GOSUB 4330
400 REM EXECUTE.SELECTION
410 IF Z = 0 THEN GOTO 490
420 ON Z GOSUB 920,1090,1270,1440,1600,1790,1970,2130,2270,2420,2600,2770,2930,3090,3250,3490,3740,3900
430 REM PRINTOUT.ANSWER.?
440 GOSUB 4410
450 REM REPEAT.SELECTION.?
460 GOTO 5130
470 REM STARTOVER.WITH.MENU
480 GOTO 360
490 REM END.OF.PROGRAM
500 GOSUB 5200
510 END
520 REM ----------------------
530 REM INTRO.SELECTION.MODULE
540 REM ----------------------
550 HOME
560 VTAB 9: GOSUB 4330
570 PRINT " **** BANKING AND FINANCIAL ****"
580 PRINT : PRINT TAB( 16);"PROGRAMS"
590 PRINT : GOSUB 4330
600 FOR I = 1 TO 2000: NEXT I
610 RETURN
620 REM ------------------
630 REM MASTER.MENU.MODULE
640 REM ------------------
650 GOSUB 4370: GOSUB 4330: CALL -998: REM THE CALL MOVES CURSOR UP ONE LINE
660 PRINT " *** MASTER MENU ***"
670 GOSUB 4330: CALL -998
680 PRINT TAB( 5);"(1) FUTURE VALUE OF INVESTMENT"
690 PRINT TAB( 5);"(2) FUTURE VALUE OF ANNUITY"
700 PRINT TAB( 5);"(3) FUTURE VALUE OF SAVINGS"
710 PRINT TAB( 5);"(4) WITHDRAWALS FROM INVESTMENT"
720 PRINT TAB( 5);"(5) MINIMUM INVESTMENT FOR INCOME"
730 PRINT TAB( 5);"(6) INCOME FROM INVESTMENTS"
740 PRINT TAB( 5);"(7) NOMINAL INTEREST RATES"
750 PRINT TAB( 5);"(8) EFFECTIVE INTEREST RATES"
760 PRINT TAB( 5);"(9) ANNUAL DEPRECIATION TABLE"
770 PRINT TAB( 4);"(10) DEPRECIATED INVESTMENT"
780 PRINT TAB( 4);"(11) SALVAGE VALUE YEAR END"
790 PRINT TAB( 4);"(12) DISCOUNTED COMMERCIAL PAPER"
800 PRINT TAB( 4);"(13) LOAN PRINCIPAL"
810 PRINT TAB( 4);"(14) LOAN PAYMENT SCHEDULES"
820 PRINT TAB( 4);"(15) FINAL LOAN PAYMENT"
830 PRINT TAB( 4);"(16) REMAINING LOAN BALANCE"
840 PRINT TAB( 4);"(17) LOAN REPAYMENT PERIODS"
850 PRINT TAB( 4);"(18) MORTGAGE AMORTIZATION TABLE"
860 GOSUB 4330: CALL -998
870 PRINT "SELECT A PROGRAM BY NUMBER AND THEN"
880 INVERSE : PRINT "PRESS RETURN (ENTER '0' TO QUIT) ...";: NORMAL
890 INPUT Z
900 IF Z <0 OR Z >20 THEN 620
910 RETURN
920 REM -------------------
930 REM FUTURE.INVEST.VALUE
940 REM -------------------
950 PRINT " #1 FUTURE VALUE OF AN INVESTMENT"
960 PRINT : GOSUB 4330
970 INPUT "ENTER THE INITIAL INVESTMENT: $";P
980 PRINT
990 INPUT "ENTER THE NOMINAL INTEREST : ";I: CALL -998: HTAB (32): PRINT I;" %"
1000 PRINT
1010 INPUT "COMPOUNDING PERIODS PER YEAR: ";N: CALL -998: HTAB (32): PRINT N;" P/Y"
1020 PRINT
1030 INPUT "NUMBER OF INVESTMENT YEARS : ";Y: CALL -998: HTAB (32): PRINT Y;" YRS"
1040 PRINT : GOSUB 4330: PRINT
1050 I = I/N/100
1060 T = P *(1 +I) ^(N *Y)
1070 PRINT "THE FUTURE INVESTMENT VALUE = $"; INT(T *100 +.5)/100
1080 RETURN
1090 REM --------------------
1100 REM FUTURE.DEPOSIT.VALUE
1110 REM --------------------
1120 PRINT " #2 FUTURE VALUE OF REGULAR DEPOSITS"
1130 PRINT TAB( 15)"(ANNUITY)"
1140 PRINT : GOSUB 4330
1150 INPUT "ENTER REGULAR DEPOSIT AMOUNT: $";R
1160 PRINT
1170 INPUT "ENTER NOMINAL INTEREST RATE : ";I: CALL -998: HTAB (33): PRINT I;" %"
1180 PRINT
1190 INPUT "NUMBER OF DEPOSITS PER YEAR : ";N: CALL -998: HTAB (33): PRINT N;" D/Y"
1200 PRINT
1210 INPUT "ENTER NUMBER OF YEARS USED : ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
1220 I = I/N/100
1230 T = R *((1 +I) ^(N *Y) -1)/I
1240 PRINT : GOSUB 4330: PRINT
1250 PRINT "THE FUTURE DEPOSIT VALUE IS : $"; INT(T *100 +.5)/100
1260 RETURN
1270 REM --------------------
1280 REM FUTURE.SAVINGS.VALUE
1290 REM --------------------
1300 PRINT " #3 FUTURE VALUE OF AN ANNUITY OR SAVINGS ACCOUNT"
1310 PRINT : GOSUB 4330
1320 INPUT "ENTER THE END-OF-YEARS VALUE: $";T
1330 PRINT
1340 INPUT "ENTER THE NOMINAL INTEREST : ";I: CALL -998: HTAB (33): PRINT I;" %"
1350 PRINT
1360 INPUT "NUMBER OF DEPOSITS EACH YEAR: ";N: CALL -998: HTAB (33): PRINT N;" D/Y"
1370 PRINT
1380 INPUT "ENTER NUMBER YEARS DEPOSITED: ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
1390 I = I/N/100
1400 R = T *I/((I +1) ^(N *Y) -1)
1410 PRINT : GOSUB 4330: PRINT
1420 PRINT "EACH REGULAR DEPOSIT MUST BE= $"; INT(R *100 +.5)/100
1430 RETURN
1440 REM ---------------------
1450 REM INVESTMENT.WITHDRAWAL
1460 REM ---------------------
1470 PRINT " #4 REGULAR INVESTMENT WITHDRAWALS"
1480 PRINT : GOSUB 4330
1490 INPUT "INITIAL INVESTMENT AMOUNT : $";P: PRINT
1500 INPUT "ENTER NOMINAL INTEREST RATE : ";I: CALL -998: HTAB (33): PRINT I;" %"
1510 PRINT
1520 INPUT "NUMBER WITHDRAWALS EACH YEAR: ";N: CALL -998: HTAB (33): PRINT N;" W/Y"
1530 PRINT
1540 INPUT "ENTER NUMBER OF YEARS TO USE: ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
1550 I = I/N/100
1560 R = P *(I/((1 +I) ^(N *Y) -1) +I)
1570 PRINT : GOSUB 4330: PRINT
1580 PRINT "MAXIMUM WITHDRAWAL EACH TIME= $"; INT(R *100 +.5)/100
1590 RETURN
1600 REM ---------------------
1610 REM MIN.INVEST.FUTURE.INC
1620 REM ---------------------
1630 PRINT " #5 INVESTMENT REQUIRED TO"
1640 PRINT " PROVIDE FUTURE VALUE.."
1650 PRINT : GOSUB 4330
1660 INPUT "DESIRED RESULT OF INVESTMENT: $";T
1670 PRINT
1680 INPUT "COMPOUNDING PERIODS PER YEAR: ";N: CALL -998: HTAB (33): PRINT N;" P/Y"
1690 PRINT
1700 INPUT "NUMBER OF INVESTMENT YEARS : ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
1710 PRINT
1720 INPUT "ENTER THE NOMINAL INTEREST : ";I: CALL -998: HTAB (33): PRINT I;" %"
1730 I1 = I
1740 I = I/N/100
1750 P = T/(1 +I) ^(N *Y)
1760 PRINT : GOSUB 4330: PRINT
1770 PRINT "MINIMUM INVESTMENT REQUIRED = $"; INT(P *100 +.5)/100
1780 RETURN
1790 REM ------------------
1800 REM INCOME.FROM.INVEST
1810 REM ------------------
1820 PRINT TAB( 5)"#6 MINIMUM INVESTMENT FOR INCOME"
1830 PRINT : GOSUB 4330
1840 INPUT "NUMBER WITHDRAWALS EACH YEAR: ";N: CALL -998: HTAB (33): PRINT N;" W/Y"
1850 PRINT
1860 INPUT "ENTER AMOUNT EACH WITHDRAWAL: $";R
1870 PRINT
1880 INPUT "ENTER NOMINAL INTEREST RATE : ";I: CALL -998: HTAB (33): PRINT I;" %"
1890 PRINT
1900 INPUT "NUMBER YEARS OF WITHDRAWALS : ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
1910 I1 = I
1920 I = I/100
1930 P = R *N/I *(1 -1/((1 +I/N) ^(N *Y)))
1940 PRINT : GOSUB 4330: PRINT
1950 PRINT "MINIMUM INVESTMENT MUST BE = $"; INT(100 *P +.5)/100
1960 RETURN
1970 REM ---------------------
1980 REM NOMINAL.INTEREST.RATE
1990 REM ---------------------
2000 PRINT "#7 NOMINAL INTEREST RATE ON INVESTMENTS"
2010 PRINT : GOSUB 4330
2020 INPUT "ENTER AMOUNT OF PRINCIPAL : $";P
2030 PRINT
2040 INPUT "INVESTMENT AMOUNT DESIRED : $";T
2050 PRINT
2060 INPUT "NUMBER OF INVESTMENT YEARS : ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
2070 PRINT
2080 INPUT "COMPOUNDING PERIODS PER YEAR: ";N: CALL -998: HTAB (33): PRINT N;" P/Y"
2090 I2 = N *((T/P) ^(1/(N *Y)) -1) *100
2100 PRINT : GOSUB 4330: PRINT
2110 PRINT "NOMINAL INTEREST RATE NEEDED= "; INT(I2 *100 +.5)/100;" %"
2120 RETURN
2130 REM -------------------
2140 REM EFFECTIVE.INT.RATES
2150 REM -------------------
2160 PRINT " #8 EFFECTIVE INVESTMENT INTEREST RATE"
2170 PRINT : GOSUB 4330
2180 INPUT "INITIAL AMOUNT OF INVESTMENT: $";P
2190 PRINT
2200 INPUT "THE END-OF-INVESTMENT AMOUNT: $";T
2210 PRINT
2220 INPUT "LIFE OF INVESTMENT IN YEARS : ";Y: CALL -998: HTAB (33): PRINT Y;" YRS"
2230 I3 = ((T/P) ^(1/Y) -1) *100
2240 PRINT : GOSUB 4330: PRINT
2250 PRINT "ANNUAL INTEREST RATE RESULT = "; INT(I3 *100 +.5)/100;" %"
2260 RETURN
2270 REM ------------------
2280 REM ANNUAL.DEPREC.RATE
2290 REM ------------------
2300 PRINT "#9 ANNUAL INVESTMENT DEPRECIATION RATE"
2310 PRINT : GOSUB 4330
2320 INPUT "ORIGINAL PRICE OF THE ITEM : $";P
2330 PRINT
2340 INPUT "SUGGESTED ITEM RESALE PRICE: $";T
2350 PRINT
2360 INPUT "LIFE IN YEARS OF THE ITEM : ";Y: CALL -998: HTAB (32): PRINT Y;" YRS"
2370 PRINT
2380 D = 100 *(1 -(T/P) ^(1/Y))
2390 PRINT : GOSUB 4330: PRINT
2400 PRINT "RESULTING DEPRECIATION RATE= "; INT(1000 *D +.5)/1000;" %"
2410 D1 = D: RETURN
2420 REM -----------------
2430 REM DEPREC.INVESTMENT
2440 REM -----------------
2450 PRINT " #10 AMOUNT DEPRECIATED WITHIN A YEAR"
2460 PRINT : GOSUB 4330
2470 INPUT "ORIGINAL PRICE OF THE ITEM : $";P
2480 PRINT
2490 K = 100
2500 INPUT "DEPRECIATION PERCENT NEEDED: ";I: CALL -998: HTAB (32): PRINT I;" %"
2510 PRINT : GOSUB 4330: PRINT
2520 I = I/100
2530 FOR Y = 1 TO K
2540 D = P *I *(1 -I) ^(Y -1)
2550 PRINT "THE YEAR #";Y;" DEPRECIATION = $"; INT(100 *D +.5)/100
2560 X = X +1: IF X = 5 THEN X = 0
2570 INVERSE : PRINT "PRESS RETURN FOR NEXT YEAR": GET X$: NORMAL : CALL -998
2580 IF D > = 2 THEN NEXT Y
2590 RETURN
2600 REM --------------------
2610 REM YEARLY.SALVAGE.VALUE
2620 REM --------------------
2630 PRINT " #11 YEARLY SALVAGE VALUE OF AN ITEM"
2640 PRINT : GOSUB 4330
2650 INPUT "ORIGINAL PRICE OF AN ITEM : $";P
2660 PRINT
2670 INPUT "DEPRECIATION RATE OF ITEM : ";I: CALL -998: HTAB (32): PRINT I;" %"
2680 PRINT : GOSUB 4330: PRINT
2690 K = 100
2700 FOR Y = 1 TO K
2710 S = INT(100 *P *(1 -I/100) ^Y +.5)/100
2720 PRINT "THE YEAR #";Y;" SALVAGE VALUE = $";S
2730 X = X +1: IF X = 5 THEN X = 0
2740 INVERSE : PRINT "PRESS RETURN FOR NEXT YEAR": GET X$: NORMAL : CALL -998
2750 IF S > = 2 THEN NEXT Y
2760 RETURN
2770 REM -------------------
2780 REM DISCOUNT.COMM.PAPER
2790 REM -------------------
2800 PRINT " #12 THE NET COST OF DISCOUNTED PAPER"
2810 PRINT : GOSUB 4330
2820 INPUT "ENTER NOTE'S FUTURE VALUE : $";T
2830 PRINT
2840 INPUT "ENTER THE DISCOUNTED RATE : ";D: CALL -998: HTAB (32): PRINT D;" %"
2850 PRINT
2860 INPUT "NUMBER OF DAYS TO MATURITY : ";N: CALL -998: HTAB (32): PRINT N;" DAYS"
2870 D = D/100
2880 D1 = T *D *N/360
2890 PRINT : GOSUB 4330: PRINT
2900 PRINT "THE DISCOUNT AMOUNT WILL BE= $"; INT(100 *D1 +.5)/100
2910 PRINT "THE NOTE'S ORIGINAL COST IS= $"; INT(100 *(T -D1) +.5)/100
2920 D2 = D: RETURN
2930 REM --------------
2940 REM LOAN.PRINCIPAL
2950 REM --------------
2960 PRINT " #13 PRINCIPAL ON A LOAN"
2970 PRINT : GOSUB 4330
2980 INPUT "NUMBER OF PAYMENTS PER YEAR: ";N: CALL -998: HTAB (32): PRINT N;" P/Y"
2990 PRINT
3000 INPUT "ENTER EACH PAYMENT'S AMOUNT: $";R
3010 PRINT
3020 INPUT "LOAN'S ANNUAL INTEREST RATE: ";I: CALL -998: HTAB (32): PRINT I;" %"
3030 PRINT
3040 INPUT "LIFE OF THE LOAN IN YEARS : ";Y: CALL -998: HTAB (32): PRINT Y;" YRS"
3050 PRINT : GOSUB 4330: PRINT
3060 P = R *N *(1 -1/((I/100)/N +1) ^(N *Y))/(I/100)
3070 PRINT "THE PRINCIPAL OF THIS LOAN = $"; INT(100 *P +.5)/100
3080 RETURN
3090 REM --------------------
3100 REM SCHEDULE.OF.PAYMENTS
3110 REM --------------------
3120 PRINT " #14 REGULAR PAYMENT ON A LOAN"
3130 PRINT : GOSUB 4330
3140 INPUT "LIFE OF THE LOAN IN YEARS : ";Y: CALL -998: HTAB (32): PRINT Y;" YRS"
3150 PRINT
3160 INPUT "ENTER ANNUAL INTEREST RATE : ";I: CALL -998: HTAB (32): PRINT I;" %"
3170 PRINT
3180 INPUT "NUMBER OF PAYMENTS PER YEAR: ";N: CALL -998: HTAB (32): PRINT N;" P/Y"
3190 PRINT
3200 INPUT "ENTER LOAN PRINCIPAL AMOUNT: $";P
3210 PRINT : GOSUB 4330: PRINT
3220 R = ((I/100) *P/N)/(1 -1/((I/100)/N +1) ^(N *Y))
3230 PRINT "YOUR REGULAR PAYMENTS ARE = $"; INT(100 *R +.5)/100
3240 RETURN
3250 REM ------------------
3260 REM FINAL.LOAN.PAYMENT
3270 REM ------------------
3280 PRINT " #15 LAST PAYMENT ON A LOAN"
3290 PRINT : GOSUB 4330
3300 INPUT "LIFE OF THE LOAN IN YEARS : ";Y: CALL -998: HTAB (32): PRINT Y;" YRS"
3310 PRINT
3320 INPUT "ENTER ANNUAL INTEREST RATE : ";I: CALL -998: HTAB (32): PRINT I;" %"
3330 PRINT
3340 INPUT "EACH REGULAR PAYMENT AMOUNT: $";R
3350 PRINT
3360 INPUT "NUMBER OF PAYMENTS PER YEAR: ";N: CALL -998: HTAB (32): PRINT N;" P/Y"
3370 PRINT
3380 INPUT "ENTER LOAN PRINCIPAL AMOUNT: $";P
3390 PRINT : GOSUB 4330: PRINT
3400 I1 = I:I = I/100:BO = P
3410 IF N *Y >100 THEN PRINT " *** WORKING THE PROBLEM ***": CALL -998
3420 FOR J1 = 1 TO N *Y
3430 I2 = INT((BO *I/N) *100 +.5)/100
3440 A = R -I2
3450 BO = BO -A
3460 NEXT J1
3470 PRINT "LAST LOAN PAYMENT AMOUNT : $"; INT(100 *(R +BO) +.5)/100
3480 RETURN
3490 REM -------------------
3500 REM END-OF-LOAN.BALANCE
3510 REM -------------------
3520 PRINT " #16 REMAINING BALANCE ON A LOAN"
3530 PRINT : GOSUB 4330
3540 INPUT "NUMBER OF PAYMENTS PER YEAR: ";N: CALL -998: HTAB (32): PRINT N;" P/Y"
3550 PRINT
3560 INPUT "ENTER ANNUAL INTEREST RATE : ";I: CALL -998: HTAB (32): PRINT I;" %"
3570 PRINT
3580 INPUT "ENTER EACH PAYMENT AMOUNT : $";R
3590 PRINT
3600 INPUT "ENTER AMOUNT OF PRINCIPAL : $";P
3610 PRINT
3620 INPUT "PYMT # OF LAST PAYMENT MADE: #";N1
3630 INPUT "YEAR # OF LAST PAYMENT MADE: #";Y
3640 PRINT : GOSUB 4330: PRINT : PRINT " *** WORKING ON PROBLEM ***"
3650 I = I/100
3660 BO = P
3670 FOR J1 = 1 TO N *(Y -1) +N1
3680 I1 = INT((BO *I/N) *100 +.5)/100
3690 A = R -I1
3700 BO = BO -A
3710 NEXT J1
3720 CALL -998: PRINT "THE REMAINING LOAN BALANCE = $"; INT(100 *BO +.5)/100
3730 RETURN
3740 REM ----------------
3750 REM REPAYMENT.PERIOD
3760 REM ----------------
3770 PRINT " #17 THE TERM OF A LOAN"
3780 PRINT : GOSUB 4330
3790 INPUT "NUMBER OF PAYMENTS PER YEAR: ";N: CALL -998: HTAB (32): PRINT N;" P/Y"
3800 PRINT " (# PYMTS >= INT.RATE #)
3810 INPUT "ENTER ANNUAL INTEREST RATE : ";I: CALL -998: HTAB (32): PRINT I;" %"
3820 PRINT
3830 INPUT "ENTER LOAN PRINCIPAL AMOUNT: $";P
3840 PRINT " (PYMT.AMT. >= 1% OF PRIN.)
3850 INPUT "EACH REGULAR PAYMENT AMOUNT: $";R
3860 PRINT : GOSUB 4330: PRINT
3870 Y = -( LOG(1 -(P *(I/100))/(N *R))/( LOG(1 +I/100/N) *N))
3880 PRINT "LOAN REPAYMENT WILL REQUIRE= "; INT(10 *Y +.5)/10;" YRS"
3890 RETURN
3900 REM -------------------
3910 REM LOAN.AMORT.SCHEDULE
3920 REM -------------------
3930 PRINT " THE MORTGAGE AMORTIZATION TABLE"
3940 PRINT : GOSUB 4330
3950 REM LEADING & TRAILING ZERO'S NOT ?"ED"
3960 C = 0:F = 0
3970 INPUT "ENTER INITIAL LOAN AMOUNT : $";A
3980 PRINT
3990 INPUT "ENTER LOAN'S INTEREST RATE : ";J: CALL -998: HTAB (32): PRINT J;" %"
4000 PRINT
4010 INPUT "LIFE OF THE LOAN IN YEARS : ";N: CALL -998: HTAB (32): PRINT N;" YRS"
4020 PRINT : GOSUB 4330: PRINT
4030 J = J/100
4040 N = N *12:I = J/12:B = 1 +I:R = A *I/(1 -1/B ^N)
4050 R = INT(100 *R +.5)/100
4060 PRINT "PAYMENT AMOUNT EACH MONTH = $";R
4070 Q = INT(100 *(R *N -A) +.5)/100
4080 PRINT "TOTAL INTEREST AMOUNT PAID : $";Q
4090 PRINT
4100 INVERSE : PRINT "WANT THIS ON SCREEN OR PRINTER ";: FLASH : PRINT "(S/P)";: NORMAL : PRINT ":";: GET SP$: PRINT
4110 IF SP$ = "P" THEN 4250
4120 CALL -998
4130 INVERSE : PRINT "TO BEGIN LISTING HIT THE SPACE BAR ...": NORMAL : GET A$
4140 PRINT : GOSUB 4330:B = A
4150 PRINT "PMT INTEREST PRINCIPAL BALANCE"
4160 C = C +1:L = B *I:P = R -L:B = B -P
4170 C = INT(100 *C +.5)/100:L = INT(100 *L +.5)/100:P = INT(100 *P +.5)/100:B = INT(100 *B +.5)/100
4180 PRINT "#";C: CALL -998: HTAB (7): PRINT L: CALL -998: HTAB (18): PRINT P: CALL -998: HTAB (29): PRINT B
4190 F = F +1
4200 IF F = 20 THEN 4280
4210 IF B > = R THEN 4160
4220 C = C +1
4230 PRINT "#";C: CALL -998: HTAB (7): PRINT INT(100 *(B *I) +.5)/100: CALL -998: HTAB (18): PRINT (R -( INT(100 *(B *I) +.5)/100))
4240 PRINT : PRINT " THE FINAL PAYMENT WAS $"; INT(D)/100 +B;" <=="
4250 RETURN
4260 F = 0
4270 RETURN
4280 INVERSE : PRINT "HIT SPACE BAR TO CONTINUE LISTING ...": NORMAL : GET A$
4290 PRINT
4300 F = 0
4310 PRINT "PMT INTEREST PRINCIPAL BALANCE"
4320 GOTO 4210
4330 REM -----------------
4340 REM MAKE-A-LINE GOSUB
4350 REM -----------------
4360 FOR II = 1 TO 39: PRINT "-";: NEXT II: PRINT "-": RETURN
4370 REM ------------------
4380 REM CLEAR.SCREEN.GOSUB
4390 REM ------------------
4400 CALL -936: RETURN
4410 REM -----------------
4420 REM PRINTOUT.ANSWER.?
4430 REM -----------------
4440 IF SP$ = "S" THEN 5120
4450 IF Z = 18 THEN 4490
4460 PRINT " ": PRINT : PRINT "WANT A ";: INVERSE : PRINT "PRINTOUT";: NORMAL : PRINT " OF THIS ANSWER ";: FLASH : PRINT "(Y/N)";: NORMAL : PRINT ":";: GET Y$: PRINT
4470 IF Y$ = "Y" THEN 4490
4480 RETURN
4490 CALL -998: INVERSE : PRINT "TURN ON";: NORMAL : PRINT " YOUR PRINTER AND PRESS ";: FLASH : PRINT "RETURN";: NORMAL : GET Y$
4500 PR# 1: REM PRINTER ON
4510 PRINT : FOR D = 1 TO 78: PRINT "-";: NEXT D: PRINT "-": PRINT : PRINT
4520 ON Z GOSUB 4550,4570,4590,4610,4630,4650,4670,4690,4710,4720,4770,4820,4840,4850,4870,4890,4910,4920
4530 PRINT : PRINT : FOR D = 1 TO 78: PRINT "-";: NEXT D: PRINT "-": PRINT : PRINT
4540 PRINT : RETURN
4550 PRINT "WITH AN INITIAL INVESTMENT OF $";P;" AT A NOMINAL INTEREST RATE OF ";100 *I *N;" %;": PRINT : PRINT "USING ";N;" COMPOUNDING PERIODS PER YEAR OVER ";Y;" YEARS, YOU WOULD ATTAIN"
4560 PRINT : PRINT "A FUTURE VALUE ON THIS INVESTMENT OF $"; INT(100 *T +.5)/100;".": RETURN
4570 PRINT "WITH REGULAR DEPOSITS OF $";R;" EACH INVESTED ";N;" TIMES PER YEAR, AT A": PRINT : PRINT "NOMINAL INTEREST RATE OF ";100 *I *N;" % OVER A ";Y;"-YEAR PERIOD, YOU WOULD ATTAIN"
4580 PRINT : PRINT " A FUTURE VALUE ON THESE DEPOSITS OF $"; INT(100 *T +.5)/100;" AT MATURITY.": RETURN
4590 PRINT "IN ORDER TO ATTAIN A TOTAL FUTURE VALUE OF $";T;" AT MATURITY; SAVINGS ": PRINT : PRINT "INVESTED AT A ";100 *I *N;"% NOMINAL INTEREST RATE, AND DEPOSITED REGULARLY ";N;" TIMES"
4600 PRINT : PRINT "PER YEAR OVER A ";Y;"-YEAR PERIOD WOULD REQUIRE DEPOSITS OF $"; INT(100 *R +.5)/100;" EACH.": RETURN
4610 PRINT "YOU MAY WITHDRAW $"; INT(100 *R +.5)/100;" FROM YOUR ACCOUNT ";N;" TIMES PER YEAR OVER A PERIOD": PRINT : PRINT "OF ";Y;" YEARS WITHOUT REDUCING YOUR INITIAL INVESTMENT OF $";P;", WHICH"
4620 PRINT : PRINT "WAS ORIGINALLY DEPOSITED AT A ";100 *I *N;"% NOMINAL INVESTMENT RATE.": RETURN
4630 PRINT "YOU MUST INVEST $"; INT(100 *P +.5)/100;" ANNUALLY FOR A PERIOD OF ";Y;" YEARS AT A NOMINAL ": PRINT : PRINT "INTEREST RATE OF ";I1;"% COMPOUNDED ";N;" TIMES PER YEAR TO ATTAIN A TOTAL RETURN"
4640 PRINT : PRINT "OF $";T;" AT THE TIME OF MATURITY.": RETURN
4650 PRINT "IN ORDER TO WITHDRAW ";N;" TIMES YEARLY A REGULAR INCOME OF $";R;" EACH, YOU": PRINT : PRINT "MUST HAVE A MINIMUM INVESTMENT OF $"; INT(100 *P +.5)/100;" HELD AT A NOMINAL INTEREST RATE OF"
4660 PRINT : PRINT "AT LEAST ";I1;"% PER YEAR OVER A PERIOD OF ";Y;" YEARS.": RETURN
4670 PRINT "AN INVESTMENT OF $";P;" WHICH IS HELD FOR ";Y;" YEARS AT AN ANNUAL COMPOUNDING": PRINT : PRINT "RATE OF ";N;" TIMES PER YEAR WILL YIELD A TOTAL OF $";T;" AT MATURITY IF IT IS"
4680 PRINT : PRINT "KEPT AT A NOMINAL INTEREST RATE OF "; INT(100 *I2 +.5)/100;"% DURING THE TIME OF INVESTMENT.": RETURN
4690 PRINT "WITH AN INITIAL INVESTMENT OF $";P;" WHICH YOU WOULD LIKE TO SEE MATURE": PRINT : PRINT "IN ";Y;" YEARS TO A TOTAL END-OF-INVESTMENT VALUE OF $";T;", YOU WOULD NEED TO "
4700 PRINT : PRINT "INVEST THESE FUNDS AT AN EFFECTIVE ANNUAL INTEREST RATE OF "; INT(100 *I3 +.5)/100;"%.": RETURN
4710 PRINT "IF YOU PURCHASED AN ITEM FOR $";P;" AND THE RESOLD IT ";Y;" YEARS LATER ": PRINT : PRINT "FOR $";T;", THEN THE ACTUAL DEPRECIATION RATE WOULD BE "; INT(1000 *D1 +.5)/1000;"% .": RETURN
4720 PRINT "ANNUAL DEPRECIATION ON AN ITEM PURCHASED FOR $";P;" AT A RATE OF ";100 *I;"% IS:"
4730 FOR Y = 1 TO K:D1 = P *I *(1 -I) ^(Y -1): PRINT " YEAR #";Y;" = $"; INT(100 *D1 +.5)/100
4740 X = X +1: IF X = 5 THEN X = 0
4750 IF D1 > = 2 THEN NEXT Y
4760 RETURN
4770 PRINT "IF AN ITEM WITH A PURCHASE PRICE OF $";P;" IS DEPRECIATED AT A RATE OF ";I;"%,": PRINT "THEN THE ANNUAL SALVAGE RATE ON THIS ITEM WILL BE:"
4780 FOR Y = 1 TO K:S = INT(100 *P *(1 -I/100) ^Y +.5)/100: PRINT " YEAR #";Y;" = $";S
4790 X = X +1: IF X = 5 THEN X = 0
4800 IF S > = 2 THEN NEXT Y
4810 RETURN
4820 PRINT "IF YOU PURCHASE A NOTE WHICH IS WORTH $";T;" AND DUE TO MATURE IN ";N;" DAYS": PRINT : PRINT "AT A DISCOUNT RATE OF ";D2 *100;"%, THEN THE DISCOUNT AMOUNT WILL BE $"; INT(100 *D1 +.5)/100;" AND"
4830 PRINT : PRINT "THE NOTE'S PURCHASE COST WILL BE $";T -( INT(100 *D1 +.5)/100);" .": RETURN
4840 PRINT "IF YOU HAD A LOAN AT AN ANNUAL INTEREST RATE OF ";I;"% OVER A PERIOD OF ";Y;" YEARS": PRINT : PRINT "WITH ";N;" PAYMENTS OF $";R;" EACH PER YEAR, YOUR PRINCIPAL WOULD BE $"; INT(100 *P +.5)/100;" .": RETURN
4850 PRINT "IF YOU TAKE OUT A LOAN WITH A PRINCIPAL OF $";P;" AT AN ANNUAL INTEREST RATE": PRINT : PRINT "OF ";I;"% WITH ";N;" REGULAR PAYMENTS PER YEAR OVER A PERIOD OF ";Y;" YEARS, THEN"
4860 PRINT : PRINT "YOUR REGULAR PAYMENTS WILL BE $"; INT(100 *R +.5)/100;" EACH TIME.": RETURN
4870 PRINT "FOR A LOAN WITH AN ORIGINAL PRINCIPAL OF $";P;" AT AN ANNUAL INTEREST RATE OF ": PRINT : PRINT I *100;"% AND REGULAR PAYMENTS OF $";R;" EACH, ";N;" TIMES PER YEAR OVER A ";Y;"-YEAR"
4880 PRINT : PRINT "PERIOD, THE VERY LAST PAYMENT FOR THIS LOAN WOULD BE $"; INT((R +BO) *100 +.5)/100;" .": RETURN
4890 PRINT "FOR A LOAN WITH AN ORIGINAL PRINCIPAL OF $";P;" AT AN ANNUAL INTEREST RATE OF ": PRINT : PRINT I *100;"% AND REGULAR PAYMENTS OF $";R;" EACH, ";N;" TIMES PER YEAR, THE REMAINING"
4900 PRINT : PRINT "LOAN BALANCE AS OF YEAR #";Y;" AND PAYMENT #";N1;" WOULD BE $"; INT(100 *BO +.5)/100;" .": RETURN
4910 PRINT "ON A LOAN PRINCIPAL AMOUNT OF $";P;" AT AN ANNUAL INTEREST RATE OF ";I;"% WITH ": PRINT : PRINT N;" REGULAR PAYMENTS OF $";R;" PER YEAR, IT WOULD REQUIRE "; INT(10 *Y +.5)/10;" YEARS FOR REPAYMENT.": RETURN
4920 PRINT "THE FOLLOWING LOAN AMORTIZATION SCHEDULE IS FOR AN INITIAL LOAN OF $";A: PRINT "AT AN INTEREST RATE OF ";J *100;"% OVER A PERIOD OF ";N/12;" YEARS WITH REGULAR MONTHLY": PRINT "INSTALLMENT PAYMENTS OF $";R;" EACH TIME."
4930 PRINT :C = 0:B = A
4940 PRINT SPC( 12);"PYMT#"; SPC( 7);"INTEREST"; SPC( 6);"PRINCIPAL"; SPC( 8);"BALANCE"
4950 PRINT SPC( 12);"-----"; SPC( 7);"--------"; SPC( 6);"---------"; SPC( 8);"-------": PRINT
4960 C = C +1:L = B *I:P = R -L:B = B -P
4970 L = INT(100 *L +.5)/100:P = INT(100 *P +.5)/100:B = INT(100 *B +.5)/100
4980 C$ = STR$(C):L$ = STR$(L):P$ = STR$(P):B$ = STR$(B)
4990 LL = INT(100 *(L - INT(L)) +.5)/100:PP = INT(100 *(P - INT(P)) +.5)/100:BB = INT(100 *(B - INT(B)) +.5)/100
5000 LL$ = STR$(LL):PP$ = STR$(PP):BB$ = STR$(BB)
5010 IF LEN(BB$) = 2 THEN B$ = B$ +"0"
5020 IF LEN(BB$) <2 THEN B$ = B$ +".00"
5030 IF LEN(LL$) = 2 THEN L$ = L$ +"0"
5040 IF LEN(LL$) <2 THEN L$ = L$ +".00"
5050 IF LEN(PP$) = 2 THEN P$ = P$ +"0"
5060 IF LEN(PP$) <2 THEN P$ = P$ +".00"
5070 PRINT SPC( 17 - LEN(C$));C$; SPC( 15 - LEN(L$));L$; SPC( 15 - LEN(P$));P$; SPC( 15 - LEN(B$));B$
5080 IF C = N THEN 5100
5090 GOTO 4960
5100 PRINT : PRINT TAB( 16);"THE FINAL PAYMENT WAS $";L +P +B
5110 PRINT : PRINT TAB( 10);"THE TOTAL INTEREST PAID DURING THIS ENTIRE LOAN WAS $";Q
5120 RETURN
5130 REM ------------------
5140 REM REPEAT.SELECTION.?
5150 REM ------------------
5160 PR# 0: REM PRINTER OFF:PRINT
5170 CALL -998: INVERSE : PRINT "WANT TO RUN THIS SELECTION AGAIN";: NORMAL : PRINT " ";: FLASH : PRINT "(Y/N)";: NORMAL : PRINT ":";: GET Y$:
5180 IF Y$ = "Y" THEN GOTO 380
5190 GOTO 470
5200 REM -------------------
5210 REM PROGRAM.END.ROUTINE
5220 REM -------------------
5230 POKE -16368,0: TEXT : CALL -936: VTAB 10: HTAB 10: PRINT "* * * THE END * * *": END

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/HEADING.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 20 58 FC A9 01 8D 03 06 A9 0E 8D 04 06 A9 20 8D X|).... )....) .
$000010 06 05 8D 07 05 8D 08 05 8D 09 05 8D 0B 05 8D 0C ........ ........
$000020 05 8D 0D 05 8D 0E 05 8D 10 05 8D 11 05 8D 12 05 ........ ........
$000030 8D 13 05 8D 15 05 8D 16 05 8D 17 05 8D 18 05 8D ........ ........
$000040 86 05 8D 89 05 8D 8B 05 8D 90 05 8D 95 05 8D 98 ........ ........
$000050 05 8D 06 06 8D 07 06 8D 08 06 8D 09 06 8D 0B 06 ........ ........
$000060 8D 0C 06 8D 0D 06 8D 0E 06 8D 10 06 8D 15 06 8D ........ ........
$000070 18 06 8D 86 06 8D 89 06 8D 8E 06 8D 90 06 8D 95 ........ ........
$000080 06 8D 98 06 8D 06 07 8D 06 07 8D 09 07 8D 0B 07 ........ ........
$000090 8D 0C 07 8D 0D 07 8D 0E 07 8D 10 07 8D 11 07 8D ........ ........
$0000A0 12 07 8D 13 07 8D 15 07 8D 16 07 8D 17 07 8D 18 ........ ........
$0000B0 07 A9 D0 8D 9B 05 A9 D2 8D 9C 05 A9 CF 8D 9D 05 .)P...)R ...)O...
$0000C0 A9 C4 8D 9E 05 A9 D5 8D 9F 05 A9 C3 8D A0 05 A9 )D...)U. ..)C. .)
$0000D0 D4 8D A1 05 A9 C9 8D A2 05 A9 CF 8D A3 05 A9 CE T.!.)I." .)O.#.)N
$0000E0 8D A4 05 A9 B1 8D 9E 06 A9 B9 8D 9F 06 A9 B8 8D .$.)1... )9...)8.
$0000F0 A0 06 A9 B3 8D A1 06 60 .. .. .. .. .. .. .. .. .)3.!.`
** END **

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/HELLO.bas:

10 HOME :D$ = CHR$(4): PRINT
20 PRINT D$;"BLOAD HEADING"
30 CALL 36864
40 VTAB 10: HTAB 10: PRINT "INTERESTING PROGRAMS": PRINT : HTAB 4: PRINT "FROM THE LIBRARY OF DAVE ANGELL"
50 PRINT D$;"CATALOG"

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/HOROSCOPE.bas:

20 REM MADAM DUPRE'S
21 REM HOUSE OF THE ZODIAC
22 REM FROM KILOBAUD, FEB '79
23 REM PAGE 48
24 REM BY ADRIAN R. THORNTON
25 REM
50 DATA "A Q U A R I U S","- - - - - - - -","P I S C E S","- - - - - -"
60 DATA "A I R E S","- - - - -","T A U R U S","- - - - - -"
70 DATA "G E M I N I","- - - - - -","C A N C E R",- - - - - -"
80 DATA "L E O","- - -","V I R G O","- - - - -"
90 DATA "L I B R A ","- - - - -","S C O R P I O","- - - - - - -"
100 DATA "S A G I T T A R I U S","- - - - - - - - - - -","C A P R I C O R N","- - - - - - - - -"
130 CALL -936: VTAB 4: PRINT " WELCOME TO MADAME DUPRE'S": PRINT " 'HOUSE OF THE ZODIAC'"
140 PRINT : PRINT "TELL ME YOUR BIRTHDAY AND I WILL": PRINT "PRESENT YOUR HOROSCOPE."
150 PRINT : PRINT "ENTER YOUR BIRTH MONTH AND DAY AS": INPUT "FOUR DIGITS (MMDD) ";B
170 IF B <101 OR B >1231 THEN PRINT "INVALID DATE ENTRY - TRY AGAIN!": GOTO 150
180 IF B <120 THEN S = 12: GOSUB 340: GOTO 12000
190 IF B <219 THEN S = 1: GOSUB 340: GOTO 1000
200 IF B <321 THEN S = 2: GOSUB 340: GOTO 2000
210 IF B <420 THEN S = 3: GOSUB 340: GOTO 3000
220 IF B <521 THEN S = 4: GOSUB 340: GOTO 4000
230 IF B <621 THEN S = 5: GOSUB 340: GOTO 5000
240 IF B <723 THEN S = 6: GOSUB 340: GOTO 6000
250 IF B <823 THEN S = 7: GOSUB 340: GOTO 7000
260 IF B <923 THEN S = 8: GOSUB 340: GOTO 8000
270 IF B <1023 THEN S = 9: GOSUB 340: GOTO 9000
280 IF B <1122 THEN S = 10: GOSUB 340: GOTO 10000
290 IF B <1222 THEN S = 11: GOSUB 340: GOTO 11000
300 S = 12: GOSUB 340: GOTO 12000
340 PRINT : PRINT
350 FOR I = 1 TO S
360 READ S1$: READ S2$
370 NEXT I
375 CALL -936: VTAB 6
380 PRINT " Y O U R S I G N I S"
390 PRINT : POKE 36,(40 - LEN(S1$))/2 -1: PRINT S1$
400 POKE 36,(40 - LEN(S2$))/2 -1: PRINT S2$
410 PRINT : RETURN
500 VTAB 22: INPUT "DOES SOMEONE ELSE WISH A HOROSCOPE? (Y/N) ";Q$
510 IF Q$ = "Y" THEN RESTORE : GOTO 130
520 CALL -936: VTAB 6: PRINT "PLEASE CALL AGAIN - - BYE": END
1000 PRINT "YOU HAVE AN INVENTIVE MIND AND ARE": PRINT "INCLINED TO BE PROGRESSIVE. YOU LIE A": PRINT "GREAT DEAL. ON THE OTHER HAND YOU ARE": PRINT "INCLINED TO BE CARELESS AND IMPRAC-"
1010 PRINT "TICLE, CAUSING YOU TO MAKE THE SAME": PRINT "MISTAKES OVER AND OVER AGAIN. PEOPLE": PRINT "THINK YOU ARE STUPID."
1020 GOTO 500
2000 PRINT "YOU HAVE A VIVID IMAGINATION AND OFTEN": PRINT "THINK YOU ARE BEING FOLLOWED BY THE": PRINT "'CIA' OR 'FBI'. YOU HAVE MINOR ": PRINT "INFLUENCE OVER YOUR ASSOCIATES AND"
2010 PRINT "PEOPLE RESENT YOU FOR YOUR FLAUNTING": PRINT "OF YOUR POWER. YOU LACK CONFIDENCE ": PRINT "AND GENERALLY ARE A COWARD. PISCES ": PRINT "PEOPLE DO TERRIBLE THINGS TO SMALL": PRINT "ANIMALS."
2020 GOTO 500
3000 PRINT "YOU ARE THE PIONEER TYPE AND HOLD MOST": PRINT "PEOPLE IN CONTEMPT. YOU ARE QUICK": PRINT "TEMPERED, IMPATIENT AND SCORNFUL OF": PRINT "ADVICE. YOU ARE NOT VERY NICE."
3010 GOTO 500
4000 PRINT "YOU ARE PRACTICLE AND PERSISTENT. YOU": PRINT "HAVE A DOGGED DETERMINATION AND WORK": PRINT "LIKE HELL. MOST PEOPLE THINK YOU ARE"
4010 PRINT "STUBBORN AND BULLHEADED.": PRINT "YOU ARE A COMMUNIST."
4020 GOTO 500
5000 PRINT "YOU ARE A QUICK AND INTELLIGENT ": PRINT "THINKER. PEOPLE LIKE YOU BECAUSE YOU": PRINT "ARE A LOSER. HOWEVER, YOU ARE ": PRINT "INCLINED TO EXPECT TOO MUCH FOR TOO ": PRINT "LITTLE. THIS MEANS YOU ARE CHEAP."
5010 PRINT "GEMINIS ARE KNOWN FOR COMMITTING": PRINT "SUICIDE."
5020 GOTO 500
6000 PRINT "YOU ARE SYMPATHETIC AND UNDERSTANDING": PRINT "OF OTHER PEOPLE'S PROBLEMS. THEY": PRINT "THINK YOU ARE A SUCKER. YOU ARE": PRINT "ALWAYS PUTTING THINGS OFF. THAT'S WHY"
6010 PRINT "YOU'LL NEVER MAKE ANYTHING OF YOURSELF.": PRINT "MOST WELFARE RECIPIENTS ARE CANCER": PRINT "PEOPLE."
6020 GOTO 500
7000 PRINT "YOU CONSIDER YOURSELF A BORN LEADER.": PRINT "OTHERS THINK YOU ARE PUSHY. MOST LEO": PRINT "PEOPLE ARE BULLIES. YOU ARE VAIN AND"
7010 PRINT "DISLIKE HONEST CRITICISM. YOUR ": PRINT "ARROGANCE IS DISGUSTING. LEO PEOPLE": PRINT "ARE KNOWN THIEVES."
7020 GOTO 500
8000 PRINT "YOU ARE THE LOGICAL TYPE AND HATE DIS-": PRINT "ORDER. THIS NITPICKING IS SICKENING": PRINT "TO YOUR FRIENDS. YOU ARE COLD AND"
8010 PRINT "UNEMOTIONAL AND SOMETIMES FALL ASLEEP": PRINT "WHILE CONVERSING. VIRGOS MAKE GOOD": PRINT "BUS DRIVERS."
8020 GOTO 500
9000 PRINT "YOU ARE THE ARTISTIC TYPE AND HAVE A": PRINT "DIFFICULT TIME WITH REALITY. IF YOU ": PRINT "ARE A MAN, YOU ARE MORE THAN LIKELY "
9010 PRINT "IN PRISON. CHANCES FOR MONETARY GAINS": PRINT "ARE TERRIBLE. MOST LIBRA WOMEN MAKE": PRINT "GOOD HITCH HIKERS. ALL LIBRAS": PRINT "DIE OF OVEREATING."
9020 GOTO 500
10000 PRINT "YOU ARE SHREWD IN BUSINESS AND CANNOT": PRINT "BE TRUSTED. YOU SHALL ACHIEVE THE": PRINT "PINNACLE OF SUCCESS BECAUSE OF YOUR": PRINT "TOTAL LACK OF ETHICS. MOST SCORPIO"
10010 PRINT "PEOPLE ARE MURDERED."
10020 GOTO 500
11000 PRINT "YOU ARE OPTOMISTIC AND ENTHUSIASTIC.": PRINT "YOU HAVE A RECKLESS TENDENCY TO RELY ": PRINT "ON LUCK SINCE YOU LACK TALENT. THE": PRINT "MAJORITY OF SAGITTARIANS ARE DRUNKS"
11010 PRINT "OR DOPE FIENDS. PEOPLE LAUGH AT YOU A": PRINT "GREAT DEAL."
11020 GOTO 500
12000 PRINT "YOU ARE CONSERVATIVE AND AFRAID OF": PRINT "TAKING RISKS. YOU DON'T DO MUCH OF": PRINT "ANYTHING AND ARE LAZY. THERE HAS ": PRINT "NEVER BEEN A CAPRICORN OF ANY "
12010 PRINT "IMPORTANCE. CAPRICORNS SHOULD AVOID": PRINT "STANDING STILL FOR TOO LONG AS THEY": PRINT "TEND TO TAKE ROOT AND BECOME TREES."
12020 GOTO 500

Text found in 029_Interesting_Programs_Library_of_Dave_Angell_1983.dsk/RECIPE FILE 1.3.bas:

0 TEXT : HOME : INVERSE : LIST 61001 -: NORMAL : VTAB 1: HTAB 5
1 PRINT "%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%": FOR X = 2 TO 23: PRINT " %%%%%%%";: HTAB 33: PRINT "%%%%%%%": NEXT : HTAB 5: PRINT "%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%";
10 VTAB 1: PRINT CHR$(13) CHR$(4)"NOMONCIO"
20 REM SUB-STRING SEARCH FNCTN
30 REM BY LEE REYNOLDS,
40 REM 1/81 ISSUE OF CALL -APPLE
50 REM ***********************
60 REM ** **
70 REM ** RECIPE FILE 1.3 **
80 REM ** **
90 REM ***********************
100 REM
110 GOTO 1600: REM INIT & MENU
120 REM CENTER A$ SUBROUTINE
130 HTAB 20 - LEN(A$)/2 + NOT INPT: PRINT A$: RETURN
140 REM INPUT C/R TO CONTINUE
150 POKE CB,0: REM CLR KEYBOARD
160 NORMAL : PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : PRINT " TO CONTINUE ";: FLASH : PRINT U$;: NORMAL
170 WAIT KB,128: IF PEEK(KB) < >141 THEN 170
180 POKE CB,0: VTAB PEEK(VC) +1: HTAB 1: PRINT SPC( 40): RETURN
190 REM PRINT "READING" MESSAGE
200 VTAB 12: HTAB 16: PRINT "[READING]"
210 RETURN
220 REM ::: INPUT ROUTINE :::
230 REM MARGINS:A=LEFT,B=RIGHT,C=TOP,D=BOTTOM
240 INVERSE : FOR X = C TO D: VTAB X: HTAB A: PRINT SPC( B -1): PRINT : NEXT : REM DRAW "RECIPE CARD"
250 POKE LFT,A -1: POKE TP,C -1: POKE BM,D: POKE WTH,B: REM SET WINDOW
260 A$(0) = "": REM CLEAR FIRST STRING
270 VTAB C: PRINT : VTAB C: HTAB 1: REM POSITION CURSOR
280 STRING = 0: POKE CB,STRING
290 IF POS(X) < >B -1 THEN 320
300 IF PEEK(VC) = D -1 THEN CALL UP: VTAB PEEK(VC): NORMAL : PRINT S$;: INVERSE : PRINT SPC( B -1);: HTAB 1: GOTO 320
310 VTAB PEEK(VC) +2: HTAB 1
320 FLASH : PRINT U$;: INVERSE : WAIT KB,128:A$ = CHR$( PEEK(KB)): IF ASC(A$) <160 OR ASC(A$) >222 OR ASC(A$) = 162 THEN 370
330 A$(STRING) = A$(STRING) +A$: IF LEN(A$(STRING)) = 217 THEN STRING = STRING +1:A$(STRING) = ""
340 IF STRING >9 THEN CALL BP: CALL BP: CALL BP: CALL BP: GOTO 480
350 HTAB POS(X): PRINT A$;
360 POKE CB,0: GOTO 290
370 REM SPECIAL CHARACTER
380 IF A$ = CHR$(134) THEN 480
390 IF A$ = CHR$(155) THEN NORMAL : POKE CB,0: POP : TEXT : HOME : GOTO 1840
400 IF A$ = CHR$(136) THEN 420
410 PRINT H$;: CALL BP: GOTO 360
420 IF LEN(A$(STRING)) >1 THEN A$(STRING) = LEFT$(A$(STRING), LEN(A$(STRING)) -1): GOTO 450
430 IF NOT LEN(A$(STRING)) THEN 410
440 A$(STRING) = ""
450 PRINT A$S$;
460 IF POS(X) = 1 AND PEEK(VC) >C -1 THEN VTAB PEEK(VC): HTAB B +1
470 GOTO 350
480 POKE CB,0: CALL BP: TEXT : HOME : NORMAL : RETURN
490 REM ::: ENTER RECIPES :::
500 HOME : INVERSE : VTAB 3:A$ = ": FILE NEW RECIPES :": GOSUB 120: NORMAL
510 VTAB 6: FOR X = 0 TO 4: PRINT "<" CHR$(X +65)">. . "CT$(X): NEXT : VTAB 6: FOR X = 5 TO 9: HTAB 23: PRINT "<" CHR$(X +65)">. . "CT$(X): NEXT
520 FOR X = 5 TO 11 STEP 6: VTAB X: PRINT DASH$: NEXT
530 PRINT
540 PRINT "ENTER THE LETTER OF THE": PRINT "APPROPRIATE CATEGORY :"U$;: HTAB 28: GET CG$: PRINT CG$: IF CG$ = "" THEN HOME : GOTO 1840
550 CG = ASC(CG$) -65: IF CG <0 OR CG >9 THEN HOME : GOTO 1840
560 PRINT : PRINT "NAME OF RECIPE ";: FOR X = 1 TO 20: PRINT U$;: NEXT : HTAB 15: INPUT ":";NM$
570 IF LEN(NM$) >20 THEN NM$ = LEFT$(NM$,20)
580 IF NOT LEN(NM$) THEN CALL BP: GOTO 500
590 VTAB 19: PRINT "NAME:";: FLASH : PRINT NM$: NORMAL : PRINT : PRINT "CATEGORY:";: FLASH : PRINT CT$(CG): NORMAL
600 PRINT : PRINT "IS THE ABOVE INFO CORRECT ?"U$;: HTAB 33: GET YN$: PRINT YN$: IF YN$ < >"N" THEN 620
610 VTAB 14: CALL CT: GOTO 540
620 REM INPUT THE RECIPE
630 INPT = 1: REM FLAG FOR CENTERING SUBR
640 HOME :A$ = NM$ +" (" +CT$(CG) +")": GOSUB 120
650 PRINT :A$ = ".....TYPE THE RECIPE BELOW.....": GOSUB 120
660 INPT = 0
670 VTAB 5: HTAB 4: PRINT LEFT$(DASH$,31): VTAB 22: HTAB 4: PRINT LEFT$(DASH$,31)
680 VTAB 24: HTAB 2: PRINT "";
690 A = 4:B = 32:C = 6:D = 21: GOSUB 220: REM SET WINDOW MARGIN PARAMETERS;GO TO "INPUT" SUBROUTINE
700 LNGTH = STRING: REM NUMBER OF"CHUNKS" OF TEXT (EACH CHUNK=217 CHARS,7 LINES OF 31)
710 VTAB 9
720 PRINT "INSERT DISK CONTAINING": PRINT "RECIPE FILES...": PRINT : GOSUB 140
730 PRINT
740 PRINT D$"OPENRF."CT$(CG)",L2000"
750 PRINT D$"READRF."CT$(CG)",R0"
760 INPUT REC
770 PRINT D$"WRITERF."CT$(CG)",R"REC +1
780 PRINT NM$: PRINT LNGTH
790 FOR X = 0 TO LNGTH
800 PRINT Q$A$(X)Q$
810 NEXT
820 PRINT D$"WRITERF."CT$(CG)",R0"
830 PRINT REC +1
840 PRINT D$"CLOSE"
850 CT(CG) = CT(CG) +1:TTL = TTL +1
860 REM PREVIOUS LINES OPEN THE FILE, ADD THE NEW DATA, REC 0 CONTAINS NUMBER OF RECIPESIN THIS FILE
870 PRINT : PRINT "THE RECIPE FOR "NM$" HAS": PRINT "BEEN ADDED TO THE "Q$CT$(CG)Q$" FILE.": PRINT : GOSUB 140: PRINT : HOME
880 GOTO 1840
890 REM ::: READ RECIPES :::
900 HOME : INVERSE : VTAB 3:A$ = ": READ RECIPES :": GOSUB 120: NORMAL :X1 = 0
910 PRINT : PRINT "LTR";: HTAB 5: PRINT "CATEGORY";: HTAB 36: PRINT "RECS": HTAB 5: PRINT LEFT$(DASH$,35)
920 FOR X = 0 TO 9:CG$ = CT$(X):REC = CT(X)
930 PRINT "< > . . . . . . . . . . . . . . . . . .";: HTAB 2: PRINT CHR$(X +65);: HTAB 5: PRINT CG$;: HTAB 39 -(REC >9): PRINT REC
940 NEXT
950 HTAB 5: PRINT LEFT$(DASH$,35)
960 HTAB 31: PRINT "TOTAL:";: HTAB 39 -(TTL >9) -(TTL >99): PRINT TTL: PRINT
970 HTAB 3: PRINT "PRESS THE LETTER OF": HTAB 3: PRINT "YOUR CHOICE :"U$;: HTAB 21: GET CG$: HOME : IF CG$ = "" THEN 1840
980 CG = ASC(CG$) -65: IF CG <0 OR CG >9 THEN 1840
990 PRINT : GOSUB 190
1000 PRINT D$"OPENRF."CT$(CG)",L2000"
1010 PRINT D$"READRF."CT$(CG)",R0"
1020 INPUT REC
1030 IF NOT REC THEN PRINT D$"CLOSE": GOTO 1430
1040 FOR X = 1 TO REC
1050 PRINT D$"READRF."CT$(CG)",R"X
1060 INPUT NM$(X)
1070 NEXT
1080 PRINT D$"CLOSE"
1090 HOME : INVERSE :A$ = ":" +S$ +Q$ +CT$(CG) +Q$ +S$ +"FILE :": GOSUB 120
1100 NORMAL : PRINT "NMBR";: HTAB 34: PRINT "RECIPE": PRINT LEFT$(DASH$,39)
1110 FOR X = 1 TO REC: PRINT ". . . . . . . . . . . . . . . . . . .";: HTAB 1: PRINT "<"X">";: HTAB 40 - LEN(NM$(X)): PRINT NM$(X)
1120 IF PEEK(37) = 21 AND X < >REC THEN 1140: REM CHECK FOR FULL PAGE OF TEXT
1130 NEXT : GOTO 1170
1140 PRINT LEFT$(DASH$,39): PRINT "ENTER # OR ";: INVERSE : PRINT "RETURN";: NORMAL : INPUT " FOR MORE: ";A$:N = VAL(A$)
1150 IF A$ = "" THEN VTAB 3: PRINT : GOTO 1130: REM RETURN FOR MORE
1160 GOTO 1190
1170 CALL CT: PRINT LEFT$(DASH$,39): PRINT "ENTER # OR ";: INVERSE : PRINT "RETURN";: NORMAL : INPUT " FOR MENU: ";A$:N = VAL(A$)
1180 IF A$ = "" THEN HOME : GOTO 1840: REM "RTN" SO BACK TO MENU
1190 IF N >REC THEN 1170
1200 HOME : GOSUB 190
1210 PRINT D$"OPENRF."CT$(CG)",L2000"
1220 PRINT D$"READRF."CT$(CG)",R"N
1230 INPUT NM$,LNGTH
1240 IF DL THEN PRINT D$"CLOSE": RETURN
1250 FOR X = 0 TO LNGTH
1260 INPUT A$(X)
1270 NEXT
1280 PRINT D$"CLOSE"
1290 HOME : VTAB 10: PRINT "OUTPUT TO CREEN OR

RINTER? "U$;: HTAB 34: GET A$: PRINT A$: IF A$ < >"S" AND A$ < >"P" THEN 1290
1300 IF A$ = "S" THEN 1460
1310 VTAB 13: PRINT "ENTER PRINTER'S SLOT # (DEFAULT=1)": PRINT : INPUT "OR BINARY DRIVER CALL: ";A$:PR = VAL(A$)
1320 IF A$ = "" THEN PR = 1: REM DEFAULT TO SLOT 1
1330 IF PR <1 OR PR >7 THEN CALL PR: GOTO 1350
1340 PRINT D$"PR#"PR: REM ACTIVATE PRINTER
1350 PRINT
1360 PRINT CHR$(9)"80N": PRINT "RECIPE FOR "NM$
1370 PRINT DASH$
1380 FOR X = 0 TO LNGTH:A$ = A$(X): FOR X1 = 0 TO 6: PRINT MID$ (A$,X1 *31 +1,31): NEXT : NEXT
1390 PRINT DASH$
1400 PRINT : PRINT
1410 PRINT D$"PR#0": REM RETURN TO SCREEN
1420 GOSUB 140: PRINT : HOME : GOTO 1840
1430 REM NO RECIPES IN CATEGORY
1440 FOR X = 1 TO 3: CALL BP: NEXT : HOME
1450 VTAB 11: PRINT "THERE ARE NO RECIPES CURRENTLY IN THE": PRINT Q$CT$(CG)Q$" FILE.": PRINT : GOSUB 140: HOME : GOTO 1840
1460 REM ::: SCREEN OUTPUT :::
1470 HOME : PRINT "RECIPE FOR ";: INVERSE : PRINT NM$: NORMAL : POKE TP,2: PRINT
1480 FOR X = 0 TO LNGTH:A$ = A$(X): FOR X1 = 0 TO 6: HTAB 4: PRINT MID$ (A$,X1 *31 +1,31)
1490 IF PEEK(37) = 22 THEN PRINT : GOSUB 140: HOME
1500 NEXT : NEXT
1510 GOSUB 140: HOME : VTAB 11
1520 PRINT "WOULD YOU NOW LIKE TO PRINT OUT THIS RECIPE ? "U$;: HTAB 15: GET A$: PRINT A$: IF A$ < >"Y" AND A$ < >"N" THEN VTAB 11: GOTO 1520
1530 TEXT : HOME : IF A$ = "Y" THEN 1310
1540 GOTO 1840
1550 REM ::: ERROR TRAP :::
1560 TEXT : HOME : NORMAL : PRINT CHR$(13)D$"CLOSE": PRINT D$"PR#0"
1570 ER = PEEK(222): IF ER = 255 THEN 2710
1580 PRINT "ERROR #"ER" HAS OCCURRED IN LINE #" PEEK(218) + PEEK(219) *256
1590 FOR X = 1 TO 5: CALL BP: NEXT : PRINT : END
1600 REM ::: INITIALIZATION :::
1610 SPEED= 255
1620 D$ = CHR$(4): REM CTRL-D
1630 Q$ = CHR$(34): REM QUOTE
1640 S$ = CHR$(32): REM SPACE
1650 U$ = CHR$(95): REM SCORE
1660 H$ = CHR$(8): REM BCKSPC
1670 LFT = 32: REM LEFT MARGIN
1680 WTH = 33: REM SCREEN WIDTH
1690 TP = 34: REM TOP MARGIN
1700 BM = 35: REM BOTTOM MARGIN
1710 CT = -958: REM CLR WNDW
1720 UP = -912: REM SCROLL UP
1730 KB = -16384: REM KYBOARD
1740 CB = -16368: REM CLR KBD
1750 BP = -198: REM CALL BEEP
1760 VC = 37: REM VERT.CURSOR
1770 DIM NM$(150)
1780 DASH$ = "----------------------------------------"
1790 NOTRACE
1800 FOR X = 0 TO 9: READ CT$(X): NEXT : REM GET CATEGORY NAMES
1810 IF PEEK(768) < >32 OR PEEK(769) < >227 THEN GOSUB 3330
1820 GOSUB 2010
1830 REM ::: MENU :::
1840 INVERSE : VTAB 3: HTAB 3: PRINT SPC( 36): FOR X = 4 TO 21: VTAB X: HTAB 2: PRINT SPC( 38): NEXT : VTAB 22: HTAB 3: PRINT SPC( 36)
1850 DL = 0: VTAB 4: PRINT
1860 A$ = "*** RECIPE FILE 1.3 ***": GOSUB 120
1870 PRINT :A$ = ".........BY JIM GANZ.........": GOSUB 120
1880 PRINT :A$ = "A PROGRAM WHICH ALLOWS YOU TO": GOSUB 120
1890 A$ = "ORGANIZE YOUR RECIPES ON DISK": GOSUB 120
1900 A$ = ".............................": GOSUB 120: PRINT
1910 HTAB 6: PRINT "NSERT A RECIPE": HTAB 6: PRINT "EAD RECIPES ("TTL" ON FILE)": HTAB 6: PRINT "EARCH FOR RECIPES": HTAB 6: PRINT "ELETE RECIPES"
1920 HTAB 6: PRINT "OW TO USE RF 1.3": HTAB 6: PRINT "UIT": PRINT
1930 HTAB 6: PRINT "SELECT:"U$;: HTAB 13: GET A$: IF NOT TTL AND (A$ = "R" OR A$ = "S" OR A$ = "D") THEN A$ = "X"
1940 IF A$ < >"I" AND A$ < >"R" AND A$ < >"S" AND A$ < >"D" AND A$ < >"H" AND A$ < >"Q" THEN CALL BP: GOTO 1930
1950 PRINT A$;: NORMAL : PRINT
1960 ON A$ = "I" GOTO 490: ON A$ = "R" GOTO 890: ON A$ = "S" GOTO 2740: ON A$ = "D" GOTO 3040: ON A$ = "H" GOTO 2160: GOTO 2710
1970 REM CATEGORY NAME DATA
1980 DATA BEVERAGES,BREADS,DESSERTS,FISH,HORS D'OEUVRES,MEAT,POULTRY,SOUPS,VEGETABLES,OTHER
1990 REM CHANGE CATEGORY NAMES AS NEEDED
2000 REM CATEGORY NAMES MAY NOT EXCEED 16 CHARS.
2010 REM ::: INIT FILES :::
2020 POKE 33,3: ONERR GOTO 2040
2030 PRINT D$"VERIFYRF."CT$(0): POKE 216,0: GOTO 2120
2040 IF PEEK(222) < >6 THEN TEXT : HOME : STOP : REM AN ERROR DID OCCUR, BUT IT WASN'T A "FILE NOT FOUND" ERROR SO STOP
2050 FOR X = 0 TO 9:CT$ = CT$(X)
2060 PRINT D$"OPENRF."CT$",L2000"
2070 PRINT D$"WRITERF."CT$",R0"
2080 PRINT 0:CT(X) = 0
2090 PRINT D$"CLOSE"
2100 NEXT : POKE 216,0: RUN 1600
2110 REM THE PREVIOUS ROUTINE CREATES ALL 10 RECIPE FILES AND SPECIFIES IN EACH ONE THAT THERE ARE 0 RECORDS
2120 FOR X = 0 TO 9:CG$ = CT$(X): PRINT D$"OPENRF."CG$",L2000": PRINT D$"READRF."CG$",R0": INPUT CT(X): PRINT D$"CLOSE":TTL = TTL +CT(X): NEXT
2130 TEXT : HOME : ONERR GOTO 1550
2140 RETURN
2150 REM ::: INSTRUCTIONS :::
2160 TEXT : HOME : PRINT "::::::::";: INVERSE : PRINT "RECIPE FILE INSTRUCTIONS";: NORMAL : PRINT "::::::::"
2170 PRINT : POKE TP,3
2180 PRINT " THIS PROGRAM WILL STORE YOUR MOST": PRINT
2190 PRINT "OFTEN USED RECIPES ON DISK AND ALLOW YOU"
2200 PRINT "TO OBTAIN A PRINT-OUT OF THEM ON YOUR": PRINT
2210 PRINT "PRINTER. WHEN YOU WANT A PARTICULAR": PRINT
2220 PRINT "RECIPE, OR WHEN A FRIEND WANTS A COPY OF"
2230 PRINT "ONE OF YOUR RECIPES, SIMPLY SELECT THAT": PRINT
2240 PRINT "RECIPE FROM THE PROGRAM'S 'MENU' AND IT": PRINT
2250 PRINT "WILL BE PRINTED OUT FOR YOU. FOR THOSE ": PRINT "WITHOUT A PRINTER THERE IS A SCREEN-ONLY": PRINT "OPTION.": PRINT
2260 PRINT ":::::::";: GOSUB 140
2270 PRINT " BEFORE YOU ACTUALLY BEGIN ENTERING": PRINT
2280 PRINT "YOUR RECIPES INTO THIS PROGRAM, IT IS": PRINT
2290 PRINT "SUGGESTED THAT YOU SAVE THIS PROGRAM,": PRINT
2300 PRINT "CALLED 'RECIPE FILE 1.3,' ON A SEPARATE": PRINT
2310 PRINT "DISK. THE 10 TEXT FILES WHICH ACCOMPANY"
2320 PRINT "'RECIPE FILE,' WHICH ARE IDENTIFIED BY": PRINT
2330 PRINT "THEIR PREFIX 'RF.', SHOULD BE THE ONLY": PRINT
2340 PRINT "OTHER FILES ON THE SAME DISK AS THIS": PRINT
2350 PRINT "PROGRAM.": PRINT
2360 PRINT " EACH RECIPE IS ENTERED ON A KIND OF": PRINT
2370 PRINT ":::::::::";: GOSUB 140
2380 PRINT "VIDEO RECIPE CARD. PRETEND THAT YOU ARE": PRINT
2390 PRINT "TYPING ON A REAL RECIPE CARD AND ENTER": PRINT
2400 PRINT "ALL NECESSARY INFORMATION. YOU MAY": PRINT
2410 PRINT "JUSTIFY THE TEXT AS YOU WISH, AND WHEN": PRINT
2420 PRINT "YOU REACH THE BOTTOM OF THE CARD, IT": PRINT
2430 PRINT "WILL SCROLL UPWARD SO YOU CAN CONTINUE.": PRINT
2440 PRINT "IT IS NOT NECESSARY TO TYPE THE TITLE OF"
2450 PRINT "THE RECIPE ON THE CARD, AND YOU SHOULD": PRINT
2460 PRINT "KNOW THAT BOTH THE QUOTATION MARK AND": PRINT
2470 PRINT "THE FORWARD ARROW (->) ARE INOPERATIVE.": PRINT
2480 PRINT "::::::::";: GOSUB 140
2490 PRINT "PRESS CTRL-F WHEN YOU ARE COMPLETELY": PRINT
2500 PRINT "FINISHED TYPING IN THE RECIPE. TO RETURN"
2510 PRINT "TO THE MAIN MENU WITHOUT SAVING THE": PRINT
2520 PRINT "RECIPE, PRESS THE ESCAPE KEY.": PRINT
2530 PRINT " THE DELETE OPTION FROM THE MAIN MENU"
2540 PRINT "ALLOWS YOU TO DELETE A RECIPE FROM THE": PRINT
2550 PRINT "FILE. NOTE THAT ONCE A RECIPE HAS BEEN": PRINT
2560 PRINT "DELETED, IT CANNOT BE RESTORED.": PRINT
2570 PRINT " WITH THE SEARCH OPTION YOU CAN ENTER"
2580 PRINT "AN INGREDIENT (OR OTHER KEYWORD) AND": PRINT
2590 PRINT "::::::::";: GOSUB 140: VTAB 23
2600 PRINT "OBTAIN A LIST OF ALL RECIPES CONTAINING": PRINT
2610 PRINT "THAT INGREDIENT IN A GIVEN CATEGORY. FOR"
2620 PRINT "INSTANCE, YOU CAN FIND OUT HOW MANY OF": PRINT
2630 PRINT "YOUR DESSERT RECIPES USE PEANUT BUTTER.": PRINT
2640 PRINT " THAT'S ABOUT IT... THANK YOU ALL FOR"
2650 PRINT "MAKING THE APPLE COOKBOOK A SUCCESS, AND"
2660 PRINT "GOOD LUCK WITH RECIPE FILE 1.3. JG": PRINT
2670 GOSUB 140
2680 TEXT : HOME
2690 GOTO 1840: REM RETURN TO MENU
2700 REM END PROGRAM
2710 TEXT : HOME : TEXT
2720 PRINT "THANK YOU FOR USING "Q$"RECIPE FILE 1.3"Q$: PRINT "TODAY - AND ";: FLASH : PRINT "ENJOY";: NORMAL : PRINT "!"
2730 FOR I = 1 TO 2000: NEXT : PRINT CHR$(13); CHR$(4);"RUN KICK.IT.OFF"
2740 REM ::::: SEARCH :::::
2750 HOME : PRINT DASH$;: INVERSE : PRINT SPC( 40): VTAB 2:A$ = "*** RECIPE FILE SEARCH ***": GOSUB 130: NORMAL : PRINT DASH$
2760 POKE 34,3: PRINT : VTAB 4
2770 FOR X = 0 TO 4: PRINT "<" CHR$(X +65)">. . "CT$(X): NEXT : VTAB 4: FOR X = 5 TO 9: HTAB 23: PRINT "<" CHR$(X +65)">. . "CT$(X): NEXT
2780 PRINT DASH$
2790 PRINT : PRINT "SEARCH CATEGORY : "U$;: HTAB 24: GET CT$:CS = ASC(CT$) -65: IF CS <0 OR CS >9 THEN 3030
2800 PRINT CT$:CT$ = CT$(CS)
2810 IF NOT CT(CS) THEN CALL BP: PRINT : PRINT "THERE ARE NO RECIPES CURRENTLY FILED IN THAT CATEGORY... PLEASE TRY AGAIN:": GOTO 2790
2820 PRINT
2830 INPUT "ENTER SEARCH INGREDIENT:";SS$
2840 IF NOT LEN(SS$) THEN 2820
2850 POKE 34,2: HOME : PRINT DASH$;: PRINT "CATEGORY:";: INVERSE : PRINT CT$;: NORMAL : HTAB 34 - LEN(SS$): PRINT "INGRED:";: INVERSE : PRINT SS$;: NORMAL
2860 PRINT "FOUND IN OF "CT(CS)" RECIPES CHECKED": PRINT DASH$
2870 POKE 34,6:SF = 0
2880 PRINT D$"OPENRF."CT$",L2000"
2890 FOR X = 1 TO CT(CS)
2900 PRINT D$"READRF."CT$",R"X
2910 INPUT NM$,LNGTH
2920 FOR XX = 0 TO LNGTH
2930 INPUT TXT$(XX)
2960 & TXT$(XX),SS$
2970 IF NOT PEEK(26) THEN 3010
2980 REM STRING FOUND
2990 SF = SF +1: PRINT SF".";: HTAB 5: PRINT NM$:XX = LNGTH
3000 IF PEEK(37) = 22 AND X < >CT(CS) THEN PRINT D$"CLOSE": VTAB 24: GOSUB 150: HOME : PRINT CHR$(13)D$"OPENRF."CT$",L2000"
3010 NEXT : NEXT : PRINT D$"CLOSE": VTAB 5: HTAB 10: PRINT SF: VTAB 24
3020 GOSUB 150
3030 TEXT : HOME : GOTO 1840
3040 REM ::::: DELETE :::::
3050 DL = 1: REM FLAG FOR DELETE
3060 HOME : INVERSE : VTAB 3:A$ = ": DELETE RECIPES :": GOSUB 120: NORMAL :X1 = 0
3070 GOSUB 910:DL = 0
3080 HOME : VTAB 9
3090 PRINT "ARE YOU SURE YOU WANT TO ";: FLASH : PRINT "DELETE";: NORMAL : PRINT " THE": PRINT
3100 PRINT "RECIPE FOR ";: INVERSE : PRINT NM$;: NORMAL : PRINT " FROM"
3110 PRINT : PRINT "THE FILE ? "U$;
3120 HTAB 17: GET A$: IF A$ < >"Y" AND A$ < >"N" THEN 3120
3130 PRINT A$: IF A$ = "N" THEN HOME : GOTO 1840
3140 PRINT : PRINT "STAND BY -- NOW DELETING"
3150 REM
3160 REM RECIPE TO DELETE: NM$
3170 REM RECORD NUMBER: N
3180 REM CATEGORY: CT$(CG)
3190 REM # RECS IN CAT: CT(CG)
3200 REM TOTAL # RECS: TTL
3210 REM
3220 PRINT D$"OPENRF."CT$(CG)",L2000": PRINT D$"READRF."CT$(CG)",R"CT(CG)
3230 INPUT NO$,LNGTH
3240 FOR X = 0 TO LNGTH: INPUT TXT$(X): NEXT
3250 PRINT D$"WRITERF."CT$(CG)",R"N
3260 PRINT NO$: PRINT LNGTH
3270 FOR X = 0 TO LNGTH: PRINT Q$TXT$(X)Q$: NEXT
3280 CT(CG) = CT(CG) -1:TTL = TTL -1
3290 PRINT D$"WRITERF."CT$(CG)",R0"
3300 PRINT CT(CG)
3310 PRINT D$"CLOSE"
3320 HOME : GOTO 1840
3330 REM :::: POKE SEARCH ::::
3340 POKE 1013,76: POKE 1014,0: POKE 1015,3: REM JMP $300
3350 FOR X = 768 TO 879: READ Y: POKE X,Y: NEXT : RETURN
3360 DATA 32,227,223,133,6,132,7,160,0,132,26,177,6,133,24,200,177,6,72,200,177,6,133,7,104,133,6,32,190,222,32,227,223,133,8,132,9,160,0,177,8,133,25,200,177,8,72,200,177,8,133,9
3370 DATA 104,133,8,165,24,240,30,197,25,144,26,165,25,240,22,165,24,56,229,25,133,27,160,0,177,6,209,8,208,8,200,196,25,144,245,230,26,96,230,26,165,27,197,26,144,8,230,6,208,2,230,7,208,224,169,0,133,26,240,233
9000 REM
9010 REM FILES CREATED WITH
9020 REM "RECIPE.FILE" &
9030 REM "RECIPE FILE 1.2"
9040 REM ARE COMPATIBLE WITH
9050 REM "RECIPE FILE 1.3"
9060 REM
9070 REM PUBLISHED IN
9080 REM SOFTDISK MAGAZETTE
9090 REM 3811 ST. VINCENT
9100 REM SHREVEPORT, LA
9110 REM 71108
9120 REM
9130 REM 1.3 - 8/19/82
9140 REM
65535 REM *********************
65535 REM * *
65535 REM * RECIPE FILE 1.3 *
65535 REM * *
65535 REM * BY JIM GANZ *
65535 REM * 82 SPRING LANE *
65535 REM * WEST HARTFORD,CT *
65535 REM * 06107 *
65535 REM * *
65535 REM *ALL RIGHTS RESERVED*
65535 REM * *
65535 REM * DEDICATION: TO *
65535 REM * SALLY GANZ, STILL *
65535 REM * THE WORLD'S MOST *
65535 REM * DISORGANIZED COOK.*
65535 REM * *
65535 REM * REQUIRES: *
65535 REM * 48K APPLE ][+ *
65535 REM * ONE DISK DRIVE & *
65535 REM * PRINTER (OPTIONAL)*
65535 REM * *
65535 REM *********************