Notes

Disk info for Volume_196_Religious_Programs.dsk:

File Name: riag_006_Volume_196_-_Religious_Programs/Volume_196_Religious_Programs.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 0
Used Space (bytes): 143360
Physical Size (KB): 140
Free Space (KB): 0
Used Space (KB): 140
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 0
Used Sectors: 560
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for Volume_196_Religious_Programs.dsk:

riag_006_Volume_196_-_Religious_Programs/Volume_196_Religious_Programs.dsk DISK VOLUME #254
A 002 A*************************A
A 002 A BIG RED APPLE CLUB A
A 002 A 423 NORFOLK AVE. A
A 002 A NORFOLK NE. 68701 A
A 002 A A
A 009 A VOLUME N09 A
A 002 B*************************B
T 014 HELLO.TXT
A 010 GRAPE MENU
A 005 HELLO
T 023 APPLE BASIC
B 006 ALPHA SHAPES
A 007 AMAZING GRACE
A 021 BIBLE DRILL
T 005 BIBLE FATHERS.DRILL
T 004 BIBLE MOTHERS.DRILL
T 004 BIBLE NAMES MEANINGS.DRILL
T 045 BIBLE STUDY
T 012 BIBLICAL METROLOGY.DRILL
A 020 BLESSINGS
A 017 CRYPTOGRAMS
A 019 EYE-QUE
A 003 FREE SPACE
A 032 GRAPE MAZE
A 011 I'M THINKING
A 004 MUSICAL KEYS
A 005 NEW JERUSALEM
T 005 NEW TESTAMENT BOOKS.DRILL
T 014 NEW TESTAMENT VERSES.DRILL
A 014 NT BOOKS QUIZ
A 030 OLD OLD STORY
T 006 OLD TESTAMENT BOOKS.DRILL
A 014 OT BOOKS QUIZ
A 006 PEACE MAKER
T 019 QUOTATIONS
T 010 ROCK OF AGES.DRILL
T 006 SALVATION
A 007 SCRAMBLED VERSES
A 023 STUDY PROGRAM
A 039 STUDY QUESTION.U
A 010 STUDYFILE XFER.U
T 002 SUBJECT FILE
B 002 TONE.B
T 001 VERSION 1.0
DOS 3.3 format; 0 bytes free; 143,360 bytes used.

Text found in Volume_196_Religious_Programs.dsk/A NORFOLK NE. 68701 A.bas:

10 REM *** CHAINING HELLO
20 REM *** 4/7/97
30 REM *** DOUG TRUEMAN
40 PRINT CHR$(4);"RUN HELLO"

Text found in Volume_196_Religious_Programs.dsk/A VOLUME N09 A.bas:

1 REM *** BIG RED APPLE CLUB
3 REM *** VERSION 1.3.1
4 REM *** VERSION C (RUN ONE PROGRAM)
5 :
10 D$ = CHR$(4): PRINT D$;"PR#0": TEXT : HOME
20 V1 = 0: GOSUB 7000
30 INVERSE :A$ = "+": GOSUB 800: NORMAL
40 VTAB 14:A$ = "DISTRIBUTED BY": GOSUB 300: VTAB 6:A$ = ISSUE$: GOSUB 300: VTAB 7:A$ = DISKNAME$: GOSUB 300
50 VTAB 16:A$ = "THE BIG RED APPLE CLUB": GOSUB 300:A$ = "423 NORFOLK AVENUE": GOSUB 300:A$ = "NORFOLK, NE 68701": GOSUB 300
60 HTAB 8: GOSUB 5000
70 HOME : INVERSE :A$ = " ": GOSUB 810: NORMAL : VTAB 2: HTAB 2: INVERSE : FOR V1 = 1 TO 5: PRINT " ";: NEXT : HTAB 35: FOR V1 = 1 TO 5: PRINT " ";: NEXT : NORMAL
75 VTAB 1: INVERSE :A$ = ": :": GOSUB 300: VTAB 3: GOSUB 300: NORMAL
77 V1 = 13 -( LEN(ISSUE$)/2):I2$ = IS$: FOR V2 = 1 TO V1:I2$ = " " +I2$ +" ": NEXT : IF LEN(I2SUE$)/2 < > INT( LEN(I2SUE$)/2) THEN I2SUE$ = I2SUE$ +" "
80 VTAB 2: INVERSE :A$ = I2SUE$: GOSUB 300: NORMAL : VTAB 23:A$ = " THE BIG RED APPLE CLUB ": GOSUB 300
90 FOR V1 = T1 TO T2: HTAB 5: VTAB 5 +V1 -T1: INVERSE
100 IF V1 >9 THEN PRINT CHR$(55 +V1);: GOTO 120
110 PRINT V1;
120 NORMAL : PRINT TAB( 10);TITLE$(V1,1): NEXT
130 VTAB 21: HTAB 10: PRINT "ENTER SELECTION ";: GET A$: PRINT A$
132 IF ASC(A$) >96 THEN A$ = CHR$( ASC(A$) -32)
135 IF A$ > = "A" AND A$ < = "Z" THEN A$ = STR$( ASC(A$) -64 +9)
140 PK = INT( VAL(A$)): IF PK <1 OR PK >W THEN CALL -198: GOTO 130
150 IF PK = W THEN TEXT : HOME : END
151 VTAB 2: INVERSE :A$ = " ": GOSUB 300: NORMAL
152 VTAB 2: INVERSE :A$ = TITLE$(PK,1): GOSUB 300: NORMAL
155 POKE 34,3: POKE 35,22: POKE 32,1: POKE 33,36: VTAB 5: HTAB 10: HOME : POKE 32,5: VTAB 6
160 IF PK 96 THEN A$ = CHR$( ASC(A$) -32)
164 IF A$ < >"M" AND A$ < >"R" THEN CALL -198: GOTO 163
165 PRINT A$: IF A$ = "R" THEN TEXT : HOME : PRINT D$: PRINT D$FILE$
170 TEXT : GOTO 70
299 TEXT : HOME : END
300 HTAB (21 - LEN(A$)/2): PRINT A$: RETURN : REM *** CENTER LINE
400 VTAB 21: HTAB 3: PRINT "M = MENU R = RUN PROGRAM ";: GET A$: PRINT A$
410 IF A$ < >"M" AND A$ < >"R" THEN CALL -198: GOTO 400
420 VTAB 3: HOME : RETURN
799 REM *** PRINT BORDERS
800 VTAB 1: FOR X = 1 TO 40: PRINT A$;: NEXT
810 VTAB 23: FOR X = 1 TO 40: PRINT A$;: NEXT : VTAB 2: FOR X = 2 TO 22: HTAB 1: PRINT A$;: HTAB 40: PRINT A$;: NEXT : RETURN
5000 POKE -16368,0: VTAB 22: INVERSE : PRINT "PRESS ANY KEY TO CONTINUE ";: NORMAL : GET PT$: PRINT PT$: HOME : VTAB 6: RETURN
6999 REM ***READ TEXT FILE
7000 PRINT D$: PRINT D$"OPEN HELLO.TXT": PRINT D$"READ HELLO.TXT": INPUT ARTICLE: DIM TITLE$(AR,1): FOR V1 = 1 TO AR: INPUT TITLE$(V1,0): INPUT TITLE$(V1,1): NEXT : INPUT ISSUE$: INPUT DISKNAME$: INPUT FILE$
7010 DIM ARTICLE$(AR -1,14): FOR V2 = 1 TO AR -1: FOR V1 = 1 TO 14: INPUT ARTICLE$(V2,V1): NEXT : NEXT
7020 PRINT D$: PRINT D$"CLOSE"
7030 T1 = 1:W = AR:T2 = W
7040 RETURN

Text found in Volume_196_Religious_Programs.dsk/AMAZING GRACE.bas:

80 REM ***********************
85 REM MUSIC BY S. M. LAWSON
90 REM ***********************
95 REM
100 REM "AMAZING GRACE
105 GOSUB 3000
110 PRINT CHR$(4)"BLOADTONE.B"
120 DIM T(33):T(1) = 128:T(2) = 64:T(3) = 96:T(4) = 32:T(5) = 48:T(8) = 16:T(9) = 24:T(16) = 8:T(17) = 12:T(32) = 4:T(33) = 6
130 REM "NOTE: 7*OCTAVE+NOTE (ADD 22 FOR SHARP)
140 REM "TIME: DENOMINATOR (ADD 1 IF DOTTED)
150 FOR I = 1 TO 41: READ J,K: POKE 0,J: POKE 1,T(K): CALL 768: NEXT
155 PRINT : PRINT CHR$(4)"RUN GRAPE MENU"
160 DATA 4,4,7,2,9,8,7,8,9,2,8,4,7,2,5,4,4,2,,16,4,4,7,2,9,8,7,8,9,2,8,4,11,2,,8
170 DATA 9,4,11,5,9,8,11,8,9,8,7,2,4,4,5,5,7,8,7,8,5,8,4,2,,16,4,4,7,2,9,8,7,8,9,2,8,4,7,2,,4,7,3,7,3
2999 REM * FISH BY AMY *
3000 HOME
3005 GR
3010 COLOR= 15
3015 HLIN 22,23 AT 7
3020 HLIN 20,25 AT 8
3025 HLIN 18,19 AT 9: HLIN 26,28 AT 9
3030 HLIN 16,17 AT 10: HLIN 29,30 AT 10
3035 HLIN 14,15 AT 11: HLIN 31,32 AT 11: PLOT 3,11
3040 HLIN 3,4 AT 12: HLIN 13,14 AT 12: HLIN 33,34 AT 12
3045 HLIN 5,7 AT 13: HLIN 12,13 AT 13: PLOT 35,13
3050 HLIN 7,8 AT 14: HLIN 10,11 AT 14: PLOT 36,14
3055 PLOT 9,15: PLOT 37,15
3060 HLIN 7,8 AT 16: HLIN 10,11 AT 16: PLOT 36,16
3065 HLIN 6,7 AT 17: HLIN 12,13 AT 17: PLOT 35,17
3070 HLIN 5,6 AT 18: HLIN 13,14 AT 18: HLIN 33,34 AT 18
3075 HLIN 3,4 AT 19: HLIN 14,15 AT 19: HLIN 31,32 AT 19
3080 HLIN 16,17 AT 20: HLIN 29,30 AT 20
3085 HLIN 18,19 AT 21: HLIN 26,28 AT 21
3090 HLIN 20,25 AT 22: HLIN 22,23 AT 23
3095 PLOT 3,20
3100 HLIN 0,39 AT 0: HLIN 0,39 AT 39
3105 VLIN 0,39 AT 0: VLIN 0,39 AT 39
3106 COLOR= 3
3110 VLIN 29,33 AT 11
3115 PLOT 13,29: PLOT 13,33: PLOT 14,30: PLOT 14,32: PLOT 15,31: PLOT 16,30: PLOT 16,32: PLOT 17,29: PLOT 17,33
3120 VLIN 30,32 AT 19: VLIN 30,32 AT 21: PLOT 20,29: PLOT 20,33: PLOT 20,31
3125 VLIN 29,31 AT 23: VLIN 29,31 AT 27: PLOT 24,32: PLOT 25,33: PLOT 26,32
3130 HLIN 29,31 AT 29
3135 HLIN 29,31 AT 31: HLIN 29,31 AT 33: PLOT 29,30: PLOT 31,32
3140 HTAB 33: PRINT "BY AMY"
3150 RETURN
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/APPLE BASIC.txt:

45,A REVIEW OF INTEGER (INT) AND APPLESOFT (FP) BASIC - AND OTHER STUFF
IF A$ EQUALS 'SMART' WHAT DOES MID$(A$;3;3) EQUAL,ART,SEE LINE NUMBER 12000
WHAT DECIMAL LOCATION CAN YOU POKE TO CANCEL AN ONERR GOTO STATEMENT,216,?
IF X = INT (3.971) WHAT NUMBER WILL X BE,3,THE INT FUNCTION DROPS THE DECIMALS
IN INT BASIC WHAT WILL THIS PRODUCE- A$ = 'APPLE II' + 'I',SYNTAX ERR,JUST TO SEE IF YOU'RE ON YOUR TOES
WHEN USING DOS AND YOU USE A 'GET'; IT SHOULD BE FOLLOWED BY WHAT,PRINT,OR GET WILL GET YOUR GOAT
TRUE OR FALSE- THE APPLE HAS PROVISIONS FOR THREE PUSH BUTTONS,TRUE,?
ION,'GHR' APPEARS ON GRAPE VOLUME 103.

TO PLOT ON HIRES PAGE TWO WITHOUT USING A HGR2 COMMAND; POKE WHAT LOCATION,230,TRY POKE 230;64
IN INT BASIC COULD YOU SEE THE LINE* 1 LOMEM*4096,YES,ENTER FROM THE MONITOR BY TOKEN CHANGE
IF YOU SAW THE STATEMENT HCOLOR=4 WHAT COLOR WOULD YOU EXPECT TO SEE,BLACK,0 AND 4 PRODUCE BLACK
IF AN APPLE HAD A DISK DRIVE CONNECTED IN WHAT SLOT WOULD IT USUALLY BE IN,6,PRETTY EASY QUESTION
FOR D = 10 TO 1 STEP -.5 * NEXT D WHAT WOULD D BE AFTER THIS STATEMENT,.5,?
'RECALL' IS A RESERVED WORD IN FP BASIC (Y/N),YES,?
PUGETSOUND,HOT LINE IS (206) 932-6588
IF YOU WANT TO REUSE THE DATA LIST WHAT WORD SHOULD YOU USE,RESTORE,?
CHANGE,YES,BOX283 PORT ORCHARD WA 98366
NORMAL LOMEM IS SET AT WHAT DECIMAL LOCATION,2048,?
8192 DECIMAL IN HEX IS*,2000,$2000 IS ALSO CORRECT
PEEK; POKE; PRINT; POP; PLOT; POS AND PDL ARE LEGAL COMMANDS. HOW ABOUT 'PUT',NO,TRS-80'S HAVE IT
YES OR NO - IN INTEGER BASIC ON AN APPLEPLUS READ & DATA STATEMENTS ARE LEGAL,NO,TOO BAD; ISN'T IT
WHEN EDITING; A ESC D WILL MOVE THE CURSOR DOWN OR UP,UP,THAT MAKES SENSE
JOINING TWO STRINGS TOGETHER IS CALLED,CONCATENATION,HARD TO SAY; TOO
THE APPLE II HAS PROVISIONS FOR HOW MANYPADDLE (PDL) INPUTS,4,MOST PEOPLE FIND TWO ENOUGH
TYPING POKE 50;127 IN INTEGER BASIC IS THE SAME AS WHAT IN APPLESOFT,FLASH,?
IN INT BASIC 7 MOD 3 WILL GIVE WHAT RESULT,1,?
IN HI-RES FULL SCREEN GRAPHICS HOW MANY POINTS (DOTS) IN THE VERTICAL DIRECTION,192,0-191 FOR PLOTTING
IF YOUR SCREEN LOOKS YELLOW WHAT WILL PRINT SCRN (20;20) PRODUCE,13,13 IS THE LO-RES NUMBER FOR YELLOW
DOES THE 'CHAIN' DOS COMMAND WORK THE SAME FOR INT AS FOR FP (Y/N),NO,?
WHAT IS THE DECIMAL LENGTH OF THE TEXT SCREEN MEMORY,1024,400 HEX
HOW MANY TEXT SCREEN PAGES ARE THERE,2,?
WOULD THIS LINE WORK DIFFERENTLY IN INT THAN IN FP- IF X=0 THEN 100 * GOTO 200,YES,?
WHAT 'STEPHEN' HAS HAD SOMETHING TO DO WITH APPLE COMPUTER; INC.,WOZNIAK,STEVE JOBS IS 'STEVEN'
IF YOU ARE IN THE MINI-ASSEMBLER WHAT PROMPT CHARACTER WILL YOU SEE,!,?
THE BRAIN OF YOUR APPLE II IS A MOS TECHNOLOGY (WHAT) MICROPROCESSOR,6502,REFERENCE MANUAL; P.3
THE SECOND PAGE OF HIRES SCREEN STARTS AT WHAT HEX LOCATION,4000,?
HOW MANY ANNUNCIATOR OUTPUTS DOES THE APPLE II HAVE,4,CONNECT THEM TO LED'S; RELAYS; ETC.
WHICH LOCATION (DECIMAL) WOULD YOU PEEK AT TO FIND THE VERTICAL CURSOR POSITION,37,?
YES OR NO- IN RANDOM-ACCESS FILES YOU MUST SPECIFY THE BYTE (B),NO,?
YES OR NO- IN FP BASIC; X=100 * GOTO X; WILL TAKE THE PROGRAM TO LINE 100,NO,IT WOULD WORK IN INT BASIC
IN FP BASIC IF A = 3/2; WOULD A% = 3/2 BE THE SAME THING,NO,A WOULD BE A FRACTION; A% AN INTEGER
IF A 'CLEAR' STATEMENT IS ENCOUNTERED DOYOU HAVE TO REDIMENSION AN ARRAY,YES,PAGE 52 OF THE APPLESOFT BOOK
TRUE OF FALSE- THE 'SPEED' COMMAND CAN ONLY BE USED FROM WITHIN A PROGRAM,FALSE,?
IF YOU'RE ON 'THE SOURCE'; WHAT COMMAND WILL STOP THE ECHOING OF CHARACTERS,TERM -HALF,?
TRUE OF FALSE - 'SHLOAD' LOADS A SHAPE TABLE FROM CASSETTE IN FP BASIC,TRUE,?
IF ROT = 16 HOW MANY DEGREES WILL THE SHAPE BE ROTATED,90,?
YES OR NO- IT IS ALWAYS BEST TO KEEP THEPOWER ON WHEN REMOVING A CARD,NO,TRY IT- AND WATCH THE SMOKE
ARE 'SCALE' AND 'ROT' RESERVED WORDS IN BASIC IN ALL CASES (YES OR NO),NO,ONLY IF '=' IS THE NEXT CHARACTER
IF RND IS USED RIGHT WHEN THE COMPUTER IS TURNED ON IS THE RESULTS PREDICABLE.,YES,RND IS VERY PREDICTABLE
HOW MANY ANNUNCIATOR OUTPUTS DOES THE APPLE II HAVE,4,CONNECT THEM TO LED'S; RELAYS; ETC.
PEEK; POKE; PRINT; POP; PLOT; POS AND PDL ARE LEGAL COMMANDS. HOW ABOUT 'PUT',NO,TRS-80'S HAVE IT
IF YOU WANT TO REUSE THE DATA LIST WHAT WORD SHOULD YOU USE,RESTORE,?
'RECALL' IS A RESERVED WORD IN FP BASIC (Y/N),YES,?
YOU KNOW WHAT 'GR' AND 'HGR' MEAN. WHATIS 'GHR',G.R.A.P.E. HI-RESOLUTION,'GHR' APPEARS ON GRAPE VOLUME 103.

Text found in Volume_196_Religious_Programs.dsk/B*************************B.bas:

10 REM *** CHAINING HELLO
20 REM *** 4/7/97
30 REM *** DOUG TRUEMAN
40 PRINT CHR$(4);"RUN HELLO"

Text found in Volume_196_Religious_Programs.dsk/BIBLE DRILL.bas:

5 REM "RANDOM DRILL TUTORIALDATA BASE ADDEDBY RICK WILLIAMSCALL-A.P.P.L.E. VOL III #2REV. BY VAL J GOLDINGCALL-A.P.P.L.E. VOL. II #8MOD. BY STEVE LAWSON
10 SPEED= 255: TEXT : HOME
11 DB$(1) = "ROCK OF AGES"
12 DB$(2) = "BIBLICAL METROLOGY"
13 DB$(3) = "BIBLE FATHERS"
14 DB$(4) = "BIBLE MOTHERS"
15 DB$(5) = "NEW TESTAMENT VERSES"
16 DB$(6) = "BIBLE NAMES MEANINGS"
17 DB$(7) = "OLD TESTAMENT BOOKS"
18 DB$(8) = "NEW TESTAMENT BOOKS"
19 DB$(9) = "FINISHED FOR NOW"
20 HOME : HTAB 14: PRINT "BIBLE DRILL": VTAB 4: PRINT "THE FOLLOWING DATA BASES ARE AVAILABLE:": VTAB 8: FOR I = 1 TO 9: HTAB 4: PRINT I" "DB$(I): NEXT
30 POKE 34,0: VTAB 20: HTAB 4: CALL -958: INVERSE : PRINT " SELECT DATA BASE FROM MENU ";: NORMAL : PRINT " ";
40 D$ = CHR$(13) + CHR$(4): GET A$: PRINT
50 IF VAL(A$) <1 OR VAL(A$) >9 THEN 30
60 IF DB$( VAL(A$)) = "" OR LEFT$(DB$( VAL(A$)),1) = CHR$(60) THEN 30
70 IF VAL(A$) = 9 THEN TEXT : PRINT CHR$(4)"RUN GRAPE MENU": END
80 PRINT : PRINT : PRINT " CTRL 'X' RETURNS MENU AT ANY TIME."
90 POKE 34,23: NORMAL : PRINT D$"EXEC";DB$( VAL(A$));".DRILL": END
1000 SPEED= 255: POKE 34,0: GOTO 2250
1010 HOME :TITLE$ = " BIBLE DRILL"
1020 HOME : VTAB 5: FOR I = 1 TO 5: FOR J = 1 TO 21
1030 K = INT( RND(1) *3)
1040 IF K = 0 THEN FLASH
1050 IF K = 1 THEN NORMAL
1060 IF K = 2 THEN INVERSE
1070 PRINT TAB( 18) MID$ (TITLE$,J,1);: NEXT : PRINT : NEXT : FOR I = 1 TO 2: GOSUB 1530: NEXT : NORMAL
1080 MSG$(1) = "PRAISE THE LORD":MSG$(2) = "HALLELUJAH":MSG$(3) = "AMEN"
1090 MSG$(4) = "GOD BLESS YOU":MSG$(5) = "REJOICE!": GOTO 1830
1100 GOSUB 1500
1110 PRINT QUERY$(ITEM): PRINT
1120 PRINT TAB( 5)"1 ";ANSWER$(ITEM)
1130 PRINT TAB( 5)"2 ";ANSWER$(A2)
1140 PRINT TAB( 5)"3 ";ANSWER$(A3)
1150 PRINT TAB( 5)"4 ";ANSWER$(A4)
1160 PRINT TAB( 5)"5 ";ANSWER$(A5)
1170 GOTO 2100
1180 GOSUB 1500
1190 PRINT QUERY$(ITEM): PRINT
1200 PRINT TAB( 5)"1 ";ANSWER$(A2)
1210 PRINT TAB( 5)"2 ";ANSWER$(ITEM)
1220 PRINT TAB( 5)"3 ";ANSWER$(A3)
1230 PRINT TAB( 5)"4 ";ANSWER$(A4)
1240 PRINT TAB( 5)"5 ";ANSWER$(A5)
1250 GOTO 2100
1260 GOSUB 1500
1270 PRINT QUERY$(ITEM): PRINT
1280 PRINT TAB( 5)"1 ";ANSWER$(A2)
1290 PRINT TAB( 5)"2 ";ANSWER$(A3)
1300 PRINT TAB( 5)"3 ";ANSWER$(ITEM)
1310 PRINT TAB( 5)"4 ";ANSWER$(A4)
1320 PRINT TAB( 5)"5 ";ANSWER$(A5)
1330 GOTO 2100
1340 GOSUB 1500
1350 PRINT QUERY$(ITEM): PRINT
1360 PRINT TAB( 5)"1 ";ANSWER$(A2)
1370 PRINT TAB( 5)"2 ";ANSWER$(A3)
1380 PRINT TAB( 5)"3 ";ANSWER$(A4)
1390 PRINT TAB( 5)"4 ";ANSWER$(ITEM)
1400 PRINT TAB( 5)"5 ";ANSWER$(A5)
1410 GOTO 2100
1420 GOSUB 1500
1430 PRINT QUERY$(ITEM): PRINT
1440 PRINT TAB( 5)"1 ";ANSWER$(A2)
1450 PRINT TAB( 5)"2 ";ANSWER$(A3)
1460 PRINT TAB( 5)"3 ";ANSWER$(A4)
1470 PRINT TAB( 5)"4 ";ANSWER$(A5)
1480 PRINT TAB( 5)"5 ";ANSWER$(ITEM)
1490 GOTO 2100
1500 HOME : POKE 37,4: PRINT : RETURN
1510 CLICK = PEEK( -16336) + PEEK( -16336)
1520 FOR J = 0 TO 33: NEXT : RETURN
1530 FOR J = 1 TO 6
1540 PITCH = INT( RND(1) *8) +1
1550 TIME = INT( RND(1) *2) +9
1560 POKE 952,TRUMPET(PITCH): POKE 953,TRUMPET(TIME): CALL 954
1570 NEXT : POKE 952,TRUMPET(PITCH): POKE 953,TRUMPET(TIME) *3: CALL 954: RETURN
1580 FIVE$ = STR$(CHOICE): PRINT TAB( 5)
1590 GET ADVANCE$: IF ADVANCE$ = CHR$(24) THEN PRINT : GOTO 10
1600 IF VAL(ADVANCE$) <1 OR VAL(ADVANCE$) >5 THEN 1590
1610 PRINT
1620 IF ADVANCE$ = RIGHT$(FIVE$,1) THEN 1640
1630 GOTO 1770
1640 RIGHT = RIGHT +1: PRINT "'";ANSWER$(ITEM);"'": PRINT "IS CORRECT": PRINT : POKE 50,127
1650 SPEED= 175
1660 FOR I = 1 TO RIGHT/(RIGHT +WRNG) *6.67: PRINT " ->";: NEXT : GOSUB 1530
1670 FOR I = 1 TO 333: NEXT
1680 SPEED= 50
1690 FOR I = 1 TO LEN(MSG$(CHOICE)): POKE 952, RND(1) *250 +1: POKE 953,7: CALL 954: PRINT MID$ (MSG$(CHOICE),I,1);: NEXT
1700 NORMAL : SPEED= 225
1710 PRINT
1720 PRINT : PRINT "RIGHT ";RIGHT;: PRINT " / WRONG ";WRNG;: PRINT " / TOTAL ";RIGHT +WRNG
1730 PRINT : PRINT "> "; INT(RIGHT/(RIGHT +WRNG) *100);: PRINT "% RIGHT"
1740 PRINT TAB( 26)"PRESS ANY KEY>";
1750 GET ADVANCE$: IF ADVANCE$ = CHR$(24) THEN PRINT : GOTO 10
1760 GOTO 2110
1770 WRNG = WRNG +1: FOR I = 0 TO RND(1) *5: FOR BUZZ = 1 TO 6: GOSUB 1510: NEXT : SPEED= 200: PRINT "NO" SPC( CHOICE);: GOSUB 1510: NEXT
1780 FOR I = 0 TO RND(1) *10: FOR BUZZ = 0 TO 23:CLICK = PEEK( -16336): NEXT : SPEED= 255: NEXT
1790 PRINT : PRINT "THE CORRECT ANSWER IS": FOR I = 0 TO 777: NEXT : PRINT
1800 PRINT "---> ";: FOR I = 1 TO 20: GOSUB 1510: NEXT
1810 PRINT ANSWER$(ITEM): FOR I = 0 TO 2000: NEXT
1820 GOTO 1720
1830 READ ALPHA$,BETA$:PAIRS = PAIRS +1: POKE 952,10: POKE 953,5: CALL 954: IF ALPHA$ < >"*" THEN 1830
1840 FOR I = 1 TO 100: NEXT
1850 RESTORE :PAIRS = PAIRS -1: DIM ROSTER(PAIRS),QUERY$(PAIRS),ANSWER$(PAIRS)
1860 VTAB 19
1870 PRINT : PRINT " 1 MULTIPLE CHOICE DRILL": PRINT " 2 FLASHCARD DRILL": PRINT : PRINT " ";: GET OPT$: PRINT :OPT = VAL(OPT$)
1880 IF OPT$ = CHR$(24) THEN 10
1890 IF OPT <1 OR OPT >2 THEN 1860
1900 OPT = OPT -1: HOME
1910 PRINT : PRINT BETA$: PRINT : POKE 34,4: PRINT
1920 FOR I = 1 TO PAIRS:ROSTER(I) = I: NEXT
1930 FOR ITEM = 1 TO PAIRS
1940 MIX = INT((PAIRS -ITEM +1) * RND(1) +1)
1950 READ QUERY$(ROSTER(MIX)),ANSWER$(ROSTER(MIX))
1960 ROSTER(MIX) = ROSTER(PAIRS -ITEM +1)
1970 NEXT : RESTORE
1980 ON OPT GOTO 2140
1990 FOR ITEM = 1 TO PAIRS
2000 A2 = INT( RND(1) *PAIRS) +1:A3 = INT( RND(1) *PAIRS) +1
2010 A4 = INT( RND(1) *PAIRS) +1:A5 = INT( RND(1) *PAIRS) +1
2020 IF A2 = ITEM OR A3 = ITEM THEN 2000
2030 IF A4 = ITEM OR A5 = ITEM THEN 2000
2040 IF A2 = A3 OR A2 = A4 THEN 2000
2050 IF A2 = A5 OR A3 = A4 THEN 2000
2060 IF A3 = A5 OR A4 = A5 THEN 2000
2070 I = INT( RND(1) *10) +5
2080 CHOICE = INT( RND(1) *I) +1: IF CHOICE >5 THEN 2080
2090 ON CHOICE GOTO 1100,1180,1260,1340,1420
2100 GOTO 1580
2110 NEXT
2120 HTAB 21: SPEED= 75: PRINT "STARTING NEXT CYCLE";: SPEED= 255: GOSUB 1530
2130 FOR I = 1 TO 2: CALL -856: NEXT : GOTO 1920
2140 CYCLE = CYCLE +1
2150 FOR ITEM = 1 TO PAIRS
2160 COUNT = COUNT +1: PRINT : PRINT TAB( 5)"#"COUNT;: POKE 952, RND(1) *100 +1: POKE 953,5: CALL 954: PRINT "/CYCLE "CYCLE
2170 PRINT : PRINT QUERY$(ITEM)
2180 IF COUNT >1 THEN 2200
2190 PRINT TAB( 14)"AT THE FLASHING CURSOR...": PRINT TAB( 14)"PRESS ANY KEY TO CONTINUE>";
2200 GET ADVANCE$: IF ADVANCE$ = CHR$(24) THEN PRINT : GOTO 10
2210 IF COUNT = 1 THEN PRINT : PRINT
2220 SPEED= 100: PRINT ANSWER$(ITEM): SPEED= 255
2230 GET ADVANCE$: IF ADVANCE$ = CHR$(24) THEN PRINT : GOTO 10
2240 NEXT : GOTO 2120
2250 HEX$ = "03B8: FF FF AD 30 C0 88 D0 05 CE B9 03 F0 09 CA D0 F5 AE B8 03 4C BA 03 60 N D823G": FOR I = 1 TO LEN(HEX$): POKE 511 +I, ASC( MID$ (HEX$,I,1)) +128: NEXT : POKE 72,0: CALL -144
2260 DIM TRUMPET(10):TRUMPET(1) = 94:TRUMPET(2) = 127:TRUMPET(3) = 154:TRUMPET(4) = 75:TRUMPET(5) = 63:TRUMPET(6) = 37:TRUMPET(7) = 47:TRUMPET(8) = 188:TRUMPET(9) = 41:TRUMPET(10) = 46
2270 GOTO 1010
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/BIBLE FATHERS.DRILL.txt:

