Notes

Disk directory for Volume_287_8-Bit_Font_Editor.dsk:

riag_006_Volume_287_-_8-Bit_Font_Editor/Volume_287_8-Bit_Font_Editor.dsk /H70/
A2 BIN 009 01/08/1989 03/14/1989 3,828 A=$4000
A2FE BAS 013 01/31/1989 03/14/1989 6,076 A=$0801
EDIT BAS 013 01/15/1989 03/14/1989 6,037 A=$0801
Instructions AWP 036 01/31/1989 03/14/1989 17,409
BOCKLIN.40 FON 017 01/10/1989 03/14/1989 7,794
FINITA.12 FON 005 01/15/1989 03/14/1989 1,913
GETEOF BIN 001 08/26/1988 03/14/1989 76 A=$0300
TABLE BIN 001 08/29/1988 03/14/1989 12 A=$03C4
Y.TABLE BIN 001 08/28/1988 03/14/1989 146 A=$0300
STARTUP BAS 003 01/05/1989 03/14/1989 941 A=$0801
NEWSTUFF BAS 006 01/15/1989 03/14/1989 2,157 A=$0801
RAMOUT BIN 001 01/05/1989 03/14/1989 93 A=$0300
VARIABLES VAR 001 02/27/1989 03/14/1989 491 A=$941A
PRODOS SYS 032 04/14/1988 03/14/1989 15,485
BASIC.SYSTEM SYS 021 12/14/1987 03/14/1989 10,240
ProDOS format; 57,856 bytes free; 85,504 bytes used.

Text found in Volume_287_8-Bit_Font_Editor.dsk/A2FE.bas:

10 LOMEM: 4096 *6
15 ONERR GOTO 20000
20 AUX = 4:D$ = CHR$(4):BUF = 20480:A1 = 16504:A2 = 16512:A4 = 16520:HT = 16390:LF = 16412:CL = 16417:BT = 16419:CH = 16415:RO = 16416:AC = 16425:LC = 16424:PP = 16407:LG = 16408:F1 = 16409:ST = 16411:M4 = 16384:M5 = 16385:FA = 16398:FD = 16399
25 KN = 16428:PL = 16429:PR = 16430:AF = PP -2:AL = PP -1:A = 65
30 MS = 16467:TA = 16495:TM = TA +3:FI = 16527:CI = 17024:SR = 17647:DR = 17187:MW = 17981:MN = 18874:NS = 19354:FC = 19676:NI = 20076:TC = 20121
50 PRINT D$"bload a2": CALL MS: POKE AC,255: POKE LC,255
55 PRINT CHR$(4)"bloadgeteof"
60 GOTO 100
85 PRINT "Press any key...";: GET A$: RETURN
90 PRINT CHR$(4)"restore variables"
92 PRINT CHR$(4)"bloadgeteof"
95 ONERR GOTO 20000
100 TEXT : HOME : POKE 49167,0
110 FLASH : PRINT "A@A@";: NORMAL : PRINT " The 8-Bit IIgs Font Editor ";: FLASH : PRINT "@A@A";: NORMAL
115 FLASH : PRINT "_";: NORMAL : HTAB 15: PRINT "Version 1.0";: FLASH : HTAB 40: PRINT "Z";: NORMAL
120 FLASH : PRINT "_";: HTAB 40: PRINT "Z";: NORMAL
125 FLASH : PRINT "_";: NORMAL : HTAB 12: PRINT "by John G. Thomas";: HTAB 40: FLASH : PRINT "Z";: NORMAL
130 FLASH : PRINT "_";: NORMAL : PRINT " Ewing (New Jersey) Apple Users Group";: HTAB 40: FLASH : PRINT "Z";: NORMAL
135 FLASH : PRINT "_";: HTAB 40: PRINT "Z";: NORMAL
140 FLASH : PRINT "LLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLL": NORMAL
150 INVERSE : PRINT "START SCREEN OPTIONS": NORMAL
160 PRINT
170 PRINT " View or dit character images ": PRINT
180 PRINT " Make a ew font from scratch": PRINT
182 PRINT " Toggle nput device (now ";: IF M THEN PRINT "Mouse)": PRINT : GOTO 184
183 PRINT "Keyboard)": PRINT
184 PRINT " ile stuff, font file facts": PRINT
190 PRINT " uit to ProDOS...to ASIC": PRINT
192 PRINT " Edit character

