Notes

Disk info for Volume_051_Chemistry_and_Biology_Programs.dsk:

File Name: riag_005_Volume_051_-_Chemistry_and_Biology_Programs/Volume_051_Chemistry_and_Biology_Programs.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 60416
Used Space (bytes): 82944
Physical Size (KB): 140
Free Space (KB): 59
Used Space (KB): 81
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 236
Used Sectors: 324
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for Volume_051_Chemistry_and_Biology_Programs.dsk:

riag_005_Volume_051_-_Chemistry_and_Biology_Programs/Volume_051_Chemistry_and_Biology_Programs.dsk DISK VOLUME #254
A 003 AAA CHEMISTRY & BIOLOGY 060
A 005 AAA MESSAGE
A 005 BATTERY DEMO
A 010 CIRCULAR DICHROISM
I 039 D N A
A 017 ELEMENTS TABLE
A 054 ENZYME KINETICS
A 021 MOLALITY
A 022 MOLE
A 019 MOLECULES OF C H O
I 016 MOLECULES OF CARBON
B 006 MOLECULES OF CARBON.X
B 003 MOLECULES OF CARBON.Y
A 003 TEST MAKER
A 006 TEST TAKER
T 017 TEST.CHEM CH2
T 001 TEST.CHEM COMPOUNDS
T 005 TEST.CHEM NAMES
T 008 TEST.IONS
DOS 3.3 format; 60,416 bytes free; 82,944 bytes used.

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/AAA CHEMISTRY & BIOLOGY 060.bas:

100 REM AAA HELLO PUBLIC DOMAIN BY RONALD D. MALEIKA
200 REM 721 PIKE STREET CHEYENNE * WY * 82009 28 FEB 1981
300 HOME
400 VTAB 12: HTAB 3: INVERSE
500 PRINT "APPLE AVOCATION ALLIANCE (AAA), INC.": NORMAL
600 FOR P = 1 TO 1000: NEXT P
800 PRINT CHR$(4);"CATALOG"
998 END
999 REM STOP COPYRIGHT FRAUD! CLAIM A REWARD. SEE OFFER IN 3A CATALOG.

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/AAA MESSAGE.bas:

100 REM AAA MESSAGE PUBLIC DOMAIN BY RONALD D. MALEIKA
125 REM 721 PIKE STREET CHEYENNE * WY * 82009 28 FEB 1981
135 REM
150 IF NOT PEEK( -1155) THEN CALL -1184
200 PRINT : PRINT
250 HTAB 12
300 PRINT "AN INVITATION FOR"
350 HTAB 5
400 PRINT "APPLE TREES AND APPLE SEEDLINGS": PRINT
450 PRINT "PERHAPS YOU FOUND SOME FAULTY PROGRAMS"
500 PRINT "AND YOU FIXED THEM?": PRINT
550 PRINT "MAYBE YOU EVEN TOOK LOTS OF TIME TO"
600 PRINT "REWRITE A PROGRAM FROM END TO END?": PRINT
650 PRINT "WE WOULD LIKE TO HARVEST YOUR 'IMPROVED'PROGRAMS FOR OTHERS TO ENJOY AND USE.
700 HTAB 6
750 PRINT "-- PLEASE, SEND US A COPY --": PRINT
800 PRINT "WE'LL RETURN YOUR DISK, RECOPIED WITH"
850 PRINT "ANY VOLUME YOU CHOOSE FROM OUR PUBLIC"
900 PRINT "DOMAIN LIBRARY, WITH MANY THANKS.": PRINT
950 HTAB 3
1000 PRINT "APPLE AVOCATION ALLIANCE (AAA), INC."
1050 HTAB 12
1100 PRINT "721 PIKE STREET"
1150 HTAB 6
1200 PRINT "CHEYENNE * WY * USA * 82009": PRINT
1250 PRINT "PRESS C FOR CATALOG OR RETURN TO QUIT";
1300 GET C$
1350 IF C$ = "C" THEN 1450
1400 IF NOT PEEK( -1155) THEN CALL -1184: END
1450 HOME : VTAB 12: HTAB 3: INVERSE
1475 PRINT "APPLE AVOCATION ALLIANCE (AAA), INC.": NORMAL
1500 PRINT CHR$(4);"CATALOG"
1550 END

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/BATTERY DEMO.bas:

10 HGR
20 HCOLOR= 3: GOSUB 2000
30 HPLOT 20,20 TO 80,20 TO 80,60 TO 20,60 TO 20,20
40 FOR X = 50 TO 60
50 HPLOT 20,X TO 80,X
60 NEXT X
61 FOR X = -2.2 TO -.9 STEP .1
62 HPLOT 50 + COS(X) *36,58 + SIN(X) *36 TO 50 + COS(X) *38,58 + SIN(X) *38
63 NEXT X
70 T = -( PDL(0) *1.3/255 +.9)
71 HOME : VTAB 22: HTAB 20 -( LEN( STR$(T)))/2: PRINT T: CALL -868
72 VTAB 23: PRINT TAB( 10);"H+"; TAB( 18);"VOLTS"; TAB( 30);"X"
75 HCOLOR= 3
80 GOSUB 980
85 GOSUB 1030
87 HCOLOR= 0: GOSUB 980
90 GOTO 70
100 END
115 HCOLOR= 0: GOSUB 2000
980 HPLOT 50,58 TO 50 + COS(T) *35,58 + SIN(T) *35
990 RETURN
1030 HCOLOR= 3
1040 FOR X = 50 TO 60
1050 HPLOT 20,X TO 80,X
1060 NEXT X
1070 RETURN
2000 HPLOT 10,90 TO 10,159 TO 80,159 TO 80,90
2010 HPLOT 160,90 TO 160,159 TO 240,159 TO 240,90
2020 FOR X = 110 TO 158: HCOLOR= 1: HPLOT 11,X TO 79,X
2025 HCOLOR= 2
2030 HPLOT 161,X TO 239,X
2040 NEXT X
2050 HCOLOR= 3
2060 FOR Y = 80 TO 150
2070 HCOLOR= 3: HPLOT 30,Y: HPLOT 40,Y
2080 HCOLOR= 0: HPLOT 31,Y TO 39,Y
2090 NEXT Y
2095 HCOLOR= 3
2100 HPLOT 30,80 TO 20,80
2110 HPLOT 20,75 TO 40,75 TO 40,80
2120 HPLOT 35,61 TO 35,130
2130 HPLOT 65,60 TO 65,70 TO 215,70 TO 215,100
2140 FOR X = 100 TO 150
2150 HCOLOR= (X/2 - INT(X/2)) *6
2160 HPLOT 210,X TO 220,X
2170 NEXT X
2180 FOR Y = 150 TO 80 STEP -1
2190 HCOLOR= 3
2200 HPLOT 65,Y TO 70,Y
2210 NEXT Y
2220 FOR X = 65 TO 180
2230 HPLOT X,80 TO X,85
2240 NEXT X
2250 FOR Y = 150 TO 80 STEP -1
2260 HPLOT 175,Y TO 180,Y
2270 NEXT Y
9998 HCOLOR= 3
9999 RETURN

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/CIRCULAR DICHROISM.bas:

1 HOME : PRINT : PRINT : PRINT : PRINT
2 PRINT " CIRCULAR DICHROISM BY DR.G.SCOTT OWEN"
3 PRINT : PRINT " ATLANTA UNIVERSITY"
4 FOR I = 1 TO 2000: NEXT I
10 HOME
15 DIM CAL(40),LAM(40),HP(40),RP(40),BP(40)
20 PRINT "THIS PROGRAM CALCULATES AND PLOTS THE CIRCULAR DICHROISM SPECTRUM OF A PROTEININ THE WAVELENGTH RANGE 200-250 NM."
25 PRINT "THE CD DATA COMES FROM CHEN,ETAL.BIOCHEM,1974."
30 FOR I = 1 TO 1000: NEXT I: PRINT
35 PRINT "THE SECONDARY STRUCTURE PERCENTAGES MUST TOTAL 1.0"
38 PRINT
40 INPUT "INPUT THE PERCENTAGES AS FOLLOWS; %HELIX,%B-SHEET,%RANDOM ";HELIX,BSHT,RAN
44 IF (HELIX +BSHT +RAN) < >1 THEN 40
46 RESTORE
50 FOR I = 1 TO 17
60 READ LAM(I),HP(I),BP(I),RP(I)
70 CAL(I) = HELIX *HP(I) +BSHT *BP(I) +RAN *RP(I)
75 NEXT I
80 PRINT : PRINT "CALCULATED SPECTRUM WAVELENGTH": PRINT
90 FOR I = 1 TO 17
100 PRINT "THETA= ";CAL(I),"LAMBDA= ";LAM(I)
110 NEXT I
160 PRINT "HIT ANY KEY FOR A HIRES PLOT OF THE DATA": CALL -758
170 GOSUB 1000
180 CALL -758: TEXT
200 INPUT "DO YOU WANT ANOTHER PLOT(Y/N)";A$
210 IF A$ = "Y" THEN 40
500 DATA 201,16800,8810,-23300,204,-9120,300,-11300,207,-22300,-4320,-5770,210,-26400,-8190,-2200
510 DATA 213,-24800,-8680,-850,216,-26600,-9210,1230,219,-28900,-6890,1720,222,-30000,-3360,1580
520 DATA 225,-28700,1540,260,228,-24000,4390,-480,231,-17300,4580,-770,234,-11300,3540,160,237,-6250,2410,-90
530 DATA 240,-2950,3370,-1040,243,-1230,2040,-930,246,-703,1183,-540,249,-172,285,-130
600 END
1000 REM THIS SUBROUTINE PROnhqXHH[M ABS
19120 2= LIST ZJZ
3084
2834 HX0,040,00
2562 DATA 2,8,-0 CALL 04 GR 3,3 GR 4(3 GOSUB 6,3 CALL 30 CALL ,, PR# -) ASC,8
47928 REM HGR2 4 = 9SkurR >mlyNMhhr?AX -MIN:XRANGE = 50
1130 XL = 279:YL = 159
1140 Y0 = (MAX/YRANGE *YL): IF Y0 <0 THEN Y0 = 0
1142 HPLOT 0,Y0 TO 279,Y0
1148 X0 = 27: REM INITIAL X AXIS TICK MARK
1150 FOR I = 1 TO 10: HPLOT X0,Y0 TO X0,(Y0 +4):X0 = X0 +28: NEXT I: REM PUT TICKS EVERY 5 NM ON X AXIS
1155 XL = 279:YL = 159
1160 YN = (2000/YRANGE *YL): REM PUT TICK MARKS EVERY 2000 DEGREES ON Y AXIS
1162 YT = YN
1164 NP = INT(MAX/2000)
1166 IF NP < = 0 THEN 1170
1168 FOR I = 1 TO NP: HPLOT 0,(Y0 -YT) TO 4,(Y0 -YT):YT = YT +YN: NEXT I
1170 MIN = ABS(MIN):NM = INT(MIN/2000)
1171 YT = YN
1172 FOR I = 1 TO NM: HPLOT 0,(Y0 +YT) TO 4,(Y0 +YT):YT = YT +YN: NEXT I
1190 X1 = (XL/XRANGE):Y1 = (CAL(1)/YRANGE *YL)
1192 Y1 = ABS(Y1)
1194 IF Y1 > = 0 THEN Y1 = ABS(Y1 -Y0): GOTO 1200
1196 Y1 = ABS(Y1) +Y0
1200 HCOLOR= 1: HPLOT X1,Y1
1230 X = X1
1240 FOR I = 2 TO 17
1250 Y = CAL(I)/YRANGE *YL:
1252 IF Y > = 0 THEN Y = ABS(Y -Y0): GOTO 1255
1253 Y = ABS(Y) +Y0
1255 X = X +3 *XL/XRANGE
1260 HPLOT TO X,Y
1270 NEXT I
1500 RETURN

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/D N A.int:

0 GOTO 5:REM *** "DNA" ***
1 PRINT "SAVE DNA":END
2 GOTO 6000:REM (TEXT-LISTER)
3 GOTO 7000:REM (TEXT-EDITOR)
5 DIM A$(255),B$(255):I=-384:N=-380
10 TEXT :CALL -936:GOTO 50
15 REM **** TYPEWRITER ******
20 TAB (40- LEN(A$))/2+1
25 FOR A=1 TO LEN(A$)
30 PRINT A$(A,A);
35 IF A$(A,A)#" " THEN K= PEEK (-16336)- PEEK (-16336)- PEEK (-16336)- PEEK (-16336)
40 FOR D=0 TO 30:NEXT D
45 NEXT A:RETURN
50 A$="****************************************":VTAB 3:GOSUB 15:PRINT :DLA=1:GOSUB 4000
55 A$="" D N A "":GOSUB 15
60 A$="THE LANGUAGE OF LIFE":VTAB 7:GOSUB 15:GOSUB 4000
65 A$="****************************************":VTAB 9:GOSUB 15:GOSUB 4000
70 A$="FROM A SCIENCE PAPER":VTAB 11:GOSUB 15
75 A$="BY THE":VTAB 13:GOSUB 15
80 A$="FAMED BIOLOGIST":VTAB 15:GOSUB 15:GOSUB 4000
85 A$="DR. M. BRIO":VTAB 17:GOSUB 15:GOSUB 4000
90 A$="AN "APPLE II" SCIENCE SERIES":VTAB 22:GOSUB 15
95 DLA=2:GOSUB 4000
100 GOSUB 5000:CALL -936
105 A$=" SCIENCE SERIES # 1 ":CALL I:VTAB 2:GOSUB 15:CALL N
110 DLA=1:GOSUB 4000:VTAB 5
115 A$="" D N A "":GOSUB 15
120 A$="DEOXYRIBONUCLEIC ACID":VTAB 7:GOSUB 15:VTAB 9
125 A$="D N A - THE MOST CELEBRATED":GOSUB 4000:GOSUB 15
130 A$="MOLECULE OF OUR TIME. THE CARRIER":VTAB 11:GOSUB 15
135 A$="OF THE GENETIC CODE AND THE MASTER":VTAB 13:GOSUB 15
140 A$="CHOREOGRAPHER OF THE LIVING CELL. ":VTAB 15:GOSUB 15:GOSUB 4000
145 A$="A GENE IS BASICCLLY A BIOCHEMICAL":VTAB 18:GOSUB 15
150 A$="BIT OF INFORMATION WRITTEN IN THE":VTAB 20:GOSUB 15
155 A$="RECENTLY DECODED LANGUAGE OF DNA.":VTAB 22:GOSUB 15
160 DLA=2:GOSUB 4000
165 GOSUB 5000:CALL -936
170 A$="GENES ARE MADE UP OF THE CHEMICAL DNA":VTAB 3:GOSUB 15
175 A$="=====================================":PRINT :GOSUB 15
180 DLA=1:GOSUB 4000
185 A$="BIOLOGISTS HAVE FOUND THAT VIRTUALLY ":VTAB 7:GOSUB 15
190 A$="EVERY CELL CONTAINS THE ENTIRE REPER-":VTAB 9:GOSUB 15
195 A$="TOIRE OF GENES FOR THAT PLANT OR ANI-":VTAB 11:GOSUB 15
200 A$="MAL. ONE CELL HAS ALL THE DATA IN ITS":VTAB 13:GOSUB 15
205 A$="DNA TO PRODUCE A PHYSICAL DUPLICATION":VTAB 15:GOSUB 15
210 A$="OF ITS TOTAL LIVING STATE. [FACT- THE":VTAB 17:GOSUB 15
215 A$="AMOUNT OF DATA, IF WRITTEN OUT, WOULD":VTAB 19:GOSUB 15
220 A$="FILL A THOUSAND 600-PAGE VOLUMES] ":VTAB 21:GOSUB 15
225 DLA=2:GOSUB 4000
230 GOSUB 5000:CALL -936
235 A$="ENORMOUSLY LONG STRANDS OF DNA INTER-":VTAB 2:GOSUB 15
240 A$="TWINE WITHIN THE CORE OF LIVING CELLS":VTAB 4:GOSUB 15
245 A$="AND ARE IN A FORM OF A TWIN SPIRAL OR":VTAB 6:GOSUB 15
250 A$="DOUBLE HELIX. THE 2 SPIRALS ARE LINKED":VTAB 8:GOSUB 15
255 A$="TOGETHER BY THE INTERLOCKING DNA UNITS":VTAB 10:GOSUB 15
260 A$="CALLED NUCLEOTIDES OF WHICH THERE ARE":VTAB 12:GOSUB 15
265 A$="FOUR TYPES - 'ADENINE' WHICH CAN ONLY":VTAB 14:GOSUB 15
270 A$="PAIR UP WITH 'THYMINE' AND 'CYTOSINE'":VTAB 16:GOSUB 15
275 A$="WHICH CAN ONLY PAIR UP WITH 'GUANINE'":VTAB 18:GOSUB 15:DLA=1:GOSUB 4000
280 A$="[FACT- IF ALL THE DNA STRANDS IN THE ":VTAB 20:GOSUB 15
285 A$="HUMAN BODY WERE UNWOUND AND CONNECTED":VTAB 22:GOSUB 15
290 A$="TOGETHER, THE STRING WOULD STRETCH TO":VTAB 24:GOSUB 15
295 A$="THE SUN AND BACK MORE THAN 400 TIMES]":PRINT :PRINT :GOSUB 15:DLA=2
300 GOSUB 4000:PRINT :PRINT :GOSUB 5000:CALL -936
305 GOSUB 3000:VTAB 21:GOSUB 4500:VTAB 22:GOSUB 4500:GOSUB 4000:LEN=30:A$=" "
310 B$=" ":GOSUB 2000
315 A$=" A SEGMENT OF THE DNA STRAND ":GOSUB 2000
320 CALL -198:COLOR= 0:HLIN 14,24 AT 15:HLIN 14,24 AT 27:VLIN 15,27 AT 14:VLIN 15,27 AT 24:GOSUB 4000
325 A$=" IN THE INSET ABOVE, THE DNA UNITS ARE COLOR-CODED, ":GOSUB 2000
330 A$="THE RED UNITS (ADENINE) CAN ONLY LINK UP WITH THE VIOLETS (THYMINE), ":GOSUB 2000
335 A$="AND THE YELLOWS (CYTOSINE) WITH THE GREENS (GUANINE). ":GOSUB 2000:GOSUB 4000
340 COLOR= 15:HLIN 14,24 AT 15:HLIN 14,24 AT 27:VLIN 16,19 AT 14:VLIN 25,26 AT 24:COLOR= 7:PLOT 14,20:VLIN 16,17 AT 24
345 COLOR= 2:PLOT 24,24:VLIN 25,26 AT 14:COLOR= 3:VLIN 21,22 AT 14:VLIN 18,19 AT 24:COLOR= 12:VLIN 23,24 AT 14:VLIN 20,23 AT 24
350 A$=" THE UNITS FORM A SEQUENCE ALONG THE LENGTHY DNA RIBBON ":GOSUB 2000
355 A$="AND CONTAINS IN CODE THE SPECIFIC DATA THAT THE CELL NEEDS ":GOSUB 2000
360 A$="TO MANUFACTURE ITS PARTICULAR SET OF PROTEINS. ":GOSUB 2000:GOSUB 4000
365 A$=" BY VARYING THE SEQUENCE, NATURE VARIES THE INSTRUCTIONS. ":GOSUB 2000:GOSUB 4000
370 A$=" [ FACT- THE NUMBER OF DIFFERENT WAYS OF SEQUENCING THE DNA PAIRS ":GOSUB 2000
375 A$="IN A SET OF HUMAN CHROMOSOMES = THE NUMBER 256 FOLLOWED BY 2.4 BILLION ZEROS.] ":GOSUB 2000:DLA=3
380 GOSUB 4000:GOSUB 5000
385 A$=" ":TEXT :CALL -936
390 A$="ENCODING THE DNA RIBBON":VTAB 4:GOSUB 15
395 A$="=======================":VTAB 5:GOSUB 15:DLA=1:GOSUB 4000
400 A$="IN THE NEXT GRAPHICS, YOU MAY INPUT":VTAB 8:GOSUB 15
405 A$="THE PAIRS OF DNA NUCLEOTIDES ACROSS":VTAB 10:GOSUB 15
410 A$="THE TWO STRANDS IN ANY SEQUENCE YOU":VTAB 12:GOSUB 15
415 A$="SELECT. THE "APPLE" COMPUTER UTILI-":VTAB 14:GOSUB 15
420 A$="ZING A BIOLOGICAL ALGORITHM TO DE- ":VTAB 16:GOSUB 15
425 A$="CODE THE SEQUENCE INSTRUCTIONS WILL":VTAB 18:GOSUB 15
430 A$="INFORM YOU OF THE KIND OF ORGANISM,":VTAB 20:GOSUB 15
435 A$="PLANT OR ANIMAL, YOU HAVE ENCODED. ":VTAB 22:GOSUB 15
440 DLA=2:GOSUB 4000:GOSUB 5000
445 CALL -936:GOSUB 3300
450 A$=" A B C D ":CALL I:VTAB 21:PRINT A$:CALL N:GOSUB 4000
455 CALL I:VTAB 23:TAB 4:CALL -198:PRINT " INPUT THE 'DNA' UNITS BY LETTERS ":CALL N:X=1
460 P= PEEK (-16384): POKE -16368,0:IF P<193 OR P>196 THEN 460:GOTO 465+10*(P-193)
465 COLOR= 12:VLIN 12,15 AT X:COLOR= 13:VLIN 16,19 AT X
470 X=X+2:IF X>38 THEN 505:CALL -198:GOTO 460
475 COLOR= 13:VLIN 12,15 AT X:COLOR= 12:VLIN 16,19 AT X
480 X=X+2:IF X>38 THEN 505:CALL -198:GOTO 460
485 COLOR= 3:VLIN 12,15 AT X:COLOR= 1:VLIN 16,19 AT X
490 X=X+2:IF X>38 THEN 505:CALL -198:GOTO 460
495 COLOR= 1:VLIN 12,15 AT X:COLOR= 3:VLIN 16,19 AT X
500 X=X+2:IF X>38 THEN 505:CALL -198:GOTO 460
505 VTAB 23:CALL -868:CALL -198:GOSUB 4000
510 CALL I:CALL -198:TAB 7:PRINT " TO DECODE - PRESS 'RETURN' ":CALL N
515 P= PEEK (-16384): POKE -16368,0:IF P<>141 THEN GOTO 515
520 TEXT :DLA=1:GOSUB 4000
525 CALL -936:DLA=10
530 PRINT "*** BAD RETURN ERR":GOSUB 4100:PRINT
535 PRINT "*** MEM FULL ERR":GOSUB 4100:PRINT
540 PRINT "*** 16 GOSUBS ERR":GOSUB 4100:PRINT
545 PRINT "*** SYNTAX ERR":GOSUB 4100:PRINT
550 PRINT "*** >32767 ERR":GOSUB 4100:PRINT
555 PRINT "*** TOO LONG ERR":GOSUB 4100:PRINT
560 PRINT "*** NO END ERR":GOSUB 4100:PRINT
565 PRINT "*** BAD BRANCH ERR":GOSUB 4100:PRINT
570 PRINT "*** STR OVFL ERR":GOSUB 4100:PRINT
575 PRINT "*** BAD NEXT ERR":GOSUB 4100:PRINT
580 PRINT "*** DIM ERR":GOSUB 4100:PRINT
585 PRINT "*** 16 FORS ERR":GOSUB 4100:PRINT
590 PRINT "*** BAD PROGRAM ERR":GOSUB 4100:PRINT
595 DLA=2:GOSUB 4000
600 CALL I:LIST 3000,5000:CALL N
605 GOSUB 4200
610 FOR T=0 TO 5:FOR Z=0 TO 9
615 POKE -16304,0: POKE -16302,0: POKE -16299,0: POKE -16300,0
620 FOR D=0 TO 3
625 NEXT D:NEXT Z
630 FOR Z=0 TO 10:TEXT
635 FOR D=0 TO 20:NEXT D
640 NEXT T:CALL -936
645 GR : POKE -16302,0
650 COLOR= 0:FOR ROW=40 TO 47
655 HLIN 0,39 AT ROW:NEXT ROW
660 DLA=10:GOSUB 4000
665 COLOR= 12:FOR COL=5 TO 35
670 VLIN 5,47 AT COL:NEXT COL
675 COLOR= 0:FOR ROW=35 TO 47:HLIN 7,33 AT ROW:NEXT ROW:HLIN 8,32 AT 34:HLIN 9,31 AT 33:HLIN 10,30 AT 32:HLIN 11,29 AT 31
680 FOR ROW=7 TO 30:HLIN 16,24 AT ROW:NEXT ROW:VLIN 7,24 AT 15:VLIN 7,24 AT 25:VLIN 16,20 AT 14:VLIN 16,20 AT 26:PLOT 15,28:PLOT 25,28
685 DLA=4:GOSUB 4000
690 TEXT :CALL -936:GOSUB 4000
695 A$="I'M SORRY, - YOUR DNA SEQUENCE":VTAB 5:GOSUB 15
700 DLA=1:GOSUB 4000
705 A$="MUST HAVE HAD BAD INSTRUCTIONS":VTAB 7:GOSUB 15
710 DLA=4:GOSUB 4000
715 A$="YOU CAN'T FOOL "MOTHER NATURE"":VTAB 10:GOSUB 15
720 DLA=3:GOSUB 4000
725 A$=""APPLE" SCIENCE SERIES":VTAB 17:GOSUB 15
730 DLA=4:GOSUB 4000
735 A$=" BY - WEYMAN FONG ":CALL -198:VTAB 21:TAB 12
740 CALL I:PRINT A$;:CALL N
745 END
2000 REM **** (MOVING SIGN) ****
2010 LE=LEN-1:B$( LEN(B$)+1)=A$
2020 FOR I1=1 TO LEN(B$)-LEN
2030 VTAB 21:TAB 6
2040 PRINT B$(I1,I1+LE);
2050 FOR D=0 TO 80:NEXT D
2060 POKE -16366, PEEK (-16336)= PEEK (-16336)
2070 NEXT I1
2080 B$=B$( LEN(B$)-LE, LEN(B$))
2090 RETURN
3000 REM **** (DNA GRAPHICS) ****
3010 GR :COLOR= 15
3020 FOR ROW=0 TO 39
3030 HLIN 0,39 AT ROW
3040 NEXT ROW
3050 COLOR= 2:HLIN 0,3 AT 17:HLIN 0,3 AT 18:HLIN 4,6 AT 18
3060 HLIN 4,6 AT 19:VLIN 19,20 AT 7:VLIN 20,21 AT 8:VLIN 21,22 AT 9:VLIN 22,23 AT 10
3070 VLIN 23,24 AT 11:VLIN 23,24 AT 12:VLIN 24,25 AT 13:HLIN 14,22 AT 25:HLIN 14,22 AT 26:VLIN 24,25 AT 23
3080 PLOT 24,24:VLIN 22,23 AT 25:PLOT 26,22:VLIN 20,21 AT 27:PLOT 28,20:VLIN 18,19 AT 29:PLOT 31,16:PLOT 32,15
3090 VLIN 15,16 AT 33:PLOT 34,14:VLIN 13,14 AT 35:PLOT 36,13:VLIN 13,14 AT 37:PLOT 38,12:VLIN 12,13 AT 39
3100 COLOR= 7:PLOT 0,27:HLIN 0,3 AT 28:HLIN 2,6 AT 27:PLOT 2,27:PLOT 4,26:HLIN 6,8 AT 26:HLIN 8,10 AT 25
3110 PLOT 10,24:PLOT 12,22:VLIN 21,22 AT 13:PLOT 14,20:VLIN 19,20 AT 15:PLOT 16,18:VLIN 18,19 AT 17:PLOT 18,17
3120 VLIN 17,18 AT 19:HLIN 20,29 AT 16:PLOT 21,17:HLIN 23,31 AT 17:HLIN 30,33 AT 18:HLIN 32,35 AT 19:HLIN 34,39 AT 20:HLIN 36,39 AT 21
3130 COLOR= 1:VLIN 19,22 AT 1:VLIN 23,27 AT 3:VLIN 21,22 AT 7:PLOT 9,24:PLOT 28,19
3140 VLIN 21,25 AT 20:VLIN 17,20 AT 22:VLIN 20,21 AT 26:PLOT 32,16:VLIN 13,16 AT 38
3150 COLOR= 3:VLIN 23,27 AT 1:VLIN 19,22 AT 3:VLIN 23,25 AT 7:VLIN 17,20 AT 20
3160 PLOT 9,23:VLIN 21,25 AT 22:VLIN 18,19 AT 26:PLOT 28,18:PLOT 32,17:VLIN 17,19 AT 38
3170 COLOR= 12:VLIN 20,22 AT 5:VLIN 23,24 AT 14:VLIN 22,24 AT 16:VLIN 18,21 AT 18:VLIN 20,23 AT 24:VLIN 17,18 AT 34:VLIN 14,16 AT 36
3180 COLOR= 13:VLIN 23,26 AT 5:VLIN 21,22 AT 14:VLIN 19,21 AT 16:VLIN 22,24 AT 18:VLIN 18,19 AT 24:VLIN 15,16 AT 34:VLIN 17,19 AT 36
3200 RETURN
3300 REM **** (GRAPHICS 2) ****
3310 GR :COLOR= 15
3320 FOR ROW=0 TO 39
3330 HLIN 0,39 AT ROW
3340 NEXT ROW
3350 COLOR= 12:VLIN 33,35 AT 12:VLIN 36,38 AT 17:COLOR= 13:VLIN 36,38 AT 12:VLIN 33,35 AT 17
3360 COLOR= 3:VLIN 33,35 AT 22:VLIN 36,38 AT 27:COLOR= 1:VLIN 36,38 AT 22:VLIN 33,35 AT 27
3370 COLOR= 7:HLIN 0,39 AT 10:HLIN 0,39 AT 11:COLOR= 2:HLIN 0,39 AT 20:HLIN 0,39 AT 21
3380 RETURN
3999 END
4000 REM ***** (DELAY LOOP) *****
4010 FOR D=0 TO DLA*300:NEXT D:RETURN
4100 REM *** (DELAY + CURSOR) ***
4110 CALL -198:PRINT ">";
4120 POKE PEEK (41)*256+ PEEK (40)+ PEEK (36),96
4130 FOR D=0 TO DLA*100:NEXT D:DLA=DLA-1:RETURN
4200 REM ** (PRINT GIBBERISH) **
4210 CALL -936:GOTO 4280
4220 FOR G=1 TO LEN(A$)
4230 PRINT A$(G,G);
4250 NEXT G:RETURN
4260 A$="AS+ J(9Y.O!U&(0 X25T":GOSUB 4220
4270 A$="$U,R*K%E,Y;!7T:4#^+?":GOSUB 4220:RETURN
4280 VTAB 1:GOSUB 4260:VTAB 7:GOSUB 4260:VTAB 14:GOSUB 4260:VTAB 21:GOSUB 4260
4290 VTAB 2: POKE 50,127:GOSUB 4260:VTAB 8:GOSUB 4260:VTAB 15:GOSUB 4260
4300 VTAB 22:GOSUB 4260: POKE 50,255:VTAB 3:GOSUB 4260:VTAB 9:GOSUB 4260:VTAB 16:GOSUB 4260
4310 POKE 50,127:VTAB 4:GOSUB 4260:VTAB 10:GOSUB 4260:VTAB 17:GOSUB 4260: POKE 50,63:VTAB 5:GOSUB 4260
4320 VTAB 11:GOSUB 4260:VTAB 18:GOSUB 4260: POKE 50,255:VTAB 6:GOSUB 4260:VTAB 12:GOSUB 4260:VTAB 19:GOSUB 4260
4330 VTAB 13:GOSUB 4260:VTAB 20:GOSUB 4260:VTAB 23:GOSUB 4260:VTAB 24:GOSUB 4260
4400 RETURN
4500 REM * (INVERSE LINES 21,22) *
4510 FOR W=0 TO 39:CALL I
4520 PRINT " ";:NEXT W
4530 CALL N:RETURN
5000 REM *** (SPACE BAR WAIT) ***
5010 A$=" PRESS SPACE BAR ":VTAB 24:CALL I:GOSUB 15
5020 CALL N:P= PEEK (-16384)
5030 IF P<> ASC(" ") THEN 5020
5040 POKE -16368,0:RETURN
6000 REM **** (TEXT-LISTER) ****
6010 CALL -936: POKE 33,33
6020 VTAB 2:PRINT " LIST"
6030 VTAB 1:END
7000 REM **** (TEXT-EDITOR) ****
7010 CALL -936: POKE 33,33
7020 VTAB 2:PRINT " 000 A$= :VTAB 00:GOSUB 8"
7030 PRINT " 000 A$= :VTAB 00:GOSUB 8"
7040 PRINT " 000 A$= :VTAB 00:GOSUB 8"
7050 PRINT " 000 A$= :VTAB 00:GOSUB 8"
7060 PRINT " 000 A$= :VTAB 00:GOSUB 8"
7100 VTAB 1:END
9000 REM ***** (SUBROUTINES) *****
9010 REM LINE 15 - TEXT TYPER
9020 REM LINE 2000 - SIGN BOARD
9030 REM LINE 3000 - DNA GRAPHICS
9040 REM LINE 4000 - DELAY LOOPS
9050 REM LINE 5000 - SPACE BAR WAIT
9060 REM LINE 6000 - TEXT-LISTER
9070 REM LINE 7000 - TEXT-EDITOR
9071 REM
65000 REM
65010 REM
65020 REM
65030 REM DNA PROGRAM BY: WEYMAN FONG SEPTEMBER 1979
65040 REM
65050 REM GIVEN TO APPLE CORE OF SAN FRANCISCO FOR USE OF MEMBERS BY AUTHOR.
65060 REM
65070 REM LAST MOD. SEPTEMBER 1979 FOR CONVENTIONS UPDATE
65080 REM
65090 REM ' D N A '
65100 END

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/ELEMENTS TABLE.bas:

20 DIM EL$(15),SY$(6),AN$(3),AW$(7)
30 DIM IE$(15),IS$(6),IN$(3),IW$(7)
35 CALL -936
40 PRINT "TABLE OF THE ELEMENTS FILE"
50 PRINT "FOR APPLE II COMPUTER"
55 PRINT "BY RICHARD W. WAGNER": PRINT
60 PRINT "ENTER DESIRED OPTION"
80 PRINT "1. LIST BY ELEMENT NAME"
90 PRINT "2. LIST BY SYMBOL"
100 PRINT "3. LIST BY ATOMIC NUMBER"
113 PRINT "4. AUTOMATIC SLOW LIST"
115 PRINT
120 PRINT "ENTER OPTION (1-4)"
125 GET O
130 ON O GOTO 200,400,800,600
200 CALL -936: SPEED= 255
202 RESTORE : PRINT : PRINT "ENTER ELEMENT NAME"
205 PRINT
207 PRINT "TO EXIT OPTION ENTER 'OUT' "
209 PRINT
210 INPUT IE$
215 IF IE$ = "OUT" THEN GOTO 35
220 FOR L = 1 TO 103
230 READ EL$,SY$,AN$,AW$
240 IF EL$ = "DONE" THEN GOTO 202
246 IF EL$ = IE$ THEN GOSUB 6000
250 NEXT L
260 GOTO 202
400 CALL -936: SPEED= 255
410 PRINT "ENTER SYMBOL"
420 PRINT : INPUT IS$
430 IF IS$ = "OUT" THEN GOTO 35
440 RESTORE
450 FOR L1 = 1 TO 103
560 READ EL$,SY$,AN$,AW$
565 IF EL$ = "DONE" THEN GOTO 410
570 IF SY$ = IS$ THEN GOSUB 6000
580 NEXT L1
590 GOTO 410
600 RESTORE : CALL -936
605 SPEED= 150
610 PRINT "TABLE OF THE ELEMENTS"
620 FOR L1 = 1 TO 103
630 READ EL$,SY$,AN$,AW$
635 IF EL$ = "DONE" THEN GOTO 35
640 GOSUB 6000
660 NEXT L1
670 GOTO 35
800 CALL -936: SPEED= 255
805 RESTORE : PRINT : PRINT "ENTER ATOMIC NUMBER"
810 PRINT
815 PRINT "TO EXIT OPTION ENTER 'OUT'"
820 PRINT
825 INPUT IN$
830 IF IN$ = "OUT" THEN GOTO 35
840 FOR L = 1 TO 103
850 READ EL$,SY$,AN$,AW$
860 IF EL$ = "DONE" THEN GOTO 800
870 IF AN$ = IN$ THEN GOSUB 6000
880 NEXT L
885 GOTO 805
890 CALL -936: SPEED= 255
6000 PRINT : PRINT "ELEMENT"; TAB( 16);"SYMBOL"; TAB( 24);"AT.#"; TAB( 30);"AT.WEIGHT"
6010 PRINT : INVERSE : PRINT EL$; TAB( 16);SY$; TAB( 24);AN$; TAB( 30);AW$
6020 NORMAL : PRINT : RETURN
7000 DATA HYDROGEN,H,1,1.008
7001 DATA HELIUM,HE,2,4.003
7002 DATA LITHIUM,LI,3,6.940
7003 DATA BERYLLIUM,BE,4,9.013
7004 DATA BORON,B,5,10.82
7005 DATA CARBON,C,6,12.011
7006 DATA NITROGEN,N,7,14.008
7007 DATA OXYGEN,O,8,16.0000
7008 DATA FLUORINE,F,9,19.00
7009 DATA NEON,NE,10,20.183
7010 DATA SODIUM,NA,11,22.991
7011 DATA MAGNESIUM,MG,12,24.32
7012 DATA ALUMINUM,AL,13,26.98
7013 DATA SILICON,SI,14,28.09
7014 DATA PHOSPHORUS,P,15,30.975
7015 DATA SULFUR,S,16,32.066
7016 DATA CHLORINE,CL,17,35.457
7017 DATA ARGON,AR(A),18,39.944
7018 DATA POTASSIUM,K,19,39.100
7019 DATA CALCIUM,CA,20,40.08
7020 DATA SCANDIUM,SC,21,44.96
7021 DATA TITANIUM,TI,22,47.90
7022 DATA VANADIUM,V,23,50.95
7023 DATA CHROMIUM,CR,24,52.01
7024 DATA MANGANESE,MN,25,54.94
7025 DATA IRON,FE,26,55.85
7026 DATA COBALT,CO,27,58.94
7027 DATA NICKEL,NI,28,58.71
7028 DATA COPPER,CU,29,63.54
7029 DATA ZINC,ZN,30,65.38
7030 DATA GALLIUM,GA,31,69.72
7031 DATA GERMANIUM,GE,32,72.60
7032 DATA ARSENIC,AS,33,74.91
7033 DATA SELENIUM,SE,34,78.96
7034 DATA BROMINE,BR,35,79.916
7035 DATA KRYPTON,KR,36,83.80
7036 DATA RUBIDIUM,RB,37,85.48
7037 DATA STRONTIUM,SR,38,86.63
7038 DATA YTTRIUM,Y,39,88.92
7039 DATA ZIRCONIUM,ZR,40,91.22
7040 DATA NIOBIUM,NB(CB),41,92.91
7041 DATA MOLYBDENUM,MO,42,95.95
7042 DATA TECHNETIUM,TC(MA),43,(99)
7043 DATA RUTHENIUM,RU,44,101.1
7044 DATA RHODIUM,RH,45,102.91
7045 DATA PALLADIUM,PD,46,106.4
7046 DATA SILVER,AG,47,107.880
7047 DATA CADMIUM,CD,48,112.41
7048 DATA INDIUM,IN,49,114.82
7049 DATA TIN,SN,50,118.70
7050 DATA ANTIMONY,SB,51,121.76
7051 DATA TELLURIUM,TE,52,127.61
7052 DATA IODINE,I(J),53,126.91
7053 DATA XENON,XE(X),54,131.91
7054 DATA CESIUM,CS,55,132.91
7055 DATA BARIUM,BA,56,137.36
7056 DATA LANTHANUM,LA,57,138.92
7057 DATA CERIUM,CE,58,140.13
7058 DATA PRASEODYMIUM,PR,59,140.92
7059 DATA NEODYMIUM,ND,60,144.27
7060 DATA PROMETHIUM,PM,61,(147)
7061 DATA SAMARIUM,SM(SA),62,150.35
7062 DATA EUROPIUM,EU,63,152.0
7063 DATA GADOLINIUM,GD,64,157.26
7064 DATA TERBIUM,TB,65,158.93
7065 DATA DYPROSIUM,DY(DS),66,162.51
7066 DATA HOLMIUM,HO,67,164.94
7067 DATA ERBIUM,ER,68,167.27
7068 DATA THULIUM,TM(TU),69,168.94
7069 DATA YTTERBIUM,YB,70,173.04
7070 DATA LUTECIUM,LU(CP),71,174.99
7071 DATA HAFNIUM,HF,72,178.50
7072 DATA TANTALUM,TA,73,180.95
7073 DATA TUNGSTEN,W,74,183.86
7074 DATA RHENIUM,RE,75,186.22
7075 DATA OSMIUM,OS,76,190.2
7076 DATA IRIDIUM,IR,77,192.2
7077 DATA PLATINUM,PT,78,195.09
7078 DATA GOLD,AU,79,197.0
7079 DATA MERCURY,HG,80,200.61
7080 DATA THALLIUM,TL,81,204.39
7081 DATA LEAD,PB,82,207.21
7082 DATA BISMUTH,BI,83,209.00
7083 DATA POLONIUM,PO,84,(209)
7084 DATA ASTATINE,AT,85,(210)
7085 DATA RADON,RN,86,(222)
7086 DATA FRANCIUM,FR(FA),87,(223)
7087 DATA RADIUM,RA,88,226.05
7088 DATA ACTINIUM,AC,89,(227)
7089 DATA THORIUM,TH,90,232.12
7090 DATA PROTOACTINIUM,PA,91,(231)
7091 DATA URANIUM,U(UR),92,238.07
7092 DATA NEPTUNIUM,NP,93,(237)
7093 DATA PLUTONIUM,PU,94,(244)
7094 DATA AMERICIUM,AM,95,(243)
7095 DATA CURIUM,CM,96,(248)
7096 DATA BERKELIUM,BK,97,(247)
7097 DATA CALIFORNIUM,CF,98,(251)
7098 DATA EINSTEINIUM,E,99,(254)
7099 DATA FERMIUM,FM,100,(253)
8000 DATA MENDELEEVIUM,MV,101,(256)
8001 DATA NOBELIUM,NO,102,(253)
8002 DATA LAWRENTIUM,LW,103,(256)
8999 DATA DONE,DD,1,1
9999 END

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/ENZYME KINETICS.bas:

2 GOSUB 3000
42 HOME : PRINT : PRINT : PRINT : PRINT
44 PRINT " ENZYME KINETICS ANALYSIS": PRINT : PRINT " BY DR. G. SCOTT OWEN"
50 PRINT : PRINT " ATLANTA UNIVERSITY": FOR I = 1 TO 4000: NEXT I: HOME
60 DIM S(5,20),VEL(5,20),S2(5,20),SRCIP(5,20),VRCIP(5,20),DX(20),DY(20),YCALC(20)
100 PRINT "THIS PROGRAM PERFORMS A LEAST SQUARES ANALYSIS(LINEWEAVER-BURKE OR EADIE- HOFSTEE) OF ENZYME KINETIC DATA,PLOTS THE DATA AND CALCULATES KM AND VMAX."
110 PRINT "WRITTEN BY G.SCOTT OWEN 7-78."
120 FOR I = 1 TO 3000: NEXT I: PRINT
130 INPUT "INPUT THE NUMBER OF EXPERIMENTS TO BE ANALYSED ";NEX
140 FOR I = 1 TO NEX: PRINT
150 INPUT "INPUT THE NUMBER OF DATA POINTS FOR THISEXPERIMENT ";NDA
160 PRINT : PRINT "INPUT THE EXPERIMENTAL DATA IN THE FORMAT (S),VELOCITY-WITH ONE PAIR OF POINTS PER LINE."
170 FOR I = 1 TO NDA: INPUT S(NEX,I),VEL(NEX,I): NEXT I: PRINT
180 INPUT "FOR A LINE-WEAVER BURKE ANALYSIS INPUT LB.FOR AN EADIE-HOFSTEE ANALYSIS INPUT EH.";A$
190 PRINT : IF A$ = "LB" THEN GOSUB 1000
200 IF A$ = "EH" THEN GOSUB 2000
210 IF A$ < >"EH" AND A$ < >"LB" THEN 180
300 GOTO 180
500 END
1000 REM LINEWEAVER-BURKE PLOT
1010 SVMVEL = 0:SSMSUB = 0:SUM = 0:SQMSQ = 0: FOR I = 1 TO NDA
1020 SRCIP(NEX,I) = 1/S(NEX,I):VRCIP(NEX,I) = 1/VEL(NEX,I)
1040 S2(NEX,I) = SRCIP(NEX,I) ^2
1050 SVMVEL = SVMVEL +VRCIP(NEX,I)
1060 SSMSUB = SSMSUB +SRCIP(NEX,I)
1070 SUM = SUM +SRCIP(NEX,I) *VRCIP(NEX,I)
1080 SQMSQ = SQMSQ +S2(NEX,I): NEXT
1100 REM COMPUTE KM,VMAX
1110 B = (SSMSUB *SVMVEL -NDA *SUM)/(SSMSUB ^2 -NDA *SQMSQ)
1120 A = (SVMVEL -B *SSMSUB)/NDA
1130 VMAX = 1/A:KM = B/A
1134 PRINT "VMAX= ";VMAX;" KM= ";KM
1136 PRINT : REM CALCULATE THE STANDARD DEVIATIONS
1138 SDEV = 0:SX = 0:SBAR = SSMSUB/NDA
1140 FOR I = 1 TO NDA:YCALC(I) = A +B *SRCIP(NEX,I):SDEV = SDEV +(VRCIP(NEX,I) -YCAL(I)) ^2
1142 PRINT
1144 PRINT "1/S = ";SRCIP(NEX,I),"1/V(EXPT) = ";VRCIP(NEX,I),"1/V(CALC) = ";YCALC(I)
1145 SX = SX +(SRCIP(NEX,I) -SBAR) ^2: NEXT
1146 SY = SQR(SDEV/(NDA -1)): REM STD.DEV. OF RESIDUALS
1150 SM = SQR(SY ^2/SX): REM STD. DEV. OF SLOPE
1154 SLOPE = SQR((SY ^2 *SQMSQ)/(NDA *SX)): REM STD. DEV. OF SLOPE
1158 PRINT : PRINT "STANDARD DEVIATION OF RESIDUALS= ";SY: PRINT : PRINT "STANDARD DEVIATION OF SLOPE= ";SM
1160 PRINT : PRINT " STANDARD DEVIATION OF INTERCEPT= ";SLOPE
1180 PRINT "HIT ANY KEY FOR A HIRES LB PLOT.": CALL -756
1200 REM HIGHRES PLOT
1210 XRANGE = SRCIP(NEX,1) +1/KM:YRANGE = VRCIP(NEX,1)
1230 HGR2 : HCOLOR= 3: HPLOT 0,159 TO 279,159
1250 X0 = 270 *(1/KM)/XRANGE: HPLOT X0,0 TO X0,159
1260 HCOLOR= 1: HPLOT 6,159 TO 270,0
1266 HCOLOR= 2: ROT= 0: SCALE= 1
1270 FOR I = 1 TO NDA:DX(I) = SRCIP(NEX,I) *270/XRANGE
1272 DY(I) = VRCIP(NEX,I) *148/YRANGE
1280 DRAW 1 AT (DX(I) +X0),(150 -DY(I)): NEXT : CALL -756: TEXT : HOME : RETURN
2000 REM EADIE-HOFSTEE PLOT
2010 SVMVEL = 0:SSVSUM = 0:S2VSUM = 0:SQVSUM = 0: REM SVMVEL=SUM-VEL,SSVUM=SUM-S/V,S2VSUM=SUM V^2/S,SQVSUM=SUM-(V/S)^2
2020 FOR I = 1 TO NDA: REM COMPUTE LEASTSQUARES SUMS
2030 SVMVEL = SVMVEL +VEL(NEX,I)
2040 SSVSUM = SSVSUM +VEL(NEX,I)/S(NEX,I)
2050 S2VSUM = S2VSUM +VEL(NEX,I) ^2/S(NEX,I)
2060 SQVSUM = SQVSUM +(VEL(NEX,I)/S(NEX,I)) ^2
2070 NEXT I
2080 B = (SSVSUM *SVMVEL -NDA *S2VSUM)/(SSVSUM ^2 -NDA *SQVSUM)
2090 A = (SVMVEL -B *SSVSUM)/NDA
2100 VMAX = A:KM = -B
2105 PRINT : PRINT "VMAX = ";VMAX,"KM = ";KM
2110 REM COMPUTE STANDARD DEVIATIONS
2114 SX = 0:SDEV = 0:XBAR = SSVUM/NDA
2120 FOR I = 1 TO NDA:X = (VEL(NEX,I)/S(NEX,I)):YCALC(I) = A +B *X:SDEV = SDEV +(VEL(NEX,I) -YCALC(I)) ^2
2130 PRINT : PRINT "V/S = ";X;" V(EXPT) = ";VEL(NEX,I);" V(CALC) = ";YCALC(I)
2140 SDEV = SDEV +(VEL(NEX,I) -YCALC(I)) ^2:SX = SX +(X -XBAR) ^2: NEXT
2150 SY = SQR(SDEV/(NDA -1)): REM STD. DEV. OF RESIDUALS
2160 SM = SQR(SY ^2/SX): REM STD. DEV. OF SLOPE
2170 SB = SQR((SY ^2 *SQVSUM)/(NDA *SX)): REM STD. DEV. OF INTERCEPT
2180 PRINT : PRINT "STANDARD DEVIATION OF RESIDUALS = ";SY: PRINT : PRINT "STANDARD DEVIATION OF SLOPE = ";SM: PRINT
2190 PRINT "STANDARD DEVIATION OF INTERCEPT = ";SB
2200 PRINT : PRINT "PRESS ANY KEY FOR A LORES E-H PLOT": CALL -756
2210 GR : COLOR= 15: HLIN 0,39 AT 39: VLIN 0,39 AT 0
2220 COLOR= 2: FOR I = 0 TO 39: PLOT I,I: NEXT I: REM PLOT CALC. POINTS
2230 REM PLOT EXP. POINTS
2240 XRANGE = VMAX/KM:YRANGE = VMAX: COLOR= 9
2250 FOR I = 1 TO NDA:X = VEL(NEX,I)/S(NEX,I) *39/XRANGE:Y = 39 *(1 -VEL(NEX,I)/YRANGE): PLOT X,Y: NEXT I
2260 PRINT "EADIE-HOFSTEE PLOT FOR ENZYME KINETICS VMAX= ";VMAX;" KM= ";KM
2300 CALL -756: TEXT : HOME : RETURN
3000 REM THIS LOADS THE SHAPE TABLE FOR THE EXPERIMENTAL POINTS,BEGINNING AT 32000
3020 HIMEM: 32000
3030 POKE 32000,1: POKE 32001,0: POKE 32002,4: POKE 32003,0: POKE 32004,18: POKE 32005,63
3040 POKE 32006,32: POKE 32007,100: POKE 32008,45: POKE 32009,21: POKE 32010,54: POKE 32011,30
3050 POKE 32012,7: POKE 43013,0
3060 POKE 232,0: POKE 233,125: RETURN

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/MOLALITY.bas:

1 REM WRITTEN BY CAMERON BROWNN 1901 NORTH JUNETT TACOMA, WA. 98406 (206) 752-0094
2 REM LAB ANALYSIS SECTION TO MATCH EXPERIMENT FORMAT IN FOUNDATIONS OF CHEMISTRY SERIES - BY TOON & ELLIS
5 DIM SV$(10),FP(10),BP(10),KB(10),KF(10)
10 CALL -936
20 HTAB 10: VTAB 5: PRINT "MOLALITY AND MOLECULAR"
25 VTAB 6: HTAB 11: PRINT "WEIGHT DETERMINATION"
30 PRINT : PRINT
50 PRINT "ENTER THE NUMBER OF THE TYPE OF PROBLEM": PRINT "YOU DESIRE
60 PRINT : PRINT " 1) DRILL PROBLEMS"
70 PRINT " 2) SOLVE LAB DATA FOR MOLECULAR WIGHT"
80 HTAB 10: PRINT " ": INPUT T
90 IF T = 1 THEN 5000
100 IF T < >2 THEN GOTO 10
110 GOTO 9000
5000 CALL -936
5005 SPEED= 125
5010 PRINT "WHEN A SUBSTANCE IS DISSOLVED IN A "
5015 PRINT "SOLVENT, IT ALTERS THE SOLVENT-SOLVENT": PRINT "BOND STRUCTURE AND CAN AFFECT THE "
5020 PRINT "PHYSICAL PROPERTIES OF THE SOLVENT.": PRINT "DUE TO SOLVENT-SOLUTE BOND FORMATION,": PRINT "THE VAPOR PRESSURE OF THE SOLVENT IS"
5030 PRINT "LOWERED... HENCE, THE TEMPERATURE": PRINT "REQUIRED TO BOIL THE SOLUTION IS HIGHER"
5040 PRINT "THAN THAT REQUIRED FOR THE PURE SOLVENT.": PRINT "THIS EFFECT IS CALLED BOILING POINT"
5050 PRINT "ELEVATION."
5060 PRINT : PRINT : PRINT "SOLVENT BONDS ALSO AFFECT THE FORMATION"
5070 PRINT "OF CRYSTALS AND THE TEMPERATURE OF THE": PRINT "SOLUTION MUST BE LOWERED SO IT CAN"
5080 PRINT "SOLIDIFY. THIS EFFECT IS CALLED ": PRINT "FREEZING POINT DEPRESSION."
5090 PRINT : PRINT "THE AMOUNT OF ELEVATION (OR DEPRESSION)": PRINT "IN TEMPERATURE IS DIRECTLY RELATED TO"
5100 PRINT "THE NUMBER OF PARTICLES DISSOLVED IN": PRINT "THE SOLUTE."
5130 PRINT : INPUT "DEPRESS RETURN TO CONTINUE";A$
5140 CALL -936
5150 PRINT "HERE ARE SOME TERMS YOU NEED TO KNOW:"
5155 PRINT : PRINT
5160 PRINT "MOLALITY=MOLES SOLUTE/1000 GRAMS SOLVENT"
5170 PRINT "TEMP DEPRESSION = K(FP) X MOLALITY"
5175 PRINT
5180 PRINT "TEMP ELEVATION = K(BP) X MOLALITY"
5181 PRINT : PRINT : PRINT "YOU MAY ASSUME THAT ALL SOLUTES ARE": PRINT "NON-ELECTROLYTES AND DO NOT IONIZE": PRINT "IN SOLUTION."
5185 FOR IT = 1 TO 3000: NEXT IT
5187 INPUT "PRESS RETURN TO CONTINUE";A$
5190 CALL -936: PRINT "IN THIS SECTION, THE COMPUTER WILL "
5200 PRINT "GENERATE DIFFERENT PROBLEMS FOR YOU.": PRINT "YOU ARE TO TAKE THE GIVEN INFORMATION"
5210 PRINT "AND COMPUTE THE MOLECULAR WEIGHT OF ": PRINT "AN UNKNOWN COMPOUND. IF YOU ARE"
5220 PRINT "INCORRECT, THE COMPUTER WILL GIVE YOU"
5222 PRINT "HELL-OOPS!": VTAB 7: PRINT "ASSISTANCE IN GETTING TO THE ": PRINT "RIGHT";
5230 PRINT " ANSWER."
5240 PRINT : PRINT : HTAB 10: SPEED= 255: FLASH : PRINT "GOOD LUCK !!!"
5245 NORMAL : PRINT : PRINT : INPUT "DEPRESS RETURN TO GET GOING.";A$
5499 REM DIM STATEMENTS IN LINE 5
5500 FOR I = 1 TO 5
5509 REM SV=SOLVENT NAME FP=F.POINT,BP=B.POINT,KB & KF = CONSTANTS
5510 READ SV$(I),FP(I),BP(I),KB(I),KF(I)
5520 NEXT I
5525 RESTORE
5530 J = INT(5 * RND(1) +1)
5540 T = INT(2 * RND(1) +1): IF T/2 = INT(T/2) THEN P$ = "F.P. DEPRESSION": GOTO 5550
5545 P$ = "B.P. ELEVATION"
5550 MS = INT(100 * RND(1) +1):MX = RND(1) + INT(10 * RND(1) +1)
5555 MS = INT(1000 *MS)/1000:MX = INT(1000 *MX)/1000
5570 IF LEFT$(P$,1) = "F" THEN K = KF(J): GOTO 5580
5575 K = KB(J)
5580 IF LEFT$(P$,1) = "F" THEN R$ = "FREEZES": GOTO 5585
5583 R$ = "BOILS"
5585 T = RND(1) + INT(9 * RND(1) +1):Y = T
5586 Y = INT(Y *1000)/1000
5588 T = FP(J) -T
5590 GOTO 7000
6000 REM SOLUTE DATA
6004 REM NAME OF SOLUTE,FP,BP,KB,KF
6005 DATA "WATER",0,100,0.512,1.86
6010 DATA "ACETIC ACID",16.6,118.1,3.07,3.9
6015 DATA "BENZENE",5.48,80.1,2.53,5.12
6020 DATA "CHLOROFORM",-63.5,61.26,3.63,4.68
6025 DATA "NITROBENZENE",5.67,210.9,5.24,8.1
7000 REM PROBLEM PRINTING
7010 CALL -936
7015 T = INT(T *1000)/1000
7020 PRINT "A NON-ELECTROLYTE,X, IS DISSOLVED IN ";MS: PRINT "GRAMS OF ";SV$(J);". THE FOLLOWING"
7030 PRINT "DATA IS OBTAINED:"
7040 PRINT "F.POINT OF ";SV$(J);":";FP(J)
7050 PRINT "B.POINT OF ";SV$(J);":";BP(J)
7070 PRINT P$;" CONSTANT FOR ": PRINT SV$(J);" = ";K;" DEG. C/MOLAL"
7080 PRINT : PRINT "IF ";MX;" GRAMS OF X ARE DISSOLVED IN": PRINT MS;" GRAMS OF ";SV$(J)"."
7090 PRINT "THE TEMPERATURE AT WHICH THE SOLUTION": PRINT R$;" IS ";T;" DEGREES": PRINT "CENTIGRADE."
7120 PRINT : INPUT "WHAT IS THE MOLECULAR WEIGHT OF X ";A
7130 M = MX/MS *1000/(Y/K):M = INT(1000 *M)/1000: IF ABS(M -A) <.1 THEN PRINT "CORRECT": GOTO 8000
7140 PRINT "WRONG.": INPUT "NEED HELP (YES/NO) ";Q$
7150 IF LEFT$(Q$,1) = "Y" THEN 7500
7160 INPUT " TRY SAME PROBLEM AGAIN (YES/NO) ";Q$
7170 IF Q$ = "NO" THEN 8000
7175 GOTO 7000
7500 REM HELP SECTION
7505 CALL -936
7510 PRINT "DID YOU COMPUTE A TEMP CHANGE OF ";Y
7512 INPUT "YES/NO";Q$: IF Q$ = "NO" THEN 7160
7515 M1 = INT(1000 *Y/K)/1000
7520 PRINT "DID YOU COMPUTE A MOLALITY OF ";M1
7525 INPUT "YES/NO";Q$: IF Q$ = "NO" THEN 7160
7527 M2 = MX *1000/MS:M2 = INT(1000 *M2)/1000
7530 PRINT "DID YOU COMPUTE A 1000 GRAM SOLUTION OF ";M2;" GRAMS OF X"
7535 INPUT "YES/NO";Q$: IF Q$ = "NO" THEN 7160
7540 PRINT : PRINT "YOU HAVE ALL THE RIGHT NUMBERS!! GIVE IT ANOTHER SHOT."
7545 INPUT "DEPRESS RETURN TO GO BACK ";Q$: GOTO 7010
8000 INPUT "TRY ANOTHER PROBLEM (YES/NO)";Q$
8010 IF Q$ = "YES" THEN 5530
8020 PRINT "THE ANSWER TO THE LAST PROBLEM WAS ": PRINT M" GRAMS/MOLE."
8030 END
9000 REM COMPUTATION OF LAB DATA
9010 CALL -936
9020 PRINT "THE COMPUTER WILL ASK YOU FOR A LOT OF": PRINT "DATA.......HERE WE GO."
9030 PRINT : INPUT "NAME OF SOLVENT (THE LIQUID)";A$
9040 INPUT "NAME OF SOLUTE (ENTER X IF UNKNOWN) ";X$
9050 PRINT "AMOUNT OF ";A$;" USED TO DISSOLVE ";X$;: INPUT MS
9060 PRINT "AMOUNT OF ";X$;" DISSOLVED IN ";" GRAMS OF ";A$;: INPUT MX
9070 PRINT "TEMPERATURE DEPRESSION WAS ": INPUT TD
9080 PRINT "MOLAL CONSTANT FOR THE SOLVENT ";A$;" IS ";: INPUT K
9090 PRINT : PRINT "MOLALITY OF YOUR SOLUTION IS ";TD/K
9100 PRINT "THE SOLUTION = ";MX/MS *1000;" GRAMS OF ";X$;" PER 1000 GRAMS OF ";A$
9120 PRINT : PRINT "HENCE, ";MX/MS *1000;" GRAMS ";X$;" = ";TD/K;" MOLES"
9130 PRINT TAB( 10);"OR:"
9140 PRINT "MOL. WT OF ";X$;" = ";(MX/MS *1000)/(TD/K);" GRAMS/MOLE"
9150 INPUT "DEPRESS RETURN TO RETURN TO BEGINNING OF PROGRAM.";Q$
9160 GOTO 10

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/MOLE.bas:

1 REM J MOLECULAR WEIGHTS AND VOLUMES
2 REM WRITTEN BY CAMERON BROWN :REM BROWN COMPUTER SERVICES:REM 1901 NORTH JUNETT:REM TACOMA WA 98406 (206) 752-0094
7 CALL -936
10 REM GREETING PROGRAM FOR STEP BY STEP LESSONS.
15 DIM A$(20),N$(20),S$(20),W(20),D(20)
20 FOR I = 1 TO 20
30 READ A$(I),N$(I),S$(I),W(I),D(I)
40 NEXT I
45 GOSUB 3000
50 I = INT( RND(1) *20 +1)
60 G = RND(1) *100
70 G = INT(G *100)/100
80 GOSUB 1500
90 N = 1
100 ON N GOSUB 1550,1600,1650
110 INPUT "---ANSWER ";A
130 IF ABS(C -A) <.02 THEN Q$ = "CORRECT": GOTO 150
140 Q$ = "WRONG"
150 PRINT Q$: FOR X = 1 TO 750: NEXT X
160 IF Q$ = "WRONG" THEN GOSUB 2500
170 N = N +1
180 IF N < = 3 THEN GOTO 100
190 REM MOLES-- 200 M = RND(1) *2.5
210 CALL -936: PRINT TAB( 10);"CONVERSION CHART FOR CALC ULATIONS"
220 I = INT( RND(1) *20 +1)
230 REM VALUES
240 N = 1
250 ON N GOSUB 1800,1850,1900
260 PRINT "? ANSWER";
270 INPUT A
280 IF ABS(C -A) <.02 THEN Q$ = "CORRECT": GOTO 300
290 Q$ = "WRONG"
300 PRINT Q$: FOR X = 1 TO 750: NEXT X
310 PRINT : PRINT : PRINT "DEPRESS RETURN TO CONTINUE ";: INPUT Q$
320 N = N +1
330 IF N < = 3 THEN GOTO 250
340 CALL -936: PRINT : PRINT : PRINT : PRINT "THAT'S ALL. THANKS FOR PRACTICING."
350 END
1500 REM PROBLEM DESCRIPTION
1505 CALL -936: PRINT G;" GRAMS OF ";A$(I);", ";N$(I): PRINT "ARE WEIGHED OUT."
1510 PRINT N$(I);" IS A ";S$(I): PRINT "WHOSE DENSITY IS ";D(I);" ";
1515 IF S$(I) = "GAS" THEN PRINT "GRAMS/LITER.": GOTO 1525
1520 PRINT "GRAMS/ML."
1525 RETURN
1550 PRINT : PRINT "HOW MANY MOLES IS ";G;" GRAMS OF ";A$(I)
1555 C = G/W(I)
1560 RETURN
1599 END
1600 GOSUB 1500
1605 PRINT : PRINT "HOW MANY MOLECULES ARE IN "; INT(G/W(I) *1000)/1000;" MOLES OF ": PRINT A$(I)
1607 PRINT "DIVIDE YOUR ANSWER BY 10^23 BEFORE ENTERING IT."
1610 C = G/W(I) *6.023
1615 RETURN
1650 GOSUB 1500
1655 IF S$(I) = "GAS" THEN V$ = "LITERS": GOTO 1660
1657 V$ = "ML"
1660 PRINT : PRINT "HOW MANY ";V$;" IS ";G;" GRAMS OF ";A$(I)
1665 C = G/D(I)
1670 RETURN
1800 GOSUB 2000
1805 PRINT "HOW MANY GRAMS OF ";A$(I);" ARE NEEDED";
1810 C = M *W(I)
1815 RETURN
1849 END
1850 GOSUB 2000
1860 PRINT "HOW MANY ";V$;" OF ";A$(I);" ARE NEEDED"
1870 C = M *W(I)/D(I)
1875 IF V$ = "GAS" THEN C = M *22.4
1880 RETURN
1899 END
1900 GOSUB 2000
1910 PRINT "HOW MANY MOLECULES OF ";A$(I): PRINT "WILL BE USED IN THIS REACTION?"
1920 PRINT "DIVIDE YOUR ANSWER BY 10^23 BEFORE ": PRINT "ENTERING IT."
1940 C = M *6.023
1950 RETURN
1999 END
2000 CALL -936: PRINT M;" MOLES OF ";A$(I);", ";N$(I);", ARE TO BE USED IN "
2010 PRINT "A REACTION. ";N$(I);" IS A ";S$(I);" WHOSE DENSITY"
2020 PRINT "IS ";D(I);
2030 IF S$(I) = "GAS" THEN V$ = "LITERS": GOTO 2040
2035 V$ = "ML"
2040 PRINT " GRAMS/";V$
2050 PRINT
2060 RETURN
2500 REM WRONG SECTION
2510 PRINT "NEED HELP? YES OR NO";
2520 INPUT A$
2530 IF A$ = "YES" THEN GOSUB 3200
2540 PRINT "SAME PROBLEM? YES OR NO";
2550 INPUT A$
2560 IF A$ = "YES" THEN GOTO 2600
2565 PRINT "CORRECT ANSWER IS ";C
2570 PRINT "NEW PROBLEM? YES OR NO";
2580 INPUT A$
2590 IF A$ = "YES" THEN GOTO 50
2600 GOSUB 1500
2610 N = N -1
2620 RETURN
3000 CALL -936: PRINT TAB( 5);"THE MOLE-A CHEMIST'S DOZEN"
3010 PRINT : PRINT " THE MOLE IS A UNIT OF QUANITY.": PRINT "IT STANDS FOR ";
3020 PRINT "A SPECIFIC NUMBER OF ATOMS,OR MOLECULES. ONE MOLE ";
3030 PRINT "OF ANY SUBSTANCE CONSISTS OF 6.023 X10^23 PARTICLES."
3040 PRINT "A MOLE DOES NOT IMPLY A SPECIFIC VOLUME OR MASS. THE ";
3050 PRINT "VOLUME IS RELATED TO THE OBJECT'S DENSITY, AND THE MASS "
3060 PRINT "DEPENDS UPON THE MAKEUP OF THE MOLECULE."
3070 PRINT : PRINT "FROM THE FORMULA OF A COMPOUND ONE CAN COMPUTE ITS MOLECULAR WEIGHT AND WITH "
3080 PRINT "THAT INFORMATION MANY OTHER VALUES CAN BE COMPUTED."
3100 PRINT : PRINT "DEPRESS RETURN TO CONTINUE";: INPUT Q$
3200 REM CONVERSION CHART
3210 CALL -936: PRINT TAB( 5);"CONVERSION CHART FOR CALCULATIONS"
3215 F$ = "TO GO FROM ":T$ = " TO ":M$ = "MOLES ":G$ = "GRAMS "
3230 PRINT F$;G$;T$;M$: INVERSE : PRINT "DIV. BY MOL. WT.": NORMAL
3240 PRINT F$;"LITERS OF GAS"; TAB( 24);T$;"MOLES": INVERSE : PRINT "DIV. BY 22.4 (AT STP)": NORMAL
3250 PRINT F$;"MOLECULES";T$;M$: INVERSE : PRINT "DIV. BY 6.023 X 10^23": NORMAL
3255 PRINT F$;"LITERS OF GAS";T$;G$: INVERSE : PRINT " X DENSITY": NORMAL
3260 PRINT F$;"ML OF LIQUID";T$;G$: INVERSE : PRINT " X DENSITY": NORMAL
3270 PRINT F$;M$;T$;G$: INVERSE : PRINT " X MOL. WT.": NORMAL
3280 PRINT F$;M$;T$;"MOLECULES": INVERSE : PRINT " X 6.023 X 10^23": NORMAL
3290 PRINT F$;M$;T$;"LITERS OF GAS": INVERSE : PRINT " X 22.4 (AT STP)": NORMAL
3300 PRINT F$;M$;T$;"ML OF LIQUID": INVERSE : PRINT " X MOL. WT. THEN DIV. BY DENSITY": NORMAL
3310 PRINT : PRINT : PRINT "DEPRESS RETURN TO CONTINUE";: INPUT Q$
3320 CALL -936
3330 PRINT "TO COMPUTE THE MOLECULAR WEIGHT OF A "
3335 PRINT "COMPOUND, ALL YOU HAVE TO DO IS ADD ": PRINT "UP THE ATOMIC WEIGHTS OF ALL THE ATOMS": PRINT "IN THE COMPOUND. THE ANSWER YOU GET IS"
3340 PRINT "THE MASS OF A SINGLE MOLECULE (IN AMU'S)": PRINT "OR THE MASS OF A MOLE OF MOLECULES IN "
3350 PRINT "GRAMS.": PRINT : PRINT
3360 PRINT "ALL ANSWERS ARE TO BE COMPUTED TO THE ": PRINT "NEAREST .01 OR ELSE THEY ARE COUNTED ": PRINT "WRONG.": PRINT
3400 PRINT : PRINT "DEPRESS RETURN TO RETURN TO MAIN PROGRAM.";: INPUT Q$
3410 RETURN
5000 REM DATA LIST - FORMULA, NAME, STATE, M.W., DENSITY(G/L-G/ML)
5010 DATA "BR2","BROMINE","LIQUID", 159.83, 2.928
5020 DATA "NAF","SODIUM FLUORIDE","SOLID", 42.00, 2.79
5030 DATA "H20","WATER","LIQUID", 18.00, 1.00
5040 DATA "FECL3","FERRIC CHLORIDE","SOLID", 162.22, 1.93
5050 DATA "CASO4","CALCIUM SULFATE","SOLID", 136.15, 2.96
5060 DATA "NH3","AMMONIA","GAS", 17.03, .7710
5070 DATA "O2","OXYGEN","GAS", 32.00, 1.429
5080 DATA "K2CO3","POTASSIUM CARBONATE","SOLID", 138.2,2.428
5090 DATA "CO2","CARBON DIOXIDE", "GAS", 44.01, 1.977
5100 DATA "C2H5OH","ETHYL ALCOHOL","LIQUID", 46.07,.7893
5110 DATA "(C2H5)2O", "DIETHYL ETHER","LIQUID", 74.12,.7135
5120 DATA "C6H6","BENZENE","LIQUID",78.11,.8790
5130 DATA "H2","HYDROGEN","GAS", 2.00, .0899
5140 DATA "N2H4","HYDRAZINE","LIQUID",32.05,1.011
5150 DATA "CRO3","CHROMIUM TRIOXIDE","SOLID",100.01,2.70
5160 DATA "BI2S3","BISMUTH TRISULFIDE","SOLID",514.2,7.39
5170 DATA "NH4I","AMMONIUM IODIDE","SOLID",144.96, 2.514
5180 DATA "LICL:H2O","LITHIUM CHLORIDE","SOLID",60.41,1.78
5190 DATA "PBI2","LEAD IODIDE","SOLID",461.05,6.16
5200 DATA "PF3","PHOSPHORUS TRIFLUORIDE","GAS",87.98,3.907
5210 REM TO ALTER LISTING THEN BE SURE TO CHANGE READ
5220 REM STATEMENT ON LINE 20 AND RND(0)*X TO HIGHER
5230 REM VALUES

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/MOLECULES OF C H O.bas:

98 DIM CP(15,2),OP(6,2),HP(34,2)
99 DIM C(15,4),O(6,2)
100 TEXT : CALL -936
102 VTAB 5: PRINT TAB( 8);"MOLECULES OF CARBON"
104 VTAB 10
110 PRINT "THIS PROGRAM WILL DRAW A MOLECULE": PRINT "FOR A GIVEN MOLECULAR FORMULA."
111 PRINT : PRINT : PRINT
112 PRINT "ENTER A MOLECULAR FORMULA": PRINT "IN THE FORM 'C,H,O' , WHERE"
113 PRINT " 'C' = THE NUMBER OF CARBON ATOMS": PRINT "IN THE MOLECULE, ETC."
114 INPUT NC,NH,NO:NC = INT(NC):NH = INT(NH):NO = INT(NO)
115 IF NC <1 OR NH <2 OR NO <0 OR NC >15 OR NO >6 THEN PRINT CHR$(7): PRINT "IMPROPER DATA.": PRINT "C MUST BE >= 0 AND < 16": PRINT "H MUST BE EVEN, >=2 AND < 2*C+2": PRINT "O MUST BE >=0 AND < 7": PRINT : GOTO 112
119 IF INT(NH/2) = NH/2 AND NH < = 2 *NC +2 THEN 142
120 GOTO 115
142 EU = ((2 *NC +2) -NH)/2
144 FOR I = 1 TO NC: FOR J = 1 TO 4:C(I,J) = 0: NEXT J,I
146 FOR I = 1 TO NO: FOR J = 1 TO 2:O(I,J) = 0: NEXT J,I
148 HU = 0:OU = 0:UN = 0
150 IF NC = 1 THEN 200
155 C(1,1) = 2:C(2,1) = 1: IF NC = 2 THEN 200
160 FOR I = 3 TO NC
165 X = INT( RND(1) *(I -1)) +1
170 IF C(X,2) = 0 THEN C(I,1) = X:C(X,2) = I: GOTO 190
175 IF C(X,3) = 0 THEN C(I,1) = X:C(X,3) = I: GOTO 190
180 IF C(X,4) = 0 THEN C(I,1) = X:C(X,4) = I: GOTO 190
185 GOTO 165
190 NEXT I
200 IF NO = 0 THEN 240
205 FOR I = 1 TO NO
210 X = INT( RND(1) *(NC +I -1)) +1
215 IF X < = NC THEN 220: IF O( ABS(X -NC),2) = 0 THEN O(X -NC,2) = -I:O(I,1) = -(X -NC): GOTO 235
220 IF X < = NC THEN 225: IF O( ABS(X -NC),2) < >0 THEN 210
225 IF C(X,2) = 0 THEN C(X,2) = -I:O(I,1) = X: GOTO 235
230 IF C(X,3) = 0 THEN C(X,3) = -I:O(I,1) = X: GOTO 235
232 IF C(X,4) = 0 THEN C(X,4) = -I:O(I,1) = X: GOTO 235
234 GOTO 210
235 NEXT I
240 IF UN = EU THEN 280
242 IF NC = 1 THEN 255
245 GOSUB 600
250 IF C(X1,X2) = 0 AND C(Y1,Y2) = 0 THEN C(X1,X2) = Y1:C(Y1,Y2) = X1:UN = UN +1: IF UN = EU THEN 280
255 IF NO = 0 THEN 245
260 GOSUB 610
265 IF C(X1,X2) = 0 AND O(Y1,2) = 0 THEN C(X1,X2) = -Y1:O(Y1,2) = X1:UN = UN +1: GOTO 240
267 IF NO = 1 THEN 240
270 GOSUB 620
275 IF O(X1,2) = 0 AND O(Y1,2) = 0 THEN O(X1,2) = -Y1:O(Y1,2) = -X1:UN = UN +1: GOTO 240
280 IF NC = 1 THEN C(1,1) = -101:HU = HU +1
282 FOR I = 1 TO NC: FOR J = 2 TO 4
285 IF C(I,J) = 0 THEN C(I,J) = -(101 +HU):HU = HU +1
290 NEXT J,I
295 IF NO = 0 THEN 300
296 FOR I = 1 TO NO: IF O(I,2) = 0 THEN O(I,2) = -(101 +HU):HU = HU +1
297 NEXT I
299 IF NH < >HU THEN 144
300 GOSUB 800
302 GOSUB 2500
306 PRINT "HIT 'D' TO DRAW THIS DIFFERENTLY"
308 PRINT "HIT 'I' FOR A NEW ISOMER (SAME FORMULA)"
310 PRINT "HIT 'F' FOR A NEW MOLECULAR FORMULA"
320 KK = PEEK( -16384): IF KK <128 THEN 320
330 POKE -16368,0
340 IF KK = 196 THEN 300
350 IF KK = 201 THEN 144
360 IF KK = 198 THEN 100
370 END
600 X1 = INT( RND(1) *NC) +1:Y1 = INT( RND(1) *NC) +1: IF X1 = Y1 THEN 600
605 X2 = INT( RND(1) *3) +2:Y2 = INT( RND(1) *3) +2: RETURN
610 X1 = INT( RND(1) *NC) +1:Y1 = INT( RND(1) *NO) +1
615 X2 = INT( RND(1) *3) +2: RETURN
620 X1 = INT( RND(1) *NO) +1:Y1 = INT( RND(1) *NO) +1: IF X1 = Y1 THEN 620: RETURN
800 FOR I = 1 TO NC: FOR J = 0 TO 2:CP(I,J) = 0: NEXT J,I
810 IF NO < >0 THEN FOR I = 1 TO NO: FOR J = 0 TO 2:OP(I,J) = 0: NEXT J,I
820 FF = 0:CP(1,1) = 120:CP(1,2) = 75
830 FOR II = 1 TO NC: IF CP(II,0) = 0 THEN 850
840 NEXT II: GOTO 1020
850 FOR I = II TO NC: IF CP(I,0) = 1 OR CP(I,1) = 0 THEN 1010
870 XX = INT( RND(1) *4): FOR J = 1 TO 4:KK = 0
890 IF XX = 0 THEN X = CP(I,1) +20:Y = CP(I,2)
900 IF XX = 1 THEN X = CP(I,1):Y = CP(I,2) -20
910 IF XX = 2 THEN X = CP(I,1) -20:Y = CP(I,2)
920 IF XX = 3 THEN X = CP(I,1):Y = CP(I,2) +20
930 XX = XX +1: IF XX = 4 THEN XX = 0
940 IF C(I,J) < -100 THEN HP( ABS(C(I,J) +100),1) = ((X -CP(I,1)) *7/20) +CP(I,1):HP( ABS(C(I,J) +100),2) = ((Y -CP(I,2)) *7/20) +CP(I,2): GOTO 1000
942 TX = X:TY = Y:FF = 0: GOSUB 2000: IF FF = -1 AND KK <3 THEN KK = KK +1: GOTO 890
944 IF FF = -1 AND KK >2 THEN 800
945 IF NO = 0 THEN 960
947 IF C(I,J) >0 THEN 970
950 IF C(I,J) <0 AND C(I,J) > -100 AND OP( ABS(C(I,J)),1) >0 THEN 1000
960 IF C(I,J) <0 AND C(I,J) > -100 THEN OP( ABS(C(I,J)),1) = X:OP( ABS(C(I,J)),2) = Y: GOTO 1000
970 IF CP(C(I,J),1) >0 THEN 1000
980 CP(C(I,J),1) = X:CP(C(I,J),2) = Y
1000 NEXT J:CP(I,0) = 1
1010 NEXT I: GOTO 830
1020 IF NO = 0 THEN 1080
1030 FOR I = 1 TO NO: IF OP(I,1) >0 THEN 1064
1040 FOR J = 1 TO NO: IF J = I THEN 1060
1050 IF O(J,1) = -I THEN OP(I,1) = OP(J,1):OP(I,2) = OP(J,2) +20:TX = OP(I,1):TY = OP(I,2):FF = 1: GOSUB 2000: IF FF = -1 THEN 800
1060 NEXT J
1064 IF O(I,1) < -100 THEN HP( ABS(O(I,1) +100),1) = OP(I,1) +7:HP( ABS(O(I,1) +100),2) = OP(I,2)
1066 IF O(I,2) < -100 THEN HP( ABS(O(I,2) +100),1) = OP(I,1) -7:HP( ABS(O(I,2) +100),2) = OP(I,2)
1070 NEXT I
1080 RETURN
2000 FOR K = 1 TO NC: IF K = C(I,J) AND FF = 0 THEN 2020
2010 IF TX = CP(K,1) AND TY = CP(K,2) THEN FF = -1: GOTO 2060
2020 NEXT K: IF NO = 0 THEN 2060
2030 FOR K = 1 TO NO: IF K = ABS(C(I,J)) AND FF = 0 THEN 2050
2035 IF K = I AND FF = 1 THEN 2050
2040 IF TX = OP(K,1) AND TY = OP(K,2) THEN FF = -1: GOTO 2060
2050 NEXT K
2060 RETURN
2500 HGR : CALL -936: VTAB 21: HCOLOR= 3
2510 FOR I = 1 TO NC: FOR J = 1 TO 4
2520 IF C(I,J) < -100 THEN HPLOT CP(I,1),CP(I,2) TO HP( ABS(C(I,J) +100),1),HP( ABS(C(I,J) +100),2): GOTO 2670
2530 IF C(I,J) >0 THEN 2600
2535 FF = 0
2540 FOR K = 1 TO 4: IF K = J THEN 2560
2550 IF C(I,K) = C(I,J) THEN FF = -1
2560 NEXT K
2570 HPLOT CP(I,1),CP(I,2) TO OP( ABS(C(I,J)),1),OP( ABS(C(I,J)),2)
2580 IF FF = -1 THEN HPLOT CP(I,1) +3,CP(I,2) +3 TO OP( ABS(C(I,J)),1) +3,OP( ABS(C(I,J)),2) +3
2590 GOTO 2670
2600 FF = 0: IF C(I,J) 0 THEN HPLOT CP(I,1) +3,CP(I,2) +3 TO CP(C(I,J),1) +3,CP(C(I,J),2) +3
2660 IF FF = 2 THEN HPLOT CP(I,1) -3,CP(I,2) -3 TO CP(C(I,J),1) -3,CP(C(I,J),2) -3
2670 NEXT J
2680 NEXT I
2700 IF NO = 0 THEN 2800
2710 FOR I = 1 TO NO: FOR J = 1 TO 2
2720 IF O(I,J) >0 THEN 2750
2730 IF O(I,J) < -100 THEN HPLOT OP(I,1),OP(I,2) TO HP( ABS(O(I,J) +100),1),HP( ABS(O(I,J) +100),2): GOTO 2750
2740 IF O(I,J) <0 THEN HPLOT OP(I,1),OP(I,2) TO OP( ABS(O(I,J)),1),OP( ABS(O(I,J)),2)
2750 NEXT J
2760 NEXT I
2800 HCOLOR= 1: FOR I = 1 TO NC
2810 X = CP(I,1):Y = CP(I,2): GOSUB 4000: NEXT I
2820 IF NO = 0 THEN 2850
2830 HCOLOR= 2: FOR I = 1 TO NO
2840 X = OP(I,1):Y = OP(I,2): GOSUB 4000: NEXT I
2850 HCOLOR= 3: FOR I = 1 TO NH
2860 X = HP(I,1):Y = HP(I,2): GOSUB 4500: NEXT I
2900 RETURN
4000 FOR L = -3 TO 3
4010 HPLOT X -3,Y +L TO X +3,Y +L
4020 NEXT L: RETURN
4500 FOR L = -1 TO 1
4510 HPLOT X -1,Y +L TO X +1,Y +L
4520 NEXT L: RETURN

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/MOLECULES OF CARBON.Y.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 2D 15 96 F2 3F 07 20 04 00 24 2D 2D 24 34 36 36 -..r?. . .$--$466
$000010 FE 1B 24 24 24 D7 E3 3F 17 36 36 0E 2D 05 20 00 ~.$$$Wc? .66.-. .
$000020 2D 2D 4D 62 AD F6 17 17 36 28 2D D5 DB C3 18 08 --Mb-v.. 6(-U[C..
$000030 18 24 24 24 DF 33 36 36 3E D8 1E 3F 07 20 24 64 .$$$_366 >X.?. $d
$000040 2D 15 06 00 2E 2D AD 09 0C AD 36 3F 2D 36 1E 3F -....--. .-6?-6.?
$000050 E0 D8 24 24 24 DF 33 36 36 3E D8 1E 3F 07 20 24 `X$$$_36 6>X.?. $
$000060 64 2D 15 06 00 24 24 24 24 3C 3F 3F 3F 3F 3F 2D d-...$$$ $ $000070 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 3E 3F 3F 3F 3F 3F -------- -->?????
$000080 3F 3F 3F 3F 3F 37 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D ?????7-- --------
$000090 2D 3E 3F 3F 3F 3F 3F 3F 3F 3F 3F 3F 37 2D 2D 2D ->?????? ????7---
$0000A0 2D 2D 2D 2D 2D 2D 2D 2D 3E 3F 3F 3F 3F 3F 3F 3F -------- >???????
$0000B0 3F 3F 3F 37 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 3E ???7---- ------->
$0000C0 3F 3F 3F 3F 3F 3F 3F 3F 3F 3F 37 2D 2D 2D 2D 2D ???????? ??7-----
$0000D0 2D 2D 2D 2D 2D 2D 3F 3F 3F 3F 3F 3F 3F 3F 3F 3F ------?? ????????
$0000E0 3F 37 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 3E 3F 3F ?7------ ----->??
$0000F0 3F 3F 3F 3F 3F 3F 3F 3F 37 2D 2D 2D 2D 2D 2D 2D ???????? 7-------
$000100 2D 2D 2D 2D 3E 3F 3F 3F 3F 3F 3F 3F 3F 3F 3F 37 ---->??? ???????7
$000110 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 2D 3E 3F 3F 3F 3F -------- --->????
$000120 3F 3F 3F 3F 3F 3F 07 00 32 D1 .. .. .. .. .. .. ??????.. 2Q
** END **

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/MOLECULES OF CARBON.int:

2 PRINT " BLOAD MOLECULES OF CARBON.X"
3 PRINT " BLOAD MOLECULES OF CARBON.Y"
5 POKE 204,4400 MOD 256: POKE 205,4400/256: POKE 74,4400 MOD 256: POKE 75,4400/256
10 GOTO 100
30 POKE 802,Y: POKE 800,X MOD 256
35 POKE 801,X/256:RETURN
40 POKE 804,X MOD 256: POKE 805,X/256:RETURN
100 DIM C(110)
110 TEXT :CALL -936:VTAB 5:TAB 8:PRINT "APPLE-CHEM II":PRINT
120 VTAB 10:PRINT "THIS PROGRAM WILL DRAW A MOLECULE":PRINT "FOR A GIVEN MOLECULAR FORMULA.":PRINT
130 VTAB 15:PRINT "ENTER A MOLECULAR FORMULA":PRINT "IN THE FORM'C,H' ,WHERE"
140 PRINT "'C' = THE NUMBER OF CARBON ATOMS":PRINT "IN THE MOLECULE, ETC."
150 INPUT NC,NH
152 NF=0
155 IF NC#-100 THEN 160:NC= RND (7)+2:NH=((2*NC)/2)*2
157 NF=1:CALL -936:VTAB 22:PRINT "C-";NC;",H-";NH:GOTO 180
160 IF NC>1 AND NC<16 AND NH>-1 AND NH<=2*NC+2 AND (NH/2=NH-NH/2) THEN 180
170 PRINT :PRINT "IMPROPER DATA!":PRINT "C MUST BE >=2 AND <16":PRINT "H MUST BE EVEN, >=0 AND <=2*C+2":GOTO 150
180 EU=((2*NC+2)-NH)/2
190 FOR I=0 TO NC*7:C(I)=0:NEXT I
200 C(0)=2:C(7)=1:IF NC=2 THEN 300
210 FOR I=3 TO NC
220 X= RND (I-1)+1
230 IF C((X-1)*7+1)#0 THEN 250
240 C((I-1)*7)=X:C((X-1)*7+1)=I:GOTO 290
250 IF C((X-1)*7+2)#0 THEN 270
260 C((I-1)*7)=X:C((X-1)*7+2)=I:GOTO 290
270 IF C((X-1)*7+3)#0 THEN 290
280 C((I-1)*7)=X:C((X-1)*7+3)=I
290 NEXT I
300 IF EU=0 THEN 410
310 FOR K=1 TO EU
320 X= RND (NC)+1:Y= RND (NC)+1:IF X=Y THEN 320
330 FOR I=1 TO 3:IF C((X-1)*7+I)#0 THEN 350
340 X1=I:GOTO 360
350 NEXT I:GOTO 320
360 FOR I=1 TO 3:IF C((Y-1)*7+I)#0 THEN 380
370 Y1=I:GOTO 390
380 NEXT I:GOTO 320
390 C((X-1)*7+X1)=Y:C((Y-1)*7+Y1)=X
400 NEXT K
410 FOR I=4 TO (NC-1)*7+4 STEP 7:FOR J=0 TO 2
420 C(I+J)=0:NEXT J:NEXT I
430 GOSUB 1000:GOSUB 2000
435 CALL -936:VTAB 22
437 IF NF#1 THEN 440:NC=-100:GOTO 155
440 PRINT "HIT 'D' TO DRAW THIS DIFFERENTLY"
450 PRINT "HIT 'I' FOR A NEW ISOMER (SAME FORMULA)"
460 PRINT "HIT 'F' FOR A NEW MOLECULAR FORMULA"
470 KEY= PEEK (-16384):IF KEY<128 THEN 470
480 POKE -16368,0
490 IF KEY=196 THEN 410:IF KEY=201 THEN 190:IF KEY=198 THEN 110
500 END
1000 C(5)=120:C(6)=75
1010 FOR K=1 TO NC:IF C((K-1)*7+4)=0 AND C((K-1)*7+5)#0 THEN 1030
1020 NEXT K:GOTO 1090
1030 FOR I=0 TO 3:J=(K-1)*7+I:IF C(J)=0 THEN 1080
1040 IF C((C(J)-1)*7+5)#0 THEN 1080
1050 GOSUB 1500
1060 FLAG=0:GOSUB 1600:IF FLAG=1 THEN 1050
1070 C((C(J)-1)*7+5)=TX:C((C(J)-1)*7+6)=TY
1080 NEXT I:C((K-1)*7+4)=1:GOTO 1010
1090 RETURN
1500 TX=C((K-1)*7+5):TY=C((K-1)*7+6)
1510 A1=( RND (3)*30)-30:A2=( RND (3)*30)-30
1520 TX=TX+A1:TY=TY+A2
1530 IF TX<4 OR TX>264 OR TY<4 OR TY>152 THEN 1500
1540 RETURN
1600 FOR II=1 TO NC
1610 IF C((II-1)*7+5)=TX AND C((II-1)*7+6)=TY THEN 1630
1620 NEXT II:GOTO 1640
1630 FLAG=1
1640 RETURN
2000 CALL 3072: POKE 812,255: POKE 806,1: POKE 807,0
2010 S=3805:L=3786:P=3780: POKE 28,255
2020 FOR I=1 TO NC:FOR J=0 TO 3:IF C((I-1)*7+J)=0 THEN 2160
2030 FLAG=0:IF C((I-1)*7+J)

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/TEST MAKER.bas:

10 HOME : VTAB 10
20 DIM A$(300): DIM B$(300):I = 0
30 D$ = CHR$(4): REM CTRL D
40 PRINT
50 PRINT "THIS PROGRAM LETS YOU WRITE TEXT AS EITHER QUESTIONS/ANSWERS OR PLAIN TEXT. DO NOT EXCEED 239 CHARACTERS."
60 PRINT
70 I = I +1
80 PRINT "(PRESS THE RETURN KEY TO QUIT.)
90 FOR X = 1 TO 2000: NEXT X: HOME : VTAB 10: PRINT "PRINT QUESTION #";I;". ";
100 INPUT A$(I)
110 PRINT
120 INPUT "WHAT IS THE ANSWER ? ";B$(I)
130 IF A$(I) < >"" GOTO 60
140 INPUT "WHAT FILE NAME? ";N$
150 PRINT D$;"OPEN ";N$
160 PRINT D$;"WRITE ";N$
170 PRINT I -1
180 FOR J = 1 TO I -1
190 PRINT A$(J): PRINT B$(J)
200 NEXT J
210 PRINT D$;"CLOSE ";N$

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/TEST TAKER.bas:

10 REM *********************************
20 REM * *
30 REM * RETRIEVE TEST *
40 REM * BY ALBERT LAST *
50 REM * 8-15-80 *
60 REM * SAN ANDREAS, CA *
70 REM * *
80 REM *********************************
85 HOME
90 VTAB 10: PRINT "THIS PROGRAM WILL RANDOMLY QUIZ YOU ON THE PREVIOUSLY ENTERED TEST.": FOR Q = 1 TO 2000: NEXT Q
100 HOME : VTAB 10
110 D$ = CHR$(4): REM CTRL D
120 INPUT "NAME OF TEST FILE? ";Z$
140 PRINT
150 PRINT D$;"OPEN ";Z$
160 PRINT D$;"READ ";Z$
170 INPUT I
180 DIM A$(I): DIM B$(I)
190 DIM R$(I)
200 FOR J = 1 TO I
204 HOME : VTAB 10
210 INPUT A$(J): INPUT B$(J)
220 NEXT J
230 PRINT D$;"CLOSE ";Z$
250 N = I
260 J = 0
270 FOR S = 1 TO I
280 M = INT(I * RND(1) +1)
290 HOME
310 VTAB 4: HTAB 10: PRINT "Q U E S T I O N # ";S
320 VTAB 5: HTAB 10: PRINT "- - - - - - - -"
330 VTAB 10: HTAB 3
340 PRINT A$(M)
350 VTAB 15: HTAB 13: PRINT "A N S W E R"
360 VTAB 16: HTAB 13: PRINT "- - - - - -"
370 VTAB 19: HTAB 3
380 INPUT "-----> ";W$
390 IF W$ < >B$(M) THEN HOME : VTAB 10: HTAB 15: PRINT A$(M): VTAB 13: HTAB 5: PRINT "THE CORRECT ANSWER IS : ";B$(M): GOTO 430
400 IF W$ = B$(M) THEN HOME : VTAB 10: HTAB 13: PRINT "C O R R E C T": GOTO 430
410 HOME : VTAB 10: HTAB 7: PRINT "NOT CORRECT--TRY AGAIN": FOR X = 1 TO 1000: NEXT X: HOME
420 VTAB 10: GOTO 290
430 VTAB 24: HTAB 8: PRINT "(PUSH ANY KEY TO CONTINUE)": GET Q$
440 NEXT S
450 HOME : VTAB 10: INPUT "DO YOU WANT ANOTHER QUIZ ? (Y OR N) ";U$
460 IF U$ = "Y" THEN RESTORE : GOTO 270
470 IF U$ < >"N" THEN 450
480 HOME : VTAB 10: HTAB 12: PRINT "B Y E K I D S !!"
490 END

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/TEST.CHEM CH2.txt:

64
DEFINE MASS.
MASS IS THE AMOUNT OF MATTER IN THAT BODY.
DEFINE WEIGHT OF A BODY.
THE WEIGHT VARIES IN RELATION TO
WHAT IS THE UNIT OF LENGTH AND SYMBOL.
METRE M
WHAT IS THE UNIT OF MASS AND SYMBOL.
KILOGRAM KG
WHAT IS THE UNIT OF TIME AND SYMBOL.
SECOND S
WHAT IS THE UNIT OF ELECTRIC CURRENT AND SYMBOL.
AMPERE A
WHAT IS THE UNIT OF TEMPERATURE AND SYMBOL.
KELVIN K
WHAT IS THE UNIT OF LUMINOUS INTENSITY AND SYMBOL.
CANDELA CD
WHAT IS THE UNIT OF AMOUNT OF SUBSTANCE AND SYMBOL.
MOLE MOL
IN 1960
1
HOW LONG IS A METRE?
39.37"
KILOMETRE ABBREV.AND METRE EQUIV.=
KM 10^3M
METRE ABBREV. AND METRE EQUIV.=
M 10^0M
DECIMETRE ABBREV. AND EQUIV.
DM 10^-1M
CENTIMETRE ABBREV. AND METRE EQUIV.
CM 10^-2M
MILLIMETRE ABBREV. AND METRE EQUIV.
MM 10^-3M
MICROMETRE ABBREV. AND METRE EQUIV.
UM 10^-6M
MICRON ABBREV. AND METRE EQUIV.
U 10^-6
NANOMETRE ABBREV. AND METRE EQUIV.
NM 10^-9
ANGSTROM ABBREV. AND METRE EQUIV.
O A 10^-10M
WHAT FACTOR IS USE TO CONVERT IN. TO FT.
IN.->FT. 1FT/12IN.
FACTOR FOR CONVERTING CM TO MM.
CM->MM 10MM/CM
WHAT FACTOR IS NEEDED TO CONVERT 2.5M TO MM.
M->MM 2.5M X 1000MM/M =2.5 X 1000=2500
HOW MANY CM ARE IN 2.00 FT.
FT->IN->CM 2FT X 12IN/FT X 2.54CM/IN=24 X 2.54CM=61.0CM
1 KILOGRAM(KG)=---LBS.
2.2 LBS.
1 LBS.= --- GRAMS(G)
454 G
CONVERT 25 G TO MG.
G->MG 25G X 1000/G=25 X 1000=2.5X10^4
HOW MANY GRAMS ARE IN A PACKAGE OF 1.50 LBS OF SODIUM BICAR.
LBS ->G 1.5LBS X 454G/LBS =1.5 X 454=681G
CONVERT 1.00 LBS TO MG.
LBS ->G ->MG 1LBS X 454G/LBS X 1000MG/G =4.54X10^5MG
IS A LITRE LARGER THAN A QUART?
YES
HOW MANY QUARTS DOES 1.000 LITRE EQUAL?
1.057
1 LITRE = ---ML
1000 ML
1 QT = --- ML?
946 ML = 1 QT.
HOW MANY MILILITRES ARE IN 3.5 LITRES?
L->ML 3.5L X 1000ML/L =3.5X10^3 ML
HOW MANY CUBIC CENTIMETRES ARE IN A CUBE 11.1 IN. ON A SIDE.
IN. ->CM ->CM^3 11.1 IN. X 2.54CM/IN.=28.2 CM ON EACH SIDE-- 28.2CM^3=2.24X10^4CM^3
1 ML= ---CM^3
1CM^3
NAME THE THREE COMMONLY USED TEMPERATURE SCALES (IN ALPHA ORDER).
CELSIUS FAHRENHEIT KELVIN
0 DEGREES C.= ---K.
273 DEG.K
0 DEG. C = ---F
32 DEG. F
273 DEG. K= ---F.
32 DEG. F.
WHAT IS THE UPPER LIMIT OF TEMPERATURE?
THERE IS NO UPPER LIMIT.(TEMPS OF SEVERAL THOUSAND DEG. HAVE BEEN REPORTED)
HOW MANY DEG. DIFFERENCE BETWEEN FREEZINF AND BOILING EXIST BETWEEN C-F-K
100 180 100
GIVE THE FORMULA TO CONVERT FROM CELSIUS TO KELVIN.
K=C+273
WHAT IS FORMULA TO CONVERT FROM CELSIUS TO FAHRENHEIT.
F=(1.8 X C)+32
GIVE THE FORMULA TO CONVERT FROM FAHRENHEIT TO CELSIUS.
C=(F-32)/1.8
SALT MELTS AT 800 DEG. C. WHAT IS THIS TEMP ON THE KELVIN AND FAHRENHEIT SCALE.
K=273+C=273+800=1073 DEG. K
WHAT IS THE TEMP IN F. WHEN TEMP IS 800 DEG. C.?
F=(1.8 X C)+32=(1.8 X 800)+32=1440+32=1472 DEG. F.
110 DEG. F.=---C.
C=(F-32)/1.8=(110-32)/1.8=78/1.8=43 DEG C.
DEFINE HEAT.
HEAT IS A FORM OF ENERGY ASSOCIATED WITH THE MOTION OF SMALL PARTICLES OF MATTER.
DEFINE TEMPERATURE.
TEMPERATURE IS A MEASURE OF THE INTENSITY OF HEAT(OR HOW HOT A SYSTEM IS.)
DEFINE CALORIE.
A CALORIE IS THE QUANITY OF HEAT REQUIRED TO CHANGE THE TEMP OF 1G WATER 1 DEG. C.
HOW MANY CALORIES IN 1 KILOCALORIE-KCAL.
1000
COMPLETE THE FOLLOWING
DEGREES CALORIES
DEFINE HEAT CAPACITY ALSO KNOWN AS SPECIFIC HEAT.
HEAT CAPACITY IS THE QUANTITY OF HEAT REQUIRED TO CHANGE THE TEMP. OF 1 G. OF THAT SUBSTANCE BY 1 DEG.C.
WHAT IS THE HEAT CAPACITY OF WATER?
1 CAL/G DEG.C.
DEFINE DENSITY.
DENSITY IS THE RATIOOF A SUBSTANCE TO THE VOLUME OCCUPIED BY THAT MASS.
GIVE THE DENSITY FORMULA.
D=MASS/VOLUME
DIRECT COMPARISON OF THE DINSITY COMPARED TO WATER IS CALLED?
IMMISCIBLE (DO NOT DISSOLVE IN ONE ANOTHER).
WHAT IS THE DENSITY OF AIR AT 0 DEG C.
1.293 G/LITRE
GASES LESS THAN 1.293 G/LITRE DENSITY ARE SAID TO BE
LIGHTER THAN AIR
IF AN OBJECT IS LESS DENSE THAN WATER IT WILL----
FLOAT
IF AN OBJECT IS MORE DENSE THAN WATER THEN THE OBJECT WILL ----.
SINK
DEFINE SPECIFIC GRAVITY.
SP GR IS A RATIO OF THE DENSITY OF THAT SUBSTANCE TO THE DENSITY OF ANOTHER.
WHAT IS THE NAME OF THE INSTRUMENT USED TO MEASURE THE SPECIFIC GRAVITY?
HYDROMETER

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/TEST.CHEM NAMES.txt:

28
NACL

NAME NACL?
SODIUM CLORIDE
NAME AGNO3?
SILVER NITRATE
NAME BACRO4?
BARIUM CHROMATE
NAME KOH?
POTASSIUM HYDROXIDE
NAME ZNSO4?
ZINC SULFATE
NAME MGBR2?
MAGNESIUM BROMIDE
NAME AL2O3?
ALUMINUM OXIDE
NAME CDCL2?
CADMIUM CLORIDE
NAME NH4I?
AMONIUM IODIDE
NAME FE(OH)3?
IRON III CLORIDE
NAME BA3(PO4)2?
BARIUM PHOSPHATE
NAME KCLO3?
POTASSIUM CHLORATE
NAME NA2CO3?
SODIUM CARBONATE
NAME (NH4)2C2O4?
AMONIUM OXALATE
NAME (NH4)2CO3?
AMMONIUM CARBONATE
NAME ZN(CLO3)2?
ZINC PERCLORATE
NAME CA(OH)2?
CALCIUM HYDROXIDE
NAME BASO3?
BARIUM SULFITE
NAME ALCL3?
ALUMINUM CLORIDE
NAME CU2CO3?
COPPER I CARBONATE
NAME NA2CR2O7?
SODIUM DICHROMATE
NAME FEO?
IRON II OXIDE
NAME AGC2H3O2?
SILVER ACETATE
NAME H3PO4 (AQ)?
PHOSPHORIC ACID
NAME CR2O3?
CHROMIUM OXIDE
NAME KBR?
POTASSIUM BROMIDE
NAME CD(HSO4)2?
CADMIUM HYDROGEN SULFATE

Text found in Volume_051_Chemistry_and_Biology_Programs.dsk/TEST.IONS.txt:

109
AMMONIUM
NH4+1
COPPER I
CU+1
CUPROUS
CU+1
HYDROGEN
H+1
POTASSIUM
K+1
SILVER
AG+1
SODIUM
NA+1
BARIUM
BA+2
CALCIUM
CA+2
COBALT II
CO+2
COPPER II
CU+2
CUPRIC
CU+2
IRON II
FE+2
FERROUS
FE+2
LEAD II
PB+2
MAGNESIUM
MG+2
MANGANESE
MN+2
MERCURY II
HG+2
MECURIC
HG+2
NICKEL II
NI+2
TIN II
SN+2
STANNOUS
SN+2
ZINC
ZN+2
ALUMINUM
AL+3
CHROMIUM III
CR+3
IRON III
FE+3
FERRIC
FE+3
MANGANESE IV
MN+4
TIN IV
SN+4
ACETATE
C2H3O2-1
BROMIDE
BR-1
CHLORATE
CLO3-1
CHLORIDE
CL-1
CYANIDE
CN-1
FLOURIDE
F-1
HYDRIDE
H-1
HYDROGEN CARBONATE
HCO3-1
BICARBONATE
HSO3-1
HYDROGEN SULFATE
HSO4-1
BISULFATE
HSO4-1
HYDROXIDE
OH-1
IODIDE
I-1
NITRATE
NO3-1
NITRITE
NO2-1
PERMANGANATE
MNO4-1
THIOCYANATE
SCN-1
CARBONATE
CO3-2
CHROMATE
CRO4-2
DICHROMATE
CR2O7-2
OXALATE
C2O4-2
OXIDE
O-2
SULFATE
SO4-2
SULFIDE
S-2
SULFITE
SO3-2
PHOSPHATE
PO4-3
NH4+1
AMMONIUM
CU+1
COPPER I
CU+1
CUPROUS
H+1
HYDROGEN
K+1
POTASSIUM
AG+1
SILVER
BA+2
BARIUM
CA+2
CALCIUM
CO+2
COBALT II
CU+2
COPPER II
CU+2
CUPRIC
FE+2
IRON II
FE+2
FERROUS
PB+2
LEAD II
MG+2
MAGNESIUM
MN+2
MANGANESE II
HG+2
MERCURY II
HG+2
MERCURIC
NI+2
NICKEL II
SN+2
TIN II
SN+2
STANNOUS
ZN+2
ZINC
AL+3
ALUMINUM
CR+3
CHROMIUM III
FE+3
IRON III
FE+3
FERRIC
MN+4
MANGANESE IV
SN+4
TIN IV
SN+4
STANNIC
C2H3O2-1
ACETATE
BR-1
BROMIDE
CLO3-1
CHLORATE
CL-1
CHLORIDE
CN-1
CYANIDE
F-1
FLUORIDE
HCO3-1
HYDROGEN CARBONATE
HCO3-1
BICARBONATE
HSO4-1
HYDROGEN SULFATE
HSO4-1
BISULFATE
OH-1
HYDROXIDE
I-1
IODIDE
NO3-1
NITRATE
NO2-1
NITRITE
MNO4-1
PERMANGANATE
SCN-1
THIOCYANATE
CO3-2
CARBONATE
CRO4-2
CHROMATE
CR2O7-2
DICHROMATE
C2O4-2
OXALATE
O-2
OXIDE
SO4-2
SULFATE
S-2
SULFIDE
SO3-2
SULFITE
PO4-3
PHOSPHATE