DEL100,990

100 DATA ABRAHAM,TERAH
110 DATA BARTHOLOMEW,TALMAI
120 DATA RACHEL,LABAN
130 DATA OBED,BOAZ
140 DATA JOHN THE BAPTIST,ZACHARIAS
150 DATA JESSE,OBED
160 DATA PEREZ,JONAS
170 DATA PETER,JONAS
180 DATA REHOBOAM,SOLOMON
190 DATA SETH,ADAM
200 DATA JACOB,ISAAC
210 DATA NATHAN,DAVID
220 DATA DAVID,JESSE
230 DATA METHUSELAH,ENOCH
240 DATA JUDAH,JACOB
250 DATA SHEM,NOAH
260 DATA ISAAC,ABRAHAM
270 DATA BUZ,NAHOR
280 DATA ZIPPORAH,JETHRO
290 DATA BALAAM,BEOR
300 DATA REBEKAH,BETHUEL
310 DATA MATTHEW,ALPHEUS
320 DATA JOHN THE DISCIPLE,ZEBEDEE
330 DATA ABIJAH,JEROBOAM
340 DATA LOT,HARAN
350 DATA SAMUEL,ELKANAH
360 DATA GIDEON,JOASH
370 DATA JOSHUA,NUN
380 DATA ELEAZAR,AARON
390 DATA EZEKIEL,BUZI
400 DATA PHINEHAS,ELI
410 DATA JONATHAN,SAUL
420 DATA NOAH,LAMECH
990 DATA *,NAME THE FATHER OF THE FOLLOWING BIBLE PERSON -

RUN100

Text found in Volume_196_Religious_Programs.dsk/BIBLE MOTHERS.DRILL.txt:

DEL100,990

100 DATA SOLOMON,BATHSHEBA
110 DATA LEVI,LEAH
120 DATA JOSEPH,RACHEL
130 DATA ESAU,REBEKAH
140 DATA ISHMAEL,HAGAR
150 DATA ISAAC,SARAH
160 DATA ABEL,EVE
170 DATA SAMUEL,HANNAH
180 DATA OBED,RUTH
190 DATA BOAZ,RAHAB
200 DATA TIMOTHY,EUNICE
210 DATA EUNICE,LOIS
220 DATA JOHN THE BAPTIST,ELISABETH
230 DATA JESUS,MARY
240 DATA JEROBOAM,ZERUAH
250 DATA GERSHOM,ZIPPORAH
260 DATA JEZEBEL,ETHBAAL
270 DATA PEREZ,TAMAR
280 DATA AHAZIAH,JEZEBEL
290 DATA MOSES,JOCHEBED
300 DATA UZ,MILCAH
990 DATA *,NAME THE MOTHER OF THE FOLLOWING BIBLE PERSON -

RUN100

Text found in Volume_196_Religious_Programs.dsk/BIBLE NAMES MEANINGS.DRILL.txt:

DEL100,990

100 DATA ZECHARIAH,YAHWEH REMEMBERS
110 DATA JOSHUA,YAHWEH IS SALVATION
120 DATA DAVID,BELOVED OF YAHWEH
130 DATA ELEAZAR,GOD HAS HELPED
140 DATA SAMUEL,NAME OF GOD
150 DATA LEMUEL,DEVOTED TO GOD
160 DATA EZEKIEL,GOD STRENGTHENS
170 DATA JEREMIAH,YAHWEH ESTABLISHED
180 DATA EZRA,YAHWEH HELPS
190 DATA NEHEMIAH,COMFORT OF YAHWEH
200 DATA DANIEL,GOD IS MY JUDGE
210 DATA JOEL,YAHWEH IS GOD
220 DATA OBADIAH,SERVANT OF YAHWEH
230 DATA MICAH,WHO IS LIKE YAHWEH
240 DATA ZEPHANIAH,YAHWEH HAS HIDDEN
990 DATA *,IDENTIFY THE MEANING OF THE NAMES OF THEFOLLOWING OLD TESTAMENT AUTHORS. EACH INCLUDES THE NAME 'GOD' OR 'YAHWEH'.

RUN100

Text found in Volume_196_Religious_Programs.dsk/BIBLE STUDY.txt:

100,THIS BIBLE QUIZ COVERS BOTH OLD AND NEW TESTAMENTS
WHO WAS CAST INTO A DEN OF LIONS,DANIEL,DANIEL 6*16
WHAT HUNGRY MAN CURSED A FRUITLESS FIG TREE,JESUS,MARK 11*12-14
WHAT BOY HAD A COAT OF MANY COLORS,JOSEPH,GENESIS 37*3
WHO HAD A SEAMLESS COAT,JESUS,JOHN 19*23
WHO SET FIRE TO 300 FOXES TAILS,SAMSON,JUDGES 15*4-5
WHAT PHYSICAN WAS AN AUTHOR,LUKE,COLOSSIANS 4*14
WHAT SONG COMPOSER IS CREDITED WITH 1005 SONGS,SOLOMON,I KINGS 4*32
WHO WAS THE FIRST PERSON KILLED,ABEL,GENESIS 4*8
WHO WAS BURIED IN A CAVE WITH HIS WIFE,ABRAHAM,GENESIS 25*9-10
WHAT BLIND MAN KILLED THREE THOUSAND AT A RELIGIOUS FEAST,SAMSON,JUDGES 16*23-30
WHO WAS A MIGHTY HUNTER,NIMROD,GENESIS 10*9-10
WHO WAS THE FIRST CHRISTIAN MARTYR,STEPHEN,ACTS 7
WHO KILLED GOLIATH,DAVID,I SAMUEL 17*49
WHO WALKED WITH GOD,ENOCH,GENESIS 5*22
WHO WAS SWALLOWED BY A GREAT FISH,JONAH,JONAH 1*17
TO WHAT CITY DID GOD SEND JONAH,NINEVEH,JONAH 1*1
HOW MANY BOOKS MAKE UP THE OLD TESTAMENT,39,ADD THEM UP
HOW MANY BOOKS MAKE UP THE NEW TESTAMENT,27,COUNT THEM YOURSELF
WHAT GOSPEL PRESENTS JESUS AS THE KING,MATTHEW,MATTHEW 1
NAME THE KING THAT ORDERED DANIEL INTO THE LION'S DEN,DARIUS,DANIEL 6*16
WHO WAS ISAACS' BROTHER,ISHMAEL,GENESIS 17*19-20
WHO WAS JACOBS' BROTHER,ESAU,GENESIS 25*24-26
WHO STOLE HIS BROTHER'S BLESSING,JACOB,GENESIS 27
WHERE WAS PAUL GOING WHEN HE WAS STRUCK BLIND,DAMASCUS,ACTS 9*3
WHERE WAS JOHN WHEN HE HAD THE REVELATION,PATMOS,REVELATION 1*9
HOW MANY YEARS WILL THE DEVIL BE BOUND BY THE ANGEL FROM HEAVEN,1000,REVELATION 20*2
WHAT IS THE NAME OF THE LAST BOOK IN THEOLD TESTAMENT,MALACHI,LOOK IT UP
HAVING DONE ALL; WHAT SHOULD YOU DO,STAND,EPHESIANS 6*13
WHO HAD A 'THORN IN THE FLESH',PAUL,II CORINTHIANS 12*7
THE LAST ENEMY TO BE DESTROYED WILL BE,DEATH,I CORINTHIANS 15*26
WHAT WAS THE MEANING OF PETER'S NAME; CEPHAS,STONE,JOHN 1*42
WHAT WILL THE MEEK INHERIT (ONE WORD),EARTH,MATTHEW 5*5
A VIRTUOUS WOMAN IS WORTH MORE THAN,RUBIES,PROVERBS 31*10
WHO WROTE OF THINGS HARD TO UNDERSTAND,PAUL,II PETER 3*15-16
WHO WAS KING OF ISRAEL BEFORE DAVID,SAUL,II SAMUEL 2*5-7
TRUE OR FALSE - THE BIBLE NEVER USES THETERM 'IMMORTAL SOUL',TRUE,CHECK IT OUT
HOW MANY CUBITS LONG WAS NOAH'S ARK,300,GENESIS 6*1
NOAH HAD THREE SONS. THEIR NAMES WERE HAM; JAPHETH AND,SHEM,GENESIS 6*10
OF WHAT KIND OF WOOD WAS THE ARK MADE,GOPHER,GENESIS 6*14
WHAT IS THE SHORTEST VERSE IN THE BIBLE,JESUS WEPT,JOHN 11*35
FROM WHAT LAND WAS JOB,UZ,JOB 1*1
TRUE OR FALSE - THE WORD 'RAPTURE' IS INTHE BIBLE,FALSE,CHECK IT OUT
YES OR NO - DID GOD DOUBLE THE NUMBER OFCHILDREN THAT JOB FINALLY HAD,YES,COMPARE JOB 1*2 WITH JOB 42*10-13
WHO WENT TO SEE A WITCH,SAUL,I SAMUEL 28*7-8
WHO WENT UP TO HEAVEN IN A WHIRLWIND,ELIJAH,II KING 2*11
WHO RAISED THE SHUNAMITE'S DAUGHTER FROMTHE DEAD,ELISHA,II KINGS 4*33-34
WHO WAS EATEN BY DOGS,JEZEBEL,II KINGS 9
WHAT KING ATE GRASS LIKE AN OX,NEBUCHADNEZZAR,DANIEL 12*8-9
IN DANIEL'S VISION HOW MANY HORNS DID THE FOURTH BEAST HAVE,10,DANIEL 7*7
WHO RAISED DORCAS FROM THE DEAD,PETER,ACTS 9*36-40
WHO WAS KING SAUL'S SON,JONATHAN,I SAMUEL 14*1
BESIDES JESUS; WHAT FAMOUS BIBLE PERSON CAME FROM BETHLEHEM,DAVID,I SAMUEL 16*1-13
'THE LORD IS MY SHEPHERD; I SHALL NOT WANT' IS THE FIRST VERSE OF WHICH PSALM,23,PSALM 23*1
WHO IS THE PRINCE OF THIS WORLD,SATAN,JOHN 12*31
TRUE OR FALSE - THE DEMONS (OR DEVILS) BELIEVE THERE IS ONE GOD,TRUE,JAMES 2*19
EBER HAD TWO SONS; JOKTAN AND,PELEG,GENESIS 10*25
WHO COMMITTED INCEST WITH HIS DAUGHTER,LOT,GENESIS 19*30-36
GOD CHANGED WHOSE NAME TO 'ISRAEL',JACOB,GENESIS 35*10
TWO TRIBES MADE UP THE SOUTHERN KINGDOM;JUDAH AND,BENJAMIN,I KINGS 12*21
WHO WAS THE MOTHER OF JOHN THE BAPTIST,ELISABETH,LUKE 1*5
WHAT KING SAID TO PAUL; 'ALMOST THOU PERSUADEST ME TO BE A CHRISTIAN,KING AGRIPPA,ACTS 26*28
WHAT BOOK OF THE BIBLE DOES NOT MENTION GOD,ESTHER,READ ESTHER
WHO WAS ESTHER'S COUSIN,MORDECAI,ESTHER 2*5-7
WHO WILL THE PURE IN HEART SEE,GOD,MATTHEW 5*8
WHO WILL BE CALLED THE CHILDREN OF GOD (ONE WORD),PEACEMAKERS,MATTHEW 5*9
WHAT PERSIAN KING ORDERED A HOUSE BUILT IN JERUSALEM,CYRUS,EZRA 1*1-2
TRUE OR FALSE - ZEPHANIAH IS A BOOK IN THE OLD TESTAMENT,TRUE,LOOK IT UP
THE WAGES OF SIN IS,DEATH,ROMANS 6*23
THE LOVE OF WHAT IS THE ROOT OF ALL EVIL,MONEY,I TIMOTHY 6*10
TRUE OR FALSE - FAITH MAKES VOID THE LAW,FALSE,ROMANS 3*31
WHAT IS THE NUMBER OF THE BEAST,666,REVELATION 13*10
WHO CARRIED CHRIST'S CROSS,SIMON,LUKE 23*26
WHO HAD TO SEE THE WOUNDS OF CHRIST IN ORDER TO BELIEVE,THOMAS,JOHN 20*29
WHAT PHARISEE CAME TO SEE JESUS AT NIGHT,NICODEMUS,JOHN 3*1-2
WHO SAW A WHEEL IN THE MIDST OF A WHEEL,EZEKIEL,EZEKIEL 10*10
WHAT MAN OF BETHANY DID JESUS RAISE FROMTHE DEAD,LAZARUS,JOHN 11*1-44
WE ARE NOT SAVED BY WORKS BUT BY,GRACE,EPHESIANS 2*8-9
WHO WAS MOSES' BROTHER,AARON,GENESIS 4*14
BY WHICH RIVER DID EZEKIEL SEE HIS FIRSTVISION,CHEBAR,EZEKIEL 1*1
WHO WAS CHOSEN TO REPLACE JUDAS AFTER THE RESURRECTION,MATTHIAS,ACTS 1*15
WHO FOUGHT SATAN FOR THE BODY OF MOSES,MICHAEL,JUDE 1*9
WHAT WOMAN JUDGE HELD COURT UNDER A PALMTREE,DEBORAH,JUDGES 4*4-5
WHICH DISCIPLE WAS CALLED 'SATAN' BY JESUS,PETER,MATTHEW 16*23
WHO SAW SATAN FALL FROM HEAVEN,JESUS,LUKE 10*17-18
WHAT WAS BELTESHAZZAR'S OTHER NAME,DANIEL,DANIEL 1*7
WHO KILLED A GIANT HAVING 12 FINGERS ANDTOES,JONATHAN,II SAMUEL 21*20-21
WHO CAUGHT 153 FISHES,PETER,JOHN 21*11
WHICH IS THE LONGEST PSALM,119,PSALM 119
WHO RECOMMENDED THAT OLD WOMEN SHOULD NOT DRINK TOO MUCH WINE,PAUL,TITUS 2*3
WHO DIED AT THE AGE OF 120 WITHOUT SENILITY,MOSES,DEUTERONOMY 34*7
WHO HELD A CONVERSATION WITH AN ASS,BALAAM,NUMBERS 22*28-30
WHAT CITY IS LINKED TO A SCARLET WOMAN,BABYLON,REVELATION 17*4-18
WHO HAD 300 CONCUBINES,SOLOMON,I KINGS 11*1-3
WHO FELL ASLEEP DURING A LONG SERMON,EUTYCHUS,ACTS 20*9
WHO CLIMBED A TREE TO SEE JESUS,ZACCHAEUS,LUKE 19*4
WHAT OLD TESTAMENT PROPHET DID GOD KNOW BEFORE HE WAS BORN,JEREMIAH,JEREMIAH 1*5
NAME THE HARLOT THAT WAS RELATED TO JESUS,RAHAB,MATTHEW 1*5-6
WHO DIED BECAUSE HE LIED TO GOD,ANANIAS,ACTS 5*4-5
WHO WAS KING OR ISRAEL AFTER SOLOMON,REHOBOAM,I KINGS 12*1
WHO DID NOT UNDERSTAND WHAT HE HEARD ANDWROTE,DANIEL,DANIEL 12*8-9

Text found in Volume_196_Religious_Programs.dsk/BIBLICAL METROLOGY.DRILL.txt:

DEL100,990

100 DATA "ROMAN SILVER COIN EQUIVALENT TO THE PAY FOR A DAY'S WORK FOR A COMMON LABORER.","DENARIUS MAT 20:2-13"
110 DATA "GREEK SILVER COIN EQUIVALENT TO A ROMAN DENARIUS - A DAY'S WAGES.","DRACHMA MAT 17:24"
120 DATA "JEWISH WEIGHT OF SILVER EQUIVALENT TO 1/2 SHEKEL - 2 DAY'S WAGES. 120 GRAINS.","BEKAH EXOD 38:26"
130 DATA "SMALL ROMAN OR GREEK COPPER COIN EQUAL TO 1/2 GERAH, WORTH 1 1/2 CENTS.","BRASS MAT 10:9"
140 DATA "THE PERSIAN DARIC USED BY JEWS IN CAPTI-VITY WEIGHING 128.4 GRAINS, WORTH $5.30.","DRAM EZRA 2:69; NEH 7:70"
150 DATA "GREEK KODRANTES (2 LEPTAS), 1/4 CENT; ORROMAN ASSARIUM, 1 CENT.","FARTHING MAT 10:29; MAT 5:26"
160 DATA "HEBREW COIN OF 1/20 SILVER SHEKEL, ABOUT3 CENTS. 12 GRAINS.","GERAH EXOD 30:13; LEV 27:25"
170 DATA "SMALLEST GREEK COIN (LEPTON) AT TIME OF CHRIST, 1/8 CENT.","MITE MARK 12:42; LUKE 12:59"
180 DATA "HEBREW COIN WORTH 60 DAY'S WAGES.","GOLD SHEKEL 2 KI 5:5"
190 DATA "HEBREW COIN WORTH 4 DAY'S WAGES.","SILVER SHEKEL MAT 17:27"
200 DATA "1500 SILVER SHEKELS (96 POUNDS) OR 3000 GOLD SHEKELS (108 POUNDS).","TALENT MAT 18:23-35; 25:14-30"
210 DATA "AREA A TEAM OF OXEN CAN PLOW IN A HALF- DAY.","ACRE 1 SAM 14:14"
220 DATA "DISTANCE FROM ELBOW TO TIP OF MIDDLE FINGER, ABOUT 18 INCHES.","CUBIT EX 25:10; 1 KI 7:24"
230 DATA "A COMMON CUBIT PLUS A HANDS BREADTH, 24 INCHES.","LONG CUBIT EZEK 40:5"
240 DATA "LENGTH OF SIX FEET.","FATHOM ACTS 27:28"
250 DATA "600 GEEEK FEET, 635 ROMAN FEET, OR 660 AMERICAN FEET.","FURLONG LUKE 24:13; JOHN 6:19"
260 DATA "SMALLEST HEBREW MEASURE, 3/4 INCH.","FINGER (BREADTH) JER 52:21"
270 DATA "3 OR 4 INCHES.","HANDBREADTH EX 37:12; PS 39:5"
280 DATA "146 FEET.","LINE EZEK 40:3"
290 DATA "STALK OF SWEET CANE (CALAMUS), 11 FEET.","MEASURING REED EZ 40:3; 42:16"
300 DATA "8 FURLONGS OR 1760 AMERICAN YARDS.","MILE MAT 5:41"
310 DATA "EQUIVALENT TO A YARD.","PACE 2 SAM 6:13"
320 DATA "LENGTH FROM END OF THUMB TO END OF THE LITTLE FINGER WHEN EXTENDED, 9 INCHES.","SPAN EX 28:16; 39:9"
330 DATA "1/6 SEAH OR ABOUT 2 QUARTS.","CAB 2 KI 6:25"
340 DATA "10 OMERS OR 4 1/2 PECKS.","EPHAH EX 16:36"
350 DATA "10 EPHAHS OR ABOUT 11 BUSHELS.","HOMER LEV 27:16; LUKE 16:7"
360 DATA "1/3 EPHAH, 1 1/2 PECK OR ABOUT 3 GALLONSLIQUID.","SEAH (MEASURE) GEN 18:6"
370 DATA "1/10 EPHAH OR 7 PINTS.","OMER EX 16:16-36"
380 DATA "1 EPHAH LIQUID OR 9 GALLONS.","BATH 1 KI 7:26"
390 DATA "1 HOMER, 10 BATHS, ABOUT 85 GALLONS.","COR EZ 45:11; LUKE 16:7"
400 DATA "THE GREEK MINA OF 100 DRACHMAS, ABOUT 100 DAY'S WORK.","POUND LUKE 19:12-27"
990 DATA *,"NAME THE COIN, WEIGHT OR MEASURE FOR THEDESCRIPTION GIVEN. MODERN EQUIVALENTS ARE ESTIMATES. A DAY'S WAGES IS 16 CENTS"

RUN100

Text found in Volume_196_Religious_Programs.dsk/BLESSINGS.bas:

10 REM ************************
20 REM *** RANDOM BLESSINGS ***
30 REM *** BY ALLEN DAVIS ***
60 REM ************************
80 REM
90 TEXT : HOME ::D$ = CHR$(4):I$ = CHR$(9)
100 DIM TT$(11),IC(4)
180 SPEED= 220
190 REM GENERATE TITLE PAGE
200 FOR I = 1 TO 11: READ TT$(I): NEXT I
210 DATA " B "," L "," E "," S "," S "," I "," N "," G "," S "," BY "," ALLEN H. DAVIS "
220 Z$ = " ":H = 7:X$ = " ":V = 1:BE = 1:EN = 7:SP = 1:SD = 200
230 FOR J = 1 TO 3:IC(J) = J: NEXT J
240 NORMAL
250 FOR I = 1 TO 11
260 HTAB H: VTAB V: PRINT Z$
270 HTAB H: VTAB V +IC(1): PRINT Z$: HTAB H: VTAB V: PRINT TT$(I)
280 HTAB H: VTAB V +IC(2): PRINT Z$: HTAB H: VTAB V +IC(1): PRINT TT$(I): HTAB H: VTAB V: PRINT Z$
290 FOR V = BE TO EN STEP SP
300 HTAB H: VTAB V +IC(3): PRINT Z$: HTAB H: VTAB V +IC(2): PRINT TT$(I): HTAB H: VTAB V +IC(1): PRINT Z$: HTAB H: VTAB V: PRINT X$: NORMAL :
310 NEXT V
320 IF I = 9 THEN 350
330 IF I = 10 THEN SPEED= 240: GOTO 360
340 H = H +3:V = 1: GOTO 380
350 Z$ = " ":X$ = " ":H = 18:V = 23:BE = 23:EN = 15: GOTO 370
360 Z$ = " ":H = 12:X$ = " ":V = 23:EN = 19
370 SP = -1: FOR J = 1 TO 3:IC(J) = -J: NEXT J
380 NEXT I
390 SPEED= 255
400 FOR I = 1 TO 1000: NEXT I
410 HOME : TEXT
420 Z$ = "******************":X$ = "* *":Y$ = "* INSTRUCTIONS *": HTAB 11: VTAB 1: PRINT Z$: HTAB 11: PRINT X$: HTAB 11: PRINT Y$: HTAB 11: PRINT X$: HTAB 11: PRINT Z$
430 PRINT : PRINT : PRINT "FOUR OPTIONS ARE AVAILABLE DURING PROGRAM OPERATION:"
440 PRINT : PRINT " S = STOP SCROLLING BLESSINGS"
450 PRINT : PRINT " C = CONTINUE SCROLLING BLESSINGS"
460 PRINT : PRINT " P = PRINT A BLESSING"
470 PRINT : PRINT " E = END PROGRAM"
480 PRINT
490 REM SS=NUMBER OF SUBJECTS; QQ=NUMBER OF QUALIFIERS; VV=NUMBER OF VERBS; OO=NUMBER OF OBJECTS
500 SS = 7:QQ = 6:VV = 8:OO = 6:BE = 11
510 PRINT : PRINT "THIS PROGRAM GENERATES A TOTAL OF": PRINT
515 TT = INT(BE *SS *QQ *VV *OO *(1.2))
520 PRINT ">>> ";TT;" <<<";
530 PRINT " RANDOM BLESSINGS."
540 VTAB 24: HTAB 7: INVERSE : PRINT "PRESS ANY KEY TO CONTINUE";: GET A$
550 DIM SUB$(SS),QFR$(QQ),VBS$(VV),OBS$(OO),H1(10),H2(10),H3(10),H4(10),BE$(BE),H5(10),H6(10)
560 P = 1:R = 1
570 REM LOAD THE ARRAYS FROM DATA STATEMENTS
580 FOR I = 1 TO SS: READ SUB$(I): NEXT I
590 FOR I = 1 TO QQ: READ QFR$(I): NEXT I
600 FOR I = 1 TO VV: READ VBS$(I): NEXT I
610 FOR I = 1 TO OO: READ OBS$(I): NEXT I
615 FOR I = 1 TO BE: READ BE$(I): NEXT I
620 HOME : TEXT : INVERSE
630 VTAB 1: PRINT " BLESS THOSE WHO CURSE YOU, PRAY FOR THOSE WHO MISTREAT YOU. WHOEVER HITS YOUON THE CHEEK, OFFER HIM THE OTHER ALSO; AND WHOEVER TAKES AWAY YOUR COAT, DO NOTWITHHOLD YOUR SHIRT FROM HIM EITHER. "
640 VTAB 7: PRINT "S)TOP C)ONTINUE P)RINT E)ND";
650 POKE 34,10
655 HOME
660 REM GENERATE RANDOM SUBSCRIPTS
670 C1 = INT( RND(1) *SS) +1
680 C2 = INT( RND(1) *QQ) +1
690 C3 = INT( RND(1) *VV) +1
700 C4 = INT( RND(1) *OO) +1
705 C5 = INT( RND(1) *BE) +1
706 C6 = INT( RND(1) *5) +1
710 H1(R) = C1:H2(R) = C2:H3(R) = C3:H4(R) = C4:H5(R) = C5:H6(R) = C6
720 PRINT P
725 NORMAL
730 A$ = BE$(C5) +SUB$(C1) +" OF " +QFR$(C2) +" " +VBS$(C3) +" TO YOUR " +OBS$(C4) +"."
733 IF C6 = 5 THEN A$ = BE$(C5) +SUB$(C1) +" OF " +QFR$(C2) +" " +VBS$(C3) +" TO YOU."
740 GOSUB 2000: INVERSE : PRINT
750 FOR DD = 1 TO 150
760 REM CHECK KEYBOARD FOR COMMANDS
770 X = PEEK( -16384): POKE -16368,0
780 IF X = 69 THEN 1390: REM END
790 IF X = 83 THEN 920: REM STOP
800 IF X = 80 THEN 820: REM PRINT
810 GOTO 950
820 INPUT "WHICH NUMBER SHOULD I PRINT? ";T
830 IF T >P THEN 820
840 IF T <0 THEN 820
850 IF T <(P -9) THEN PRINT "NO MORE THAN 10 BLESSINGS ARE REMEMBERED": GOTO 820
860 T$ = STR$(T):L = LEN(T$):RR = VAL( MID$ (T$,L,1))
870 PR# 1: PRINT D$;I$;"80N"; CHR$(29): REM CENTRONICS TYPE PRINTER INITIALIZATION
880 A$ = BE$(H5(RR)) +SUB$(H1(RR)) +" OF " +QFR$(H2(RR)) +" " +VBS$(H3(RR)) +" TO YOUR " +OBS$(H4(RR)) +"."
883 IF H6(RR) = 5 THEN A$ = BE$(H5(RR)) +SUB$(H1(RR)) +" OF " +QFR$(H2(RR)) +" " +VBS$(H3(RR)) +" TO YOU."
885 PRINT A$
890 PR# 0
895 NORMAL : PRINT : INVERSE
900 GOTO 950
910 REM DELAY
920 FOR K = 1 TO 10000
930 Y = PEEK( -16384): POKE -16368,0: IF Y = 67 THEN K = 10000: REM CHECK KEYBOARD FOR C
940 NEXT K
950 NEXT DD
960 P = P +1:R = R +1
970 IF R <10 THEN 990
980 R = 0
990 REM
1000 GOTO 670
1010 REM
1020 REM -----SUBJECTS-----
1030 DATA ALMIGHTY GOD,INFINITE GOD,GOD,LORD,OMNICIENT GOD
1040 DATA ONE TRUE GOD,ONLY LORD GOD
1110 REM -----QUALIFIERS-----
1120 DATA "LOVINGKINDNESS,","ALL GOODNESS,","PEACE,","JOY,","HOPE,","TRUTH,"
1200 REM -----VERBS-----
1210 DATA BRING JOY,BRING PEACE,BRING HAPPINESS,GRANT HAPPINESS,BRING AN INCREASE OF FAITH,BRING GRACE UPON GRACE
1220 DATA BRING GRACE,BESTOW BLESSINGS
1290 REM -----OBJECTS-----
1300 DATA LIFE,FAMILY,HOME,LOVED ONES,FRIENDS,CHILDREN
1330 REM -----BEGINNINGS-----
1340 DATA "MAY OUR ETERNAL FATHER, THE ","OUR PRAYER IS THAT OUR HEAVENLY FATHER, THE ","MAY OUR PRECIOUS LORD, THE ","MAY THE CREATOR, THE "
1350 DATA "MAY THE HOLY ONE, THE ","MAY THE FAITHFUL ONE, THE ","MAY THE RIGHTEOUS ONE, THE ","MAY THE AUTHOR OF LIFE, THE ","MAY THE KING ETERNAL, THE "
1360 DATA "DEAR FRIEND, MAY THE HEAVENLY FATHER, THE ","BELOVED OF GOD, MAY THE "
1380 REM
1390 NORMAL : POKE 34,0: HOME : TEXT : SPEED= 100: VTAB 4
1400 PRINT "FINALLY, BRETHREN,": PRINT : PRINT " WHATEVER IS TRUE,": PRINT " WHATEVER IS HONORABLE,": PRINT " WHATEVER IS RIGHT,": PRINT " WHATEVER IS PURE,": PRINT " WHATEVER IS LOVELY,"
1410 PRINT " WHATEVER IS OF GOOD REPUTE,": PRINT : PRINT "IF THERE IS ANY EXCELLENCE AND": PRINT "IF ANY THING WORTHY OF PRAISE,": PRINT : PRINT "LET YOUR MIND DWELL ON THESE THINGS."
1420 HTAB 30: PRINT : PRINT "PHIL. 4:8"
1430 FOR I = 1 TO 2000: NEXT I
1440 HOME : TEXT : SPEED= 255
1450 PRINT : PRINT CHR$(4)"RUN GRAPE MENU"
1460 END
1999 REM * NO WRAP AROUND *
2000 T = 0:L = 0
2080 S = LEN(A$)
2090 L = T +L
2100 IF S -L = <40 THEN 2170
2110 T = 41
2120 IF MID$ (A$,(L +T),1) = " " THEN 2150
2130 T = T -1
2140 GOTO 2120
2150 IF T = 41 THEN 2180
2160 PRINT MID$ (A$,(L +1),T -1): GOTO 2090
2170 PRINT MID$ (A$,(L +1),S -L): RETURN
2180 PRINT MID$ (A$,(L +1),T -1): VTAB ( PEEK(37)): GOTO 2090
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/CRYPTOGRAMS.bas:

100 GOSUB 2000: REM INIT
110 GOSUB 3000: REM TITLE
120 GOSUB 1000: REM GEN CODE
130 GOSUB 5000: REM PICK DATA
140 GOSUB 6000: REM CONVERT DATA TO CODE
150 GOSUB 7000: REM PRINT CODE
160 GOSUB 9000: REM GET ANSWER
170 CALL -958
180 PRINT : PRINT : PRINT "YOUR RIGHT!"
190 IF X$ = "H" THEN PRINT : PRINT "TOO BAD YOU NEEDED HELP.": GOTO 210
200 REM TRY AGAIN?
210 PRINT : PRINT "PLAY AGAIN? ";: GET A$: PRINT A$
220 IF A$ = "Y" THEN 120
230 HOME : VTAB 10: HTAB 18: PRINT "BYE!"
240 PRINT CHR$(4)"RUN GRAPE MENU"
250 VTAB 10: HTAB 18: PRINT "BYE!": END
1000 REM *** GEN CODE ***
1010 HOME : VTAB 10: FLASH : HTAB 14: PRINT "PLEASE WAIT.": NORMAL
1020 X$ = ""
1030 FOR I = 1 TO 26:C$(I) = "*": NEXT
1040 FOR I = 1 TO 26
1050 X = INT(26 *( RND(1))) +1
1060 IF C$(X) < >"*" THEN 1050
1070 C$(X) = A$(I): NEXT
1080 RETURN
2000 REM *** INIT ***
2010 DIM A$(26),C$(26),T$(100),N(100)
2020 FOR I = 1 TO 26:A$(I) = CHR$(I +64): NEXT
2030 FOR I = 1 TO 100: READ T$(I)
2040 IF T$(I) < >"END" THEN NEXT
2050 T = I -1
2060 GOSUB 5070
2070 RETURN
3000 REM *** TITLE ***
3010 HOME : VTAB 8
3020 PRINT " G . R . A . P . E .": PRINT
3030 PRINT " C R Y P T O G R A M S"
3040 PRINT : PRINT : PRINT " BASIC PROGRAM"
3050 PRINT : PRINT " BY JOHNNY GRAHAM"
3060 VTAB 22: PRINT "INSTRUCTIONS? ";: GET A$: PRINT A$
3070 IF A$ = "Y" THEN 4000
3080 RETURN
4000 REM *** INSTRUCTIONS ***
4010 HOME
4020 VTAB 5: PRINT " CRYPTOGRAMS ARE SIMPLE SUBSTITUTION CODES - ANOTHER LETTER OF THE ALPHABET IS SUBSTITUTED FOR THE RIGHT LETTER."
4030 PRINT : PRINT "'JESUS WEPT' MIGHT BE WRITTEN AS 'ORICI PRBA', O FOR J, R FOR E, I FOR S,C FOR U, P FOR W, B FOR P, A FOR T."
4040 PRINT : PRINT " I WILL PRINT THE CRYPTOGRAM THEN LET YOU TYPE THE CODE AND THEN YOUR GUESS FOR THE LETTER."
4050 PRINT : PRINT "ALL SELECTIONS ARE SCRIPTURE PORTIONS."
4060 PRINT : PRINT "IF YOU NEED HELP JUST TYPE '?'."
4070 VTAB 21: PRINT "PRESS ANY KEY TO PLAY ";: GET A$: PRINT A$
4080 RETURN
5000 REM *** PICK DATA ***
5010 N = N +1: IF N >T THEN GOSUB 5070
5020 X = INT(T *( RND(2))) +1
5030 IF N(X) < >0 THEN 5020
5040 N(X) = X
5050 T$ = T$(X)
5060 RETURN
5070 N = 0: FOR I = 1 TO T:N(I) = 0: NEXT
5080 RETURN
6000 REM *** CONVERT TO CODE ***
6010 T1$ = "":AN$ = ""
6020 L = LEN(T$)
6030 FOR I = 1 TO L
6040 P = ( ASC( MID$ (T$,I,1))) -64
6050 IF P <1 THEN T1$ = T1$ + MID$ (T$,I,1): GOTO 6070
6060 T1$ = T1$ +C$(P)
6070 NEXT
6080 T2$ = T1$
6090 RETURN
7000 REM *** PRINT CODE ***
7010 HOME : VTAB 4
7020 PRINT T1$
7030 RETURN
9000 REM *** GET ANSWERS ***
9010 FOR I = 1 TO L
9020 IF MID$ (T$,I,1) >"@" AND MID$ (T$,I,1) <"[" THEN AN$ = AN$ +"^": GOTO 9040
9030 AN$ = AN$ + MID$ (T$,I,1)
9040 NEXT
9050 VTAB 10
9060 IF X$ < >"H" THEN PRINT AN$: GOTO 9130
9070 FOR I = 1 TO L:AX$ = MID$ (AN$,I,1): IF AX$ >"@" AND AX$ <"[" THEN 9090
9080 PRINT AX$;: GOTO 9110
9090 IF AX$ = MID$ (T$,I,1) THEN 9080
9100 INVERSE : PRINT AX$;: NORMAL
9110 NEXT
9120 PRINT
9130 IF AN$ = T$ THEN RETURN
9140 VTAB 15
9150 IF X$ < >"H" THEN PRINT "PRESS '?' FOR HELP.": GOTO 9165
9160 PRINT "THE INVERSE LETTERS '";: INVERSE : PRINT " ";: NORMAL : PRINT "' ARE WRONG."
9165 PRINT : PRINT "PRESS '!' FOR ANSWER."
9170 CALL -958
9180 VTAB 20: GET A1$
9190 IF A1$ = "?" THEN 9270
9195 IF A1$ = "!" THEN 9300
9198 IF ASC(A1$) <65 OR ASC(A1$) >90 THEN PRINT : VTAB 20: GOTO 9170
9200 PRINT A1$;" = ";: GET A2$: PRINT A2$
9205 IF ASC(A2$) <65 OR ASC(A2$) >90 THEN PRINT : VTAB 20: GOTO 9170
9210 XX$ = AN$:AN$ = ""
9220 FOR I = 1 TO L
9230 IF MID$ (T1$,I,1) = A1$ THEN AN$ = AN$ +A2$: GOTO 9250
9240 AN$ = AN$ + MID$ (XX$,I,1)
9250 NEXT
9260 GOTO 9050
9270 REM *** HELP ***
9280 X$ = "H": GOTO 9050
9290 RETURN
9300 VTAB 10: CALL -958: PRINT T$
9310 PRINT : PRINT : POP : GOTO 190
10000 REM DATA STATEMENTS FOLLOW
10010 DATA JESUS WEPT.
10020 DATA ALL HAVE SINNED AND COME SHORT OF THE GLORY OF GOD.
10030 DATA REJOICE IN THE LORD ALWAYS- AGAIN I SAY- REJOICE.
10040 DATA IN THE BEGINNING WAS THE WORD- AND THE WORD WAS WITH GOD- AND THE WORD WAS GOD.
10050 DATA HE THAT HATH THE SON HATH LIFE; AND HE THAT HATH NOT THE SON HATH NOT LIFE.
10060 DATA THE WORD WAS MADE FLESH AND DWELT AMONG US.
10070 DATA EVERY KNEE SHALL BOW - EVERY TONGUE CONFESS - THAT JESUS CHRIST IS LORD.
10080 DATA FOR SIN SHALL NOT HAVE DOMINION OVER YOUFOR YE ARE NOT UNDER THE LAW BUT UNDER GRACE.
10090 DATA NOT BY WORKS LEST ANY MAN SHOULD BOAST.
10100 DATA THIS MAN IS THE SAVIOR OF THE WORLD.
10110 DATA REJOICE EVERMORE!
10120 DATA QUENCH NOT THE SPIRIT.
10130 DATA REMEMBER THE SABBATH DAY TO KEEP IT HOLY
10140 DATA CHILDREN OBEY YOUR PARENTS IN THE LORD- FOR THIS IS RIGHT.
10150 DATA THE LORD IS MY SHEPHERD; I SHALL NOT WANT.
10160 DATA MAKE A JOYFUL NOISE UNTO THE LORD ALL YELANDS.
10170 DATA ALLELUIA! FOR THE LORD GOD OMNIPOTENT REIGNETH.
10180 DATA GLORY TO GOD IN THE HIGHEST- AND ON EARTH PEACE- GOODWILL TOWARD MEN.
10190 DATA PRAY WITHOUT CEASING.
10200 DATA THE HEAVENS DECLARE THE GLORY OF GOD.
10990 DATA END
11000 REM ADD DESIRED ENTRIES BEFORE 10990. DO NOT USE COMMAS OR COLONS.
20220 REM MODIFIED BY S. LAWSON
20230 REM DELETE LINE 240 FOR INDEPENDENT USE
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/EYE-QUE.bas:

10 REM *** EYE-CUE ***
20 GOSUB 5020
30 REM * PRINTED INSTRUCTIONS *
40 TEXT : HOME : HTAB 16: INVERSE : PRINT "EYE-CUE": NORMAL
45 PRINT : PRINT "THE OBJECT IS TO DISCERN A FAMILIAR BIBLE NAME,PHRASE,OR SAYING FROM EACH ARRANGEMENT OF LETTERS."
50 PRINT : PRINT "FOR EXAMPLE:"
55 PRINT "THIS PASSAGE IS ";: INVERSE : PRINT "LUKE 18:13": NORMAL
60 GOSUB 3030: REM BOX
65 VTAB 15: HTAB 16: PRINT "MERCIFUL"
70 PRINT : HTAB 17: PRINT "ME ME"
75 INVERSE : VTAB 23: HTAB 9: PRINT "HIT ANY KEY FOR ANSWER";: NORMAL : PRINT " ";: GET A$
80 PRINT : VTAB 3: PRINT "---------------------------------------"
85 PRINT "AND THE PUBLICAN, STANDING AFAR OFF, WOULD NOT SO MUCH AS LIFT UP HIS EYES UNTO HEAVEN, BUT SMOTE UPON HIS BREAST SAYING GOD BE ";: INVERSE : PRINT "MERCIFUL TO ME";: NORMAL : PRINT " A SINNER"
90 PRINT "---------------------------------------": PRINT " "
95 VTAB 23: PRINT " DON'T GROAN THE BEST IS YET TO COME (HIT RETURN TO CONTINUE) ";: GET A$
100 REM * THE QUIZ BEGINS HERE *
105 REM * PART #1 *
110 REM THIS SHOWS THE STANDARD FORMAT FOR ENTERING MORE EYE-CUES
120 HOME : GOSUB 3000: REM INSTRUCTIONS AND BOX
140 VTAB 16: HTAB 19: PRINT "2=1": REM PUT STUFF IN BOX
180 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 200
185 N = 1: REM VERSE=N
190 GOSUB 6000: REM ENDING INSTRUCTIONS
200 REM * PART #2 *
220 HOME : GOSUB 3000
250 VTAB 16: HTAB 16: PRINT "CAM EL"
255 H = 19: FOR V = 12 TO 18: GOSUB 4000: POKE ADR,LTR: NEXT V
257 H = 18:V = 12: GOSUB 4000: POKE ADR,LTR:H = 20:V = 12: GOSUB 4000: POKE ADR,LTR:H = 18:V = 18: GOSUB 4000: POKE ADR,LTR:H = 20:V = 18: GOSUB 4000: POKE ADR,LTR
280 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 300
290 N = 2: GOSUB 6000
300 REM * PART #3 *
320 HOME : GOSUB 3000
340 VTAB 15: HTAB 20: PRINT "V": HTAB 19: PRINT "I E": HTAB 18: PRINT "L S": HTAB 17: PRINT "O"
380 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 400
390 N = 3: GOSUB 6000
400 REM * PART #4 *
420 HOME : GOSUB 3000
440 VTAB 16: HTAB 26: PRINT "F": HTAB 25: PRINT "E": HTAB 24: PRINT "I": HTAB 23: PRINT "H": HTAB 22: PRINT "C"
480 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 500
490 N = 4: GOSUB 6000
500 REM * PART #5 *
520 HOME : GOSUB 3000
540 VTAB 13: HTAB 15: PRINT "HE DOVE"
541 VTAB 13: HTAB 22: PRINT "AVEN"
580 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 600
590 N = 5: GOSUB 6000
600 REM * PART #6 *
620 HOME : GOSUB 3000
640 VTAB 15: HTAB 18: PRINT "LORD": VTAB 17: HTAB 18: PRINT "ALL"
680 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 700
690 N = 6: GOSUB 6000
700 REM * PART #7 *
720 HOME : GOSUB 3000
740 VTAB 14: HTAB 19: PRINT "S H": HTAB 17: PRINT "U E": VTAB 17: HTAB 15: PRINT "B LIGHT L"
780 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 800
790 N = 7: GOSUB 6000
800 REM * PART #8 *
820 HOME : GOSUB 3000
840 VTAB 16: HTAB 16: PRINT "WOLAMBSVES"
880 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 900
890 N = 8: GOSUB 6000
900 REM * PART #9 *
920 HOME : GOSUB 3000
940 VTAB 15: HTAB 16: PRINT "PRIDE FALL"
980 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 1000
990 N = 9: GOSUB 6000
1000 REM * PART #10 *
1020 HOME : GOSUB 3000
1040 VTAB 13: HTAB 20: PRINT "G": HTAB 20: PRINT "L": HTAB 19: PRINT "SEE": HTAB 20: PRINT "A": HTAB 20: PRINT "S": HTAB 20: PRINT "S"
1080 VTAB 1: HTAB 40: GET A$: IF A$ = "C" THEN 1100
1090 N = 10: GOSUB 6000
1100 REM * PART #11 *
1997 GOTO 100
3000 VTAB 9: HTAB 17: INVERSE : PRINT "EYE-CUE": NORMAL
3010 VTAB 1: PRINT "TYPE 'A' FOR ANSWER OR 'C' TO CONTINUE ";
3020 REM * PLOT OF BOX *
3030 LTR = 32: REM INVERTED SPACE
3040 V = 10: FOR H = 12 TO 26: GOSUB 4000: POKE ADR,LTR: NEXT H
3050 H = 26: FOR V = 11 TO 19: GOSUB 4000: POKE ADR,LTR: NEXT V
3060 V = 20: FOR H = 26 TO 12 STEP -1: GOSUB 4000: POKE ADR,LTR: NEXT H
3070 H = 12: FOR V = 19 TO 11 STEP -1: GOSUB 4000: POKE ADR,LTR: NEXT V
3080 RETURN
3998 REM * SCREEN FORMULA *
4000 ADR = 1024 +H +128 *V -984 * INT(V/8)
4010 RETURN
5000 REM * VERSES *
5020 VR$(1) = "FOR THIS REASON A MAN WILL LEAVE HIS FATHER AND MOTHER AND BE UNITED TO HIS WIFE AND THE TWO WILL BECOME ONE FLESH. MARK 10:8"
5030 VR$(2) = "INDEED,IT IS EASIER FOR A CAMEL TO GO THROUGH THE EYE OF A NEEDLE THAN FOR A RICH MAN TO ENTER THE KINGDOM OF GOD. LUKE 18:25
5040 VR$(3) = "MOUNT OF OLIVES MARK 11:1"
5050 VR$(4) = "THE STONE WHICH THE BUILDERS REJECTED, THIS BECAME THE CHIEF CORNER STONE; THISCAME ABOUT FROM THE LORD, AND IT IS MARVELOUS IN OUR EYES MARK 12:10"
5060 VR$(5) = "AS JESUS WAS COMING UP OUT OF THE WATER,HE SAW HEAVEN TORN OPEN AND THE SPIRIT DECEND ON HIM LIKE A DOVE. AND A VOICE CAME FROM HEAVEN: 'YOU ARE MY SON, WHOM I LOVE, WITH YOU I AM WELL PLEASED.' MARK 1:10"
5070 VR$(6) = "HE IS THE IMAGE OF THE INVISIBLE GOD,THEFIRSTBORN OVER ALL CREATION, FOR BY HIM ALL THINGS WERE CREATED: THINGS IN HEAVEN AND ON EARTH....AND IN HIM ALL THINGS HOLD TOGETHER COLOSSIANS 1:15"
5080 VR$(7) = "IS A CANDLE BROUGHT TO BE PUT UNDER A BUSHEL, OR UNDER A BED? AND NOT TO BE SET ON A CANDLESTICK? MARK 4:21"
5090 VR$(8) = "GO! I AM SENDING YOU OUT LIKE LAMBS AMONG WOLVES. LUKE 10:3
5100 VR$(9) = "PRIDE GOES BEFORE DESTRUCTION, AND A HAUGHTY SPIRIT BEFORE A FALL. PROVERBS 16:18
5110 VR$(10) = "FOR NOW WE SEE THROUGH A GLASS,DARKLY; BUT THEN FACE TO FACE: NOW I KNOW IN PART; BUT THEN SHALL I KNOW EVEN AS ALSOI AM KNOWN. 1 CORINTHIANS 13:12"
5120 REM * NEXT VERSE GOES HERE
5900 RETURN
6000 VTAB 1: HTAB 1: PRINT "---------------------------------------"
6010 PRINT VR$(N): PRINT "---------------------------------------"
6998 REM * ENDING INSTRUCTIONS *
7000 VTAB 23: PRINT "PRESS 'C' FOR CONTINUE OR 'M' FOR MENU ";: GET A$: IF A$ < >"M" THEN RETURN
7010 PRINT : POP : PRINT "RUN GRAPE MENU"
7030 REM WRITTEN FOR GRAPE BY
7040 REM DOUG TRUSTY
63999 REM "DISTRIBUTED 1980 BY: THE G.R.A.P.E. PRESS P.O. BOX 283 PORT ORCHARD WA 98366