adding": PRINT
200 PRINT "Pick one ";: GET A$
210 B$ = "EeNnIiFfBbQqPp": GOSUB 2900
215 IF K = 0 THEN PRINT CHR$(7): GOTO 100
220 ON K GOTO 940,4000,250,5000,230,230,8000
230 HOME : PRINT "Quit now??? (y/n) ";: GET A$: IF A$ < >"Y" AND A$ < >"y" THEN 100
233 IF K = 5 THEN 240
235 PRINT D$"bye"
240 END
250 M = M +1: IF M = 2 THEN M = 0
255 GOTO 100
260 HOME : HTAB 6: FLASH : PRINT "XY";: NORMAL : PRINT " Prefix Control Center ";: FLASH : PRINT "XY": NORMAL
280 IF PF$ = "" THEN PRINT D$"prefix": INPUT VN$:PF$ = VN$
290 PRINT : PRINT : PRINT "Font directory: "PF$: PRINT : PRINT
300 PRINT "The above directory will be the data disk unless you specify a new one.": PRINT : PRINT
310 PRINT "Press to return to the File options or any other key to enter a new directory.";: GET A$: IF A$ = CHR$(27) THEN 5000
330 PRINT : PRINT : PRINT : INPUT "New directory: ";PF$
340 IF RIGHT$(PF$,1) < >"/" THEN PF$ = PF$ +"/"
350 GOTO 5000
940 IF NOT FM THEN HOME : PRINT "No font in memory yet.": GOSUB 85: GOTO 100
950 PRINT D$"store variables"
960 PRINT D$"-edit"
1010 HOME : INPUT "Font file to load: ";F$: IF F$ = "" THEN 5000
1012 A$ = PF$ +F$: POKE 828, LEN(A$)
1015 FOR X = 1 TO LEN(A$): POKE 828 +X, ASC( MID$ (A$,X,1)): NEXT
1017 CALL 768:EF = PEEK(804) +256 * PEEK(805):B = 0:AUX = 4
1020 IF EF +1024 >48895 THEN HOME : PRINT "That file's too big.": PRINT "Pick another.": GOSUB 85: GOTO 5000
1025 IF EF <4097 THEN 1093
1030 PRINT D$"bload"A$",t$c8,a"BUF",l4096,b"B
1070 POKE A1,80: POKE A2,95: POKE A4,AUX: CALL TA
1080 B = B +4096:AUX = AUX +16:EF = EF -4096: IF EF <4097 THEN 1093
1090 GOTO 1030
1093 PRINT D$"bload"A$",t$c8,a"BUF",l"EF",b"B
1095 POKE A1,80: POKE A2,95: POKE A4,AUX: CALL TA
1100 FM = 1: CALL FI: GOTO 100
2900 K = 0: FOR X = 1 TO LEN(B$)
2910 IF A$ = MID$ (B$,X,1) THEN K = X
2920 NEXT
2927 K = K/2: IF K < > INT(K) THEN K = INT(K) +1
2930 RETURN
3020 IF NOT FM THEN HOME : PRINT "No font to save.": GOSUB 85: GOTO 5000
3030 HOME : PRINT "Enter filename";: IF LEN(F$) THEN PRINT " or press ": PRINT "to use "F$: PRINT : PRINT "New filename: ";: GOTO 3032
3031 PRINT ": ";
3032 INPUT "";A$: IF A$ = "" THEN A$ = F$
3033 A$ = PF$ +A$
3034 B = 0:AUX = 4: CALL FI:EF = PEEK(LF) + PEEK(LF +1) *256
3035 PRINT : PRINT : PRINT "Saving "A$"...": PRINT
3036 PRINT D$"verify"A$
3037 PRINT D$"delete"A$: GOTO 3040
3038 ONERR GOTO 20000
3040 PRINT D$"create"A$",t$c8"
3043 IF EF <4097 THEN 3065
3045 POKE A1,AUX: POKE A2,AUX +15: POKE A4,80: CALL TM: PRINT D$"bsave"A$",t$c8,a"BUF",l4096,b"B
3055 B = B +4096:AUX = AUX +16:EF = EF -4096: IF EF <4097 THEN 3065
3060 GOTO 3045
3065 POKE A1,AUX: POKE A2,AUX +15: POKE A4,80: CALL TM: PRINT D$"bsave"A$",t$c8,a"BUF",l"EF",b"B
3100 PRINT "Done. ";: GOSUB 85: GOTO 5000
4000 PRINT D$"store variables"
4010 PRINT D$"run newstuff"
5000 HOME : HTAB 11: FLASH : PRINT "FG";: NORMAL : PRINT " File Stuff ";: FLASH : PRINT "FG": NORMAL
5010 PRINT : PRINT : PRINT
5020 PRINT " oad file": PRINT
5030 PRINT " ave font": PRINT
5040 PRINT " Get atalog": PRINT
5050 PRINT " Select