Text found in Volume_196_Religious_Programs.dsk/FREE SPACE.bas:

10 VTAB 22: CALL -958:LOC = PEEK(175) + PEEK(176) *256
15 POKE LOC -39, PEEK(987) -4: REM MEM SIZE CORRECTION
20 PRINT " * ";: CALL LOC -52: PRINT " FREE SECTORS ";: GET A$: PRINT
30 PRINT CHR$(4)"RUN GRAPE MENU": END
63999 REM DISTRIBUTED 1981 BY: THE G.R.A.P.E. PRESS P.O. BOX 283 PORT ORCHARD WA 98366
65535 REM

Text found in Volume_196_Religious_Programs.dsk/GRAPE MAZE.bas:

100 PRINT CHR$(4)"MAXFILES3": DIM C(3121):F = 1:BW = 1:LT = 3:RT = 5:DF = 1:NF = 1: GOSUB 1930: GOSUB 2000: GOTO 1610
110 K = 39 *TX +41 *TY: IF C(K) = MC OR C(K) = TC THEN GOSUB 490:DF = 0:NF = 0
120 RETURN
130 K = 39 *TX +41 *TY: IF C(K) = MC OR C(K) = TC THEN GOSUB 570:DF = 0:NF = 0
140 RETURN
150 K = 39 *TX +41 *TY: IF C(K) < >MC AND C(K) < >TC THEN GOSUB 780:DF = 1:NF = 0
160 IF C(K) = TC AND FTS THEN F = -F: COLOR= 8: PLOT 19 +F,37 -I *3
170 RETURN
180 REM DRAW MAZE
190 GR :MC = 3: COLOR= 3:A = 3:B = 3:X = A *2 +1:Y = B *2 +1: PLOT X,Y:SC = 360
200 IF SC >150 AND SC <350 THEN IF INT( RND(1) *20) = 0 THEN 350
210 L = 0: IF A >0 THEN L = ( SCRN( X -2,Y) = 0)
220 R = 0: IF A <18 THEN R = ( SCRN( X +2,Y) = 0)
230 U = 0: IF B >0 THEN U = ( SCRN( X,Y -2) = 0)
240 D = 0: IF B <18 THEN D = ( SCRN( X,Y +2) = 0)
250 IF L +R +U +D = 0 THEN 320
260 NL = INT( RND(1) *4) +1: ON NL GOSUB 270,280,290,300:SC = SC -1: GOTO 200
270 IF L THEN A = A -1:X = X -2: HLIN X,X +1 AT Y: RETURN
280 IF R THEN A = A +1:X = X +2: HLIN X -1,X AT Y: RETURN
290 IF U THEN B = B -1:Y = Y -2: VLIN Y,Y +1 AT X: RETURN
300 IF D THEN B = B +1:Y = Y +2: VLIN Y -1,Y AT X: RETURN
310 POP : GOTO 200
320 IF NOT SC THEN RETURN
330 IF SC <150 THEN IF MSG = 0 THEN MSG = MSG +1: PRINT : PRINT MSG$(1)
340 IF SC <10 THEN IF MSG = 1 THEN MSG = MSG +1: PRINT : PRINT MSG$(2)
350 A = INT( RND(1) *19):B = B +1: IF B >18 THEN B = 0
360 X = A *2 +1:Y = B *2 +1: IF SCRN( X,Y) = 0 THEN 350
370 GOTO 210
380 REM DRAW HALLWAY
390 FOR I = 1 TO 18
400 COLOR= 7: HLIN 19 -I,19 +I AT 19 -I
410 COLOR= 6: HLIN 20 -I,18 +I AT 18 +I
420 COLOR= 12: VLIN 19 -I,18 +I AT 19 -I
430 VLIN 19 -I,18 +I AT 19 +I: NEXT
440 COLOR= 6: HLIN 20 -I,18 +I AT 18 +I
450 HOME : VTAB 21: IF MAP THEN PRINT SPC( 11)"PRESS 'M' FOR MAP"
460 IF COMP THEN PRINT : HTAB 17: PRINT MID$ (H$,(DIR *5) +1,5)
470 RETURN
480 REM DRAW RIGHT TURN
490 ON I GOTO 510,520,530,540,550
500 FOR Q = 1 TO 5: COLOR= 4: VLIN Q,38 -Q AT 38 -Q: COLOR= 7: HLIN 37 -Q,37 AT Q: COLOR= 6: HLIN 37 -Q,37 AT 38 -Q: NEXT : RETURN
510 FOR Q = 6 TO 10: COLOR= 4: VLIN Q,38 -Q AT 38 -Q: COLOR= 7: HLIN 28,32 AT Q: COLOR= 6: HLIN 28,32 AT 38 -Q: NEXT : RETURN
520 FOR Q = 11 TO 14: COLOR= 4: VLIN Q,38 -Q AT 38 -Q: COLOR= 7: HLIN 24,27 AT Q: COLOR= 6: HLIN 24,27 AT 38 -Q: NEXT : RETURN
530 FOR IN = 21 TO 22: COLOR= 4: VLIN 17,20 AT IN: NEXT : COLOR= 7: PLOT 22,16: COLOR= 6: PLOT 22,21: RETURN
540 COLOR= 4: PLOT 20,19: COLOR= 7: PLOT 20,18: COLOR= 6: PLOT 20,20: RETURN
550 COLOR= 4: PLOT 19,19: RETURN
560 REM DRAW LEFT TURN
570 ON I GOTO 590,600,610,620,630
580 FOR Q = 1 TO 5: COLOR= 4: VLIN Q,38 -Q AT Q: COLOR= 7: HLIN 1,Q AT Q: COLOR= 6: HLIN 1,Q AT 38 -Q: NEXT : RETURN
590 FOR Q = 6 TO 10: COLOR= 4: VLIN Q,38 -Q AT Q: COLOR= 7: HLIN 6,Q AT Q: COLOR= 6: HLIN 6,Q AT 38 -Q: NEXT : RETURN
600 FOR Q = 11 TO 14: COLOR= 4: VLIN Q,38 -Q AT Q: COLOR= 7: HLIN 11,Q AT Q: COLOR= 6: HLIN 11,Q AT 38 -Q: NEXT : RETURN
610 FOR IN = 16 TO 17: COLOR= 4: VLIN 17,20 AT IN: NEXT : COLOR= 7: PLOT 16,16: COLOR= 6: PLOT 16,21: RETURN
620 COLOR= 4: PLOT 18,19: COLOR= 7: PLOT 18,18: COLOR= 6: PLOT 18,20: RETURN
630 COLOR= 4: PLOT 19,19: RETURN
640 REM TURNING
650 COLOR= 4: IF Z = 66 THEN FOR Q = 1 TO 37: HLIN 1,37 AT Q: NEXT
660 IF Z = 76 THEN FOR Q = 1 TO 37: VLIN 1,37 AT Q: NEXT
670 IF Z = 82 THEN FOR Q = 1 TO 37: VLIN 1,37 AT 38 -Q: NEXT
680 RETURN
690 REM TURN MESSAGES
700 IF EF THEN RETURN
710 IF Z = 66 THEN BW = BW +1: IF BW = 4 THEN PRINT MSG$(3):BW = 0: RETURN
720 IF Z = 76 THEN LT = LT +1: IF LT = 7 THEN PRINT MSG$(4):LT = 0: RETURN
730 IF Z = 82 THEN RT = RT +1: IF RT = 7 THEN PRINT MSG$(5):RT = 0: RETURN
740 IF DE THEN PRINT MSG$(8):DE = 0
750 IF NF AND TURN THEN PRINT MSG$(0):TURN = 0
760 NF = 1: RETURN
770 REM DRAW DEAD-END
780 COLOR= 4: IF C(K) = 15 THEN COLOR= 15:DF = 0:: IF NOT EF THEN PRINT : PRINT MSG$(9):EF = 1
790 ON I GOTO 810,820,840,850,870
800 FOR IN = 2 TO 35: VLIN 2,35 AT IN: NEXT :I = 6: RETURN
810 FOR IN = 6 TO 32: VLIN 6,32 AT IN: NEXT :I = 6: RETURN
820 FOR IN = 11 TO 27: VLIN 11,27 AT IN: NEXT :I = 6: IF DF THEN DE = 1
830 RETURN
840 FOR IN = 15 TO 23: VLIN 15,23 AT IN: NEXT :I = 6: RETURN
850 FOR IN = 18 TO 20: VLIN 17,20 AT IN: NEXT :I = 6: IF DF THEN DE = 1
860 RETURN
870 PLOT 19,19:I = 6: RETURN
880 REM HEADED SOUTH
890 FOR I = 0 TO 5
900 TX = X -1:TY = Y +I: IF TX <1 OR TY >37 THEN 920
910 GOSUB 110
920 TX = X +1: IF TX <1 THEN 940
930 GOSUB 130
940 TX = X:TY = Y +I: IF TY >38 THEN 960
950 GOSUB 150
960 NEXT : RETURN
970 REM HEADED WEST
980 FOR I = 0 TO 5
990 TY = Y -1:TX = X -I: IF TX <1 OR TY <1 THEN 1010
1000 GOSUB 110
1010 TY = Y +1: IF TX >37 THEN 1030
1020 GOSUB 130
1030 TY = Y:TX = X -I: IF TX <0 THEN 1050
1040 GOSUB 150
1050 NEXT : RETURN
1060 REM HEADED EAST
1070 FOR I = 0 TO 5
1080 TY = Y +1:TX = X +I: IF TX >37 OR TY >37 THEN 1100
1090 GOSUB 110
1100 TY = Y -1: IF TY <1 THEN 1120
1110 GOSUB 130
1120 TY = Y:TX = X +I: IF TX >38 THEN 1140
1130 GOSUB 150
1140 NEXT : RETURN
1150 REM HEADED NORTH
1160 FOR I = 0 TO 5
1170 TX = X +1:TY = Y -I: IF TX >37 OR TY <1 THEN 1190
1180 GOSUB 110
1190 TX = X -1: IF TX <1 THEN 1210
1200 GOSUB 130
1210 TX = X:TY = Y -I: IF TY <0 THEN 1230
1220 GOSUB 150
1230 NEXT : RETURN
1240 REM DRAW MAP
1250 GR :XX = X:YY = Y:SC = SC +5
1260 PRINT : PRINT MSG$(6)
1270 FOR X = 0 TO 38: FOR Y = 0 TO 38
1280 K = 39 *X +41 *Y: COLOR= C(K): PLOT X,Y
1290 NEXT : NEXT :X = XX:Y = YY: COLOR= 9: PLOT X,Y: IF LAST THEN RETURN
1300 GOSUB 1970: GOSUB 390: GOTO 1580
1310 REM REMEMBER MAP
1320 FOR A = 0 TO 38: FOR B = 0 TO 38
1330 K = 39 *A +41 *B: IF A = 19 AND B = 19 THEN GOSUB 1920: PRINT : PRINT " (A LITTLE MUSICAL INTERLUDE.)";
1340 IF A = 29 AND B = 29 THEN PRINT : PRINT MSG$;
1350 C(K) = SCRN( A,B): NEXT : NEXT : PRINT : HOME : RETURN
1360 REM READ KEYBOARD
1370 Z = PEEK( -16384):Z = Z -128:KB = KB +1: IF KB = 350 THEN PRINT : PRINT MSG$(7):KB = 0
1380 IF Z <0 THEN 1370
1390 POKE -16368,0: IF Z = 27 THEN 1880
1400 KB = 0: IF Z < >66 AND Z < >70 AND Z < >76 AND Z < >77 AND Z < >82 THEN 1370
1410 IF MAP AND Z = 77 THEN 1250
1420 XX = 3 *( ABS(X -E) + ABS(Y -G)): POKE 254,XX: POKE 255,25: CALL 768
1430 REM NEW DIRECTIONS
1440 IF Z = 70 THEN DR = DIR
1450 IF Z = 82 THEN DR = DIR +1
1460 IF Z = 66 THEN DR = DIR +2
1470 IF Z = 76 THEN DR = DIR +3
1480 DIR = INT((DR/4 - INT(DR/4)) *4 +.05)
1490 IF Z < >70 THEN TURN = 1: GOSUB 640: GOSUB 380: GOTO 1580
1500 REM MAP MOVE & ADJUST SCORE
1510 GOSUB 380: IF DIR = 0 THEN Y = Y -1:K = 39 *X +41 *Y:Y = Y +(C(K) = 0)
1520 IF DIR = 2 THEN Y = Y +1:K = 39 *X +41 *Y:Y = Y -(C(K) = 0)
1530 IF DIR = 3 THEN X = X -1:K = 39 *X +41 *Y:X = X +(C(K) = 0)
1540 IF DIR = 1 THEN X = X +1:K = 39 *X +41 *Y:X = X -(C(K) = 0)
1550 IF C(K) = 0 OR C(K) = 1 THEN SC = SC +1
1560 K = 39 *X +41 *Y: IF C(K) = 15 THEN 1800
1570 IF Z = 70 THEN C(K) = TC
1580 POKE -16368,0: ON DIR +1 GOSUB 1160,1070,890,980
1590 GOSUB 700: GOTO 1370
1600 REM START
1610 TEXT : HOME : POKE -16298,0:H$ = "NORTH EASTSOUTH WEST"
1620 HTAB 13: INVERSE : PRINT " INTERNA-MAZE ": NORMAL : PRINT : HTAB 11: PRINT "BY DENNIS G. WARD": HTAB 7: PRINT "APPLESOFT BY STEVE LAWSON"
1630 PRINT : PRINT "THE COMPUTER WILL DRAW A MAZE (IN GRAPE COLOR, OF COURSE) AND PUT YOU INSIDE IT.";
1640 PRINT "YOU HAVE TO FIND THE WAY TO THE GOAL.": PRINT : PRINT "IF YOU FEEL INSECURE, YOU CAN CHOOSE"
1650 PRINT "SOME AIDS: COMPASS, MAP, OR SOME CRUMBS.": PRINT "WOULD YOU LIKE TO DROP SOME CRUMBS AS YOU TRAVEL (Y/N)? ";
1660 GET G$: PRINT G$:FTS = 0: IF G$ = "Y" THEN FTS = 1
1670 PRINT : PRINT "WOULD YOU LIKE A COMPASS (Y/N)? ";: GET G$: PRINT G$:COMP = 0: IF G$ = "Y" THEN COMP = 1
1680 PRINT : PRINT "WOULD YOU LIKE A MAP (EACH TIME YOU USE IT YOU LOSE 5 POINTS) (Y/N)? ";: GET G$: PRINT G$:MAP = 0: IF G$ = "Y" THEN MAP = 1
1690 PRINT : PRINT " * NOTE - YOU LOSE ONE POINT EACH TIME YOU GO FORWARD IF YOU'VE ALREADY BEEN THERE! ";: GET X$: PRINT
1700 HOME : VTAB 21: PRINT SPC( 5)"NOW PLANNING YOUR JOURNEY...": PRINT : PRINT SPC( 5)"(YOU BEGIN WITH 100 POINTS)": GOSUB 190: HOME
1710 REM FIND BEGIN & END
1720 PRINT " YOU'RE AT RED; THE GOAL IS WHITE. TAKE A MOMENT TO PLAN YOUR ROUTE.":TC = 1:L = INT( RND(1) *4): COLOR= 15: ON L GOTO 1740,1750,1760
1730 PLOT 1,37: COLOR= TC:X = 37:Y = 1: PLOT X,Y:E = 1:G = 37: GOTO 1770
1740 PLOT 1,1:X = 37:Y = 37: COLOR= TC: PLOT X,Y:E = 1:G = 1: GOTO 1770
1750 PLOT 37,1:X = 1:Y = 37: COLOR= TC: PLOT X,Y:E = 37:G = 1: GOTO 1770
1760 COLOR= 15: PLOT 37,37:X = 1:Y = 1: COLOR= TC: PLOT X,Y:E = 37:G = 37
1770 GOSUB 1940: GOSUB 1320: POKE -16368,0
1780 DIR = INT( RND(1) *4): GOSUB 380: GOTO 1580
1790 REM YOU MADE IT!
1800 COLOR= 15: FOR Q = 0 TO 17: HLIN 2,36 AT 19 +Q: HLIN 2,36 AT 19 -Q: NEXT Q: POKE -16368,0: HOME
1810 COLOR= 3: VLIN 5,26 AT 8: VLIN 5,26 AT 9: HLIN 4,13 AT 10: HLIN 4,13 AT 11: HLIN 4,13 AT 12: COLOR= 13: PLOT 3,5: PLOT 4,6: PLOT 5,8: PLOT 12,7: PLOT 13,6: PLOT 14,5: PLOT 3,17: PLOT 4,16: PLOT 5,15: PLOT 12,15: PLOT 13,16: PLOT 14,17: REM CROSS
1820 COLOR= 5: VLIN 14,22 AT 16: VLIN 15,18 AT 19: VLIN 21,22 AT 19: VLIN 16,20 AT 21: VLIN 16,20 AT 24: VLIN 14,22 AT 26: VLIN 14,22 AT 31
1830 HLIN 17,18 AT 14: HLIN 17,19 AT 15: HLIN 17,18 AT 19: PLOT 18,20: HLIN 22,23 AT 14: HLIN 22,23 AT 15: HLIN 22,23 AT 21: HLIN 22,23 AT 22: HLIN 27,29 AT 21: HLIN 27,29 AT 22: HLIN 32,34 AT 21: HLIN 32,34 AT 22: REM ROLL
1840 COLOR= 5: VLIN 27,31 AT 16: VLIN 27,33 AT 21: VLIN 27,33 AT 24: VLIN 25,33 AT 26: VLIN 25,33 AT 31
1850 HLIN 17,19 AT 25: HLIN 17,19 AT 26: HLIN 17,19 AT 32: HLIN 17,19 AT 33: HLIN 22,23 AT 25: HLIN 22,23 AT 26: HLIN 22,23 AT 30: HLIN 27,29 AT 32: HLIN 27,29 AT 33: HLIN 32,34 AT 32: HLIN 32,34 AT 33: REM CALL
1860 GOSUB 1920: REM MUSICAL INTERLUDE
1870 DATA 118,100,106,50,94,100,94,50,94,100,118,50,106,100,106,50,106,100,126,50,118,255
1880 HOME : VTAB 21: PRINT " WOULD YOU LIKE TO REVIEW YOUR JOURNEY BEFORE LEAVING? ";: GET X$: PRINT : HOME : IF X$ = "Y" THEN LAST = 1: GOSUB 1250: HOME
1890 HTAB 12: PRINT "YOUR SCORE = ";(100 -SC): REM SCORE
1900 PRINT : PRINT " RETURN TO 'GRAPE MENU'? ";: GET X$: PRINT : IF X$ < >"Y" THEN TEXT : HOME : END
1910 PRINT CHR$(4)"RUN GRAPE MENU": END
1920 RESTORE : FOR SD = 1 TO 11: READ SA,SB: POKE 254,SA: POKE 255,SB: CALL 768: NEXT : RETURN
1930 REM SOUND ROUTINE
1940 POKE 768,173: POKE 769,48: POKE 770,192: POKE 771,136: POKE 772,208: POKE 773,4: POKE 774,198: POKE 775,255: POKE 776,240
1950 POKE 777,8: POKE 778,202: POKE 779,208: POKE 780,246: POKE 781,166: POKE 782,254: POKE 783,76: POKE 784,0: POKE 785,3: POKE 786,96: RETURN
1960 REM DELAY
1970 FOR D = 1 TO 1000: NEXT
1980 FOR D = 1 TO 1000: NEXT : RETURN
1990 REM MESSAGES
2000 MSG$ = "<- WEST ^ NORTH ^ EAST -> PRESS 'F' TO GO FORWARD, 'L' TO TURN LEFT, 'R' TO TURN RIGHT, 'B' TO TURN BACK. (JUST A BIT LONGER....)"
2010 MSG$(0) = " NARROW IS THE WAY WHICH LEADETH UNTO LIFE.... MATTHEW 7:14"
2020 MSG$(1) = " FOR HOW LONG SHALL THY JOURNEY BE? NEHEMIAH 2:6"
2030 MSG$(2) = " YE HAVE HEARD OF THE PATIENCE OF JOB! JAMES 5:11"
2040 MSG$(3) = " THEY...WENT BACKWARD AND NOT FORWARD. JEREMIAH 7:24"
2050 MSG$(4) = " IF THOU WILT TAKE THE LEFT HAND, THEN I WILL GO TO THE RIGHT. GENESIS 13:9"
2060 MSG$(5) = " TURN NOT TO THE RIGHT HAND NOR TO THE LEFT. PROVERB 4:27"
2070 MSG$(6) = "HE THAT WALKETH IN DARKNESS KNOWETH NOT WHITHER HE GOETH. JOHN 12:35"
2080 MSG$(7) = " PONDER THE PATH OF THY FEET, AND LET ALL THY WAYS BE ESTABLISHED. PROVERB 4:26"
2090 MSG$(8) = " I THOUGHT ON MY WAYS, AND TURNED MY FEET.... PSALM 119:59"
2100 MSG$(9) = " I PRESS TOWARD THE MARK FOR THE PRIZE OF THE HIGH CALLING.... PHIL. 3:14": RETURN
2110 REM PROGRAM FROM MAUG
2120 REM (MICRONET AUG)
2130 REM ORIGINAL IN INTEGER
2140 REM CONVERSION AND
2150 REM MAJOR MODIFICATIONS
2160 REM BY STEPHEN M. LAWSON
2170 REM SEPTEMBER 18, 1981
63999 REM DISTRIBUTED 1981 BY: THE G.R.A.P.E. PRESS P.O. BOX 283 PORT ORCHARD WA 98366

Text found in Volume_196_Religious_Programs.dsk/GRAPE MENU.bas:

10 REM *** G.R.A.P.E. MENU ***
15 REM * BY STEPHEN M LAWSON *
20 TEXT : GR : HOME : COLOR= 13: FOR I = 0 TO 16: HLIN 0,39 AT I: NEXT
30 COLOR= 3: PLOT 5,5: HLIN 5,1 AT 4: VLIN 5,11 AT 1: HLIN 2,5 AT 11: VLIN 10,9 AT 5: PLOT 4,9: PLOT 7,11
40 VLIN 4,11 AT 9: HLIN 10,13 AT 4: HLIN 10,13 AT 8: VLIN 5,7 AT 13: HLIN 10,11 AT 9: HLIN 11,12 AT 10: HLIN 12,13 AT 11: PLOT 15,11
50 PLOT 19,4: VLIN 4,6 AT 18: VLIN 4,6 AT 20: VLIN 6,11 AT 17: VLIN 6,11 AT 21: HLIN 18,20 AT 9: PLOT 23,11
60 VLIN 4,11 AT 25: HLIN 26,29 AT 4: HLIN 26,29 AT 8: VLIN 5,7 AT 29: PLOT 30,11
70 VLIN 4,11 AT 32: HLIN 33,36 AT 4: HLIN 33,35 AT 8: HLIN 33,36 AT 11: PLOT 38,11
80 HLIN 20,23 AT 29: HLIN 19,24 AT 30: HLIN 19,24 AT 31: FOR I = 1 TO 3: HLIN 20,23 AT I +31: NEXT : HLIN 21,22 AT 35: HLIN 21,22 AT 36: PLOT 21,37
90 HLIN 33,35 AT 26: HLIN 32,35 AT 27: FOR I = 1 TO 3: HLIN 32,36 AT I +27: NEXT : HLIN 33,36 AT 31: HLIN 34,36 AT 32: HLIN 35,36 AT 33: VLIN 30,33 AT 37: PLOT 36,34
100 COLOR= 8: HLIN 6,9 AT 27: HLIN 10,11 AT 28: HLIN 12,14 AT 29: HLIN 15,17 AT 28: HLIN 18,22 AT 27: HLIN 23,27 AT 26: HLIN 28,29 AT 25: HLIN 30,31 AT 24: HLIN 34,35 AT 22: PLOT 17,26: PLOT 22,28: PLOT 32,25: HLIN 32,33 AT 23: PLOT 16,26
110 COLOR= 12: VLIN 21,25 AT 2: VLIN 21,27 AT 3: VLIN 21,27 AT 4: VLIN 22,27 AT 5: VLIN 20,24 AT 12: VLIN 20,26 AT 13: VLIN 20,26 AT 14: VLIN 20,25 AT 15: VLIN 21,23 AT 16
160 COLOR= 10: HLIN 0,39 AT 17: REM END GRAPHICS
170 REM ** BEGIN MENU PROPER **
180 PRINT : PRINT : PRINT TAB( 7)"PRESS ANY KEY TO VIEW MENU ";: GET A$: PRINT : TEXT : DIM P$(22)
190 HOME : INVERSE : FOR I = 1 TO 13: PRINT " ";: NEXT : PRINT : PRINT " GOSPEL RESOURCE ": PRINT " AND PROGRAM EXCHANGE ": FOR I = 1 TO 13: PRINT " ";: NEXT : NORMAL : PRINT : PRINT
195 PRINT SPC( 13)"DISK VOLUME 1": PRINT
200 FOR I = 1 TO 20: READ P$(I): IF P$(I) = "*" THEN 220
210 NEXT
220 P = I -1: READ M$: READ M$
230 FOR J = 1 TO INT(P/2): PRINT TAB( 2)" " CHR$(64 +J)" "P$(J);: PRINT TAB( 21)" " CHR$(64 + INT(P/2) +J)" "P$( INT(P/2) +J): NEXT
240 REM *** CHOICE ROUTINE ***
250 VTAB 23: CALL -958: PRINT " PRESS KEY TO INDICATE CHOICE ";: GET A$: PRINT
260 IF ASC(A$) <65 OR A$ > CHR$(2 * INT(P/2) +64) THEN 250
270 IF ASC(A$) = 2 * INT(P/2) +64 THEN VTAB 23: PRINT " ";M$: VTAB 23: END
280 IF ASC(A$) = 2 * INT(P/2) +63 THEN PRINT CHR$(4)"CATALOG": PRINT : PRINT TAB( 8)"PRESS ANY KEY FOR MENU ";: GET A$: PRINT : RESTORE : GOTO 190
290 PRINT CHR$(4)"RUN"P$( ASC(A$) -64)
300 REM ** SELECTIONS NAMES **
310 DATA BIBLE DRILL,CRYPTOGRAMS
320 DATA GRAPE MAZE
330 DATA NT BOOKS QUIZ
350 DATA OT BOOKS QUIZ
351 DATA BLESSINGS
352 DATA SCRAMBLED VERSES
353 DATA AMAZING GRACE
354 DATA I'M THINKING
355 DATA NEW JERUSALEM
356 DATA EYE-QUE
357 DATA PEACE MAKER
358 DATA MUSICAL KEYS
365 DATA STUDY PROGRAM
370 DATA STUDY QUESTION.U
380 DATA STUDYFILE XFER.U
385 DATA OLD OLD STORY
386 DATA FREE SPACE
390 DATA DISPLAY CATALOG,FINISHED: REM DO NOT CHANGE
400 DATA *: REM DO NOT CHANGE
500 REM ** CLOSING STATEMENT **
510 DATA 'GOD BE WITH YOU 'TIL WE MEET AGAIN!'

Text found in Volume_196_Religious_Programs.dsk/HELLO.TXT:

14

GRAPE MENU

BIBLE DRILL

CRYPTOGRAMS

GRAPE MAZE

NT & OT BOOKS QUIZ

BLESSINGS & SCRAMBLED VERSES

AMAZING GRACE & I'M THINKING

NEW JERUSALEM & EYE-QUE

PEACE MAKER & MUSICAL KEYS

STUDY PROGRAM (ECT)

OLD OLD STORY

FREE SPACE

DISPLAY CATALOG & FINISH

EXIT TO BASIC
VOLUME N09
MISC. RELIGIOUS N09
RUN GRAPE MENU
This program is the main menu
program. All files are run from
it. If you run any other option
in the current program you will
be taken to it.









Bible Drill presents 8 drills
on Biblical subjects. The
drills can be taken in multiple
choice or flash card form. The
subjects covered are Rock of
"Ages, Biblical Meteorology,
"Bible Fathers, Bible Mothers,
"New Testament Verses, Bible
"Names Meanings, Old Testament
Books and New Testament Books.




This game presents scriptural
verses in a simple cryptogram
code. The user then tries to
decode the verse.










This is a well done maze game.
The player tries to find their
way out of a three dimensional
maze. Various aids are avail-
"able including a compass, bread
crumbs and a map.








These two programs quiz stu-
ents on the order of New and
Testament books.











" BLESSINGS

Blessings generates random
blessings.

" SCRAMBLED VERSES

The letters of Biblical verses
are scrambled on the screen and
then slowly unscrambled.




" AMAZING GRACE

Plays 'Amazing Grace.'

" I'M THINKING


Two games testing knowledge of
the order of books in the
Bible. One game uses the clues
hot and cold and the other
before and after.


" NEW JERUSALEM

"Presents Revelations 21:1,2
(NIV) with graphic display.

" EYE-QUE

The object of this game is to
"discern a familiar Bible name,
phrase or saying from an ar-
rangement of letters.



" PEACE MAKER

Displays the word peace.

" MUSICAL KEYS


Gives each key a musical tone
so the keyboard can be played
like an instrument. Tunes can't
be saved.



"STUDY PROGRAM: Students are
quizzed on the subjects of
"Quotations, Bible Study, Salva-
tion and Basic (both Integer
and Applesoft).

"STUDY QUESTIONS.U: This program
"allows you to add, delete and
change questions used in STUDY
PROGRAM.

"STUDYFILE XFER.U: This utility
helps set up files for use with
STUDY PROGRAM.
A story of the birth and cruci-
fixion on Christ.












Incorrectly displays the number
of free sectors on a disk.












Both options do exactly what
they say.













.. FIRST LINE HAS NUMBER OF ARTICALS
.. NAMES ARE BEST UNDER 24 CHARACTERS
.. THEN EACH ARTICLE IS LISTED WITH THE METHOD OF RUNNING "RUN" OR "BRUN"
.. OR "EXEC"
..
.. THE LAST ENTRY SHOULD BE 'EXIT TO BASIC' PRECEDED BY A EMPTY LINE
.. NEXT ENTER ISSUE OR VOLUME NAME
.. NEXT ENTER DISK NAME OR BLANK LINE
.. NEXT ENTER PROGRAM TO RUN IF ONLY ONE PROGRAM SOULD BE RUN
.. PREDEED THE PROGRAM NAME WITH RUN TYPE.
.. ANYTHING CAN BE IN LINE FOR NORMAL HELLO.
.. THEN A DESCRIPTION OF EACH ARTICLE IS ENTERED. THE DESCRIPTION IS
.. 31 BY 14 LINES. EMPTY LINES MUST BE PRESENT.
TO RUN IF ONLY ONE PROGRAM SOULD BE RUN
.. PREDEED THE PROGRAM NAME WITH RUN TYPE.
.. ANYTHING CAN BE IN LINE FOR NORMAL HELLO.

Text found in Volume_196_Religious_Programs.dsk/HELLO.bas:

10 PRINT CHR$(4)"RUN GRAPE MENU"
20 END

Text found in Volume_196_Religious_Programs.dsk/I'M THINKING.bas:

10 REM " *** I'M THINKING *** *** BY DOUG TRUSTY ****** POULSBO WA 98370 ***
20 TEXT
30 HOME
40 VTAB 7: HTAB 3: PRINT "'I'M THINKING' HAS 3 OPTIONS"
50 PRINT : HTAB 6: PRINT "1 HOT AND COLD"
60 PRINT : HTAB 6: PRINT "2 BEFORE OR AFTER"
70 PRINT : HTAB 6: PRINT "3 EXIT PROGRAM"
80 PRINT : PRINT : INPUT "INPUT YOUR CHOICE AS 1 OR 2 OR 3? ";C$
90 C = VAL(C$)
100 IF C = 3 THEN GOTO 320
110 IF C = 1 OR C = 2 THEN 130
120 GOTO 20
130 HOME
140 T = 0
150 R = INT( RND(1) *66 +1)
160 INVERSE : PRINT "I'M THINKING OF A BOOK OF THE BIBLE !": NORMAL
170 PRINT : PRINT "IF YOUR GUESS HAS A NUMBER IN IT, THEN TYPE YOUR GUESS LIKE THIS: '2 JOHN'"
180 PRINT : PRINT "WHAT IS YOUR GUESS (USE 'STOP' TO END)"
190 PRINT "---------------------------------------"
200 POKE 34,7
210 IF C = 2 THEN GOSUB 400
220 IF C = 1 THEN GOSUB 570
230 PRINT : INVERSE : PRINT "YOU DID IT!": NORMAL
240 PRINT
250 IF T = 1 THEN PRINT "HOW DID YOU DO THAT IN '1' TRY!"
260 IF T >1 AND T <8 THEN PRINT "YOU MUST HAVE USED YOUR BIBLE TO FIGURE THAT IN ";T;" TRYS"
270 IF T = 8 OR T = 9 OR T = 10 THEN PRINT "ABOVE AVERAGE WITH ";T;" TRYS"
280 IF T >10 AND T <20 THEN PRINT "AVERAGE WITH ";T;" TRYS"
290 IF T >20 THEN PRINT "YOU DID IT IN ";T;" TRYS"
300 PRINT
310 PRINT "'RTN' TO CONTINUE, 'X' TO EXIT PROGRAM";: GET G$: PRINT : IF G$ = CHR$(13) THEN 20
320 POKE 34,0: PRINT CHR$(13) CHR$(4)"RUN GRAPE MENU"
330 DATA GENESIS,EXODUS,LEVITICUS,NUMBERS,DEUTERONOMY,JOSHUA,JUDGES,RUTH,1 SAMUEL,2 SAMUEL,1 KINGS,2 KINGS,1 CHRONICLES
340 DATA 2 CHRONICLES,EZRA,NEHEMIAH,ESTHER,JOB,PSALMS,PROVERBS,ECCLESIASTES,SONG OF SOLOMON,ISAIAH,JEREMIAH,LAMENTATIONS,EZEKIEL
350 DATA DANIEL,HOSEA,JOEL,AMOS,OBADIAH,JONAH,MICAH,NAHUM,HABAKKUK,ZEPHANIAH,HAGGAI,ZECHARIAH,MALACHI
360 DATA MATTHEW,MARK,LUKE,JOHN,ACTS,ROMANS,1 CORINTHIANS,2 CORINTHIANS,GALATIANS
370 DATA EPHESIANS,PHILIPPIANS,COLOSSIANS,1 THESSALONIANS,2 THESSALONIANS,1 TIMOTHY,2 TIMOTHY,TITUS,PHILEMON
380 DATA HEBREWS,JAMES,1 PETER,2 PETER,1 JOHN,2 JOHN,3 JOHN,JUDE,REVELATION
390 REM *-----------------------*
400 INPUT G$: IF G$ = "STOP" THEN POP : GOTO 20
410 RESTORE
420 FOR N = 1 TO 66
430 READ BK$
440 IF BK$ = G$ THEN 490
450 NEXT N
460 PRINT
470 PRINT "YOUR SPELLING IS NOT CORRECT"
480 GOTO 400
490 IF N > = R THEN 520
500 PRINT : PRINT "THE BOOK COMES AFTER ";G$
510 T = T +1: GOTO 400
520 IF N = R THEN 550
530 PRINT : PRINT "THE BOOK COMES BEFORE ";G$
540 T = T +1: GOTO 400
550 T = T +1: RETURN
560 REM *---------------------*
570 INPUT G$: IF G$ = "STOP" THEN POP : GOTO 20
580 RESTORE
590 FOR N = 1 TO 66
600 READ BK$
610 IF BK$ = G$ THEN 660
620 NEXT N
630 PRINT
640 PRINT "YOUR SPELLING IS NOT CORRECT"
650 GOTO 570
660 IF N = R THEN 750
670 AMT = ABS(N -R)
680 IF AMT <3 THEN PRINT "YOU ARE RED HOT"
690 IF AMT >2 AND AMT <6 THEN PRINT "YOU ARE HOT"
700 IF AMT >5 AND AMT <11 THEN PRINT "YOU ARE JUST WARM"
710 IF AMT >10 AND AMT <16 THEN PRINT "COOL"
720 IF AMT >15 AND AMT <26 THEN PRINT "YOU'RE COLD"
730 IF AMT >25 THEN PRINT "FREEZING"
740 T = T +1: GOTO 570
750 T = T +1: RETURN
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/MUSICAL KEYS.bas:

100 GOSUB 150
110 GET C$: ON ASC(C$) = 17 GOTO 130: ON ASC(C$) = 3 GOTO 120: PRINT C$" ";: POKE 776,A( ASC(C$)): POKE 777,B: CALL 778: GOTO 110
120 HOME : GOTO 110
130 POKE 34,0: POKE 35,24: VTAB 21: PRINT : CALL -868
140 PRINT : PRINT CHR$(4)"RUN GRAPE MENU": END
150 HOME : HTAB 14: PRINT "MUSICAL KEYS": POKE 34,3
160 B = 50
170 DIM A(128): FOR I = 45 TO 59:A(I) = 20 +5 *(I -44): NEXT : FOR I = 65 TO 90:A(I) = 100 +5 *(I -64): NEXT :A(32) = 100
180 FOR I = 778 TO 798: READ P: POKE I,P: NEXT
190 DATA 173,48,192,136,208,5,206,9,3,240,9,202,208,245,174,8,3,76,10,3,96
200 VTAB 22: HTAB 9: PRINT "TYPE 'CTRL Q' TO QUIT": HTAB 10: PRINT "OR 'CTRL C' - CLEAR": VTAB 4: POKE 35,20: RETURN
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/NEW JERUSALEM.bas:

10 TEXT : HOME
20 HGR : HCOLOR= 7
30 FOR X = 1 TO 279 STEP 10
40 : HPLOT 140,80 TO X,159
50 NEXT X
60 FOR Y = 159 TO 1 STEP -10
70 : HPLOT 140,80 TO 279,Y
80 NEXT Y
90 FOR A = 279 TO 1 STEP -10
100 : HPLOT 140,80 TO A,1
110 NEXT A
120 FOR B = 1 TO 159 STEP 10
130 : HPLOT 140,80 TO 1,B
140 NEXT B
150 D = 1000: GOSUB 250:D = 7000
160 POKE 34,20: VTAB 22
170 SPEED= 100: PRINT "THEN I SAW A NEW HEAVEN AND A NEW EARTH,FOR THE FIRST EARTH HAD PASSED AWAY, ANDTHERE WAS NO LONGER ANY SEA.";: GOSUB 250: HOME
180 PRINT "I SAW THE HOLY CITY, THE NEW JERUSALEM, COMING DOWN OUT OF HEAVEN FROM GOD, PREPARED AS A BRIDE BEAUTIFULLY DRESSED FOR HER HUSBAND. (REV. 21:1,2 NIV)";: GOSUB 250
190 D = 200: FOR X = 21 TO 24: VTAB 24: PRINT : GOSUB 250: NEXT : SPEED= 255
200 D = 1000: GOSUB 250
210 HCOLOR= 0
220 HPLOT 140,72 TO 140,88: HPLOT 135,76 TO 145,76
230 VTAB 1
240 D = 5000: GOSUB 250: PRINT : PRINT CHR$(4)"RUN GRAPE MENU"
250 FOR W = 1 TO D: NEXT W: RETURN
260 REM * THE NEW JERUSALEM *
270 REM * BY TONY GARDNER *
280 REM * SAN DIEGO, CA. *
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/NEW TESTAMENT BOOKS.DRILL.txt:

DEL100,990

100 DATA MATTHEW,MARK
110 DATA MARK,LUKE
120 DATA LUKE,JOHN
130 DATA JOHN,ACTS
140 DATA ACTS,ROMANS
150 DATA ROMANS,I CORINTHIANS
160 DATA I CORINTHIANS,II CORINTHIANS
170 DATA II CORINTHIANS,GALATIANS
180 DATA GALATIANS,EPHESIANS
190 DATA EPHESIANS,PHILIPPIANS
200 DATA PHILIPPIANS,COLOSSIANS
210 DATA COLOSSIANS,I THESSALONIANS
220 DATA I THESSALONIANS,II THESSALONIANS
230 DATA II THESSALONIANS,I TIMOTHY
240 DATA I TIMOTHY,II TIMOTHY
250 DATA II TIMOTHY,TITUS
260 DATA TITUS,PHILEMON
270 DATA PHILEMON,HEBREWS
280 DATA HEBREWS,JAMES
290 DATA JAMES,I PETER
300 DATA I PETER,II PETER
310 DATA II PETER,I JOHN
320 DATA I JOHN,II JOHN
330 DATA II JOHN,III JOHN
340 DATA III JOHN,JUDE
350 DATA JUDE,REVELATION
360 DATA REVELATION,LAST NEW TESTAMENT BOOK
990 DATA *,NAME THE NEW TESTAMENT BOOK FOLLOWING THE BOOK GIVEN -

RUN100

Text found in Volume_196_Religious_Programs.dsk/NEW TESTAMENT VERSES.DRILL.txt:

DEL100,990

100 DATA "FINALLY, BROTHERS, GOOD-BY. AIM FOR PER-FECTION, LISTEN TO MY APPEAL, BE OF ONE MIND, ....","LIVE IN PEACE 2 COR 13:11"
110 DATA "REPENT, THEN, AND ..., SO THAT YOUR SINSMAY BE WIPED OUT, THAT TIMES OF REFRESH-ING MAY COME FROM THE LORD.","TURN TO GOD ACTS 3:19"
120 DATA "..., ALL YOU WHO ARE WEARY AND BURDENED,AND I WILL GIVE YOU REST.","COME UNTO ME MATTHEW 11:28"
130 DATA "BLESSED ARE THOSE WHO ... FOR RIGHTEOUS-NESS, FOR FOR THEY WILL BE FILLED.","HUNGER AND THIRST MATTHEW 5:6"
140 DATA "BLESSED ARE THE MEEK, FOR THEY WILL ....","INHERIT THE EARTH MATTHEW 5:3"
150 DATA "ANY WHY DO YOU WORRY ABOUT CLOTHES? SEE HOW THE LILIES OF THE FIELD GROW. THEY DO NOT ....","LABOR OR SPIN MATTHEW 6:28"
160 DATA "PUT ON THE FULL ARMOR OF GOD SO THAT YOUCAN ... AGAINST THE DEVIL'S SCHEMES.","TAKE YOUR STAND EPH 6:11"
170 DATA "DO NOT MERELY ..., AND SO DECEIVE YOUR- SELVES. DO WHAT IT SAYS.","LISTEN TO THE WORD JAMES 1:22"
180 DATA "FOR GOD SO LOVED THE WORLD THAT HE GAVE HIS ONE AND ONLY SON, THAT WHOSOEVER BE-LIEVES IN HIM SHALL NOT PERISH BUT ....","HAVE ETERNAL LIFE JOHN 3:16"
190 DATA "NOW IF WE DIED WITH CHRIST, WE BELIEVE THAT WE WILL ALSO ....","LIVE WITH HIM ROMANS 6:8"
200 DATA "DEAR FRIENDS, SINCE GOD SO LOVED US, WE ALSO OUGHT TO ....","LOVE ONE ANOTHER 1 JOHN 4:11"
210 DATA "THIS IS LOVE FOR GOD: TO .... AND HIS COMMANDS ARE NOT BURDENSOME.","OBEY HIS COMMANDS 1 JOHN 5:3"
220 DATA "HE CHOSE TO ... THROUGH THE WORD OF TRUTH, THAT WE MIGHT BE A KIND OF FIRST-FRUITS OF ALL HE CREATED.","GIVE US BIRTH JAMES 1:18"
230 DATA "SO THEN, THOSE WHO SUFFER ACCORDING TO GOD'S WILL SHOULD COMMIT THEMSELVES TO THEIR FAITHFUL CREATOR AND ....","CONTINUE TO DO GOOD 1 PETER 4:19"
240 DATA "SUBMIT YOURSELVES, THEN, TO GOD. ..., AND HE WILL FLEE FROM YOU.","RESIST THE DEVIL JAMES 4:7"
250 DATA "... OF YOUTH, AND PURSUE RIGHTEOUSNESS, FAITH, LOVE AND PEACE, ALONG WITH THOSE WHO CALL ON THE LORD OUT OF A PURE HEART","FLEE THE EVIL DESIRES 2 TIM 2:20"
260 DATA "LOVE MUST BE SINCERE. ...; CLING TO WHATIS GOOD.","HATE WHAT IS EVIL ROMANS 12:9"
270 DATA "THE ENTIRE LAW IS SUMMED UP IN A SINGLE COMMAND: '... AS YOURSELF.'","LOVE YOUR NEIGHBOR GAL 5:14"
280 DATA "FOR THE SON OF MAN CAME TO SEEK AND TO ....","SAVE WHAT WAS LOST LUKE 19:10"
290 DATA "THE THIEF COMES ONLY TO STEAL AND ...; IHAVE COME THAT THEY MAY HAVE LIFE, AND HAVE IT TO THE FULL.","KILL AND DESTROY JOHN 10:10"
300 DATA "IF WE LIVE, WE ...; AND IF WE DIE WE DIETO THE LORD. SO WHETHER WELIVE OR DIE, WE BELONG TO THE LORD.","LIVE TO THE LORD ROMANS 14:8"
310 DATA "THEREFORE, AS IT IS WRITTEN: 'LET HIM WHO BOASTS ....'","BOAST IN THE LORD 1 COR 1:31"
320 DATA "... ALWAYS. I WILL SAY IT AGAIN: REJOICE!","REJOICE IN THE LORD PHIL 4:4"
330 DATA "SHOW PROPER RESPECT TO EVERYONE: LOVE THE BROTHERHOOD OF BELIEVERS, FEAR GOD, ....","HONOR THE KING 1 PETER 2:17"
340 DATA "YET TO ALL WHO RECEIVED HIM, TO THOSE WHO BELIEVED IN HIS NAME, HE GAVE THE RIGHT TO ....","BECOME CHILDREN OF GOD JOHN 1:12"
990 DATA *,"COMPLETE THE FOLLOWING VERSES WITH 3 OR 4 WORDS. IDENTIFY THE SOURCE. (NIV)"

RUN100

Text found in Volume_196_Religious_Programs.dsk/NT BOOKS QUIZ.bas:

10 REM BY DOUG TRUSTY 3315 NW PARRIS ROAD POULSBO, WA 98370 (206) 779-5275
20 DOUG = 0
30 NN = 1
40 W = 0
50 HOME
60 GOSUB 190
70 GOSUB 900
80 POKE 34,21
90 F = 0
100 VTAB 24: PRINT "BOOK #";NN;" IS ";
110 INPUT IB$
120 READ NT,TB$,X,Y
130 IF IB$ = TB$ AND NN = NT THEN GOSUB 350
140 IF IB$ = TB$ AND NN = (NT +1) AND NT = 27 THEN GOSUB 620
150 IF IB$ = TB$ AND NN < >(NT) AND F < >1 THEN GOSUB 480
160 IF NT = -1 THEN GOSUB 570
170 IF F = 1 THEN GOTO 90
180 GOTO 120
190 HTAB 8: VTAB 2: PRINT "BOOKS OF THE NEW TESTAMENT": PRINT
200 HTAB 3: PRINT "ACTS LUKE"
210 HTAB 3: PRINT "COLOSSIANS MARK"
220 HTAB 3: PRINT "1 CORINTHIANS MATTHEW"
230 HTAB 3: PRINT "2 CORINTHIANS 1 PETER"
240 HTAB 3: PRINT "EPHESIANS 2 PETER"
250 HTAB 3: PRINT "GALATIANS PHILEMON"
260 HTAB 3: PRINT "HEBREWS PHILIPPIANS"
270 HTAB 3: PRINT "JAMES ROMANS"
280 HTAB 3: PRINT "JOHN REVELATION"
290 HTAB 3: PRINT "1 JOHN 1 THESSALONIANS"
300 HTAB 3: PRINT "2 JOHN 2 THESSALONIANS"
310 HTAB 3: PRINT "3 JOHN 1 TIMOTHY"
320 HTAB 3: PRINT "JUDE 2 TIMOTHY"
330 HTAB 3: PRINT " TITUS"
340 RETURN
350 VTAB 23: HTAB 32: PRINT "GOOD"
360 GOSUB 820
370 C$ = TB$
380 GOSUB 840
390 POKE 50,63
400 VTAB 19: PRINT ""
410 VTAB 1: HTAB 3: PRINT NN;" CORRECT"
420 POKE 50,255
430 GOSUB 750
440 NN = NN +1
450 F = 1
460 RESTORE
470 RETURN
480 VTAB 23: HTAB 29: PRINT "WRONG ANSWER"
490 W = W +1
500 GOSUB 800
510 POKE 50,63
520 VTAB 1: HTAB 30: PRINT W;" WRONG"
530 POKE 50,255
540 F = 1
550 RESTORE
560 RETURN
570 VTAB 23: PRINT IB$;" IS TYPED WRONG"
580 GOSUB 800
590 F = 1
600 RESTORE
610 RETURN
620 REM
630 GOSUB 750
640 HTAB 2
650 VTAB 2: PRINT " "
660 GOTO 990
670 VTAB 24: INPUT "PRESS RETURN KEY TO CONTINUE";B$
680 TEXT : HOME : PRINT "'WOW'.....YOU GOT ALL 27 BOOKS CORRECT AND ONLY MISSED ";W
690 VTAB 10: HTAB 10
700 INPUT "WOULD YOU LIKE TO TRY AGAIN";Y$
710 IF Y$ = "Y" OR Y$ = "YES" THEN GOTO 30
720 HOME
730 PRINT "GOOD BYE FRIEND"
740 PRINT "RUN GRAPE MENU": END
750 VTAB (Y -1)
760 IF X = 3 THEN HTAB 3
770 IF X = 28 THEN HTAB 23
780 PRINT " "
790 RETURN
800 FOR H = 1 TO 50: FOR J = 1 TO 10: NEXT :K = PEEK( -16336): NEXT
810 RETURN
820 FOR M = 50 TO 55: FOR N = 1 TO 10:P = PEEK( -16336): NEXT : NEXT
830 RETURN
840 REM
850 LTR = 32
860 V = 18: FOR H = 39 TO 0 STEP -1: GOSUB 970: POKE PO,LTR: NEXT
870 LTR = 32
880 V = 18: FOR H = 0 TO 39: GOSUB 970: POKE PO,LTR: NEXT
890 RETURN
900 REM
910 LTR = 32
920 V = 0: FOR H = 0 TO 39: GOSUB 970: POKE PO,LTR: NEXT H
930 H = 39: FOR V = 0 TO 18: GOSUB 970: POKE PO,LTR: NEXT
940 V = 18: FOR H = 39 TO 0 STEP -1: GOSUB 970: POKE PO,LTR: NEXT
950 H = 0: FOR V = 18 TO 0 STEP -1: GOSUB 970: POKE PO,LTR: NEXT
960 RETURN
970 PO = 1024 +H +128 *V -984 * INT(V/8)
980 RETURN
990 REM
1000 XOLD = 2
1010 YOLD = 2
1020 XS = 1
1030 YS = 1
1040 XN = XOLD +XS
1050 IF (XN >0) AND (XN <39) THEN GOTO 1090
1060 XS = -1 *XS
1070 GOSUB 1310
1080 GOTO 1040
1090 YN = YOLD +YS
1100 IF (YN >0) AND (YN <18) THEN GOTO 1140
1110 YS = -1 *YS
1120 GOSUB 1310
1130 GOTO 1090
1140 LTR = 32
1150 H = XN:V = YN
1160 GOSUB 1240
1170 LTR = 224
1180 H = XOLD:V = YOLD
1190 DOUG = DOUG +1: IF DOUG = 100 THEN 670
1200 GOSUB 1240
1210 XOLD = XN
1220 YOLD = YN
1230 GOTO 1040
1240 GOSUB 1250: POKE PO,LTR: RETURN
1250 PO = 1024 +H +128 *V -984 * INT(V/8): RETURN
1260 DATA 1,MATTHEW,28,7,2,MARK,28,6,3,LUKE,28,5,4,JOHN,3,13,5,ACTS,3,5,6,ROMANS,28,12,7,1 CORINTHIANS,3,7,8,2 CORINTHIANS,3,8,9,GALATIANS,3,10,10,EPHESIANS,3,9
1270 DATA 11,PHILIPPIANS,28,11,12,COLOSSIANS,3,6,13,1 THESSALONIANS,28,14,14,2 THESSALONIANS,28,15,15,1 TIMOTHY,28,16,16,2 TIMOTHY,28,17,17,TITUS,28,18,18,PHILEMON,28,10,19,HEBREWS,3,11
1280 DATA 20,JAMES,3,12,21,1 PETER,28,8,22,2 PETER,28,9,23,1 JOHN,3,14,24,2 JOHN,3,15,25,3 JOHN,3,16,26,JUDE,3,17
1290 DATA 27,REVELATION,28,13
1300 DATA -1,DOUGLAS TRUSTY,40,24
1310 PRINT "": RETURN
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/OLD OLD STORY.bas:

100 HOME : TEXT : HOME : VTAB 8: PRINT "ONLY ONE QUESTION...": PRINT : PRINT "this is in lower case..": PRINT : PRINT "CAN YOU READ THE ABOVE LINE? ";: GET X$: PRINT : IF X$ = "Y" THEN LC = 1
110 HOME : ON NOT LC GOSUB 170: GOTO 130
120 FOR I = 1 TO LEN(X$):X = PEEK(36):Y = PEEK(37):CH = ASC( MID$ (X$,I)): PRINT CHR$(CH);: DRAW CH -31 AT 7 *X,8 *Y: NEXT : RETURN
130 ON LC +1 GOSUB 180,190: RESTORE : FOR J = 1 TO 12: FOR K = 1 TO 22: IF K >1 THEN PRINT
140 READ X$: ON NOT LC AND LEN(X$) >0 GOSUB 120: IF LC THEN PRINT X$;
150 NEXT : GET X$: PRINT : ON LC +1 GOSUB 180,190: NEXT : ON X$ = "R" GOTO 130: ON LC GOTO 160: POKE 49236,0: POKE 49233,0: HIMEM: HM
160 PRINT : PRINT CHR$(4)"RUN GRAPE MENU"
170 HM = PEEK(115) + PEEK(116) *256: HIMEM: 16384:D$ = CHR$(4): PRINT D$"BRUNALPHA SHAPES": HCOLOR= 3: SCALE= 1: ROT= 0
180 HGR2
190 HOME : RETURN
200 DATA " I LOVE TO TELL THE STORY"," "," On September 19, 1944, Minnie Elsie","Freeman made a recording; a recitation","of forty-three stanzas presenting the"
210 DATA "'old, old story of Jesus and His love.'"," Grandma Freeman recited the poem to","all who would hear it, until that joy","was ended by death in February, 1959.","But her voice will never be silent in"
220 DATA "heaven, as she eternally sings praises","to her Lord and Savior, Jesus Christ."," Some 20 years after her death, the","16 inch, glass transcription disk was","'found.' Grandma's voice is now heard"
230 DATA "by many, by transferring her story to","cassette tape. And many more will now","read her beloved words from a new kind","of disk! Grandma would be astonished","at the means God has given for her to"
240 DATA "continue telling the 'old, old story'."," ...."
250 DATA " ","You have asked me for a story","Of unseen things above,","Of Jesus and His glory,","Of Jesus and His love."," ","You want the old, old story,","And nothing else will do."
260 DATA "Indeed, I do not wonder","It always seems so new."," ","I often wish that someone","Would tell me it each day.","I never would grow tired","Of what they had to say."," "
270 DATA "But I am wasting moments --","Oh, how shall I begin","To tell that old, old story","How Jesus saves from sin."," "," ...."," "
280 DATA "Well, you listen and I will tell you.","God help both you and me","To make this old, old story","His message unto thee."," ","Once in a pleasant garden","God placed a happy pair;"
290 DATA "All within was peaceful,","All around was fair."," ","But they disobeyed Him.","The one thing that He denied","They longed for, they took, they tasted","They ate of it and they died."
300 DATA " ","Yet in His love and mercy","The Lord at once declared","How man though lost and ruined,","Might after all be spared."," "," ...."," "
310 DATA "For one of these descendants,","Not sinful like the rest,","Has spoiled the work of Satan --","And man be saved and blest."," ","Hundreds of years were over","And Adam and Eve had died,"
320 DATA "And the following generation,","And many more beside."," ","At last, the shepherds watching","Beside their flocks one night","Was startled in the darkness","By a strange and heavenly light."
330 DATA " ","One of the holy angels","Had come from heaven above","To tell that new, new story","Of Jesus and His love."," "," ...."," "
340 DATA "He came to bring glad tidings --","'You must not - need not - fear,","For Christ your new-born Savior","Lies in a village near.'"," ","Then many other angels","Took up the chorus them,"
350 DATA "'On high to God be glory,","Goodwill and peace to men.'"," ","And was it true, that story?","They went at once to see;","And they found Him in the manger,","And they knew that it was He."
360 DATA " ","He, whom the Father promised","So many ages past,","Had come to save poor sinners;","Yes, He had come at last."," "," ...."," "
370 DATA "He was content to do it --","To seek and to save the lost --","Although He knew beforehand,","Knew all that it would cost."," ","He lived a life most hold.","His every thought was love,"
380 DATA "His every action showed it","To man and to God above."," ","His path on earth was lowly,","He was a working man.","Who knows the poor man's trials","So well as Jesus can?"," "
390 DATA "His last three years were lovely.","He could no more be hid,","And time and strength would fail me","To tell all the good He did."," "," ...."," "
400 DATA "He gave away no money","For He had none to give;","But He had power for healing,","And He made dead people live."," ","He did kind things so kindly --","It seemed His heart's delight"
410 DATA "To make poor people happy","From morning until night."," ","He always seemed at leisure","For everyone who came,","However tired or busy","They found Him just the same."," "
420 DATA "He heard each tale of sorrow","With an attentive ear.","He took away each burden","Of suffering, sin and fear."," "," ...."," ","He was a Man of Sorrow,"
430 DATA "And when He gave relief","He gave it like a brother,","Aquainted with their grief."," ","Such was the man Christ Jesus,","A friend of sinful men.","But, hush, the tale grows sadder --"
440 DATA "I'll tell it if I can."," ","This gentle, holy Jesus","Without a spot or stain","By wicked hands was taken,","Was crucified, was slain."," ","Look! Look! If you can bear it!"
450 DATA "Look at your dying Lord!","Stand near the cross and watch Him.","Behold, the Lamb of God!"," "," ...."," ","His hands and feet are pierced,"
460 DATA "He cannot hide His face;","And cruel men stand staring","In crowds about the place."," ","They laugh at Him, they mock Him,","They tell Him to come down --","To leave that cross of suffering"
470 DATA "And exchange it for a crown."," ","Why did He bear their mockings;","Was He almighty God?","And could He have destroyed them","With one almighty word?"," ","Yes! He could have done it!"
480 DATA "But I will tell you why","He would not use His power","But He chose instead to die."," "," ...."," ","He had become our surety","And what we could not pay"
490 DATA "He paid instead and for us","On that one dreadful day."," ","For our sins He suffered!","For our sins He died!","Not for ours only,","But for all the world beside."," "
500 DATA "And now He has ascended","And He sits upon the throne,","To be a Prince and Savior","And to claim us for His own."," ","Now, when He left His people","He promised them to send"
510 DATA "A Comforter to teach them","And to guide them to the end."," "," ...."," ","And that same Holy Spirit","Is with us to this day,","And is ready now to teach us"
520 DATA "That new and that living way."," ","Now, this is the old, old story --","Say, do you take it in --","This wonderful redemption,","God's remedy for sin?"," "
530 DATA "Do you with heart believe it?","Do you believe it was true","And was sent for every sinner,","And was therefore meant for you?"," ","Then take this great salvation,"
540 DATA "For Jesus loves to give.","Believe, and you'll receive it!","Believe, and you shall live!"," "," ...."," ","Now, if this simple message"
550 DATA "Has now brought peace to you","Then tell the old, old story,","For others need it, too."," ","Let everybody know it --","That Christ has made you free --","And if it gets them longing"
560 DATA "Tell them, 'Jesus died for thee.'"," ","Soon, soon, our eyes shall see Him;","And then in heaven above","We'll sing that old, old story","Of Jesus and His love."," "," "
570 DATA " -author and source unknown"," transcribed by S. Lawson 1977"," "," ","<'R' to restart - any other key to end>"
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/OLD TESTAMENT BOOKS.DRILL.txt:

DEL100,990

100 DATA GENESIS,EXODUS
110 DATA EXODUS,LEVITICUS
120 DATA LEVITICUS,NUMBERS
130 DATA NUMBERS,DEUTERONOMY
140 DATA DEUTERONOMY,JOSHUA
150 DATA JOSHUA,JUDGES
160 DATA JUDGES,RUTH
170 DATA RUTH,I SAMUEL
180 DATA I SAMUEL,II SAMUEL
190 DATA II SAMUEL,I KINGS
200 DATA I KINGS,II KINGS
210 DATA II KINGS,I CHRONICLES
220 DATA I CHRONICLES,II CHRONICLES
230 DATA II CHRONICLES,EZRA
240 DATA EZRA,NEHEMIAH
250 DATA NEHEMIAH,ESTHER
260 DATA ESTHER,JOB
270 DATA JOB,PSALMS
280 DATA PSALMS,PROVERBS
290 DATA PROVERBS,ECCLESIASTES
300 DATA ECCLESIASTES,SONG OF SOLOMON
310 DATA SONG OF SOLOMON,ISAIAH
320 DATA ISAIAH,JEREMIAH
330 DATA JEREMIAH,LAMENTATIONS
340 DATA LAMENTATIONS,EZEKIEL
350 DATA EZEKIEL,DANIEL
360 DATA DANIEL,HOSEA
370 DATA HOSEA,JOEL
380 DATA JOEL,AMOS
390 DATA AMOS,OBADIAH
400 DATA OBADIAH,JONAH
410 DATA JONAH,MICAH
420 DATA MICAH,NAHUM
430 DATA NAHUM,HABAKKUK
440 DATA HABAKKUK,ZEPHANIAH
450 DATA ZEPHANIAH,HAGGAI
460 DATA HAGGAI,ZECHARIAH
470 DATA ZECHARIAH,MALACHI
480 DATA MALACHI,LAST OLD TESTAMENT BOOK
990 DATA *,NAME THE OLD TESTAMENT BOOK FOLLOWING THE BOOK GIVEN -

RUN100

Text found in Volume_196_Religious_Programs.dsk/OT BOOKS QUIZ.bas:

5 REM BY DOUG TRUSTY 3315 NW PARRIS ROADPOULSBO, WA 98370(206) 779-5275
10 IF PEEK( -8192) = 32 THEN LOMEM: 24576
20 DIM X(100),Y(100)
30 NN = 1
40 W = 0
50 HOME
60 GOSUB 190
70 GOSUB 870
80 POKE 34,21
90 F = 0
100 VTAB 24: PRINT "BOOK #";NN;" IS ";
110 INPUT IB$
120 READ NT,TB$,X,Y
130 IF IB$ = TB$ AND NN = NT THEN GOSUB 350
140 IF IB$ = TB$ AND NN = (NT +1) AND NT = 39 THEN GOSUB 620
150 IF IB$ = TB$ AND NN < >(NT) AND F < >1 THEN GOSUB 480
160 IF NT = -1 THEN GOSUB 570
170 IF F = 1 THEN GOTO 90
180 GOTO 120
190 VTAB 3: HTAB 8: PRINT "BOOKS OF THE OLD TESTAMENT"
200 PRINT
210 HTAB 3: PRINT "SONG OF SOLOMON HABAKKUK ZEPHANIAH"
220 HTAB 3: PRINT "ECCLESIASTES ISAIAH JOB"
230 HTAB 3: PRINT "1 CHRONICLES JEREMIAH EZEKIEL"
240 HTAB 3: PRINT "LAMENTATIONS RUTH JOEL"
250 HTAB 3: PRINT "ZECHARIAH DANIEL JONAH"
260 HTAB 3: PRINT "EXODUS HOSEA NAHUM"
270 HTAB 3: PRINT "2 CHRONICLES OBADIAH AMOS"
280 HTAB 3: PRINT "NUMBERS MICAH HAGGAI"
290 HTAB 3: PRINT "1 KINGS MALACHI GENESIS"
300 HTAB 3: PRINT "DEUTERONOMY 2 KINGS JOSHUA"
310 HTAB 3: PRINT "1 SAMUEL JUDGES ESTHER"
320 HTAB 3: PRINT "LEVITICUS 2 SAMUEL EZRA"
330 HTAB 3: PRINT "NEHEMIAH PSALMS PROVERBS"
340 RETURN
350 VTAB 23: HTAB 30: PRINT "VERY GOOD"
360 GOSUB 790
370 C$ = TB$
380 GOSUB 810
390 POKE 50,63
400 VTAB 19: PRINT ""
410 VTAB 1: HTAB 3: PRINT NN;" CORRECT"
420 POKE 50,255
430 GOSUB 730
440 NN = NN +1
450 F = 1
460 RESTORE
470 RETURN
480 VTAB 23: HTAB 29: PRINT "WRONG ANSWER"
490 W = W +1
500 GOSUB 770
510 POKE 50,63
520 VTAB 1: HTAB 30: PRINT W;" WRONG"
530 POKE 50,255
540 F = 1
550 RESTORE
560 RETURN
570 VTAB 23: PRINT IB$;" IS TYPED WRONG"
580 GOSUB 770
590 F = 1
600 RESTORE
610 RETURN
620 REM
630 GOSUB 730
640 GOSUB 960
650 GOTO 1030
660 TEXT : HOME : PRINT "'WOW'.....YOU GOT ALL 39 BOOKS CORRECT AND ONLY MISSED ";W
670 VTAB 10: HTAB 10
680 INPUT "WOULD YOU LIKE TO TRY AGAIN";Y$
690 IF Y$ = "Y" OR Y$ = "YES" THEN GOTO 30
700 HOME
710 PRINT "GOOD BYE FRIEND"
720 PRINT "RUN GRAPE MENU": END
730 HTAB X: VTAB Y
740 IF X = 3 THEN PRINT " "
750 IF X = 20 OR X = 30 THEN PRINT " "
760 RETURN
770 FOR H = 1 TO 50: FOR J = 1 TO 10: NEXT :K = PEEK( -16336): NEXT
780 RETURN
790 FOR M = 50 TO 55: FOR N = 1 TO 10:P = PEEK( -16336): NEXT : NEXT
800 RETURN
810 REM
820 LTR = 32
830 V = 18: FOR H = 39 TO 0 STEP -1: GOSUB 940: POKE PO,LTR: NEXT
840 LTR = 32
850 V = 18: FOR H = 0 TO 39: GOSUB 940: POKE PO,LTR: NEXT
860 RETURN
870 REM
880 LTR = 32
890 V = 0: FOR H = 0 TO 39: GOSUB 940: POKE PO,LTR: NEXT H
900 H = 39: FOR V = 0 TO 18: GOSUB 940: POKE PO,LTR: NEXT
910 V = 18: FOR H = 39 TO 0 STEP -1: GOSUB 940: POKE PO,LTR: NEXT
920 H = 0: FOR V = 18 TO 0 STEP -1: GOSUB 940: POKE PO,LTR: NEXT
930 RETURN
940 PO = 1024 +H +128 *V -984 * INT(V/8)
950 RETURN
960 RETURN
970 DATA 1,GENESIS,30,13,2,EXODUS,3,10,3,LEVITICUS,3,16,4,NUMBERS,3,12,5,DEUTERONOMY,3,14,6,JOSHUA,30,14
980 DATA 7,JUDGES,20,15,8,RUTH,20,8,9,1 SAMUEL,3,15,10,2 SAMUEL,20,16,11,1 KINGS,3,13,12,2 KINGS,20,14
990 DATA 13,1 CHRONICLES,3,7,14,2 CHRONICLES,3,11,15,EZRA,30,16,16,NEHEMIAH,3,17,17,ESTHER,30,15
1000 DATA 18,JOB,30,6,19,PSALMS,20,17,20,PROVERBS,30,17,21,ECCLESIASTES,3,6,22,SONG OF SOLOMON,3,5,23,ISAIAH,20,6,24,JEREMIAH,20,7,25,LAMENTATIONS,3,8
1010 DATA 26,EZEKIEL,30,7,27,DANIEL,20,9,28,HOSEA,20,10,29,JOEL,30,8,30,AMOS,30,11,31,OBADIAH,20,11,32,JONAH,30,9,33,MICAH,20,12,34,NAHUM,30,10,35,HABAKKUK,20,5
1020 DATA 36,ZEPHANIAH,30,5,37,HAGGAI,30,12,38,ZECHARIAH,3,9,39,MALACHI,20,13,-1,DOUG TRUSTY,40,24
1030 FOR N = 1 TO 5
1040 OFF = 79
1050 H = 6.283181/ INT( RND(1) *22 +5)
1060 MAG = 79
1070 LOC = 0
1080 HOME
1090 HGR2
1100 HCOLOR= INT( RND(1) *3 +1)
1110 FOR ANGLE = 0 TO 6.283181 STEP H
1120 LOC = LOC +1
1130 X(LOC) = MAG * SIN(ANGLE)
1140 Y(LOC) = MAG * COS(ANGLE)
1150 NEXT ANGLE
1160 FOR STPT = 1 TO (LOC -1)
1170 FOR ENPT = STPT +1 TO LOC
1180 HPLOT X(STPT) +130,Y(STPT) +OFF TO X(ENPT) +130,Y(ENPT) +OFF
1190 NEXT : PRINT "": NEXT
1200 FOR D = 1 TO 1000: NEXT D
1210 NEXT N
1220 GOTO 660
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/PEACE MAKER.bas:

10 HIMEM: 16384
20 GOSUB 160: REM INSTALL MACHINE LANGUAGE PROGRAM
30 REM (DRAW HIRES PICTURE)
40 TEXT : HOME : HGR : HCOLOR= 3: FOR Y = 39 TO 55: FOR X = 56 TO 74: HPLOT X,Y: NEXT X: FOR X1 = 93 TO 125: HPLOT X1,Y: NEXT X1: FOR X2 = 132 TO 148: HPLOT X2,Y: NEXT X2: FOR X3 = 169 TO 182
50 HPLOT X3,Y: NEXT X3: FOR X4 = 207 TO 230: HPLOT X4,Y: NEXT X4: NEXT Y: FOR Y = 63 TO 71: FOR X = 65 TO 82: HPLOT X,Y: NEXT X: FOR X1 = 100 TO 122: HPLOT X1,Y: NEXT X1: FOR X2 = 132 TO 148: HPLOT X2,Y: NEXT X2
60 FOR X3 = 169 TO 188: HPLOT X3,Y: NEXT X3: FOR X4 = 213 TO 230: HPLOT X4,Y: NEXT X4: NEXT Y: FOR Y = 47 TO 55: FOR X = 182 TO 194: HPLOT X,Y: NEXT X: NEXT Y: FOR Y = 55 TO 63: FOR X = 118 TO 125: HPLOT X,Y: NEXT X
70 FOR X1 = 169 TO 194: HPLOT X1,Y: NEXT X1: NEXT Y: FOR Y = 71 TO 79: FOR X = 65 TO 86: HPLOT X,Y: NEXT X: FOR X1 = 132 TO 148: HPLOT X1,Y: NEXT X1: FOR X2 = 118 TO 122: HPLOT X2,Y: NEXT X2: NEXT Y: FOR Y = 32 TO 79
80 FOR X = 83 TO 86: HPLOT X,Y: NEXT X: FOR X1 = 118 TO 120: HPLOT X1,Y: NEXT X1: FOR X2 = 157 TO 160: HPLOT X2,Y: NEXT X2: FOR X3 = 195 TO 198: HPLOT X3,Y
90 NEXT X3: NEXT Y: GET A$: HPLOT 49,32 TO 49,79 TO 230,79 TO 230,32 TO 49,32: FOR D = 1 TO 2000: NEXT
100 REM (CALL TO INVERSE THE HIRES SCREEN PICTURE)
110 CALL 768
120 REM (EXIT ROUTINE)
130 VTAB 22: INPUT "HIT RETURN KEY TO END";A$: PRINT : PRINT CHR$(4)"RUN GRAPE MENU"
140 REM (INSTALL MACHINE LANGUAGE CODE)
150 POKE 230,32: REM 230,32 FOR HIRES PAGE 1 AND 230,64 FOR PAGE 2
160 AD = 768:K = AD: FOR I = 0 TO 28: READ J: POKE I +K,J: NEXT I: RETURN
170 REM (MACHINE LANGUAGE CODE)
180 DATA 169,0,133,235,168,165, 230,133,236,24,105,32, 170,177,235,73,127, 145,235,200,208,247, 230,236,228,236,208, 241,96
200 REM BY DOUG TRUSTY
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/QUOTATIONS.txt:

40,WHICH BIBLICAL CHARACTER SAID THIS- (IF MANY SAID IT; TYPE 'ALL')
THE WAGES OF SIN IS DEATH; BUT THE GIFT OF GOD IS ETERNAL LIFE THROUGH CHRIST,PAUL,ROMANS 6*23
STAND STILL AND SEE THE SALVATION OF THELORD,MOSES,EXODUS 14*13
FOR WHOSOEVER SHALL CALL UPON THE NAME OF THE LORD SHALL BE SAVED,PAUL,ROMANS 10*13
FOR WHERE THOU GOEST I WILL GO.... AND THY GOD; MY GOD,RUTH,RUTH 1*16
PUT FORTH THINE HAND NOW; AND TOUCH ALL THAT HE HATH; AND HE WILL CURSE THEE,SATAN,JOB 1*11
FOR THE PREACHING OF THE CROSS IS TO THEM THAT PERISH FOOLISHNESS,PAUL,I CORINTHIANS 1*18
THE FEAR OF THE LORD IS THE BEGINNING OFKNOWLEDGE,SOLOMON,PROVERBS 1*7
GOD SAVE THE KING,ALL,I SAMUEL 10*24 ALL ISRAEL SAID THIS
TRUST IN THE LORD WITH ALL THINE HEART; LEAN NOT UNTO THINE OWN UNDERSTANDING,SOLOMON,PROVERBS 3*5
WHAT; THEREFORE; GOD HATH JOINED TO- GETHER; LET NOT MAN PUT ASUNDER,JESUS,MARK 10*9
LET THERE BE LIGHT,GOD,GENESIS 1*3
YE SHALL NOT SURELY DIE,SATAN,GENESIS 3*4
THE LORD GOD OF ISRAEL GAVE THE KINGDOM OVER ISRAEL TO DAVID FOREVER,ABIJAH,II CHRON. 13*4-5
CRUCIFY HIM; CRUCIFY HIM,ALL,LUKE 23*21
TODAY THOU SHALT BE WITH ME IN PARADISE,JESUS,LUKE 23*43
I WAS IN THE SPIRIT ON THE LORD'S DAY,JOHN,REVELATION 1*10
WE BELIEVE THAT THROUGH THE GRACE OF THELORD JESUS CHRIST WE SHALL BE SAVED,PETER,ACTS 15*7-11
ALMOST THOU PERSUADEST ME TO BE A CHRISTIAN,KING AGRIPPA,ACTS 26*28 VERY SAD; ARE YOU 'ALMOST'?
WHERE IS THE PROMISE OF HIS COMING,SCOFFERS,II PETER 3*3-4
JESUS; WHO IS TAKEN UP FROM YOU INTO HEAVEN; SHALL SO COME IN LIKE MANNER,ANGEL,ACTS 1*11
I SEE THE HEAVENS OPENED; AND THE SON OFGOD STANDING ON THE RIGHT HAND OF GOD,STEPHEN,ACTS 7*56
GOD HATH MADE ME LAUGH; SO THAT ALL THATHEAR WILL LAUGH WITH ME,SARAH,GENESIS 21*6
GOD WILL PROVIDE HIMSELF A LAMB FOR A BURNT OFFERING,ABRAHAM,GENESIS 22*8
AM I MY BROTHER'S KEEPER,CAIN,GENESIS 4*9
FOR WHERE YOUR TREASURE IS; THERE WILL YOUR HEART BE ALSO,JESUS,MATTHEW 6*21
I SAW IN THE WAY A LIGHT FROM HEAVEN ABOUT THE BRIGHTNESS OF THE SUN,PAUL,ACTS 26*13
I AM VERILY A MAN WHO IS A JEW; BORN IN TARSUS; A CITY IN CILICIA,PAUL,ACTS 22*3
JESUS I KNOW; AND PAUL I KNOW; BUT WHO ARE YOU,EVIL SPIRIT,ACTS 19*15
LOVE YOUR ENEMIES; BLESS THEM THAT CURSEYOU; DO GOOD TO THEM THAT HATE YOU,JESUS,MATTHEW 5*44
SEEK YE FIRST THE KINGDOM OF GOD,JESUS,MATHEW 6*33
BEWARE OF FALSE PROPHETS WHO COME TO YOUIN SHEEP'S CLOTHING,JESUS,MATTHEW 7*15
WE SPEAK THAT WHICH WE DO KNOW; AND TESTIFY TO THAT WHICH WE HAVE SEEN,JESUS,JOHN 3*11
BEFORE ABRAHAM WAS; I AM,JESUS,JOHN 8*58
I KNOW THAT HE SHALL RISE AGAIN IN THE RESURRECTION AT THE LAST DAY,MARTHA,JOHN 11*24
WHOSOEVER LIVETH AND BELIEVETH IN ME SHALL NEVER DIE. BELIEVEST THOU THIS,JESUS,JOHN 11*26
THOU ART THE CHRIST; THE SON OF THE LIVING GOD,PETER,MATTHEW 16*16
I GO IN UNTO THE KING; ..... AND IF I PERISH; I PERISH,ESTHER,ESTHER 4*16
TAKE ME UP; AND CAST ME FORTH INTO THE SEA,JONAH,JONAH 1*12
THE DAY I BID YOU SHOUT; THEN SHALL YE SHOUT,JOSHUA,JOSHUA 6*10
I FLEE FROM THE FACE OF MY MISTRESS; SARAI,HAGAR,GENESIS 16*8

Text found in Volume_196_Religious_Programs.dsk/ROCK OF AGES.DRILL.txt:

DEL100,990

100 DATA "HE IS THE ROCK, HIS WORKS ARE PERFECT, AND ALL HIS WAYS ARE JUST. A FAITHFUL GOD..., UPRIGHT AND JUST IS HE.","DEUTERONOMY 32:4"
110 DATA "THESE ARE THE COMMANDMENTS THE LORD PROCLAIMED.... HE WROTE THEM ON TWO STONE TABLETS.","DEUTERONOMY 5:22"
120 DATA "THESE STONES ARE TO BE A MEMORIAL TO THEPEOPLE OF ISRAEL FOREVER.","JOSHUA 4:7"
130 DATA "THERE IS NO ONE HOLY LIKE THE LORD; THERE IS NO ONE BESIDES YOU; THERE IS NO ROCK LIKE OUR GOD.","I SAMUEL 2:2"
140 DATA "THEN SAMUEL TOOK A STONE.... HE NAMED ITEBENEZER, SAYING, 'THUS FAR HAS THE LORDHELPED US.'","I SAMUEL 7:12"
150 DATA "THE LORD IS MY ROCK, MY FORTRESS AND MY DELIVERER; MY GOD IS MY ROCK, IN WHOM I TAKE REFUGE....","PSALM 18:2"
160 DATA "COME, LET US SING FOR JOY TO THE LORD; LET US SHOUT TO THE ROCK OF OUR SALVA- TION.","PSALM 95:1"
170 DATA "...HE WILL HIDE ME IN THE SHELTER OF HISTABERNACLE AND SET ME HIGH UPON A ROCK.","PSALM 27:5"
180 DATA "I WILL REMOVE FROM YOU YOUR HEART OF STONE AND GIVE YOU A HEART OF FLESH. AND I WILL PUT MY SPIRIT IN YOU....","EZEKIEL 36:26-27"
190 DATA "'WHICH OF YOU, IF HIS SON ASKS FOR BREAD, WILL GIVE HIM A STONE?'","MATTHEW 7:9"
200 DATA "THE STONE THE BUILDERS REJECTED HAS BECOME THE CAPSTONE.","PSALM 118:22"
210 DATA "'I TELL YOU,' HE REPLIED, 'IF THEY KEEP QUIET, THE STONES WILL CRY OUT.'","LUKE 19:40"
220 DATA "'IF ANY ONE OF YOU IS WITHOUT SIN, LET HIM BE THE FIRST TO THROW A STONE AT HER.'","JOHN 8:7"
230 DATA "THEY DRANK FROM THE SPIRITUAL ROCK THAT ACCOMPANIED THEM, AND THAT ROCK WAS CHRIST.","I CORINTHIANS 10:4"
240 DATA "YOU ALSO, LIKE LIVING STONES, ARE BEING BUILT INTO A SPIRITUAL HOUSE TO BE A HOLY PRIESTHOOD....","I PETER 2:5"
250 DATA "'I TELL YOU THAT YOU ARE PETER, AND ON THIS ROCK I WILL BUILD MY CHURCH....'","MATTHEW 16:18"
260 DATA "'WHEN MY GLORY PASSES BY, I WILL PUT YOUIN A CLEFT IN THE ROCK AND COVER YOU WITH MY HAND UNTIL I HAVE PASSED BY.'","EXODUS 33:22"
990 DATA *,"THESE VERSES SPEAK OF ROCKS OR STONES. IDENTIFY THE SOURCE. (NIV)"

RUN100

Text found in Volume_196_Religious_Programs.dsk/SALVATION.txt:

10,A BIBLE STUDY ON SALVATION
WHO SAID 'STAND STILL AND SEE THE SALVATION OF THE LORD',MOSES,EXODUS 14*13
WHAT PSALM SAYS; 'BLESSED BE MY ROCK; LET THE GOD OF MY SALVATION BE EXALTED',18,PSALM 18*46
WHO WROTE; 'ALL THE ENDS OF THE EARTH SHALL SEE THE SALVATION OF OUR GOD',ISAIAH,ISAIAH 52*10
WHO IS THE HORN OF OUR SALVATION,JESUS,LUKE 1*69-71
YES OR NO - WILL ALL FLESH SEE THE SALVATION OF GOD,YES,LUKE 3*6
IN EPHESIANS 6 PAUL LIKENED SALVATION UNTO WHAT PIECE OF ARMOUR,HELMET,EPHESIANS 6*17
TRUE OR FALSE - THOSE WHO HAVE CHRIST'S SALVATION MAY SEE THE WRATH OF GOD,FALSE,I THESSALONIANS 5*9
YES OR NO - IF WE WORK EXTREMELY HARD FOR GOD WE WILL EARN OUR SALVATION,NO,JOHN 4*10 AND ROMANS 6*23
YES OR NO - WE WILL NOT HAVE GOD'S SALVATION UNTIL WE DIE,NO,LUKE 7*50; JOHN 3*36; 5*24; 6*47
CHRIST'S GOSPEL IS NOT FOR THE JEWS TRUE OR FALSE,FALSE,ROMANS 1*16

Text found in Volume_196_Religious_Programs.dsk/SCRAMBLED VERSES.bas:

10 HOME : TEXT : HOME : PRINT SPC( 10)"* SCRAMBLED VERSES *"
15 PRINT
20 PRINT SPC( 10)"BY STEPHEN M. LAWSON"
30 VTAB 12: PRINT "WHEN THE PROGRAM BEGINS YOU MAY EXIT BY PRESSING ANY KEY."
40 VTAB 22: HTAB 8: PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : PRINT " TO CONTINUE ";
50 GET A$
100 DIM X(40),Y(40)
110 V = 12: REM "DISPLAY LINE
120 FOR K = 1 TO 10: READ A$
130 L = LEN(A$): FOR I = 1 TO L:Y(I) = INT( RND(1) *23 +1):Y(I) = Y(I) +(Y(I) = V) *(1 -2 *(V = 23)):X(I) = INT( RND(1) *40 +1): NEXT : HOME
140 C = 0: FOR J = 1 TO L: IF (Y(J) = V AND X(J) = J) OR ASC( MID$ (A$,J)) = 32 THEN C = C +1: GOTO 160
150 VTAB Y(J): HTAB X(J): PRINT " ";:X(J) = X(J) -(X(J) >J) +(X(J) ABS(X(J) -J) THEN Y(J) = Y(J) -(Y(J) >V) +(Y(J) 127 THEN 500
160 VTAB Y(J): HTAB X(J): PRINT MID$ (A$,J,1);: NEXT : ON C BY STEPHEN LAWSON
63999 REM "DISTRIBUTED BY THE G R A P E PRESS P.O. BOX 576 KEYPORT WA 98345

Text found in Volume_196_Religious_Programs.dsk/STUDY PROGRAM.bas:

1 REM STUDY PROGRAM
10 D$ = CHR$(4)
20 DIM Q$(101),A$(101),R$(101),S$(40),Q(101)
30 R = 0: GOSUB 10000: GOTO 1000
50 PRINT D$;"OPEN SUBJECT FILE,L16": RETURN
52 PRINT D$;"READ SUBJECT FILE,R";R: RETURN
56 PRINT D$;"CLOSE SUBJECT FILE": RETURN
60 PRINT D$;"OPEN ";S$(L);",L110": RETURN
62 PRINT D$;"READ ";S$(L);",R";R: RETURN
66 PRINT D$;"CLOSE ";S$(L): RETURN
70 REM KEEP SCORE
72 HOME : PRINT
74 PRINT " ASKED: ";N;" RIGHT: ";C;" WRONG: ";W
76 GOSUB 9000: RETURN
80 REM LAST QUESTION
82 VTAB 20: PRINT " "
84 PRINT "LAST ANSWER: ";LA$
86 IF LR$ < >"?" THEN PRINT LR$
88 LA$ = A$:LR$ = R$: RETURN
100 REM MAIN PROGRAM
110 TEXT : HOME
120 PRINT " SUBJECT: ";
130 INVERSE : PRINT S$(L);: NORMAL : HTAB 27: PRINT NQ;" QUESTIONS"
140 FLASH : PRINT E$
150 FOR D = 1 TO 1200: NEXT D
160 NORMAL
170 VTAB 2: PRINT E$
180 GOSUB 9000: POKE 34,5
190 HOME
200 FOR J = NQ TO 1 STEP -1
210 R = INT( RND(1) *J +1)
220 Q$ = Q$(Q(R)):A$ = A$(Q(R)):R$ = R$(Q(R))
230 FOR D = 1 TO LEN(Q$)
232 IF MID$ (Q$,D,1) = "*" THEN Q$ = LEFT$(Q$,D -1) +":" + MID$ (Q$,D +1, LEN(Q$))
234 IF MID$ (Q$,D,1) = ";" THEN Q$ = LEFT$(Q$,D -1) +"," + MID$ (Q$,D +1, LEN(Q$))
236 NEXT D
238 FOR D = 1 TO LEN(R$)
240 IF MID$ (R$,D,1) = "*" THEN R$ = LEFT$(R$,D -1) +":" + MID$ (R$,D +1, LEN(R$))
242 IF MID$ (R$,D,1) = ";" THEN R$ = LEFT$(R$,D -1) +"," + MID$ (R$,D +1, LEN(R$))
244 NEXT D:K = 0
246 FOR D = 1 TO LEN(A$)
248 IF ASC( MID$ (A$,D,1)) = 32 THEN K = K +1:W2 = D +1
250 NEXT D
254 Q(R) = Q(J)
256 VTAB 10:
260 IF N >0 THEN GOSUB 70: GOSUB 80
270 IF NOT N THEN GOSUB 88
280 N = N +1:T = 1
300 VTAB 10: PRINT " THIS IS QUESTION #";N
310 PRINT "----------------------------------------"
320 PRINT Q$ +"?": IF K THEN PRINT " (ANS. HAS ";K +1;" WORDS)"
322 PRINT
330 PRINT "ANSWER, PLEASE...";: INPUT Z$
340 IF Z$ = "" THEN 800
350 IF Z$ = "STOP" OR Z$ = "QUIT" OR Z$ = "END" THEN N = N -1: GOTO 2000
360 IF Z$ = A$ THEN 900
362 IF Z$ = "T" AND A$ = "TRUE" THEN 900
364 IF Z$ = "F" AND A$ = "FALSE" THEN 900
366 IF Z$ = "Y" AND A$ = "YES" THEN 900
368 IF Z$ = "N" AND A$ = "NO" THEN 900
380 IF A$ = "JESUS" AND Z$ = "CHRIST" THEN 900
382 IF A$ = "SATAN" AND Z$ = "DEVIL" OR A$ = "SATAN" AND Z$ = "LUCIFER" THEN 900
384 IF Z$ = "HOLY GHOST" AND A$ = "HOLY SPIRIT" THEN 900
400 REM CHECK SPELLING
402 IF LEN(A$) <4 THEN 800
404 IF LEFT$(Z$,1) < > LEFT$(A$,1) THEN 800
406 IF LEN(Z$) > LEN(A$) +3 OR LEN(Z$) < LEN(A$) -3 THEN 800
414 IF K THEN 600
416 IF LEN(A$) >8 THEN 550
418 IF LEN(A$) >5 THEN 500
420 REM LEN A$ IS 4 OR 5
430 IF LEFT$(Z$,2) = LEFT$(A$,2) AND RIGHT$(Z$,1) = RIGHT$(A$,1) THEN 3000
440 IF T = 2 THEN 800
450 IF RIGHT$(Z$,2) = RIGHT$(A$,2) THEN 4000
460 IF MID$ (Z$,2,2) = MID$ (A$,2,2) THEN 4000
490 GOTO 800
500 REM LEN A$ 6 OR 7
510 IF LEFT$(Z$,3) = LEFT$(A$,3) AND RIGHT$(Z$,2) = RIGHT$(A$,2) THEN 3000
520 IF T = 2 THEN 800
530 IF MID$ (Z$,3,3) = MID$ (A$,3,3) THEN 4000
540 GOTO 800
550 REM A$ MORE THAN 8
560 IF MID$ (Z$,3,3) = MID$ (A$,3,3) AND RIGHT$(Z$,3) = RIGHT$(A$,3) THEN 3000
570 IF T = 2 THEN 800
580 IF MID$ (Z$,3,2) = MID$ (A$,3,2) AND RIGHT$(Z$,1) = RIGHT$(A$,1) THEN 4000
590 IF NOT W2 THEN 800
600 REM TWO OF MORE WORDS
610 IF LEFT$(Z$,2) = LEFT$(A$,2) AND MID$ (Z$,W2,2) = MID$ (A$,W2,2) AND RIGHT$(Z$,1) = RIGHT$(A$,1) THEN 3000
640 IF T = 2 THEN 800
650 IF MID$ (Z$,W2,1) = MID$ (A$,W2,1) AND RIGHT$(Z$,1) = RIGHT$(A$,1) THEN 4000
690 GOTO 800
700 NEXT J
710 GOSUB 70: GOSUB 80
720 VTAB 10: PRINT "THAT IS THE FINAL QUESTION."
730 PRINT
740 PRINT "PLEASE HIT ANY KEY...";: GET A$: PRINT
750 GOTO 2000
800 REM WRONG ANSWER
810 W = W +1
830 PRINT
840 PRINT "SORRY! THE ANSWER WAS:";
842 PRINT A$
850 FOR D = 1 TO 20
852 S = PEEK( -16336)
854 NEXT D
860 FOR D = 1 TO 1000: NEXT D
890 GOTO 700
900 REM RIGHT ANSWER
910 C = C +1
920 PRINT "CORRECT!"
930 PRINT ""
940 FOR D = 1 TO 600: NEXT D
990 GOTO 700
1000 REM SHOW SUBJECTS
1010 TEXT : HOME
1020 PRINT " SUBJECTS AVAILABLE FOR QUIZ ARE:
1030 PRINT "NO. NAME"
1040 PRINT "--- ----"
1044 POKE 34,3
1050 FOR L = 1 TO NS
1060 PRINT L;: HTAB 13: PRINT S$(L)
1070 IF PEEK(37) >19 THEN GOSUB 8000: HOME
1080 NEXT L
1090 VTAB 23
1100 PRINT "TYPE IN YOUR CHOICE (BY NUMBER) ";: INPUT L$:L = VAL(L$)
1110 IF L = 0 THEN 2000
1120 IF L >NS THEN 1090
1124 TEXT : HOME : VTAB 10
1130 INVERSE : PRINT "NOW LOADING ";S$(L);" FILE": NORMAL
1140 R = 0: GOSUB 60: GOSUB 62
1150 INPUT NQ,E$
1160 IF NQ = 0 THEN PRINT "NO QUESTIONS ON THIS SUBJECT": TEXT : END
1170 PRINT "WAIT OF ABOUT "; INT(NQ/3 +3);" SECONDS."
1200 FOR R = 1 TO NQ
1210 GOSUB 62: INPUT Q$(R),A$(R),R$(R)
1220 NEXT R
1230 GOSUB 66: PRINT
1236 HTAB 1: PRINT "SORTING QUESTIONS"
1240 N = 0:C = 0:W = 0
1250 FOR I = 1 TO NQ
1252 Q(I) = I
1254 NEXT I
1260 F = FRE(0)
1270 GOTO 100
2000 REM TOTAL UP ANSWER
2010 HOME : IF N = 0 THEN 2300
2020 PRINT : PRINT "THERE WERE A TOTAL OF ";N;" QUESTIONS."
2030 GOSUB 9000
2040 PRINT "YOU GOT ";C;" CORRECT AND ";W;" WRONG!"
2050 PRINT
2060 TS = INT(100/N *C +.5)
2070 PRINT "YOUR FINAL SCORE IS: ";TS;"%"
2080 GOSUB 9000
2090 IF N >1 AND TS = 100 THEN PRINT "PERFECT!"
2100 IF N = 1 AND TS = 100 THEN PRINT "PERFECT, BUT WITH ONLY ONE QUESTION IT'SEASY."
2120 IF TS <100 AND TS >94 THEN PRINT "EXCELLENT!"
2130 IF TS <95 AND TS >89 THEN PRINT "VERY GOOD."
2140 IF TS <90 AND TS >84 THEN PRINT "GOOD."
2150 IF TS <85 AND TS >74 THEN PRINT "AVERAGE."
2160 IF TS <75 AND TS >64 THEN PRINT "NOT TOO GOOD."
2170 IF TS <65 AND TS >49 THEN PRINT "NOT GOOD, TRY AGAIN."
2180 IF TS <50 AND TS >39 THEN PRINT "REVIEW AND TRY AGAIN!"
2190 IF TS <40 THEN PRINT "STUDY IS IN ORDER!!"
2200 GOSUB 9000
2300 PRINT "ANOTHER SUBJECT (Y/N)? ";: GET A$: PRINT
2310 IF A$ = "Y" THEN 1000
2320 PRINT
2330 PRINT "ANOTHER TRY AT THIS SUBJECT (Y/N)?";: GET A$: PRINT
2340 IF A$ = "Y" THEN 1236
2990 TEXT : HOME : PRINT CHR$(4): PRINT CHR$(4);"RUN GRAPE MENU": REM ADDED BY DOUG TRUEMAN 3/10/87
3000 REM ANS OK, SPELLING MISTAKE
3006 KA = 0:KZ = 0
3010 FOR D = 1 TO LEN(A$)
3020 K = ASC( MID$ (A$,D,1))
3030 KA = KA +K
3040 NEXT D
3050 K = 0
3060 FOR D = 1 TO LEN(Z$)
3070 K = ASC( MID$ (Z$,D,1))
3080 KZ = KZ +K
3090 NEXT D
3100 K = 0
3200 HOME
3210 PRINT
3220 PRINT "IT LOOKS LIKE YOU KNOW THE ANSWER BUT YOU JUST SPELLED IT WRONG."
3230 PRINT
3240 PRINT " THE ANSWER IS: ";A$
3242 PRINT "YOUR ANSWER WAS: ";Z$
3250 PRINT
3260 IF KA = KZ THEN PRINT "YOU JUST GOT THE LETTERS MIXED UP."
3700 GOSUB 9000
3800 PRINT "I'LL GIVE YOU FULL CREDIT FOR THIS QUESTION."
3810 GOSUB 8000
3820 C = C +1
3830 GOTO 700
4000 REM GIVE ANOTHER CHANCE
4010 T = T +1
4014 VTAB 6: PRINT "YOUR ANSWER WAS: ";Z$
4020 VTAB 7: PRINT "SPELLING MISTAKE? I THINK YOU KNOW IT!"
4030 VTAB 8: PRINT "HINT - THE ANSWER HAS "; LEN(A$) -K;" LETTERS"
4040 PRINT "TRY AGAIN-"
4050 GOTO 300
8000 VTAB 23: HTAB 1: PRINT "PRESS ANY KEY TO CONTINUE...";: GET A$: PRINT : RETURN
9000 PRINT : PRINT "?***??****?****?****?****?****?***??***?": RETURN
10000 TEXT : HOME
10010 PRINT " * QUIZ PROGRAM *"
10020 GOSUB 9000
10030 PRINT "THIS PROGRAM WILL TEST YOUR KNOWLEDGE OFVARIOUS SUBJECTS."
10040 PRINT
10050 PRINT "IF A QUESTION HAS MORE THAN ONE WORD YOUWILL BE ADVISED OF HOW MANY WORDS ARE INTHE ANSWER."
10060 GOSUB 9000
10070 PRINT "YOU MAY END THE QUIZ BY TYPING 'STOP'.
10080 GOSUB 9000
10090 PRINT "ONE MOMENT WHILE I CHECK WHAT SUBJECTS ARE AVAILABLE FOR THE QUIZ."
10094 ONERR GOTO 10120
10100 GOSUB 50: GOSUB 52
10110 INPUT NS
10120 IF NS = 0 THEN PRINT "NO SUBJECTS ON THIS DISK!": VTAB 23: END
10130 FOR R = 1 TO NS
10140 GOSUB 52: INPUT S$(R)
10150 NEXT R
10160 GOSUB 56: PRINT
10170 POKE 216,0: PRINT D$
10180 GOSUB 8000
10190 RETURN
12000 REM PROGRAM BY ART UDE
12002 REM (603) 446-2234
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/STUDY QUESTION.U.bas:

1 REM QUESTION MAKER
2 REM * MODIFIED BY DOUG TRUEMAN
3 REM *** 3/10/87
5 SLOT = 1: REM PRINTER
10 D$ = CHR$(4):I$ = CHR$(9)
20 DIM Q$(101),A$(101),R$(101),S$(40)
30 R = 0: GOSUB 11000: GOTO 100
40 FLAG = 0
41 IF Z$ = "S" THEN FLAG = 1
42 IF Z$ = "L" THEN FLAG = 2
43 IF Z$ = "A" THEN FLAG = 3
44 IF Z$ = "C" THEN FLAG = 4
45 IF Z$ = "D" THEN FLAG = 5
46 IF Z$ = "M" THEN FLAG = 6
47 IF Z$ = "E" THEN TEXT : HOME : PRINT CHR$(4): PRINT CHR$(4);"RUN GRAPE MENU"
49 RETURN
50 PRINT D$;"OPEN SUBJECT FILE,L16": RETURN
52 PRINT D$;"READ SUBJECT FILE,R";R: RETURN
54 PRINT D$;"WRITE SUBJECT FILE,R";R: RETURN
56 PRINT D$;"CLOSE SUBJECT FILE": RETURN
60 PRINT D$;"OPEN ";S$(L);",L110": RETURN
62 PRINT D$;"READ ";S$(L);",R";R: RETURN
64 PRINT D$;"WRITE ";S$(L);",R";R: RETURN
66 PRINT D$;"CLOSE ";S$(L): RETURN
100 TEXT : HOME
110 PRINT " * QUESTION MAKER PROGRAM *"
120 GOSUB 9000
130 PRINT "THIS PROGRAM WILL ALLOW YOU TO ADD, DELETE, AND CHANGE QUESTIONS THAT ARE"
132 PRINT "TO BE USED IN THE STUDY PROGRAMS."
140 GOSUB 9000
150 PRINT "DO YOU NEED INSTRUCTIONS? (Y/N) ";: GET Z$: PRINT
160 IF Z$ = "Y" THEN GOSUB 10000
200 TEXT : HOME : REM MENU
210 PRINT " * MENU *": GOSUB 9000
220 PRINT " THE FOLLOWING OPTIONS ARE AVAILABLE WHEN YOU ARE ASKED FOR A SUBJECT:"
222 GOSUB 9000
230 PRINT "S-LIST SUBJECTS L-LIST QUESTIONS"
234 PRINT "A-ADD QUESTIONS C-CHANGE QUESTIONS"
240 PRINT "D-DELETE QUESTION E-END PROGRAM"
248 GOSUB 9000: POKE 34,15
250 HOME
260 VTAB 23: CALL -868: INPUT "TYPE IN SUBJECT..";Z$
270 GOSUB 40
280 IF FLAG THEN ON FLAG GOTO 1000,2000,3000,4000,5000,200
290 IF LEN(Z$) <2 THEN 260
300 IF LEN(Z$) >15 THEN VTAB 22: PRINT "15 CHARACTERS ONLY!": GOTO 260
310 LS = 0
330 IF NS = 0 THEN 400
340 FOR L = 1 TO NS
350 IF Z$ = S$(L) THEN 500
360 NEXT L
370 S$(L) = Z$: GOTO 600
400 REM FIRST SUBJECT
410 NS = 1:R = 0: GOSUB 50: GOSUB 54: PRINT NS
420 R = NS: GOSUB 54: PRINT Z$
430 GOSUB 56
440 R = 0:L = 1:S$(L) = Z$: GOSUB 60
450 GOSUB 64: PRINT R
460 GOSUB 66
480 GOTO 600
500 REM OLD SUBJECT
504 TEXT : HOME : GOSUB 9000
510 PRINT S$(L);" IS ON FILE.": GOSUB 9000
520 R = 0:B = 0: GOSUB 60: GOSUB 62: INPUT NQ,E$: GOSUB 66
522 PRINT "THERE ARE ";NQ;" QUESTIONS RECORDED."
524 IF NQ = 100 THEN 530
526 VTAB 10: PRINT "DO YOU WISH TO ADD QUESTIONS (Y/N)? ";: GET A$: PRINT
528 IF A$ = "Y" THEN 3000
530 VTAB 10: CALL -868: PRINT "DO YOU WISH TO DELETE SUBJECT (Y/N)? ";: GET A$: PRINT
532 IF A$ < >"Y" THEN 560
534 PRINT : PRINT "ARE YOU SURE YOU WANT TO": FLASH : PRINT "DELETE";: NORMAL : PRINT " THIS SUBJECT (Y/N)?";: GET A$: PRINT
536 IF A$ < >"Y" THEN 560
538 GOSUB 50: GOSUB 54: PRINT (NS -1)
540 R = L: GOSUB 54: PRINT S$(NS)
542 GOSUB 56
544 PRINT D$;"DELETE ";S$(L)
546 S$(L) = S$(NS):NS = NS -1
556 S = 0:L = 0:: GOTO 1000
560 VTAB 10: CALL -958: PRINT "DO YOU WISH TO CHANGE SUBJECT NAME? ";: GET A$: PRINT
562 IF A$ < >"Y" THEN 580
564 HOME
566 VTAB 14: INPUT "TYPE IN NEW NAME.. ";Z$
570 IF LEN(Z$) <2 OR LEN(Z$) >15 THEN PRINT "15 CHARACTERS MAX.": GOTO 566
572 PRINT D$;"RENAME ";S$(L);",";Z$
574 S$(L) = Z$
576 R = L: GOSUB 50: GOSUB 54
578 PRINT S$(L): GOSUB 56: PRINT : GOTO 200
580 VTAB 10: CALL -958: PRINT "DO YOU WISH TO CHANGE THE SPECIAL INITIAL STATEMENT (Y/N)? ";: GET A$: PRINT
582 IF A$ < >"Y" THEN 200
584 GOSUB 9000
590 GOTO 660
598 GOTO 200
600 REM NEW SUBJECT
610 HOME : GOSUB 9000
620 PRINT S$(L);" IS A NEW SUBJECT.": GOSUB 9000
622 PRINT : PRINT "NOW DEVELOPING NEW FILE": GOSUB 9000
630 R = 0:NS = NS +1
634 GOSUB 50: GOSUB 54: PRINT NS
640 R = NS: GOSUB 54: PRINT S$(L)
650 GOSUB 56:NQ = 0
660 PRINT " - ENTER AN EXPLANATION OR SPECIAL"
670 PRINT "INSTRUCTION OR SOME OTHER COMMENT THAT"
680 PRINT "MAY BE HELPFUL TO THE USER OF THIS"
690 PRINT "STUDY SUBJECT.": GOSUB 9000
700 VTAB 20: HTAB 40: CALL -958: INPUT E$
710 IF E$ = "" THEN E$ = "?"
720 IF LEN(E$) >80 THEN PRINT "80 CHARACTERS ONLY": GOTO 700
750 R = 0: GOSUB 60
760 GOSUB 64: PRINT NQ;",";E$
770 GOSUB 66
790 GOTO 200
1000 REM SHOW SUBJECTS
1010 TEXT : HOME
1020 PRINT " SUBJECTS ON THIS DISK ARE:"
1030 GOSUB 9000: POKE 34,4
1040 IF NS = 0 THEN PRINT "NO SUBJECTS RECORDED": GOSUB 8000: GOTO 200
1050 FOR D = 1 TO NS
1060 PRINT S$(D)
1070 IF PEEK(37) >19 THEN PRINT D$: GOSUB 8000: HOME : PRINT
1080 NEXT D
1090 GOTO 260
2000 REM LIST QUESTIONS
2002 IF S$(L) = "" THEN 200
2010 TEXT : HOME : GOSUB 9000
2012 IF NQ = 0 THEN PRINT "THERE ARE NO QUESTIONS FOR THIS SUBJECT": GOSUB 8000: GOTO 200
2020 PRINT "SEND LIST TO CRT OR PRINTER (C/P)?";: GET A$: PRINT
2030 IF A$ = "M" THEN 200
2032 IF ASC(A$) = 13 THEN 2360
2034 IF LS THEN 2110
2040 PRINT
2050 INVERSE : PRINT "ONE MOMENT PLEASE": NORMAL
2054 PRINT "WAIT OF ABOUT "; INT(NQ/3 +2);" SECONDS."
2060 GOSUB 60
2070 FOR R = 1 TO NQ
2080 GOSUB 62: INPUT Q$(R),A$(R),R$(R)
2090 NEXT R
2100 GOSUB 66: PRINT :LS = 1
2110 HOME
2120 IF A$ < >"P" THEN 2200
2140 PRINT D$;"PR#";SLOT
2150 PRINT I$;"40N"
2200 PRINT "LIST FOR ";S$(L): PRINT : PRINT E$
2210 GOSUB 9000: POKE 34,10
2220 FOR R = 1 TO NQ
2222 IF A$ < >"P" THEN HOME
2230 PRINT "QUESTION #";R
2232 IF A$ < >"P" THEN PRINT
2240 PRINT Q$(R);"?"
2250 PRINT "ANSWER: ";
2260 PRINT A$(R)
2270 PRINT "REFERENCE: ";
2280 PRINT R$(R)
2290 PRINT
2300 IF A$ < >"P" THEN VTAB 22: PRINT "TYPE 'M' TO TERMINATE LISTING": GOSUB 8000
2310 IF A$ = "M" THEN 2360
2340 NEXT R
2350 PRINT D$;"PR#0"
2360 ON FLAG GOTO 200,200,200,4000,5000
2371 GOTO 200
3000 REM ADD QUESTION
3002 IF S$(L) = "" THEN 200
3004 IF NQ = 100 THEN 3710
3010 TEXT : HOME
3020 PRINT " * ADD QUESTIONS MODE *": GOSUB 9000
3030 PRINT " TYPE 'M' TO RETURN TO THE MENU"
3040 PRINT "SUBJECT IS: ";
3050 INVERSE : PRINT S$(L): NORMAL
3060 PRINT E$
3070 POKE 34,11
3100 HOME
3110 VTAB 10: CALL -868: PRINT "THERE ARE NOW ";NQ;" QUESTIONS."
3114 IF NQ = 100 THEN 3720
3120 SQ = NQ +1
3130 GOSUB 6000
3200 HOME
3210 VTAB 10: CALL -868: PRINT "THERE ARE NOW ";NQ;" QUESTIONS."
3230 GOSUB 6200
3300 HOME
3310 VTAB 10: CALL -868: PRINT "THERE ARE NOW ";NQ;" QUESTIONS."
3330 GOSUB 6400
3500 HOME
3510 PRINT
3520 PRINT "QUESTION:"
3530 PRINT Q$(NQ +1);"?"
3540 PRINT
3550 PRINT "ANSWER:"
3560 PRINT A$(NQ +1)
3570 PRINT
3580 PRINT "REFERENCE:"
3590 PRINT R$(NQ +1)
3600 PRINT
3610 PRINT "IS THIS ALL CORRECT (Y/N)?";: GET A$: PRINT
3620 IF A$ < >"Y" THEN 3100
3650 GOSUB 60:R = 0:NQ = NQ +1
3660 GOSUB 64: PRINT NQ;",";E$
3670 R = NQ: GOSUB 64
3680 PRINT Q$(NQ);",";A$(NQ);",";R$(NQ)
3690 GOSUB 66: PRINT
3700 GOTO 3100
3710 HOME : PRINT
3720 PRINT ""
3730 PRINT "YOU HAVE NOW THE MAXIMUM NUMBER (100)"
3740 PRINT "OF QUESTIONS ALLOWED."
3750 GOSUB 8000: GOTO 200
4000 REM CHANGE QUESTION
4010 IF S$(L) = "" THEN 200
4100 GOSUB 7000
4110 Q$(NQ +1) = Q$(R):A$(NQ +1) = A$(R):R$(NQ +1) = R$(R)
4130 GOTO 4280
4200 GOSUB 7200
4280 PRINT "CHANGE WHICH - Q-QUESTION"
4282 PRINT " A-ANSWER"
4284 PRINT " R-REFERENCE"
4286 PRINT " N-ALL OK, NO CHANGES"
4290 VTAB 22: CALL -868: PRINT "YOUR CHOICE...";: GET A$: PRINT
4300 IF A$ = "Q" THEN 4400
4310 IF A$ = "A" THEN 4500
4320 IF A$ = "R" THEN 4600
4330 IF A$ = "N" THEN 4700
4340 GOTO 4290
4400 HOME : PRINT "TYPE IN CORRECTED QUESTION:"
4410 CH = 1: GOSUB 6000
4420 Q$(R) = Q$(NQ +1)
4430 TEXT : GOTO 4200
4500 HOME : PRINT "TYPE IN CORRECTED ANSWER:"
4510 CH = 1: GOSUB 6200
4520 A$(R) = A$(NQ +1)
4530 TEXT : GOTO 4200
4600 HOME : PRINT "TYPE IN CORRECTED REFERENCE:"
4610 CH = 1: GOSUB 6400
4620 R$(R) = R$(NQ +1)
4630 TEXT : GOTO 4200
4700 REM MAKE CHANGES
4710 IF NOT CH THEN 200
4720 GOSUB 60: GOSUB 64
4730 PRINT Q$(R);",";A$(R);",";R$(R)
4740 GOSUB 66
4750 GOTO 200
5000 REM DELETE QUESTION
5010 IF S$(L) = "" THEN 200
5020 GOSUB 7000
5100 PRINT "DO YOU WANT TO DELETE THIS QUESTION?";: GET A$: PRINT
5110 IF A$ < >"Y" THEN 200
5200 CH = R:R = NQ
5210 GOSUB 60: GOSUB 62
5220 INPUT Q$(R),A$(R),R$(R)
5230 R = CH: GOSUB 64
5240 PRINT Q$(NQ);",";A$(NQ);",";R$(NQ)
5250 R = 0:NQ = NQ -1: GOSUB 64
5260 PRINT NQ;",";E$
5270 GOSUB 66: PRINT
5275 Q$(R) = Q$(NQ +1):A$(R) = A$(NQ +1):R$(R) = R$(NQ +1)
5280 GOTO 200
6000 REM INPUT QUESTION
6010 POKE 34,11: HOME
6020 PRINT "ENTER QUESTION #";SQ
6022 GOSUB 9000: GOSUB 9000
6030 VTAB 14: HTAB 40: INPUT Q$(NQ +1)
6040 IF Q$(NQ +1) = "M" OR Q$(NQ +1) = "" THEN POP : GOTO 200
6050 IF LEN(Q$(NQ +1)) >79 THEN 6000
6060 VTAB 12: CALL -868: PRINT "QUESTION #";SQ;" IS:"
6070 VTAB 15: CALL -868: PRINT Q$(NQ +1);"?"
6080 VTAB 20: PRINT "IS THIS CORRECT (Y/N)? ";: GET A$: PRINT
6090 IF A$ = "Y" THEN RETURN
6100 VTAB 15: CALL -868: VTAB 16: CALL -868: GOTO 6000
6200 REM INPUT ANSWER
6210 POKE 34,11: HOME
6220 PRINT "ENTER ANSWER #";SQ
6222 GOSUB 9000: GOSUB 9000: GOSUB 8100
6228 VTAB 16: PRINT " (";A%;" CHARACTERS MAX)"
6230 VTAB 14: HTAB 40: INPUT A$(NQ +1)
6240 IF A$(NQ +1) = "M" OR A$(NQ +1) = "" THEN POP : GOTO 200
6250 IF LEN(A$(NQ +1)) >A% THEN 6210
6260 VTAB 12: CALL -868: PRINT " ANSWER #";SQ;" IS:"
6270 VTAB 15: CALL -868: PRINT A$(NQ +1)
6280 VTAB 20: PRINT "IS THIS CORRECT (Y/N)? ";: GET A$: PRINT
6290 IF A$ = "Y" THEN RETURN
6300 VTAB 15: CALL -868: VTAB 16: CALL -868: GOTO 6200
6400 REM INPUT REFERENCE
6410 POKE 34,11: HOME
6420 PRINT "ENTER REFERENCE #";SQ
6422 GOSUB 9000: GOSUB 9000: GOSUB 8200
6428 VTAB 16: PRINT " (";R%;" CHARACTERS MAX)"
6430 VTAB 14: HTAB 40: INPUT R$(NQ +1)
6440 IF R$(NQ +1) = "M" THEN POP : GOTO 200
6444 IF R$(NQ +1) = "" THEN R$(NQ +1) = "?"
6450 IF LEN(R$(NQ +1)) >R% THEN 6400
6460 VTAB 12: CALL -868: PRINT "REFERENCE #";SQ;" IS:"
6470 VTAB 15: CALL -868: PRINT R$(NQ +1)
6480 VTAB 20: PRINT "IS THIS CORRECT (Y/N)? ";: GET A$: PRINT
6490 IF A$ = "Y" THEN RETURN
6500 VTAB 15: CALL -868: VTAB 16: CALL -868: GOTO 6400
7000 REM CHANGE & DELETE ROUTINE
7010 TEXT : HOME : GOSUB 9000
7020 IF NQ = 0 THEN PRINT "NO QUESTIONS ON THIS SUBJECT": GOSUB 8000: POP : GOTO 200
7030 PRINT "THERE ARE ";NQ;" QUESTIONS.": GOSUB 9000
7040 PRINT : PRINT "DO YOU KNOW THE NUMBER OF THE QUESTION YOU WISH TO ";
7042 IF FLAG = 4 THEN PRINT "CHANGE";
7044 IF FLAG = 5 THEN PRINT "DELETE";
7046 PRINT " (Y/N)? ";
7048 GET A$: PRINT
7050 IF A$ < >"Y" THEN POP : GOTO 2000
7060 PRINT : INPUT "TYPE IN THE QUESTION NUMBER ";R
7070 CH = 0
7080 IF R <1 OR R >NQ THEN POP : GOTO 200
7090 IF LS THEN 7200
7100 GOSUB 60: GOSUB 62: INPUT Q$(R),A$(R),R$(R)
7110 GOSUB 66
7200 TEXT : HOME
7210 PRINT "QUESTION #";R;" IS:"
7220 SQ = R: GOSUB 9000
7230 PRINT "QUESTION:": PRINT Q$(R);"?"
7232 PRINT "ANSWER: ";A$(R)
7240 PRINT "REFERENCE: ";R$(R)
7250 GOSUB 9000: POKE 34,11
7300 RETURN
8000 VTAB 23: HTAB 1: CALL -958: PRINT "PRESS ANY KEY TO CONTINUE...";: GET A$: PRINT : RETURN
8100 A% = 110 -( LEN(Q$(NQ +1)) +11): IF A% >30 THEN A% = 30
8110 RETURN
8200 R% = 110 -( LEN(Q$(NQ +1)) + LEN(A$(NQ +1)) +3): IF R% >40 THEN R% = 40
8210 RETURN
9000 PRINT : PRINT "?***??****?****?****?****?****?***??***?": RETURN
10000 HOME : REM INSTRUCTIONS
10010 PRINT " * INSTRUCTIONS *"
10020 GOSUB 9000
10030 PRINT " THIS PROGRAM WILL GIVE YOU THE CONTROL NECESSARY TO ENTER, DELETE AND CHANGE"
10040 PRINT "QUESTIONS FOR THE STUDY PROGRAMS."
10050 PRINT "IT ALSO PROVIDES A MEANS TO CHANGE AND DELETE STUDY TOPICS OR SUBJECTS."
10055 GOSUB 9000
10060 PRINT "THE GRAPE DISK IS FULL. IF YOU DESIRE TO ADD OR CHANGE FILES YOU MUST TRANSFERTHE FOLLOWING FILES ON THIS DISK TO A BLANK DISK: STUDY PROGRAM,SUBJECT FILE"
10070 PRINT "BIBLE STUDY, QUOTATIONS, SALVATION,APPLEBASIC, AND STUDY QUESTION.U"
10090 GOSUB 9000
10100 GOSUB 8000
10110 HOME
10120 PRINT " QUESTIONS CAN BE UP TO 79 CHARACTERS INLENGTH AND A QUESTION MARK (?) DOES"
10130 PRINT "NOT NEED TO BE PLACED AT THE END OF THE QUESTION."
10140 GOSUB 9000
10150 PRINT " THE ANSWER AND REFERENCE WILL BE OF DIFFERENT LENGTH DEPENDING ON THE QUESTION."
10160 PRINT "IF YOU DO NOT WANT TO ENTER A REFERENCE JUST HIT THE 'RETURN' KEY WHEN IT CALLS"
10170 PRINT "FOR THAT INPUT."
10180 GOSUB 9000
10190 PRINT " THE ANSWER SHOULD BE ONE OR TWO WORDS ONLY (ONE IS BEST)."
10200 PRINT "IF THE ANSWER CALLS FOR A NUMBER IT MUSTBE ENTERED AS A NUMERAL (IE. 27)."
10210 GOSUB 9000: GOSUB 8000
10220 HOME
10230 PRINT " WHEN ENTERING QUESTIONS, ANSWERS OR REFERENCES DO NOT, REPEAT ";
10240 INVERSE : PRINT "NOT";: NORMAL
10250 PRINT ", USE"
10260 PRINT "THE COMMA (,) OR THE COLON (:) SYMBOLS AS THEY WILL NOT BE ACCEPTED BY THE PROGRAM."
10280 PRINT "INSTEAD USE ';' FOR A COMMA AND '*' FOR A COLON."
10290 GOSUB 9000
10300 PRINT " YOU CAN ENTER A MAXIMUM OF 100 QUESTIONS.": PRINT
10310 PRINT " WHEN STARTING A NEW SUBJECT YOU WILL BEASKED FOR A STATEMENT DESCRIBING THE QUIZ.": PRINT
10320 PRINT " YOU CAN ALWAYS RETURN TO THE MENU PAGE BY TYPING AN 'M' CHARACTER."
10330 GOSUB 9000: GOSUB 8000
10340 RETURN
11000 REM CHECK SUBJECT FILE
11010 TEXT : HOME
11020 VTAB 10: INVERSE : PRINT "ONE MOMENT PLEASE": NORMAL
11100 ONERR GOTO 11200
11130 GOSUB 50: GOSUB 52: INPUT NS
11140 IF NS = 0 THEN 11190
11150 FOR R = 1 TO NS
11160 GOSUB 52
11170 INPUT S$(R)
11180 NEXT R
11190 GOSUB 56: POKE 216,0: PRINT D$: RETURN
11200 PRINT "CREATING NEW SUBJECT FILE"
11206 PRINT D$;"DELETE SUBJECT FILE"
11210 GOSUB 50: GOSUB 54: PRINT 0
11220 GOSUB 56
11230 POKE 216,0: PRINT D$: GOTO 100
12000 REM PROGRAM BY ART UDE
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/STUDYFILE XFER.U.bas:

10 D$ = CHR$(4)
20 DIM Q$(100),A$(100),R$(100),S$(40)
30 R = 0: GOSUB 800: GOTO 100
50 PRINT D$;"OPEN SUBJECT FILE,L16": RETURN
52 PRINT D$;"READ SUBJECT FILE,R";R: RETURN
54 PRINT D$;"WRITE SUBJECT FILE,R";R: RETURN
56 PRINT D$;"CLOSE SUBJECT FILE": RETURN
60 PRINT D$;"OPEN ";S$(L);",L110": RETURN
62 PRINT D$;"READ ";S$(L);",R";R: RETURN
64 PRINT D$;"WRITE ";S$(L);",R";R: RETURN
66 PRINT D$;"CLOSE ";S$(L): RETURN
100 TEXT : HOME : REM MENU
110 PRINT " * FILE TRANSFER PROGRAM *"
120 PRINT : GOSUB 900
130 PRINT " THIS PROGRAM IS TO BE USED WITH THE STUDY AND QUESTION MAKER PROGRAMS"
140 PRINT : PRINT " IT WILL TRANSFER THE SUBJECT FILE AND"
150 PRINT "THE STUDY FILES TO ANOTHER DISK"
160 PRINT : GOSUB 900
170 VTAB 15: PRINT "WHICH DO YOU WANT:"
172 PRINT " 1 - TRANSFER SUBJECT FILE"
174 PRINT " 2 - TRANSFER STUDY FILE"
176 PRINT " 3 - END PROGRAM"
180 VTAB 20: CALL -868: PRINT "YOUR CHOICE...";: GET A$: PRINT
190 IF A$ = "1" THEN 200
192 IF A$ = "2" THEN 500
194 IF A$ = "3" THEN TEXT : HOME : PRINT
195 END
196 GOTO 180
200 REM SUBJECT FILE TRANSFER
210 TEXT : HOME
220 PRINT " * SUBJECT FILE TRANSFER *"
230 PRINT : GOSUB 900: PRINT
240 PRINT "INSERT NEW DISK -"
242 PRINT " THEN HIT ANY KEY";
250 GET A$: PRINT
260 R = 0
270 GOSUB 50: GOSUB 54
280 PRINT NS
290 FOR R = 1 TO NS
300 GOSUB 54: PRINT S$(R)
310 NEXT R
320 GOSUB 56: PRINT
330 PRINT "TRANSFER COMPLETE!"
340 PRINT "PUT ORIGINAL DISK BACK IN DRIVE"
350 PRINT "THEN HIT ANY KEY..";: GET A$: PRINT
360 GOTO 100
500 REM STUDY FILE TRANSFER
510 TEXT : HOME
520 PRINT " * STUDY QUESTIONS TRANSFER *"
530 PRINT : GOSUB 900: PRINT
532 PRINT "NO. SUBJECTS"
534 PRINT "--- --------"
540 FOR L = 1 TO NS
550 PRINT L;: HTAB 14: PRINT S$(L)
560 NEXT L
570 VTAB 23: CALL -868: PRINT "SUBJECT TO TRANSFER (BY NUMBER) ";: INPUT L
572 IF L <1 OR L >NS THEN 570
580 TEXT : HOME
590 VTAB 10: INVERSE : PRINT "ONE MOMENT PLEASE": NORMAL
600 GOSUB 60:R = 0: GOSUB 62
610 INPUT NQ,E$
620 FOR R = 1 TO NQ
630 GOSUB 62: INPUT Q$(R),A$(R),R$(R)
640 NEXT R
650 GOSUB 66: PRINT
660 PRINT "PLACE NEW DISK IN DRIVE -"
670 PRINT " THEN HIT ANY KEY";: GET A$: PRINT
680 PRINT
690 PRINT "TRANSFER IN PROGRESS"
700 R = 0: GOSUB 60: GOSUB 64
710 PRINT NQ;",";E$
720 FOR R = 1 TO NQ
730 GOSUB 64
740 PRINT Q$(R);",";A$(R);",";R$(R)
750 NEXT R
760 GOSUB 66: PRINT
770 GOTO 330
800 REM GET SUBJECTS
804 TEXT : HOME : VTAB 10
806 INVERSE : PRINT "ONE MOMENT PLEASE": NORMAL
807 ONERR GOTO 813
810 GOSUB 50: GOSUB 52
812 INPUT NS
813 POKE 216,0
814 IF NS = 0 THEN PRINT "NO SUBJECTS ON THIS DISK": END
820 FOR R = 1 TO NS
824 GOSUB 52: INPUT S$(R)
830 NEXT R
840 GOSUB 56: PRINT : RETURN
900 PRINT "****************************************": RETURN
910 REM WRITTEN BY ART UDE.
63999 REM DISTRIBUTED 1982 BY: THE G.R.A.P.E. PRESS P.O. BOX 576 KEYPORT, WA 98345

Text found in Volume_196_Religious_Programs.dsk/SUBJECT FILE.txt:

4
BIBLE STUDY
QUOTATIONS
SALVATION
APPLE BASIC