refix for data disk": PRINT
5052 PRINT " See ont facts": PRINT
5060 PRINT " ape to Start Screen": PRINT
5070 PRINT : PRINT "Pick one ";: GET A$
5080 B$ = "LlSsCcPpFf" + CHR$(27) + CHR$(27): GOSUB 2900: IF K = 0 THEN PRINT CHR$(7): GOTO 5000
5090 ON K GOTO 1010,3020,7000,260,8500,100
7000 HOME
7010 X = LEN(PF$): IF X THEN PRINT D$"cat"PF$: GOTO 7040
7020 PRINT D$"cat"
7040 PRINT : GOSUB 85: GOTO 5000
8000 HOME : IF NOT FM THEN PRINT "No font in memory.": GOSUB 85: GOTO 100
8005 X = PEEK(PP): IF X >0 AND X <255 THEN PRINT "Non-proportional font.": GOSUB 85: GOTO 100
8010 CALL FI:X = PEEK(BUF):A$ = "": FOR Y = 1 TO X:A$ = A$ + CHR$( PEEK(BUF +Y)): NEXT
8020 PRINT "Font Family Name: "A$: HTAB 13: PRINT "Size: " PEEK(HT)
8030 FOR X = 1 TO 40: PRINT "-";: NEXT
8040 PRINT : INPUT "Enter the ASCII number of the character to work with: ";A$:A = VAL(A$): IF A < PEEK(AF) OR A > PEEK(AL) THEN PRINT CHR$(7): PRINT "Error--out of range...": FOR X = 1 TO 2500: NEXT : GOTO 8000
8050 POKE CH,A: CALL CI: IF PEEK(CH) = PEEK(AF -1) THEN PRINT "This character is undefined.": GOSUB 85: GOTO 8000
8060 PRINT : HTAB 7: PRINT "Character: " CHR$(A): PRINT
8070 X = PEEK(BT): HTAB 5: PRINT "Image width: "X
8080 X = PEEK(LC -1) -X: PRINT "Padding ight: "X
8090 X = PEEK(HT -5): IF X <128 THEN X = PEEK(LC -2): GOTO 8120
8110 X = X -256 + PEEK(LC -2)
8120 PRINT " Padding eft: "X: PRINT : PRINT : PRINT "Pick padding to change, press to see another, or to go back... ";: GET A$
8130 B$ = "RrLl" + CHR$(13) + CHR$(13) + CHR$(27) + CHR$(27): GOSUB 2900: IF K = 0 THEN PRINT CHR$(7): GOTO 8000
8140 ON K GOTO 8150,8220,8000,100
8150 PRINT : PRINT : PRINT "Padding on right for character " CHR$(A): PRINT "should be: ";: INPUT A$:X = VAL(A$): IF ABS(X) >255 THEN PRINT CHR$(7): PRINT "Error--out of range...": FOR X = 1 TO 2500: NEXT : GOTO 8150
8160 IF X > -1 THEN POKE PR,X: POKE PR +1,0: GOTO 8180
8170 POKE PR +1, ABS(X): POKE PR,0
8180 CALL CI: CALL FC: CALL FI: CALL CI
8200 PRINT "Done.": PRINT : PRINT "Work with the ame or a ifferent character, or press to return to Start Screen options. ";: GET A$:B$ = "SsDd" + CHR$(27) + CHR$(27): GOSUB 2900: IF K = 0 THEN PRINT CHR$(7);: GOTO 8200
8210 ON K GOTO 8060,8000,100
8220 PRINT : PRINT : PRINT "Padding on left for character " CHR$(A): PRINT "should be: ";: INPUT A$:X = VAL(A$): IF ABS(X) >255 THEN PRINT CHR$(7): PRINT "Error--out of range...": FOR X = 1 TO 2500: NEXT : GOTO 8220
8230 IF X > -1 THEN POKE PL,X: GOTO 8250
8240 POKE KN, ABS(X): POKE PL,0
8250 CALL CI: CALL FC: CALL FI: CALL CI: GOTO 8200
8500 HOME : IF NOT FM THEN PRINT "No font in memory.": GOSUB 85: GOTO 5000
8510 CALL FI:X = PEEK(BUF):A$ = "": FOR Y = 1 TO X:A$ = A$ + CHR$( PEEK(BUF +Y)): NEXT
8520 PRINT " Family Name: "A$: PRINT "Family Number: " PEEK(F1) + PEEK(F1 +1) *256;: HTAB 31: PRINT "Size: " PEEK(HT)
8530 FOR X = 1 TO 40: PRINT "-";: NEXT
8535 PRINT : PRINT
8540 X = PEEK(LF) + PEEK(LF +1) *256: HTAB 4: PRINT "File length in bytes: "X
8550 PRINT " ASCII, first character: " PEEK(AF)
8560 PRINT " ASCII, last character: " PEEK(AL)
8570 PRINT "Maximum character width: " PEEK(M4)
8580 X = PEEK(M5): IF X >127 THEN X = X -256
8585 PRINT " Maximum leftward kern: "X
8590 HTAB 13: PRINT "Font ascent: " PEEK(FA)
8600 HTAB 12: PRINT "Font descent: " PEEK(FD)
8610 HTAB 17: PRINT "Leading: " PEEK(LG)
8620 HTAB 14: PRINT "Style byte: " PEEK(ST)
8630 X = PEEK(PP): HTAB 6: PRINT "Proportional (y/n): ";: IF X = 255 THEN PRINT "can't tell yet": GOTO 8700
8640 IF X THEN PRINT "No--NPCWC="X: GOTO 8700
8650 PRINT "Yes"
8644 REM
8700 PRINT : GOSUB 85: GOTO 5000
9000 END
20000 POKE 216,0:EC = PEEK(222):EL = PEEK(218) + PEEK(219) *256:ER$ = "Unexpected error #" + STR$(EC)
20005 IF EC = 6 AND EL = 3036 THEN POKE 216,0: CALL -3288: GOTO 3038
20020 IF EC = 6 THEN ER$ = "That file is not on this disk."
20030 IF EC = 8 THEN ER$ = "Bad disk or drive door open."
20040 IF EC = 9 THEN ER$ = "No more room on this disk."
20060 IF EC = 13 THEN ER$ = "That file is the wrong type -- check a catalog listing."
20070 IF EC = 6 AND EL = 950 THEN ER$ = "Put program disk in drive & try again."
20100 HOME : FOR X = 1 TO 3: PRINT CHR$(7);: NEXT : PRINT ER$: PRINT : PRINT "Line #"EL: PRINT : PRINT : PRINT
20120 CALL -3288: GOSUB 85
20130 ONERR GOTO 20000
20140 GOTO 100

roportional or onproportional? ";: GET A$:B$ = "PpNn": GOSUB 2900: IF K = 0 THEN PRINT CHR$(7): GOTO 3210
3220 ON K GOTO 3230,3250
3230 POKE PP,0: RETURN
3250 PRINT : PRINT : INPUT "Enter the width of these non- proportional characters: ";A$:X = VAL(A$): IF X <0 OR X >95 THEN PRINT CHR$(7): PRINT "Out of range--try again...": PRINT : GOTO 3250
3260 POKE PP,X: RETURN
4000 HCOLOR= 0: DRAW 1 AT H1,V1
4050 PRINT D$"pr#4": PRINT CHR$(1);: PRINT D$"in#4": PRINT D$"pr#0":H2 = 100:V2 = 2
4055 HOME : VTAB 22: INVERSE : PRINT "DRAW OPTIONS";: NORMAL : PRINT " Move mouse to move cursor,";
4056 HTAB 9: PRINT "Click to draw, ";: FLASH : PRINT "@";: NORMAL : PRINT " to erase,"
4057 HTAB 13: PRINT " to go back";
4058 XDRAW 1 AT H1,V1: HCOLOR= 3
4060 INPUT "";X,Y,B: VTAB 1: XDRAW 1 AT H1,V1:H1 = INT(H2 +X/3):V1 = INT(V2 +Y/5): IF H1/2 < > INT(H1/2) THEN H1 = H1 -1
4080 IF V1/2 < > INT(V1/2) THEN V1 = V1 -1
4082 IF H1 <100 THEN H1 = 100
4084 IF H1 >100 +NB *2 THEN H1 = 100 +NB *2
4086 IF V1 <2 THEN V1 = 2
4088 IF V1 > PEEK(HT) *2 THEN V1 = PEEK(HT) *2
4100 XDRAW 1 AT H1,V1: ON B < >1 GOTO 5000: IF H1 = 100 + PEEK(BT) *2 THEN PRINT CHR$(7);: GOTO 5000
4420 XDRAW 1 AT H1,V1: GOSUB 2820: GOTO 4060
5000 Z = PEEK( -16384): ON Z <128 GOTO 5100: POKE -16368,0: IF Z = 155 THEN PRINT D$"in#0": GOTO 7000
5100 ON PEEK( -16286) >127 GOTO 5115: GOTO 4060
5115 IF H1 = 100 + PEEK(BT) *2 THEN PRINT CHR$(7);: GOTO 4060
5120 XDRAW 1 AT H1,V1: HCOLOR= 0: GOSUB 2820: HCOLOR= 3: GOTO 4060
7000 HOME : VTAB 21: INVERSE : PRINT "MOUSE OPTIONS";: NORMAL : PRINT " Save haracter,"
7010 PRINT "raw, <+>, <-> add, lose column,";
7020 PRINT " return to View Options ";
7030 GET A$:B$ = "CcDd++--" + CHR$(27) + CHR$(27): GOSUB 2900: IF K = 0 THEN PRINT CHR$(7): GOTO 7000
7040 ON K GOTO 7050,4000,7060,7070,1210
7050 GOSUB 2950: POKE CH,A: CALL CI: GOTO 1140: REM Save char
7060 C1 = (H1 -98)/2: GOSUB 2440: GOTO 7000: REM Add col
7070 C1 = (H1 -98)/2: GOSUB 2460: GOTO 7000: REM Lose col
8000 HOME : VTAB 21: PRINT "Copy above character to which 'missing' character? (specify by ASCII code # or just press to go back) ";: INPUT "";A$: IF A$ = "" THEN RETURN
8010 X = VAL(A$): IF X < PEEK(AF) OR X > PEEK(AL) THEN HOME : VTAB 21: PRINT "Error--out of range...(#" PEEK(AF)"-" PEEK(AL)" only)": PRINT : GOSUB 30: GOTO 8000
8020 Y = PEEK(BT)
8030 POKE CH,X: CALL CI: IF PEEK(CH) < > PEEK(AF -1) THEN HOME : VTAB 21: PRINT "Error--copy to 'missing' chars only...": PRINT : GOSUB 30: POKE CH,A: GOTO 8000
8040 POKE CH,X: CALL NI:A = X
8050 FOR X = 1 TO Y: CALL MW: NEXT : GOSUB 3010:N1 = 1
8060 RETURN
9000 PRINT CHR$(7)"Error--out of range": FOR X = 1 TO 2500: NEXT : RETURN
10000 IF N1 THEN GOSUB 2950
10005 PRINT D$"store variables"
10010 PRINT D$"run a2fe,@90"
20000 POKE 216,0:EC = PEEK(222):EL = PEEK(218) + PEEK(219) *256:ER$ = "Unexpected error #" + STR$(EC)
20100 TEXT : HOME : FOR X = 1 TO 3: PRINT CHR$(7);: NEXT : PRINT ER$: PRINT : PRINT "Line #"EL: PRINT : PRINT : PRINT
20120 CALL -3288: GOSUB 30
20130 ONERR GOTO 20000
20140 GOTO 1113

adding

Apple IIgs fonts have a table that keeps information for each character which indicates how that character should be positioned with respect to the current "pen location," and how far to advance the pen after drawing it. This editor translates this as padding left of and padding right of the character. The idea of "padding" is stretched a bit here because "negative padding" is allowed so that characters may be drawn leaning into their neighbors' space on either side. (When this occurs on the left side, it is called "kerning.")

When you choose to Edit character Padding, you can reset those values for any characters already created in the font in memory. This option only works with proportional fonts because the padding values in a non-proportional font are calculated by the editor to keep each character in the center of its space.

Specify each character you want to edit here by its ASCII value. That character's text value, image width (adjustable within the image editor), and current right and left padding values will be displayed. Press or to change the padding values which may range from -254 to 254.



Create a New Font

When you choose to Make a New font from scratch, you will come to a screen wherein you define the attributes of a new font. Enter each one or just press to accept the default if one is suggested.


Font Family Name and Number

Fonts of the same type face but with different sizes (size=height in pixel rows) constitute font families. For example, the Medici.9, .10, .12, .18, and .24 fonts together comprise the Medici font family. Each font family has a unique family number which can range from 0 to 65,000. Numbers 0 to 512 are reserved for Apple-assigned fonts and the others are for arbitrary assignment by font developers. In general, if you are creating a font of a new size of an existent font family, keep the same name and number. If you think you are creating a brand new family, choose a number higher than 512. When you enter the name, capitalize the first letter of it.


Proportional

If you choose to create a non-proportional font, you will later be asked for the "Non-proportional character width constant." This is the width in pixels that each character will take up in a line of text--not its image width. The image width of non-proportional characters may range from 1 to the non-proportional character width constant of the font. Remember to keep track of this value at least until 'i' and 'm' or 'I' and 'M' are created.


Point size (Height)

Note that 72 is the upper limit for this editor. 6 would be a "tiny" size and anything smaller would be hard to make recognizable characters in.


Descent

Associated with every character in a single font is an imaginary, common line called the base line. This separates the ascent portion of the character from the descent. Most characters don't have a part that descends below the base line (called a descender), but in most fonts, letters like 'j' and 'p' do. Enter a value that's just enough pixel rows to accommodate the lowest descent of any character.


Leading and Style

(See discussion above)


After the font is created, you may return to the Start Screen and save it to disk or go directly to the editor and begin to create characters.



Using the Editor

You should settle the mouse/keyboard situation at the Start Screen before coming to the editor. When you choose to View or Edit character images, the editor program is loaded and the font in memory is tested for proportionality. If this cannot be determined, you will be asked if the font is proportional, and, if not, you will also be asked for the non-proportional character width constant. The editor will then try to display the letter 'A' or the current character. If this character has not been defined yet, you will be asked if you want to define it.


Defining a new character

You will be asked how many pixels wide you want to start with. This question refers to the image width of the character. An estimation will be close enough here because image widths may be widened or made narrower via the Add and Lose Columns option. Enter your choice of image width and after a little while, you will come to the View Options screen with an empty Edit Box near the top of the screen. The Edit Box has little tabs on either side indicating the (common) base line of the font. The graphic cursor may be moved around inside the box with the current input device. Use the Edit Options to draw the character. Be sure that the image in the Edit Box does not include any padding to the left or right of the character. That is, the image should extend from one wall of the Edit Box to the other. Choose to save the character. Proportional characters require more input regarding padding; the padding of non-proportional characters is calculated by the program. You should return to the Start Screen (File stuff) and save the font to disk each time after defining a few characters. Fonts are usually named as the family name, a period, and a number for the point size.


View Options

Here you may Select another character to work with by key press or ASCII value, move to the Edit Options, browse through the characters of the font using the left and right arrow keys, escape to the Start Screen, or Copy the current character to an as yet undefined character. (You must know the ASCII value of the new character in order to copy an image to it.)


Edit Options (keyboard control)

If you are using the keyboard to edit characters, you have the following options:

- haracter save: writes the version of the character shown on the screen to the font in memory. Note--this does not save the font onto the data disk!

- Move the cursor with the arrow keys one pixel at a time.

- Add a column <+>, or lose one <-> at the current column position of the cursor. Note--there will be instances when you will not be able to lose columns: never in the case of the font's "missing character" symbol (see discussion below), and not when the current character is "too close" to the missing character. Note, also--to add a column at the right of a character, move the cursor into the right boundary of the Edit Box and press <+>.

- Turn a pixel on with the open apple key or turn a pixel off with the solid apple key.

- Escape back to the View Options screen.

Missing character notes: When a font is first created, the ASCII value of the first and last characters that it may contain are determined. This editor provides an ASCII range of 0 to 254. Some fonts, you may notice, have different ranges of ASCII availability. Defined immediately after the last character, there will be the "missing character" which applications use in a line of text to represent undefined characters in that font. This missing character may be edited with this editor except in the case where it has an ASCII value that is higher than 255. To select this character, choose Select from the View Options, and 'by ASCII' from the Select screen. The default missing character is a rectangle, but many font developers like to personalize the font with a custom missing character.


Mouse Options

- Character ave, Add <+>, lose <-> columns, and Escape back to the View Options work the same as when using the keyboard for input.

- raw takes you to the Draw Options screen


Draw Options

Use the mouse to move the graphic cursor in the Edit Box, as with the arrow keys in keyboard mode. Click the mouse button to turn on a pixel. Press the solid apple key turn off a pixel.


Revision List

Version 1.0 (January 15, 1989):

- "Sorry..." message in Startup program changed to all capitals.

- Improved mouse response

- Fixed bug in 'defined, 0-width character' routine

- Improved frequency of editor asking if font proportional or not